4b3
@verb #0:"server_started" this none this rxdo #55
@program #0:"server_started" this none this
if (!valid(caller_perms()))
  $last_restart_time = time()
  $last_checkpoint_time = time()
  $running_checkpoint = 0
  `kill_task($shutdown_task) ! E_INVARG, E_TYPE'
  $shutdown_task = E_NONE
  $network.open_connections = $network.connect_connections_to = $network.ignore = {}
  $last_gap_start = $running_checkpoint
  $port = listeners()[1][2]
  if (where = listiassoc($login, this.listeners))
    this.listeners[where][2] = $port
  endif
  "Unlisten on #0, so $login can do it itself..."
  unlisten(listeners()[1][2])
  for x in (this.listeners)
    `listen(@x) ! ANY'
  endfor
  if ($setuid_user)
    "Anyone who wanted to listen() to stuff < 1000 better have already done so, hmm?"
    setuid($setuid_user)
  endif
  $dont_unlisten = {}
  for x in (listeners())
    x[2] <= 1024 && ($dont_unlisten = setadd($dont_unlisten, x))
  endfor
  if (server_version() != $version)
    this:new_server_version()
  endif
  for x in (this.startup_tasks)
    $scheduler:run(10.0, @x, #-1, $slacker)
  endfor
endif
"Last modified by Cecil (#7407) on Mon Nov  4 23:50:01 2002 MST."
.

0