5bc
@verb #12:"@forward" any any any rxdo #55
@program #12:"@forward" any any any
"@forward <msg> [on *<recipient>] to <recipient> [<recipient>...]"
set_task_perms(valid(caller_perms()) ? caller_perms() | player)
if (!(p = this:parse_mailread_cmd(verb, args, "", "on", 1)))
  "...lose..."
  return
elseif (length(p[4]) < 2 || p[4][1] != "to")
  player:tell("Usage:  ", verb, " [&lt;message&gt;] [on &lt;folder&gt;] to &lt;recip&gt;...")
  return
endif
sequence = p[2]
recips = {}
for rs in (listdelete(p[4], 1))
  if ($mail_agent:match_failed(r = typeof(m = $mail_agent:match_recipient(rs)) == $LIST ? m[1] | m, rs))
    return
  endif
  recips = {@recips, r}
endfor
this:set_current_folder(folder = p[1])
for m in (folder:messages_in_seq(sequence))
  {msgnum, msgtxt} = m
  from = msgtxt[2]
  subject = tostr("[Fwd: ", msgtxt[4], "]")
  result = $mail_agent:send_message(player, recips, subject, $mail_agent:to_text(@msgtxt))
  if (!result)
    player:notify(tostr(result))
  elseif (result[1])
    player:notify(tostr("Message ", msgnum, @folder == this ? {} | {" on ", $mail_agent:name(folder)}, " @forwarded to ", $mail_agent:name_list(@listdelete(result, 1)), "."))
  else
    player:notify(tostr("Message ", msgnum, @folder == this ? {} | {" on ", $mail_agent:name(folder)}, " NOT @forwarded to ", $mail_agent:name_list(@listdelete(result, 1)), "."))
  endif
endfor
"Last modified by Dax (#789) on Tue May  3 13:55:52 2005 MDT."
.

0