8dc
@verb #13:"@recreate" any as any rdo #55
@program #13:"@recreate" any as any
"@recreate <object> as <parent-class> named [name:]alias,alias,..."
"  effectively recycles and creates <object> all over again."
set_task_perms(player)
named = "named" in args || "called" in args || "nomme" in args
as = prepstr in args
if (named <= as + 1 || named == length(args))
  player:tell({tostr("Usage:  ", verb, " &lt;object&gt; as &lt;parent-class&gt; named [name:]alias,...,alias"), "", "where &lt;parent-class&gt; is one of the standard classes ($note, $letter, $thing, or $container) or an object number (e.g., #999), or the name of some object in the current room.  The [name:]alias... specification is as in @create."})
  return
elseif ($command_utils:object_match_failed(dobj = player:my_match_object(dobjstr), dobjstr))
  return
elseif (is_player(dobj))
  player:tell("You really *don't* want to do that!")
  return
endif
parentstr = $string_utils:from_list(args[as + 1..named - 1], " ")
namestr = $string_utils:from_list(args[named + 1..length(args)], " ")
if (parentstr[1] == "$")
  try
    parent = #0.(parentstr[2..$])
  except (E_PROPNF)
    return player:tell(tostr("\"", parentstr, "\" does not name an object."))
  endtry
else
  parent = player:my_match_object(parentstr)
  if ($command_utils:object_match_failed(parent, parentstr))
    return
  endif
endif
if ($recycler:valid(dobj) && $perm_utils:controls(player, dobj) && !$command_utils:yes_or_no(tostr("Warning: ", dobj, " is not a garbage object, but an object you own (", dobj.name, "). Destroy and recreate anyway")))
  return
endif
try
  e = $building_utils:recreate(dobj, parent)
except v (ANY)
  player:tell(verb, " failed: ", v[1])
  player:tell("Object: ", dobj, ".  Parent: ", parent, ".")
  player:tell("Reason: ", v[2])
  return
endtry
if (dobj:isa($physical))
  dobj:moveto(player)
endif
$building_utils:set_names(dobj, namestr)
if ((other_names = setremove(dobj.aliases, dobj.name)) != {})
  aka = " (aka " + $string_utils:english_list(other_names) + ")"
else
  aka = ""
endif
player:tell("Object number ", dobj, " is now ", dobj.name, aka, " with parent ", $su:nn(parent), ".")
"Last modified by Dax (#789) on Thu Nov  8 11:38:30 2001 MST."
.

0