56e
@verb #13:"@garbage" any at/to any rdo #60
@program #13:"@garbage" any at/to any
usage = {"Usage: @garbage [start] to [end]", "Displays available objects from start to end."}
if (player != this)
  return $msg:mtell("huh")
endif
dobjstr && dobjstr[1] == "#" && (dobjstr = dobjstr[2..$])
iobjstr && iobjstr[1] == "#" && (iobjstr = iobjstr[2..$])
if ($string_utils:is_numeric(dobjstr) && toint(dobjstr) >= 0)
  start = toint(dobjstr)
else
  return this:tell(usage)
endif
if (!(end = min(toint(iobjstr), toint(max_object()))))
  if (!iobjstr)
    end = toint(max_object())
  elseif (iobjstr != tostr(end))
    return this:tell(usage)
  endif
endif
lwidth = length(tostr(max_object()))
space = $string_utils:space(lwidth)
text = {space + "          1111111111222222222233333333334444444444", space + "01234567890123456789012345678901234567890123456789"}
for y in [start / 50..end / 50]
  s = $string_utils:right(tostr(ln = y * 50), lwidth)
  for j in [ln..min(ln + 49, end)]
    o = toobj(j)
    s = s + (j < start ? " " | (valid(o) ? o.owner == this ? "#" | (parent(o) == $garbage ? "*" | (is_player(o) ? "@" | ".")) | "X"))
  endfor
  text = {@text, s}
  $command_utils:suspend_if_needed()
endfor
player:tell(text)
player:tell("  . - object in use  # - your object  * - garbage  @ - player")
"Last modified by Dax (#789) on Tue May  3 14:11:54 2005 MDT."
.

0