7c8
@verb #13:"@thaw" any none none rdo #55
@program #13:"@thaw" any none none
"Copied from Generic player (#6):@thaw by manta (#7165) Sep 24 09:08:38 1997"
"Allows builders to thaw their objects."
if (this != player)
  return $msg:mtell("huh")
elseif ($command_utils:object_match_failed(dobj, dobjstr))
  return
elseif (!$perm_utils:controls(this, dobj) && !this:isa($guardian))
  return player:sub_tell("You have no permission to thaw %d (#%D~#).")
endif
expires = !(dobj:_get_solidified() || dobj:_get_petrified())
usesquota = !(dobj:_get_subsidised() || dobj:_get_petrified())
currentstatus = {"petrified", "subsidised", "solidifed", "unfrozen"}[expires + usesquota * 2 + 1]
newstatus = "unfrozen"
if (currentstatus == "unfrozen")
  return player:sub_tell("Because %d (#%D~#) is neither petrified, subsidised, nor solidified, it cannot be thawed.")
elseif (currentstatus == "petrified")
  if (!player:isa($guardian))
    if ($command_utils:yes_or_no(tostr($string_utils:nn(dobj), " is petrified; do you want it to remain subsidised?")))
      newstatus = "subsidised"
    endif
    if ($command_utils:yes_or_no(tostr($string_utils:nn(dobj), " is petrified; do you want it to remain solidified?")))
      if (newstatus == "subsidised")
        return player:sub_tell("%D (#%D~#) is still petrified.")
      else
        newstatus = "solidified"
      endif
    endif
  endif
endif
if (newstatus == "unfrozen")
  dobj:_set_petrified(0)
  dobj:_set_solidified(0)
  dobj:_set_subsidised(0)
elseif (newstatus == "solidified")
  dobj:_set_solidified(1)
elseif (newstatus == "subsidised")
  dobj:_set_subsidised(1)
endif
player:sub_tell("%D (#%D~#), which was %1, is now %2.", currentstatus, newstatus)
"Last modified by manta (#7165) on Sat Nov  7 05:48:08 1998 EST."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:04 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:50:04 2002 MDT."
.

0