65d
@verb #12:"netforward" this none this rxdo #789
@program #12:"netforward" this none this
"args[1] is folder, args[2] is msg_seq"
caller_perms():controls(this) || raise(E_PERM)
$network:email_will_fail(email = player.email_address) && raise(E_NACC)
{folder, msg_seq} = args
player:set_current_folder(folder)
if (folder:isa($newsgroup) ? !folder:is_readable_by(this) | !this:controls(folder))
  raise(E_PERM, "folder not readable.")
endif
folderstr = folder == player ? "" | tostr(" from *", folder.name, "(", folder, ")")
msg_seq = $seq_utils:intersection(msg_seq, {folder.messages[1][1], 100000})
seq_size = $seq_utils:size(msg_seq)
player._mail_task = task_id()
netmail = {}
linelength = player:linelength()
maxmsg = minmsg = 0
gotone = 0
for msg in (folder:messages_in_seq(msg_seq))
  gotone = 1
  $command_utils:suspend_if_needed()
  minmsg = minmsg ? min(msg[1], minmsg) | msg[1]
  maxmsg = maxmsg ? max(msg[1], maxmsg) | msg[1]
  lines = {tostr("Message ", msg[1], folderstr, ":"), tostr("Date:     ", ctime(msg[2][1])), "From:     " + msg[2][2], "To:       " + msg[2][3], @length(subj = msg[2][4]) > 1 ? {"Subject:  " + subj} | {}}
  for line in (msg[2][5..length(msg[2])])
    lines = {@lines, @$editor:fill_string(line, linelength)}
    $command_utils:suspend_if_needed()
  endfor
  netmail = {@netmail, @lines, "", "--------------------------", "", ""}
endfor
if (gotone)
  return player:send_self_netmail({tostr($name, " Message(s) ", minmsg, @minmsg != maxmsg ? {" - ", maxmsg} | {}, folderstr), @netmail})
endif
"Last modified by Lao-Tzu (#8084) on Mon Dec 10 19:28:25 2001 MST."
.

0