658
@verb #14:"@check-chp*arent" any at/to any rdo #55
@program #14:"@check-chp*arent" any at/to any
"@check-chparent <object> to <newparent>"
"Checks for property name conflicts or -o verb conflics that would make @chparent bomb."
set_task_perms(player)
if (!(dobjstr && iobjstr))
  player:tell("Usage:  ", verb, " &lt;object&gt; to &lt;newparent&gt;")
elseif ($command_utils:object_match_failed(object = player:my_match_object(dobjstr), dobjstr))
  "...bogus object..."
elseif ($command_utils:object_match_failed(parent = player:my_match_object(iobjstr), iobjstr))
  "...bogus new parent..."
elseif (player != this)
  player:tell(E_PERM)
elseif (typeof(presult = object:property_conflicts(parent)) == $ERR)
  player:notify(tostr(presult))
elseif (typeof(vresult = object:overb_conflicts(parent)) == $ERR)
  player:notify(tostr(vresult))
else
  if (presult)
    data = {}
    for r in (presult)
      data = {@data, {tostr(parent, ".", r[1]), $string_utils:from_list(listdelete(r, 1), " ")}}
      $command_utils:suspend_if_needed()
    endfor
    player:tellColumns({1, 1}, {"Property", "Also Defined on"}, @data)
  else
    player:notify("No property conflicts found.")
  endif
  if (vresult)
    data = {}
    for r in (vresult)
      data = {@data, {tostr(parent, ":", r[1]), $string_utils:from_list(listdelete(r, 1), " ")}}
      $command_utils:suspend_if_needed()
    endfor
    player:tellColumns({1, 1}, {"-o Verb", "Also Defined on"}, @data)
  else
    player:notify("No -o verb conflicts found.")
  endif
endif
"Last modified by Dax (#789) on Tue May  3 13:45:56 2005 MDT."
.

0