636
@verb #1011:"@code" any any any rxdo #7153
@program #1011:"@code" any any any
"Lists verbcode without line #'s in a format."
"Usage: @code <object>:verb"
"A copy of an original verb by Quinn."
this:update_usage(verb)
if (player != caller_perms())
  return E_PERM
elseif (!(spec = $code_utils:parse_verbref(args[1])))
  player:tell("Usage:  @code &lt;object&gt;:&lt;verb&gt;")
  return E_INVARG
endif
object = player:my_match_object(spec[1])
if ($command_utils:object_match_failed(object, spec[1]))
  return
endif
what = object
vname = spec[2]
while (what != $nothing && (code = verb_code(what, vname)) == E_VERBNF)
  what = parent(what)
endwhile
info = verb_info(what, vname)
if (code == E_VERBNF)
  player:tell("That object does not define that verb.")
elseif (typeof(code) == $ERR)
  player:tell(code)
elseif (!index(info[2], "r") && !$perm_utils:controls(player, what))
  return player:notify(tostr(E_PERM))
elseif (code == {})
  player:tell("That verb has not been programmed.")
else
  if (what != object)
    player:tell("Object ", object, " does not define that verb, but its ancestor ", what, " does.")
  endif
  info = verb_info(what, vname)
  vargs = verb_args(what, vname)
  if (index(vargs[2], "/"))
    vargs[2] = $code_utils:short_prep(vargs[2])
  endif
  player:tell(tostr("@verb ", what, ":", toliteral(info[3]), " ", $string_utils:from_list(vargs, " "), " ", info[2]))
  player:tell(tostr("@prog ", what, ":", vname))
  player:tell(code)
  player:tell(".")
endif
"Last modified by Dax (#789) on Thu May  5 17:08:54 2005 MDT."
.

0