673
@verb #14:"@vw" any any any rdo #55
@program #14:"@vw" any any any
if (player != this)
  return $msg:mtell("huh")
endif
set_task_perms(player)
re = $regexp:new("^%([:;,.]*%)%(.*%)$")
"No non-greedy regexps available, so we'll just flip it around for the match, then flip it back :->"
re:exec($string_utils:reverse(argstr))
code = $string_utils:reverse(re._2)
query = re._1
w = player:eval_cmd_string(code)[2]
if (typeof(w) != WAIF)
  return player:tell("Not a waif!")
endif
all_verbs = index(query, ";")
all_props = index(query, ",")
verbs = index(query, ":")
props = index(query, ".")
if (all_verbs || all_props)
  d = {w.class, @w.class:ancestors()}
elseif (verbs || props)
  d = {w.class}
endif
o = {}
for x in (d)
  if (verbs || all_verbs)
    for v in [1..length(verbs(x))]
      {owner, perms, name} = verb_info(x, v)
      if (name[1] != ":")
        continue
      endif
      o = {@o, {tostr(x, w.class == x ? ":" | ";", name[2..$]), owner:nn(), perms}}
    endfor
  endif
  if (props || all_props)
    for p in (properties(x))
      if (p[1] != ":")
        continue
      endif
      {owner, perms} = property_info(x, p)
      o = {@o, {tostr(x, w.class == x ? "." | ",", p[2..$]), owner:nn(), perms, $html_utils:literal_text(toliteral(w.(p[2..$])))[1..min($, 80)]}}
    endfor
  endif
endfor
player:tellcolumns({1, 1, 1, 1}, {}, @o, "-")
"Last modified by manta (#7165) on Fri Dec  7 12:58:44 2001 MST."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:04 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:50:04 2002 MDT."
.

0