643
@verb #14:"@forked" any none none rdo #55
@program #14:"@forked" any none none
player:isa($guardian) || set_task_perms(player)
if (!dobjstr)
  tasks = queued_tasks()
elseif ($command_utils:player_match_result(dobj = $string_utils:match_player(dobjstr), dobjstr)[1])
  return
elseif ((tasks = `$wiz_utils:queued_tasks(dobj) ! E_PERM') == E_PERM)
  return player:tell(verb, " ", $string_utils:nn(dobj), ":  ", tasks)
endif
if (tasks)
  su = $string_utils
  player:tell("Queue ID    Start Time            Owner         Verb (Line) [This]")
  player:tell("--------    ----------            -----         ------------------")
  now = time()
  for task in (tasks)
    {q_id, start, x, y, owner, vloc, vname, lineno, this} = task
    if (vloc == $command_utils && vname in {"suspend_if_needed", "suspend_as"})
      {this, vname, quack, vloc, quack, lineno} = task_stack(q_id, 1)[2]
    endif
    if (start == $maxint)
      time = "Never"
    elseif (start == -1)
      time = "Reading input..."
    elseif (start == now)
      time = "Now"
    elseif (start < now)
      time = tostr(now - start, " seconds ago...")
    else
      time = $string_utils:from_seconds(start - now)
    endif
    time = su:left(time, 20)
    owner_name = valid(owner) ? owner.name | tostr("Dead ", owner)
    player:tell(su:left(tostr(q_id), 10), "  ", time, "  ", su:left(owner_name, 12), "  ", vloc, ":", vname, " (", lineno, ")", this != vloc ? tostr(" [", this, "]") | "")
  endfor
else
  player:tell("No tasks.")
endif
"Last modified by Dax (#789) on Fri Jul 10 21:11:02 1998 EDT."
.

0