4fb
@verb #13:"@join*2" any at/to any rdo #7407
@program #13:"@join*2" any at/to any
if ($command_utils:player_match_failed(dobj = $string_utils:match_player(dobjstr), dobjstr) || $command_utils:player_match_failed(iobj = $string_utils:match_player(iobjstr), iobjstr))
  return
elseif (!iobj:isa($project))
  player:sub_tell("%i (#%i~#) isn't a project!")
  return
elseif (dobj:isa($project))
  player:sub_tell("%d (#%d~#) is a project, and cannot join another project.")
  return
endif
can_hack = player:controls(iobj)
can_join = dobj == player || dobj.owner == player || player.wizard
if (dobj in iobj.teachers)
  player:sub_tell("%D is already a member of %i.")
  return
endif
if (can_join)
  if (can_hack || dobj in iobj.wanted)
    iobj.wanted = setremove(iobj.wanted, dobj)
    dobj:_set_students(setadd(dobj.students, iobj))
    player:sub_tell("OK, %d is now a member of %i.")
  else
    player:sub_tell("You must get %1 to agree to join %d to %i first.")
  endif
elseif (can_hack)
  iobj.wanted = setadd(iobj.wanted, dobj)
  player:sub_tell("OK, you must now get %d to agree to join %i.")
else
  player:tell("You can only join other people to groups you own.")
endif
"Last modified by Lao-Tzu (#8084) on Wed Nov  6 21:50:17 2002 MST."
.

0