632
@verb #1011:"@lastlog" any any any rdo #7153
@program #1011:"@lastlog" any any any
this:update_usage(verb)
if (pstrs = $string_utils:explode(argstr))
  ps = $string_utils:match_player(pstrs)
  folks = {}
  for i in [1..length(ps)]
    if (!$command_utils:object_match_failed(ps[i], pstrs[i]))
      folks = setadd(folks, ps[i])
    endif
  endfor
  if (!folks)
    return
  endif
else
  folks = players()
endif
day = week = month = ever = never = {}
a_day = 24 * 60 * 60
a_week = 7 * a_day
a_month = 30 * a_day
now = time()
for x in (folks)
  if ($object_utils:has_property(x, "last_connect_time"))
    when = x.last_connect_time
    how_long = now - when
    if (when == 0)
      never = {@never, x}
    elseif (how_long < a_day)
      day = {@day, x}
    elseif (how_long < a_week)
      week = {@week, x}
    elseif (how_long < a_month)
      month = {@month, x}
    else
      ever = {@ever, x}
    endif
  endif
endfor
for entry in ({{day, "the last day"}, {week, "the last week"}, {month, "the last 30 days"}, {ever, "recorded history"}})
  if (entry[1])
    player:tell("Players who have connected within ", entry[2], ":")
    for x in (entry[1])
      player:tell("  ", x.name, " last connected ", ctime(x.last_connect_time), ".")
    endfor
  endif
endfor
if (never)
  player:tell("Players who have not connected since connect-time accounting was established:")
  player:tell("  ", $string_utils:english_list($list_utils:map_prop(never, "name")))
endif
"Last modified by Absolute (#7153) on Fri Dec  8 16:50:31 2000 MST."
.

0