504
@verb #12:"@edit 2edit" any any any rdo #60
@program #12:"@edit 2edit" any any any
"Copied from Dax (#789):2edit by Hacker (#38) Jul 22 18:04:16 1997"
actives = {}
for x in ({$note_editor, $verb_editor, $mail_editor})
  if (x:loaded(player))
    actives = {@actives, x}
  endif
endfor
if (player != this)
  $msg:mtell("huh")
elseif (dobjstr)
  "Are we going to edit a verb or a property/file/note?"
  if ($code_utils:parse_verbref(dobjstr))
    if (player:isa($prog))
      this:("@verbedit")()
    else
      player:tell("Sorry, you need to be a programmer to edit verbs.")
    endif
  else
    this:("@notedit")()
  endif
elseif (length(actives) == 1)
  actives[1]:invoke(argstr, "@edit")
else
  "Display a chart of current editor acitvity."
  data = {{"Command", "Working on", "Modified", "Since"}}
  for x in ({{"@notedit", $note_editor}, {"@verbedit", $verb_editor}, {"@send", $mail_editor}})
    if (who = x[2]:loaded(player))
      data = {@data, {x[1], x[2]:working_on(who), x[2]:changed(who) ? "Yes" | "No", player:ctime(x[2].times[who])}}
    else
      data = {@data, {x[1], "---", "---", "---"}}
    endif
  endfor
  this:tellColumns(3, {3, 1, 2, 2}, @data)
endif
"Last modified by Lao-Tzu (#8084) on Tue Jan 12 20:38:53 1999 MST."
.

0