8bb
@verb #13:"@disa*ssemble" any any any rdo #55
@program #13:"@disa*ssemble" any any any
"Copied from Generic builder (#4):@list by Slacker (#2) Aug 19 15:40:13 1996"
"@disassemble <obj>:<verb> [<dobj> <prep> <iobj>]"
if (player != this)
  return $msg:mtell("huh")
endif
if (!$object_utils:isa(this, $guardian))
  "Allow guardians to see all -r verbs."
  set_task_perms(this)
endif
argspec = {}
if (args)
  spec = $code_utils:parse_verbref(args[1])
  if (length(args) == 4)
    if (typeof(pas = $code_utils:parse_argspec(@args[2..$])) == $LIST)
      argspec = pas[1]
      argspec[2] = $code_utils:full_prep(argspec[2]) || argspec[2]
    else
      args = E_INVARG
    endif
  elseif (length(args) != 1)
    args = E_INVARG
  endif
else
  args = E_INVARG
endif
if (args == E_INVARG || !spec)
  this:notify(tostr("Usage:  ", verb, " <object>:<verb> [<dobj> <prep> <iobj>] "))
  return
elseif ($command_utils:object_match_failed(object = player:my_match_object(spec[1]), spec[1]))
  return
endif
what = object
if (argspec)
  vnum = $code_utils:find_verb_named(what, spec[2], 1)
  while (vnum < 0 ? valid(what = parent(what)) | verb_args(what, vname = tostr(vnum)) != argspec)
    vnum = $code_utils:find_verb_named(what, spec[2], vnum + 1)
  endwhile
  code = vnum < 0 ? E_VERBNF | `disassemble(what, vnum) ! ANY'
else
  vname = spec[2]
  while (valid(what) && (code = `disassemble(what, vname) ! ANY') == E_VERBNF)
    what = parent(what)
  endwhile
endif
inf = `verb_info(what, vname) ! ANY'
if (code == E_VERBNF)
  this:notify(tostr("That object does not define that verb", argspec ? " with those args." | "."))
elseif (typeof(code) == $ERR)
  this:notify(tostr(code))
else
  if (what != object)
    this:notify(tostr("Object ", object, " does not define that verb", argspec ? " with those args" | "", ", but its ancestor ", what, " does."))
  endif
  info = verb_info(what, vname)
  vargs = verb_args(what, vname)
  if (index(vargs[2], "/"))
    vargs[2] = tostr("(", vargs[2], ")")
  endif
  this:tell(what, ":", toliteral(info[3]), "   ", $string_utils:from_list(vargs, " "))
  player:tell(code)
endif
"Last modified by Dax (#789) on Tue May  3 13:45:55 2005 MDT."
.

0