866
@verb #1011:"@olverbs" any any any rxo #7153
@program #1011:"@olverbs" any any any
"@olverbs -- Lists verbs on the specified object.  Optionally, you can specify"
"     the depth at which to search down for callable verbs.  You can"
"     use 'all' to search all the way down."
this:update_usage(verb, player)
if (!args)
  player:tell("@lverbs object [all|{level}] -- where level is depth as a number")
  return
endif
if (length(args) > 1)
  if (args[2] == "all")
    depth = 999
  else
    ret = $string_utils:to_value(args[2])
    if (ret[1])
      depth = ret[2]
    else
      player:tell("Bad argument 2: " + args[2] + ".  Type '@lverbs' for help.")
      return
    endif
  endif
else
  depth = 1
endif
ob = player:my_match_object(args[1])
if (valid(ob))
  player:tell("Listing verbs for ", ob.name, " (", ob, "):")
  player:tell("---------------")
  tot_verbs = 0
  d = 0
  v = 1
  vl = ob:all_verbs()
  while (d < depth)
    ret = ob:has_verb(vl[v])
    if (!ret)
      if (!v)
        player:tell("No verbs!")
      endif
      return
    endif
    if (ret[1] == ob || (d = d + 1) < depth)
      if (ret[1] != ob)
        ob = ret[1]
        player:tell("   ---( Verbs from: ", ob:title(), " (", ob, "), depth ", d + 1, " )---")
        v = 1
        vl = ob:all_verbs()
      endif
      info = verb_info(ret[1], tostr(vl[v]))
      if (typeof(info) == $ERR)
        player:tell(tostr(info))
      else
        owner = info[1]
        perms = info[2]
        names = info[3]
        arg_sp = verb_args(ret[1], tostr(vl[v]))
        player:tell(tostr(ret[1], ":", names, "[", perms, "] ", arg_sp[1], " ", arg_sp[2], " ", arg_sp[3], " Owner: ", owner.name, "(", owner, ")"))
      endif
      v = v + 1
      tot_verbs = tot_verbs + 1
    endif
  endwhile
else
  player:tell("Sorry, that object doesn't exist!")
endif
if (tot_verbs)
  player:tell("---------------")
  player:tell("Finished - ", tostr(tot_verbs), " verb", tot_verbs == 1 ? "" | "s", " found.")
else
  player:tell("No verbs found!")
endif
"Last modified by Dax (#789) on Tue May  3 13:45:58 2005 MDT."
.

0