The story title is "Guma Adventure [close bracket]I[bracket]".
The story author is "Alex Guma[line break]Based on legacy HP2000 BASIC 'Adventure [close bracket]I[bracket]' code and data, original authors(s) unknown.".
The release number is 2.

When play begins, say "Somewhere nearby is the land of Erehwon, a mysterious place filled with fantasy and magic.  It is your task to explore this
unknown region, requiring your physical skill and cunning to be at their peak.  I will be your eyes and ears in this expedition, describing your surroundings and any points of interest that you happen to run across.[line break][line break]The object of the game is to collect all of the valuables and to put them in the treehouse (you will find the treehouse soon).".

Section 1 - Debug - Not for release

The player is lit.

Teleporting is an action applying to one topic.
Understand “Allez to [text]” or "Allez [text]" as teleporting.
target-room is text that varies. match-room is text that varies.
Carry out teleporting:
	Now the target-room is the topic understood in lower case;
	Let L be the list of rooms;
	Repeat with room running through L:
		Now match-room is printed name of the room in lower case;
		If  match-room matches the text "[target-room]":
			Move player to the room;
			Stop the action;
	Say "There is no room by that full or partial name, say 'Rooms' to see a list.".

Rooms is an action applying to nothing.
Understand "rooms" as rooms.
Carry out rooms:
	Say "[list of rooms][line break]".

Section 2 - Story
	
[Enable tracking of score]
Use scoring.
The maximum-score is always 1400.
The Maximum score is maximum-score.
A thing has a number called points.

Table 1 - Rankings
Score	Rank
0	"Beginner"
200	"Novice"
400	"Amateur"
600	"Intermediate"
800	"Class IV"
1000	"Advanced"
1200	"Expert"
1400	"Zarka"

[Track weight of inventory and prevent carrying too much or something that cannot be carried]
A thing has a number called weight.
Definition: A thing is heavy if its weight is 500. 
Definition: A thing is dangerous if its weight is -1.
Before taking something (called item-to-take):
	If heavy:
		Say "[one of]A valiant attempt.[or]Want a hernia?[or]Close but no cigar.[or]Nice try.[purely at random]";
		Stop the action;
	Otherwise if dangerous:
		Say "Not only is taking the [the noun] not possible, it is also very dangerous!";
		Stop the action;		
	Otherwise if item-to-take is portable and weight of item-to-take is greater than 0:
		Let total-weight be weight of the item-to-take;
		Let L be the list of things held by the player;
		Repeat with thing running through L:
			Increase total-weight by weight of the thing;
		If total-weight is greater than 150:
			Say "You're load is too heavy.  You'll have to drop something first.";
			Stop the action;
	Continue the action.

[Adjust weight and score based on what has been taken or dropped, and where]
After taking something:
	If player is in tree-house:
		decrease score by points;
	Otherwise:
		Increase score by points;
	Continue the action.

After dropping something:
	If player is in tree-house:
		Increase score by points;
	Otherwise:
		Decrease score by points;
	Continue the action.

[Need way to tell if a dark room has a source of light somewhere in it]
The light-meter is a privately-named scenery thing.
Definition: a room (called the target room) is light-filled:
	If the target room is lighted:
		yes;
	Move the light-meter to the target room;
	Let the answer be false;
	If the light-meter can see a lit thing:
		Now the answer is true;
	Now the light-meter is nowhere;
	Decide on the answer.
	
[Lamp can be switched on or off, affecting the light output]
Carry out switching on the lamp: Now the lamp is lit.
Carry out switching off the lamp: Now the lamp is unlit. 
Instead of switching on the lamp:
	If the lamp-life is 0:
		Say "The batteries are drained.";
	Otherwise:
		Continue the action.

[Rule changes to print room description in way similar to how original version worked, also handle darkness]
The improved room description body text rule is listed before the room description body text rule in the carry out looking rulebook.
The the room description body text rule is not listed in the carry out looking rulebook.
Carry out looking (this is the improved room description body text rule):
	If the location is dark and the location is not light-filled:
		Say “It is pitch dark in here, and you can’t see a thing.”;
	If  this-room is not the location:
		Now last-room is this-room;
		Now this-room is location;
		If the location is dark and the location is not light-filled:
			If a random chance of 1 in 10 succeeds:
				Say "Oh no!!!  Wild xeener bugs just ate your head!";
				End the story;
			Otherwise:
				Say "[line break]Wild xeener bugs are approaching!";	
	If the location is dark and the location is not light-filled:
		Stop the action;
	Now printed-room-item is false;
	If set to abbreviated room descriptions:
		Continue the action;
	Otherwise if set to sometimes abbreviated room descriptions and location of the player is not unvisited:
		Continue the action;
	Otherwise:
		Let desc be the description of the location;
		Say "[desc]";
		Continue the action.

[Make sure we get a blank line after all the room and contents are listed]
The blank after desc rule is listed after the  improved room description body text rule in the carry out looking rulebook.
Carry out looking (this is the blank after desc rule):
	Say "".

[Rule changes to list room contents in a way similar to original version]
Rule for writing a paragraph about something (called item):
	If printed-room-item is false:
		Now printed-room-item is true;
		Say "I see:[line break][line break]";
	If item is in a container (called cont):
		Let L be the list of things in the cont;
		If L is not empty:
			Say "In the [cont] is ";
			Let and-sep be "";
			Repeat with contained running through L:
				If contained is not yourself:
					Say "[and-sep][the indefinite article of the contained] [contained]";
					Now and-sep is " and ";
	Otherwise:
		Say "[initial appearance]";
	If item is a supporter:
		Let L be the list of things on the item;
		If L is not empty:
			Say "[line break]   (On the [item] is ";
			Let and-sep be "";
			Repeat with supported running through L:
				Say "[and-sep][the indefinite article of the supported] [supported]";
				Now and-sep is " and ";
			Say ")";
	Otherwise if item is a container:
		Let L be the list of things in the item;
		If L is not empty:
			Say "[line break]   (In the [item] is ";
			Let and-sep be "";
			Repeat with contained running through L:
				Say "[and-sep][the indefinite article of the contained] [contained]";
				Now and-sep is " and ";
			Say ")";
	Rule succeeds.

The describe what's on mentioned supporters in room descriptions rule is not listed in any rulebook.

[Handle events that need to be checked every turn everywhere]
last-room is a room that varies. this-room is a room that varies.
lamp-life is a number that varies. lamp-life is 450.
reactor-running is a truth state that varies. reactor-running is initially true.
countdown is a time that varies. The countdown is initially 4:00 AM.
girl-following is a truth state that varies. girl-following is initially false.
zarka-following is a truth state that varies. zarka-following is initially false.
printed-room-item is a truth-state that varies. printed-room-item is initially false.
Every turn:
	If the lamp is lit:
		Decrease the lamp-life by 1;
		If lamp-life is 100:
			Say "The lamp seems dimmer.";
		If lamp-life is 50:
			Say "Your lamp is dying.  I hope you can see in the dark!";
		Otherwise if lamp-life is 0:
			Say "The lamp's batteries are dead.";
			Try silently switching off the lamp;
	If reactor-running is true:
		If turn count is 200:
			Say "An EPA official runs by muttering, [quotation mark]Tsk, tsk.  Another TMI.[quotation mark]";
		Otherwise if turn count is 215:
			Say "A calm, pleasant voice reports,  [quotation mark]Meltdown...4 minutes.  Warning only.[quotation mark]";
		Otherwise if turn count is greater than 215: 
			Decrease countdown by 10 minutes;
			Let H be the hours part of the countdown;
			Let M be the minutes part of the countdown;
			Let Z be "";
			If M is 0:
				Now Z is "0";
			If countdown is 12:00 AM:
				Say "Booooom!!!";
				End the story;
			Otherwise:
				Say "[quotation mark]Time until meltdown: [H]:[Z][M][quotation mark]";
	If girl-following is true:
		If the location of the girl is not the location of the player:
			Let the way be the best route from the location of the girl to the location of the player, using doors;
			If way is nothing:
				Move the girl to the location of the player;
				Say "The girl suddenly appears next to you.";
			Otherwise:
				Try the girl going the way; 
	If zarka-following is true:
		If the location of the zarka is not the location of the player:
			Let the way be the best route from the location of the zarka to the location of the player, using doors;
			If way is nothing:
				Move the zarka to the location of the player;
				Say "The zarka suddenly appears next to you.";
			Otherwise:
				Try the zarka going the way; 
	If score is not less than maximum-score:
		Say "Congratulations, you have solved the adventure!";
		End the story;
	Continue the action.

[Disable certain automatic taking of items]
The sanity-check rules are a rulebook.
This is the sanity-check stage rule:
	abide by the sanity-check rules.
The sanity-check stage rule is listed after the before stage rule in the action-processing rules.
sanity-check eating something (called the item):
	If player does not have the item:
		Say "You don't have the [item].";
		Stop the action.

[Convert entered command to support communicating with girl/zarka, as well as sitting on something]
After reading a command:
	Let cmd be "[the player's command]";
	Let cmd1 be word number 1 in cmd;
	If cmd1 is "ask" or cmd1 is "tell" or cmd1 is "order":
		Replace the regular expression "\b(ask|tell|order) (.+?) to (.+)" in cmd with "\2, \3";
		Change the text of the player's command to cmd;
	Otherwise if cmd1 is "sit" or cmd1 is "get":
		If word number 2 in cmd is "on":
			Replace the text "sit on" in cmd with "sit";
			Replace the text "get on" in cmd with "sit";
			Change the text of the player's command to cmd.

Instead of telling someone about something, try asking the noun about it.
Instead of answering the noun that something, try asking the noun about it.

Instead of asking the girl about something:
	Let cmd be the player's command;
	If cmd includes "follow me" or cmd includes "follow":
		If girl-following is true:
			Say "The girl is already following you.";
		Otherwise:
			Say "girl: [quotation mark]Lead on.[quotation mark][line break]";
			If player is in tree-house:
				Decrease score by points;
			Otherwise:
				Increase score by points;
			Now girl-following is true;
	Otherwise if cmd includes "wait here" or cmd includes "stay" or cmd includes "stay here":
		If girl-following is false:
			Say "The girl is not currently following you.";
		Otherwise:
			Say "girl: [quotation mark]I will wait here.[quotation mark][line break]";
			If player is in tree-house:
				Increase score by points;
			Otherwise:
				Decrease score by points;		
			Now girl-following is false;
	Otherwise:
		Say "girl: [quotation mark]I have no response to that.[quotation mark][line break]".
Instead of asking the girl to try waiting:
	Try asking the girl about "stay".
Instead of taking the girl:
	Say "Instead of taking the girl, you tell her to follow you.";
	Try asking the girl about "follow me";
Instead of dropping the girl:
	Say "Instead of dropping the girl, you tell her to wait here.";
	Try asking the girl about "wait here";

Instead of asking the zarka about something:
	Let cmd be the player's command;
	If cmd includes "follow me" or cmd includes "follow":
		If zarka-following is true:
			Say "The zarka is already following you.";
		Otherwise:
			Say "zarka: [quotation mark]Grunt![quotation mark][line break]";
			If player is in tree-house:
				Decrease score by points;
			Otherwise:
				Increase score by points;		
			Now zarka-following is true;
	Otherwise if cmd includes "wait here" or cmd includes "stay" or cmd includes "stay here":
		If zarka-following is false:
			Say "The zarka is not currently following you.";
		Otherwise:
			Say "zarka: [quotation mark]Grunt![quotation mark][line break]";
			If player is in tree-house:
				Increase score by points;
			Otherwise:
				Decrease score by points;		
			Now zarka-following is false;
	Otherwise:
		Say "zarka: [quotation mark]Grunt?[quotation mark][line break]".
Instead of asking the zarka to try waiting:
	Try asking the zarka about "stay".
Instead of taking the zarka:
	Say "Instead of taking the zarka, you tell it to follow you.";
	Try asking the zarka about "follow me".
Instead of dropping the zarka:
	Say "Instead of dropping the zarka, you tell it to wait here.";
	Try asking the zarka about "wait here".

[Custom cases for interacting with the girl]
married is a truth state that varies. married is initially false.
Instead of attacking the girl with a weapon (called the weapon):
	Say "At your attempt, the girl flees in terror!";
	Now the girl is nowhere.
Instead of kissing the girl:
	If married is true:
		Say "The girl gazes dreamily into your eyes as your lips press gently together.";
	Otherwise:
		Say "The girl will become angry if you persist!".

[Add ability to attack something with something else]
A weapon is a kind of thing.
Attacking it with is an action applying to one visible thing and one carried thing requiring light.
Understand "attack [someone] with [something preferably held]" as attacking it with.
Attacking with is an action applying to one carried thing requiring light.
Understand "attack with [something preferably held]" as attacking with.
Understand the command "bite" or "kick" or "poke" or "stab" as "attack".
Carry out attacking with something:
	Say "You need to specify what you will attack.".
Carry out attacking someone (called the victim):
	Let cmd be the player's command;
	If cmd includes "bite" or cmd includes "kick" or cmd includes "poke" or cmd includes "punch":
		Say "That only gets the [victim] angry.";
	Otherwise:
		Say "You need to specify what you will attack with.".
Carry out attacking someone (called the victim) with something (called the weapon):
	Let cmd be the player's command;
	If cmd includes "bite" or cmd includes "kick" or cmd includes "poke" or cmd includes "punch":
		Say "You can't do that with the [weapon][line break]";
	Otherwise If weapon is a weapon:
		Try attacking the victim with the noun;
	Otherwise:
		Say "You can't attack with that.".

[Special handling for eating]
gum-eaten is a truth state that varies. gum-eaten is initially false.
Instead of eating something:
	If noun is structure:
		Say "You are not Yule Gibbons!";
	Otherwise if noun is fries or noun is fish or noun is pizza or noun is cube:
		If noun is cube:
			Say "Somewhat chewy and refreshing, breathing seems somehow easier.";
			Now the gum-eaten is true;
		Otherwise:
			Say "Yummy.";
		Decrease score by points;
		Now the noun is nowhere;
	Otherwise if noun is witch or noun is girl or noun is nurse:
		Say "This is not that kind of game!";
	Otherwise if noun is slime or noun is zarka or noun is clown or noun is snake:
		Say "The [noun] will become angry if you persist!";
	Otherwise if noun is the can:
		Say "Fluorocarbon poisoning.";
		End the story;
	Otherwise if noun is the note:
		Say "The note was written with India Ink.  You've been poisoned!";
		Say "The note was written with India Ink.  You've been poisoned!";
		End the story;
	Otherwise if noun is the water or noun is the pool or noun is the oasis:
		Say "You would be better served by drinking from the [noun].";
	Otherwise:
		Say "[one of]I don't think that would agree with you.[or]But there's no vitamin content.[purely at random]".

[Add ability to swim where possible]
Swimming is an action applying to nothing.
Understand "swim" as swimming.
underwater-award is a truth state that varies. underwater-award is initially false.
Carry out swimming:
	If location is waterfall-base or location is wet-room:
		If gum-eaten is true:
			Say "For some reason, you can breathe underwater!  After swimming for a while, you surface on the other side of the waterfall.";
			If location is waterfall-base:
				Move player to wet-room;
			Otherwise:
				Move player to waterfall-base;
			If underwater-award is false:
				Increase score by 10;
				Now underwater-award is true;
		Otherwise:
			Say "You can't breathe under water; you wisely return back to shore.";
	Otherwise if location is sea-hall:
		Say "You paddle around for a bit but soon return to shore since there is nowhere to swim to.";
	Otherwise:
		Say "I don't see how to swim here.".

[Add ability to dig, keeping track of where we have already dug (and how deep), plus cases where it makes a difference]
A room can be diggable.
A room has a number called dug-hole. The dug-hole is usually -1.
Digging is an action applying to nothing.
Understand "dig" as digging.
Carry out digging:
	Let dug be the dug-hole of the location;
	If player has the shovel:
		Increase dug by 1;
		Now the dug-hole of the location is dug;
		If location is not diggable:
			Say "You can't dig here.";
		Otherwise if location is mine-field and the hills are in mine-field:
			Say "Booom!  You just dug up a live mine!";
			End the story;
		Otherwise if location is garden-room and dug is 4:
			Say "You have unearthed a beautiful jade statue.";
			Move statue to garden-room;
			Increase score by 30;
		Otherwise If dug is 0:
			Say "You are digging a hole.";
			Let desc be the description of the location;
			Now desc is "[run paragraph on with special look spacing][desc][line break]Someone has been digging a hole here.";
			Now the description of the location is desc;
		Otherwise If dug is 1:
			Say "The hole is getting deeper, but that's about all.";
		Otherwise If dug is 2:
			Say "You are getting your nails dirty.";
		Otherwise If dug is 3:
			Say "You are surrounded on all sides by earth.";
		Otherwise:
			Say "The ground has gotten too hard to dig further.";
	Otherwise:
		Say "You don't have anything to dig with.".

[Magic word to move between two specific rooms]
Argyle is an action applying to nothing. Understand “Argyle" and "Say Argyle" as Argyle.
Carry out Argyle:
	If player is in catacomb-room:
		Say "In a flash...";
		Move player to library-room;
	Otherwise:
		If player is in library-room:
			Say "In a flash...";
			Move player to catacomb-room;
		Otherwise:
			Say "They make socks don't they?".

[Vase breaks when dropped unless empty stool is on the ground]
Instead of dropping the vase:
	If stool is in the location and the stool is not occupied:
		Say "The vase gently lands on the soft stool.";
		Move vase to stool;
		If player is in tree-house:
			Increase score by points;
		Otherwise:
			Decrease score by points;
	Otherwise:
		If stool is occupied:
			Say "There is no room on the stool, so the vase slides off and smashes into a million pieces!";
		Otherwise:
			Say "The vase falls to the floor and smashes into a million pieces!";
		Decrease score by points;
		Now the vase is nowhere;
		Move pieces to the location of the player;

[And vase is broken if you smash it directly]
Instead of attacking the vase:
	Say "The vase is reduced to worthless shards of pottery.";
	If player has the vase:
		Decrease score by points;
	Now the vase is nowhere;
	Move pieces to location of the player.

[Allow sitting on the stool or toilet]
Sitting is an action applying to one thing.
Understand "sit [something]" as sitting.
Carry out sitting a thing:
	If noun is the stool:
		If stool is in the location:
			If player is on the toilet:
				Say "You need to get off the toilet first.";
			Otherwise if player is on the stool:
				Say "You already are.";
			Otherwise if stool is occupied:
				Say "You can't, the stool is not empty.";
			Otherwise:
				Say "You are now sitting on the stool.";
				Move player to stool, without printing a room description;
		Otherwise if player has the stool:
			Say "You need to drop the stool first.";
	Otherwise if noun is the toilet:
		If player is on the stool:
			Say "You need to get off the stool first.";
		Otherwise if player is on the toilet:
			Say "You are already on the toilet.";
		Otherwise if the toilet is occupied:
			Say "You can't, the toilet is not empty.";
		Otherwise:
			Say "You are on the toilet.";
			Move player to toilet, without printing a room description;
	Otherwise if noun is the disc:
		Try boarding the disc;
	Otherwise:
		Say "You can't sit on that.".

Instead of getting off the supporter:
	If player is on the stool or player is on the toilet:
		Say "You are no longer sitting.";
		Move the player to the location, without printing a room description;
	Otherwise:
		Say "You are not on anything.".
		
[Support opening and closing the toilet, and dealing with trying to put something into it.]
toilet-open is a truth state that varies. toilet-open is initially true.
Instead of closing the toilet:
	If toilet-open is true:
		Say "The toilet lid is now closed.";
		Now toilet-open is false;
	Otherwise:
		Say "The toilet lid is already closed.".
Instead of opening the toilet:
	If toilet-open is false:
		Say "The toilet lid is now open.";
		Now toilet-open is true;
	Otherwise:
		Say "The toilet lid is already open.".
Instead of inserting something into the toilet:
	If toilet-open is true:
		Say "That could clogs the pipes!";
	Otherwise:
		Say "You can't, the toilet lid is closed.".

[Stool can be taken only if nothing on it]
Definition: A supporter is occupied if something is on it.
Instead of taking the stool:
	If stool is occupied:
		Say "You can't, the stool is not empty.";
	Otherwise:
		Continue the action.

[Cold block should only be taken when wearing the glove]
Instead of taking the block:
	If the player is wearing the glove:
		Move the block to the player;
		Say "Taken.";
		Increase score by points;
	Otherwise:
		If player has the block:
			Say "You are already carrying the block.";
		Otherwise:
			Say "Your hand feels VERY warm and the block begins to adhere to it.  Luckily you drop it just in time.".

[Support for playing something, notably the cello]
Playing is an action applying to one touchable thing.
Understand "play [something]" as playing.
Carry out playing a thing:
	If noun is cello:
		If player has the cello:
			Say "Squeeek!";
			Continue the action;
		Otherwise:
			Say "You don't have the [noun].";
	Otherwise:
		Say "I don't see how to play that!".

[Have sex with girl]
Understand "screw [something]" and "have sex with [something]" as turning.
screwed is a truth state that varies. screwed is initially false.
Instead of turning something:
	If player's command matches the regular expression "^screw" or player's command matches the regular expression "^have sex":
		If noun is girl:
			If location is bed-room:
				If screwed is false:
					Say "Cosmic!  What a WOMAN!";
					Increase score by 10;
					Now screwed is true;
				Otherwise:
					Say "Not now the girl has a headache.";
			Otherwise:
				Say  "I see no bed here.";
		Otherwise:
			Say "Okay, but your a strange one![line break]";
			Say "[noun]: A valiant attempt.".

[Spraying something]
Spraying is an action applying to one visible thing requiring light.
Understand "spray [something]" as spraying.
Carry out spraying something:
	If player has the can:
		If the slime is in the location:
			Say "The slime quickly dehydrates and becomes a powder that falls into the crevices in the floor.";
			Increase score by 10;
			Now the slime is nowhere;
		Otherwise if the player is in bath-room:
			Say "The bathroom was tidy to begin with, but you do a bit more cleaning.";
		Otherwise:
			Say "I see no reason to spray the [noun].";
	Otherwise:
		Say "You don't have anything to spray with.".

[Custom actions for the disc]
on-disc is a truth state that varies. on-disc is initially false.
Boarding is an action applying to one visible thing.
Understand "board" as boarding.
Understand "board [something]" as boarding.
Carry out boarding something:
	If noun is the disc:
		If on-disc is true:
			Say "You are already aboard the disc!";
		If the disc is in the location:
			Say "You are aboard the disc!";
			Now on-disc is true;
		Otherwise:
			Say "The disc must be on the ground to board.";
	Otherwise:
		Say "I don't see how to board that!";
Instead of taking the disc:
	If on-disc is true:
		Say "You need to get off the disc first.";
	Otherwise:
		Continue the action.
		
Instead of getting off something:
	If on-disc is true:
		Say "You are off the SNO-DISC.";
		Now on-disc is false;
	Otherwise:
		Say "You are not on anything.".
		
Instead of exiting:
	If on-disc is true:
		Say "You are off the SNO-DISC.";
		Now on-disc is false;
	Otherwise:
		Continue the action.

Instead of going somewhere:
	If on-disc is true:
		Say "You're still on the disk!";
		Stop the action;
	Otherwise:
		Continue the action.

Launching is an action applying to nothing.
Understand "launch" as launching.
Carry out launching:
	If on-disc is true:
		If location is expert-trail:
			Say "You are going 90 meters per second on a sheet of ice.[line break]";
			Say "[quotation mark]A cliff!  Watch out![quotation mark][line break]";
			Say "You impaled yourself on a tree limb, you do not survive.";
			End the story;
		Otherwise if location is bunny-slope:
			Say "You coast down the gentle grade with ease.";
			if cylinder is nowhere and reactor-running is true:
				Say "You seem to have dislodged something on the way down.";
				Move cylinder to base-of-mountain;
				Increase score by 10;
			Move disc to base-of-mountain;
			Move player to base-of-mountain;
		Otherwise:
			Say "You don't seem to go anywhere.";
	Otherwise:
		Say "You are not aboard the disc.".

[Custom reaction to climbing]
Does the player mean climbing the tree in near-tree: it is very likely.
Instead of climbing something:
	If location is near-tree:
		Say "";
		Move player to tree-house;
	Otherwise:
		Say "I don't see how to climb that.".

[Response to examining generic room features]		
The current room is a backdrop. The current room is everywhere.
Understand "room" or "ceiling" or "floor" or "walls" or "wall" or "sky" as the current room.
Instead of examining the current room:
	Say "You need to examine something specific.".

[Pray]
Praying is an action applying to nothing. Understand "pray" as praying.
prayer-answered is a truth state that varies. prayer-answered is initially false.
Carry out praying:
	If player is in church-chapel and player has the lamp and prayer-answered is false:
		Say "Thou hast honored me with thy words...[line break]";
		Say "For thine worship ye shall be blessed.[line break][line break]";
		Say "LET THERE BE LIGHT![line break]";
		Now lamp-life is 450;
		Now prayer-answered is true;
	Otherwise:
		Say "Oh father, who art in heaven...".

[Jump]
Instead of jumping:
	If the hills are in the location:
		Say "As your feet hit the ground, one of the mines explodes.  You have died.";
		End the story;
	Otherwise:
		Say "[one of]Very good.  Now you can go to second grade.[or]Wheeeeeeeee![or]Are you enjoying yourself?[purely at random]".

[Sing]
Singing is an action applying to nothing. Understand "sing" as singing.
Carry out Singing:
	Say "If I were a rich man...".
	
[Hide]
Hiding is an action applying to nothing. Understand "Hide" as Hiding.
Carry out Hiding:
	Say "There is no place to hide!".

[Locking]
Understand "lock [something]" as locking keylessly. Locking keylessly is an action applying to one thing.
Check locking keylessly:
	if the noun is not the chest:
		say "[The noun] is not something you can lock.";
	Otherwise:
		If the chest is locked:
			Say "The chest is already locked.";
		Otherwise If the chest is open:
			Say "You need to close the chest.";
		Otherwise:
			Now the chest is locked;
			Say "You lock the padlock on the chest.";
			If the keys are in in-chest:
				Say "Unfortunately you have locked the keys inside the chest.".

[Flask can contain water]
Filling is an action applying to one visible thing. 
Understand "fill [something]" as filling.
Carry out filling something:
	If noun is the flask:
		If the pool is in the location or the oasis is in the location:
			if water is in flask:
				Say "The flask already contains water.";
			Otherwise:
				Say "The flask is now full of water.";
				Now water is in the flask;
		Otherwise if player is in the reactor-core:
			Say "That would not be a good idea.";
		Otherwise:
			Say "There is nothing here to fill it with.";
	Otherwise:
		Say "That cannot be filled.".
Instead of taking the pool:
	Say "The water slips through your fingers.. You would do better to fill a container with it.".
Instead of inserting something into the flask:
	Say "Just fill the flask directly when there is water present.".
Instead of taking the water:
	Say "The water just runs through your fingers.".
Rule for printing the name of the flask:
	Say "[printed name of flask]";
	Omit contents in listing.		

[Drink]	
Understand "drink from [something]" as drinking.
Instead of drinking:
	If noun is the flask or the noun is the water:
		If water is in the flask:
			Say "Refreshing, but the flask is now empty.";
			Now the water is nowhere;
		Otherwise:
			Say "The flask is empty.";
	Otherwise if the noun is the pool or the noun is the oasis:
		Say "Refreshing.";
	Otherwise if noun is the reactor-water:
		Say "That would not be a good idea.";
	Otherwise:
		Say "You can't drink from that.".

[Pour or Empty the flask]
Pouring is an action applying to one visible thing.
Understand "pour [something]" as pouring.
Understand "empty [something]" as pouring.
Carry out pouring:
	If noun is the flask or the noun is the water:
		If water is in the flask:
			Say "The water soaks into the ground and disappears.";
			Now the water is nowhere;
		Otherwise:
			Say "The flask is already empty.";
	Otherwise:
		If noun is a container:
			If something is in noun:
				Now everything enclosed by noun is in location;
				Say "The [noun] contents is now all on the floor.";
			Otherwise:
				Say "There is nothing in the [noun].";
		Otherwise:
			Say "That is not possible.".

[Comb]
Combing is an action applying to one visible thing. Understand "comb [something]" as combing.
Understand "brush [something]" as combing.
zarka-combed is a truth state that varies. zarka-combed is initially false.
Carry out combing:
	If player has comb:
		If noun is zarka:
			If weight of the zarka is 50 and zarka-combed is false:
				Say "The Zarka becomes enraged [bracket]but shiny[close bracket].";
				Now zarka-combed is true;
			Otherwise:
				Say "The Zarka is not very amused.";
		Otherwise:
			Say "I don't see how to comb that!";
	Otherwise:
		Say "You don't have the comb.";

[Waving something in places it does nothing]
Instead of waving something:
	If noun is the staff:
		Say "That doesn't accomplish much.";
	Otherwise:
		Say "I see no reason to wave that.".
		
[Original game has crawl as a synonym for moving]
Understand the command "crawl" as "walk".

[Help keyword]
Understand the command "help" as something new. Understand "help" as helping.
Helping is an action applying to nothing.
Carry out helping:
	Say "No help at all.".
	
[Describe an object in more detail]
Understand the command "describe" as something new. Understand "describe [something]" as describing.
Describing is an action applying to one thing, requiring light.
Carry out describing:
	Let D be the initial appearance of the noun;
	If D is empty:
		Say "[noun]: It is exactly that, no more and no less.";
	Otherwise:
		Say "[noun]: [D][line break]".

[Support for reading]
A thing has some text called printing. The printing of a thing is usually "blank".
Understand the command "read" as something new. Understand "read [something]" as reading.
Reading is an action applying to one thing, requiring light.
Check reading:
	If the printing of the noun is "blank":
		Say "Nothing is written on [the noun]." instead.
Carry out reading:
	 Say "You read: [printing of the noun][line break]".
Report reading: Do nothing.

[Reading or examining lamp shows remaining charge]
Instead of reading the lamp:
	Let charge be (lamp-life * 100) / 450;
	Say "A small display on the lamp indicates the remaining charge: [charge]%.".
After examining the lamp:
	Try reading the lamp.

[Specific cases of reading something]
Does the player mean reading the carvings in near-tree: it is very likely.
Instead of reading the tree:
	Try reading the carvings.
Instead of reading the carvings:
	Say "The carvings say:   --> Morton's treehouse -- Six metres above <--[line break]".

Instead of reading the post:
	Say "[fixed letter spacing]";
	Say "   Remove Pole Straps From Wrists.";
	Say "         Do Not Swing Cars.";
	Say "   Do Not Throw Objects From List.";
	Say "See Attendant Should Lift Malfunction.";
	Say "[roman type]".

Instead of reading the button:
	Say "- HIGH VOLTAGE -[line break]".

Instead of reading the label:
	Say "[fixed letter spacing]";
	Say "      This is the TRINITY/3000 Automatic Coupler.";
	Say "               Pull knob for directions...";
	Say "        Mgfd. by FROBOZZ MAGIC COMPUTER COMPANY.";
	Say "[roman type]".

Instead of reading the board:
	Say "[fixed letter spacing]";
	Say "The bulletin board Says:[line break]";
	Say "                        MOUNT FROBOZZ SKI RESORT[line break]";
	Say "                           Ski lodge ^ (west)[line break]";
	Say "              <- Bunny Slope (south)   Expert Slope (north) ->[line break]";
	Say "[roman type]".

Instead of reading the note:
	Say "[fixed letter spacing]";
	Say "The note Says: 'Thou who hast desecrated the Hallowed Tomb of[line break]";
	Say "                Malak Fa'ar shall be forever plagued by[line break]";
	Say "                His deadly curse!![line break]";
	Say "At the bottom is scribbled the word:[line break]";
	Say "                       ARGYLE[line break]";
	Say "[roman type]".

Instead of reading the book:
	Say "[fixed letter spacing]";
	Say "            Care and Feeding of Your Zarka[line break]";
	Say "                Copyright (C) 1999 by[line break]";
	Say "[line break]";
	Say "              FROBOZZ MAGIC BOOK COMPANY.[line break]";
	Say "                All rights reserved.[line break]";
	Say "[line break]";
	Say "         Zarkas need a daily supply of water,[line break]";
	Say "         and like a good combing every week.[line break]";
	Say "         They eat very little, but when they[line break]";
	Say "         are hungry, they are very picky.[line break]";
	Say "[line break]";
	Say "         Most zarkas will eat only pizza, and[line break]";
	Say "         this preference was probably estab-[line break]";
	Say "         lished by the unusual climate in which[line break]";
	Say "         they live.  Zarkas always enjoy a day[line break]";
	Say "         outside, which helps to make their[line break]";
	Say "         reddish-purple fur shiny.  Because of[line break]";
	Say "         their size, they can be found anywhere[line break]";
	Say "         particularly near caves, usually in[line break]";
	Say "         an enclosed place.  They love precious[line break]";
	Say "         metals.  Zarkas have an interesting[line break]";
	Say "         way of reproducing: they find anoth...[line break]";
	Say "[line break]";
	Say "The Printing has faded with age and becomes undecipherable here.";
	Say "[roman type]".

Instead of reading the parchment:
	Say "[fixed letter spacing]";
	Say "The parchment contains words and sketches:[line break]";
	Say "           ------------------------[line break]";
	Say "           | Le Jardin       /    |[line break]";
	Say "           |                /     |[line break]";
	Say "           |               /      |[line break]";
	Say "           |  La Route -> /       |[line break]";
	Say "           |             /        |[line break]";
	Say "           |   ----------         |[line break]";
	Say "           |  /                   |[line break]";
	Say "           |_/          \ /       |[line break]";
	Say "           |             X        |[line break]";
	Say "           |            / \       |[line break]";
	Say "           ------------------------[line break]";
	Say "[roman type]".

Instead of reading the globe:
	Say "[fixed letter spacing]";
	Say "         This Globe is protected internally by[line break]";
	Say "         FROBOZZ MAGIC SECURITY SYSTEM[line break]";
	Say "         *************************************";
	Say "[roman type]".

Instead of reading the disc:
	Say "[fixed letter spacing]";
	Say "              FROBOZZ MAGIC SNO-DISC COMPANY[line break]";
	Say "              Instructions for use:[line break]";
	Say "[line break]";
	Say "              (1) First, BOARD the disc, and[line break]";
	Say "              (2) Second, LAUNCH it![line break]";
	Say "[line break]";
	Say "This SNO-DISC is guaranteed for 3.45 seconds from time of purchase, whichever comes first.[line break]";
	Say "Happy Landing![line break]";
	Say "[roman type]".

[Description of items]
The lamp is a device. "A battery-powered lamp.". The indefinite article of the lamp is "a".
The chest is a container. "A dusty oak chest". The indefinite article of the chest is "a".
The keys are a thing. "A set of iron keys". The indefinite article of the keys is "a set of".
The jewel is a thing. "Sparkling diamond jewelry". The indefinite article of the jewel is "a".
The gold is a thing. "A dazzling nugget of gold". The indefinite article of the gold is "a".
The witch is a woman. "A wrinkly old witch". The indefinite article of the witch is "a".
The girl is a woman. "A sexy young girl". The indefinite article of the girl is a "a".
The pearl is a thing. "A perfectly round pearl". The indefinite article of the pearl is "a".
The note is a thing. "An obscure, wrinkled note". The indefinite article of the note is "a".
The cello is a thing. "A Stradivarius cello". The indefinite article of the cello is "a".
The watch is a wearable thing. "A finely-crafted Swiss timepiece". The indefinite article of the watch is "a".
The parchment is a thing. "An ancient piece of parchment". The indefinite article of the parchment is "a".
The vase is a thing. "A delicate Ming vase". The indefinite article of the vase is "a".
The staff is a weapon. "A three-foot long staff". The indefinite article of the staff is "a".
The coins is a thing. "A set of very rare coins". The indefinite article of the coins is "some".
The knife is a weapon. "A sharp butcher's knife". The indefinite article of the knife is "a".
The slime is an animal. "A threatening mass of slime on the floor". The indefinite article of the slime is "a".
The stool is a portable supporter. "A soft, velvet foot stool". The indefinite article of the stool is "a".
The flask is a  unopenable transparent container. "A transparent glass flask".
The indefinite article of the flask is "[if water is in flask]a water-filled[otherwise]an empty[end if]".
The hills is a thing. "A great number of little dirt hills". The indefinite article of the hills is "some".
The beast is an animal. "A huge gorilla-like beast". The indefinite article of the beast is "a".
The cylinder is a thing. "A white crystal cylinder". The indefinite article of the cylinder is "a".
The zarka is an animal. "A horrible Zarka". The indefinite article of the zarka is "a".
The globe is a thing. "A shining Platinum globe with readable coating". The indefinite article of the globe is "a".
The snake is an animal. "A hungry looking black snake". The indefinite article of the snake is "a".
The rocks is a thing. "A wall of large rocks blocking your exit". The indefinite article of the rocks is "some".
The fries is a thing. "A large order of french fries". The indefinite article of the fries is "some".
The plate is a thing. "A Burgerland dinner plate". The indefinite article of the plate is "a".
The fish is a thing. "A filet-o-fish sandwich". The indefinite article of the fish is "a".
The clown is a person. "An odd clown with red hair and yellow overalls". The indefinite article of the clown is "a".
The can is a thing. "A can of disinfectant spray". The indefinite article of the can is "a".
The pizza slice is a thing. "A generous slice of pizza". The indefinite article of the pizza slice is "a".
The book is a thing. "A tiny yellow book with a broken binding". The indefinite article of the book is "a".
The ring is a wearable thing. "An emerald wedding ring". The indefinite article of the ring is "a".
The block is a thing. "A steamy white brick-like block". The indefinite article of the block is "a".
The pool is a fixed in place thing. "A pool of clear water [bracket]in waterfall[close bracket]". The indefinite article of the pool is "a".
The glove is a wearable thing. "A leather work glove". The indefinite article of the glove is "a".
The disc is a thing. "A silver disc with markings". The indefinite article of the disc is "a".
The shovel is a thing. "A dirty shovel". The indefinite article of the shovel is "a".
The statue is a thing. "A beautiful jade statue". The indefinite article of the statue is "a".
The comb is a thing. "An ivory-handled comb". The indefinite article of the comb is "a".
The pieces is a thing. "Worthless shards of pottery". The indefinite article of the pieces is "some".
The sapphire is a thing. "A flawless blue sapphire". The indefinite article of the sapphire is "a".
The boots is a wearable thing. "A pair of orange rubber boots". The indefinite article of the boots is "a pair of".
The cube is a thing. "A cube of pliable material". The indefinite article of the cube is "a".
The nurse is a person. "A menacing nurse with huge needle". The indefinite article of the nurse is "a".
The needle is a thing. "A sickening amber solution [bracket]in the needle[close bracket]". The indefinite article of the needle is "a".
The card is a thing. "A card with a green F and a brown strip on it". The indefinite article of the card is "a".
The painting is a thing. "A priceless painting of King Frobozz II". The indefinite article of the painting is "a".
The skull is a thing. "A magnificent crystal skull". The indefinite article of the skull is "a".
The water is a fixed in place thing. "A quantity of water". The indefinite article of the water is "some".

[Item weights]
The weight of the beast is -1. The weight of the block is 5. The weight of the book is 5. The weight of the boots is 0.
The weight of the can is 8. The weight of the card is 8. The weight of the cello is 30. The weight of the chest is 500.
The weight of the clown is -1. The weight of the coins is 5. The weight of the comb is 20. The weight of the cube is 5.
The weight of the cylinder is 50. The weight of the disc is 30. The weight of the fish is 4. The weight of the flask is 7.
The weight of the fries is 5. The weight of the girl is 80. The weight of the globe is 60. The weight of the glove is 5.
The weight of the gold is 60. The weight of the hills is 8. The weight of the jewel is 30. The weight of the keys is 4.
The weight of the knife is 10. The weight of the lamp is 5. The weight of the needle is 0. The weight of the note is 3.
The weight of the nurse is -1. The weight of the painting is 70. The weight of the parchment is 30. The weight of the pearl is 30.
The weight of the pieces is 18. The weight of the pizza slice is 5. The weight of the plate is 4. The weight of the ring is 30.
The weight of the rocks is 500. The weight of the sapphire is 75. The weight of the shovel is 10. The weight of the skull is 10.
The weight of the slime is -1. The weight of the snake is -1. The weight of the staff is 17. The weight of the statue is 40.
The weight of the stool is 30. The weight of the vase is 30. The weight of the watch is 30. The weight of the witch is -1.
The weight of the zarka is -1.
 
[Item values]
The points of the book is 10. The points of the cello is 20. The points of the coins is 35. The points of the fish is 5.
The points of the fries is 5. The points of the girl is 25. The points of the globe is 100. The points of the gold is 50.
The points of the jewel is 50. The points of the painting is 50. The points of the pearl is 50. The points of the plate is 5.
The points of the ring is 25. The points of the sapphire is 50. The points of the skull is 50. The points of the statue is 35.
The points of the vase is 10. The points of the watch is 20. The points of the zarka is 25.

[Objects that are not initially anywhere]
The coins are nowhere. The cylinder is nowhere. The fries are nowhere. The pieces are nowhere.
The girl is nowhere. The ring is nowhere. The rocks are nowhere. The statue is nowhere.
The water is nowhere. The zarka is nowhere.
	
[Alternate names for various objects]
Understand "nugget" as a gold. Understand "ming" as a vase. Understand "footstool" and "foot" and "chair" as a stool.
Understand "stradivarius" as a cello. Understand "timepiece" as a watch.
Understand "yellow" as a book. Understand "butcher" as a knife.
Understand "map" as a parchment. Understand "rod" and "wand" as a staff.
Understand "mine" and "mines" and "hill" and "dirt" as a hills. Understand "h20" as a pool.
Understand "gorilla" as a beast. Understand "sphere" and "coating" as a globe. Understand "viper" as a snake.
Understand "dinner" as a plate. Understand "filet" and "sandwich" as a fish. Understand "mitten" and "work" as a glove.
Understand "disinfectant" and "spray" as a can. Understand "john" as a toilet. Understand "bathtub" and "bath" as a tub.
Understand "farecard" and "fare" as a card. Understand "brush" and "ivory" as a comb.
Understand "brick" and "dry ice" and "ice" as a block. Understand "spade" and "tool" as a shovel.
Understand "disk" and "saucer" and "silver" as a disc. Understand "diamond" and "gem" as a jewel.
Understand "oxygum" and "gum" and "material" as a cube. Understand "boot" and "rubber" as a boots.
Understand "amber" and "solution" as a needle. Understand "art" and "picture" as the painting.
Understand "woman" or "bride" as a girl. Understand "bottle" as a flask. Understand "crystal" and "white" as a cylinder.
Understand "stones" and "rock" and "boulders" as a rocks. Understand "french things" as a fries.
Understand "emerald" and "wedding" as a ring. Understand "jade" as a statue.
Understand "shards" and "pottery" as a pieces. Understand "coin" as a coins. Understand "key" and "iron" as keys.
Understand "hag" as a witch. Understand "crystal skull" or "crystal" as skull. Understand "holes" as hole.

[Alternate names for various backdrops]
Understand "oak" as the tree.
Understand "treehouse" and "morton" and "mortons" as the structure.
Understand "stair" and "staircase" and "stairway" and "stairways" as the stairs.
Understand "glow" and "light" and "green" and "green glow" and "green light" as a green-glow.
Understand "glow" and "light" and "red" and "red glow" and "red light" as a red-glow.
Understand "glow" and "light" and "blue" and "blue glow" and "blue light" as a blue-glow.
Understand "glow" and "light" and "purple" and "purple glow" and "purple light" as a purple-glow.
Understand "lever" as a green-lever. Understand "lever" as a red-lever.
Understand "lever" as a blue-lever. Understand "lever" as a purple-lever.
Understand "oak" and "walls" and "oak walls" as the oak-walls.
Understand "chest" as the chest-interior. Understand "hole" and "ceiling" as ceiling-hole.
Understand "fog" and "eerie" as the mist. Understand "walls" as the shadows.
Understand "wooden thing" and "door" as the wooden. Understand "water" as the pool..
Understand "water" or "pool" as the oasis. Understand "door" as foyer-door.
Understand "door" as the house-door. Understand "signpost" and "sign" as a post.
Understand "low room" as the low-room.
Understand "rocks" or "rock" as rocky path. Understand "rocks" or "rock" as rocky floor.
Understand "key" and "beige" as a button. Understand "tram" and "contraption" and "gondola" and "chair" as a lift.
Understand "machine" and "large machine" and "trinity" and "3000" as a computer. Understand "red" and "button" as a knob.
Understand "sign" and "tan" as a label. Understand "mount" and "frobozz" as the mountain.
Understand "bulletin" and "notice" as a board. Understand "flashing" and "light" as the flashing-light.
Understand "animal" as animal-humming. Understand "dais" as a platform. Understand "rod" as the cylinder.
Understand "flashing" as the flashing-light. Understand "light" as the flashing-light.
Understand "insulation" and "slab" and "metal" as the slabs.  Understand "water" as reactor-water.
Understand "grating" as a grate. Understand "bronze" and "F" as a pillar. Understand "gate" and "slot" as the box.
Understand "shelves" or "shelf" as the library. Understand "living room" as the living. Understand "soupy" or "pool" as sand.
Understand "train" and "subway" as train-interior. Understand "subway" as train.

[Room Definitions]
vast-meadow is a room. vast-meadow is diggable. The printed name of vast-meadow is "Meadow".
The description of vast-meadow is "You're in a vast meadow that stretches endlessly in all directions.  To the west is a tree.".
near-tree is west of vast-meadow. nowhere is east of vast-meadow. nowhere is south of vast-meadow. nowhere is north of vast-meadow.
Instead of going nowhere from vast-meadow, Say "The Meadow is too vast to just wander around in it.".
meadow is a backdrop in vast-meadow. tree is a backdrop in vast-meadow.
Instead of examining the meadow in vast-meadow: Say "Other than the tree to the west, there is nothing else visible.".
Instead of examining the tree in vast-meadow: Say "It is to the west of here.".

near-tree is a room. near-tree is diggable. The printed name of near-tree is "Meadow Near Tree".
The description of near-tree is  "You're in the meadow, underneath a large oak tree.  There are small carvings on the tree, and they seem to mean something.".
vast-meadow is east of near-tree. tree-house is up from near-tree.
meadow is a backdrop in near-tree. tree is a backdrop in near-tree. carvings is a backdrop in near-tree.
Instead of examining the meadow in near-tree: Say "It stretches endlessly in all directions.".
Instead of examining the tree in near-tree: Say "It appears to be climbable.".
Instead of examining the structure in near-tree: Say "It appears to be a treehouse.".
The structure are in near-tree. The structure are fixed in place. "There is a small structure in the tree.".
Instead of going nowhere from near-tree:
	 Say "The Meadow is too vast to just wander around in it.".
Instead of examining the carvings in near-tree:
	Say "There appears to be something written there.".
Instead of cutting something in near-tree:
	If player has the knife:
		Say "An EPA official runs up and upon discovering you evil intent, sentences you to death.";
		End the story;
	Otherwise:
		Say "You don't have anything to cut with.".

tree-house is a room. The printed name of tree-house is "Treehouse".
The description of tree-house is "You're in a treehouse, barren of furnishings except a cubicle to the south, which is filled with shimmering green light.".
near-tree is down from tree-house. green-cubicle is south of tree-house. green-cubicle is inside from tree-house.
treehouse is a backdrop in tree-house. cubicle is a backdrop in tree-house.
Instead of examining the treehouse in tree-house: Say "It is barren of furnishings.".
Instead of examining the cubicle in tree-house: Say "Other than the green glow, there is nothing else you can see from here.".
The green-glow is a privately-named backdrop in tree-house. The printed name of the green-glow is "green glow".
Instead of examining the green-glow in tree-house: Say "It is coming from the cubicle.".
The lamp is in tree-house.

green-cubicle is a room. The printed name of green-cubicle is "Green Cubicle".
The description of green-cubicle is "You're in a cubicle. A green glow surrounds you on all sides, but it is impossible to see the source of it.".
tree-house is north of green-cubicle. tree-house is inside from green-cubicle.
cubicle is a backdrop in green-cubicle. 
green-glow is a privately-named backdrop in green-cubicle. The printed name of the green-glow is "green glow".
Instead of examining the cubicle in green-cubicle: Say "It is all around.".
Instead of examining the green-glow in green-cubicle: Say "You can't find the source of the green glow.".
The green-lever is a fixed in place privately-named thing in green-cubicle. "There is a black 6-inch lever embedded in the wall of the cubicle.".
The printed name of the green-lever is "lever".
Instead of pulling the green-lever in green-cubicle:
	Say "Your molecules shimmer away...";
	Move the player to small-room.

small-room is a room. small-room is dark. The printed name of small-room is "Small Room".
The description of small-room is "You are in a small, dark room with a passage to the north and a set of ascending stone stairs to the east.".
chest-room is north of small-room. turkish-bath is east from small-room. turkish-bath is up from small-room.
passage is a backdrop in small-room. stairs is a backdrop in small-room.
Instead of examining the passage in small-room: Say "It leads to the north.".

maze1 is a room. maze1 is dark. The printed name of maze1 is "Maze".
The description of maze1 is "You are in a twisting maze of little passages, all alike.".
maze1 is east of maze1. maze1 is up from maze1. maze1 is down from maze1.
nowhere is south of maze1. nowhere is north of maze1. maze2 is west of maze1. 
maze is a backdrop in maze1. "It is all around.".
passages is a backdrop in maze1. "They lead in many directions.".
The keys are in maze1.

maze2 is a room. maze2 is dark. The printed name of maze2 is "Maze".
The description of maze2 is "You are in a little maze of twisty passages, all alike.".
maze2 is north of maze2. maze2 is east from maze2. maze2 is down from maze2. nowhere is west of maze2.
maze3 is south of maze2. strobe-room is up from maze2.
maze is a backdrop in maze2. passages is a backdrop in maze2.

maze3 is a room. maze3 is dark. The printed name of maze3 is "Maze".
The description of maze3 is "You are in a twisty maze of little passages, all alike.".
maze3 is south from maze3. maze3 is west of maze3. maze3 is up from maze3. nowhere is east of maze3.
maze2 is west of maze1. mystery-room is down from maze3.
The maze is a backdrop in maze3. The passages is a backdrop in maze3.

chest-room is a room. chest-room is dark. The printed name of chest-room is "Chest Room".
The description of chest-room is "You are in a very dusty room with a teakwood floor.  You may leave this room to the north and south.".
maze1 is north of chest-room. small-room is south of chest-room.
The teakwood floor is a backdrop in chest-room. The padlock is a backdrop in chest-room. The lock is a backdrop in chest-room.
Instead of examining the teakwood floor in chest-room: Say "It is quite attractive.".
The chest is in chest-room. The chest is locked. The chest is closed. The matching key of the chest is the keys.
Instead of going down from chest-room:
	Try entering the chest.
Instead of going inside from chest-room:
	Try entering the chest.
Instead of entering the chest:
	If the chest is closed:
		Say "The chest is closed.[line break]";
	Otherwise:
		Say "You carefully manage to climb down into the chest.";
		Move player to in-chest.	
Instead of inserting something (called the item) into the chest:
	If the chest is open:
		Move the item to in-chest;
		Say "The [item] falls out of reach to the bottom of the chest.";
	Otherwise:
		Say "The chest is closed.".
Instead of searching the chest:
	If the chest is closed:
		Say "The chest is closed.";
	Otherwise:
		Let L be the list of things in in-chest;
		Let chest-empty be true;
		repeat with item running through L:
			If item is not a backdrop:
				If chest-empty is true:
					Say "At the bottom of the chest you can just make out the following items:[line break][line break]";
				Say the "[initial appearance of the item][line break]";
				Now chest-empty is false;
		If chest-empty is true:
			Say "The chest appears to be empty.".
Instead of examining chest:
	If the chest is locked:
		Say "The chest is closed and locked with a rusty padlock.";
	Otherwise If the chest is closed:
		Say "The chest is closed.";
	Otherwise:
		Say "The chest is open.";
		Try searching the chest.
After deciding the scope of the player when location is chest-room:
	If the chest is open:
		Let L be the list of things in in-chest;
		repeat with item running through L:
			If item is not a backdrop:
				Place the item in scope.
Rule for reaching inside in-chest:
	Say "The [noun] is just out of reach inside the chest.";
	Rule fails.

in-chest is a room. in-chest is dark. The printed name of in-chest is "Inside Chest".
The description of in-chest is "You are in a very small room with oak walls, and it's a little cramped.".
chest-room is up from in-chest. chest-room is outside from in-chest.
oak-walls is a privately-named backdrop in in-chest. The printed name of the oak-walls is "the oak walls".
chest-interior is a privately-named backdrop in in-chest. The printed name of the chest-interior is "the chest interior".
The gold is in in-chest.

mystery-room is a room. mystery-room is dark. The printed name of mystery-room is "Mystery Room".
The description of mystery-room is "You are in the Mystery Room, a very lovely room with exits to the east, west and south.  The hole in the ceiling is too far up to use.".
slime-room is south from mystery-room. time-chamber is east from mystery-room.
sea-hall is west from mystery-room. nowhere is up from mystery-room.
ceiling-hole is a privately-named backdrop in mystery-room. The printed name of the ceiling-hole is "the hole in the ceiling".
The witch is in mystery-room.
Before going a direction (called the path) from mystery-room:
	If witch is in mystery-room:
		If the room path from mystery-room is not last-room:
			Say "You can't get past the witch.";
			Stop the action;
		Otherwise:
			Say "You wisely back away from the witch.";
	Continue the action.
Instead of kissing witch in mystery-room:
	Say "Smack!";
	Say "There is a billowing cloud of yellowish-brown smoke!";
	Say "As the smoke clears, the hideous hag transforms into a sexy young girl!";
		Now the witch is nowhere;
	Move girl to mystery-room.
Instead of attacking the witch with a weapon (called the weapon):
	Say "The witch laughs at your attempt, and your weapon disintegrates.";
	Now the weapon is nowhere;
	Decrease score by points of the weapon.

sea-hall is a room. sea-hall is dark. The printed name of sea-hall is "Hall of the Sea".
The description of sea-hall is "You have entered the Hall of the Sea, a room filled with blue-green mists.  Mysterious shadows seem to dance upon the walls as your Lamp sheds light through the eerie colored fog.  The only exit is to the east.".
mystery-room is east from sea-hall.
sea is a backdrop in sea-hall. mist is a backdrop in sea-hall. shadows is a backdrop in sea-hall.
Instead of examining the sea in sea-hall: Say "Not much to see, but certainly not a good idea to swim in.";
Instead of examining the mist in sea-hall: Say "It is all around you.";
Instead of examining the shadows in sea-hall: Say "You can't see their source.".
The pearl is in sea-hall.
Instead of going west from sea-hall:
	If rocks are in catacomb-room:
		Say "The way is blocked by the huge boulders.";
	Otherwise:
		 Continue the action.

catacomb-room is a room. catacomb-room is dark. The printed name of catacomb-room is "Catacomb".
The description of catacomb-room is "You're in a damp, somewhat musty chamber that appears to be an ancient catacomb.  There is a door to the east.".
The wooden is a door. The wooden is openable and open. The wooden is west of catacomb-room and east of e-w-crawl.
The printed name of the wooden is "[if the wooden is open]open[otherwise]closed[end if] wooden door".
The initial appearance of the wooden is "Stately Wooden Door [bracket]door is [if the wooden is open]open[otherwise]closed[end if][close bracket]".
catacomb is a backdrop in the catacomb-room. chamber is a backdrop in the catacomb-room.
The note is in catacomb-room. The skull is in catacomb-room.
Instead of taking the skull:
	If rocks are nowhere:
		Say "Taken.[line break]";
		Say "Avalanche!  Huge boulders!  Aaaaaah! The way through the door to the west is now blocked.";
		Now the wooden is closed;
		Move rocks to catacomb-room;
		Move skull to the player;
	Otherwise:
		Continue the action.
Instead of opening the wooden:
	If rocks are in catacomb-room:
		Say "The rocks are blocking the door.";
	Otherwise:
		Continue the action.
Instead of closing the wooden :
	If rocks are in catacomb-room:
		Say "The rocks are blocking the door.";
	Otherwise:
		Continue the action.
Instead of going from catacomb-room:
	If rocks are in catacomb-room:
		Say "The way is blocked by the huge boulders.";
	Otherwise:
		 Continue the action.

turkish-bath is a room. turkish-bath is dark. The printed name of turkish-bath is "Turkish Bath".
The description of turkish-bath is "You're in the Turkish Bath.  Soothing mist surrounds you.  You may go down stone stairs to the west, or up a metal ramp To the east.".
garden-room is east from turkish-bath. small-room is west from turkish-bath. garden-room is up from turkish-bath. small-room is down from turkish-bath.
mist is a backdrop in turkish-bath. stairs is backdrop in turkish-bath. metal ramp is a backdrop in turkish-bath. bath is a backdrop in the turkish-bath.
Instead of examining the mist in turkish-bath: Say "It is quite soothing.".
Instead of examining the stairs in turkish-bath: Say "It leads downward to the west. Beyond that there is nothing else to see.".
Instead of examining the metal ramp in turkish-bath: Say "It leads upward to the east.  Beyond that there is nothing else to see.".
The flask is in turkish-bath.

garden-room is a room. garden-room is diggable. The printed name of garden-room is "Garden".
The description of garden-room is "You have entered a small garden.  The soil is very loose here.  To the west is a metal ramp that leads downward; to the north is a large glass building.".
green-house is north from garden-room. turkish-bath is west from garden-room. turkish-bath is down from garden-room.
garden is a backdrop in garden-room. soil is a backdrop in garden-room. ramp is a backdrop in garden-room. building is a backdrop in garden-room.
Instead of examining the garden in garden-room: Say "The garden is totally devoid of any plants.".
Instead of examining the soil in garden-room: Say "It appears to be rather loose here.".
Instead of examining the ramp in garden-room: Say "It leads downward to the west.  Beyond that there is nothing else to see.".
Instead of examining the building in garden-room: Say "It is to the north of here and appears to be a greenhouse.".
The vase is in garden-room.

green-house is a room. green-house is diggable. The printed name of green-house is "Greenhouse".
The description of green-house is "You're in an empty glass building that seems to have been used for a greenhouse.  To the north is a house; to the south is a garden;  to the west is a store room.".
house is a backdrop in green-house. garden is a backdrop in green-house.
greenhouse is a backdrop in green-house. The store room is a backdrop in the green-house.
Instead of examining the greenhouse in green-house:
	 Say "It is a well lit and comfortably warm greenhouse.  Any plants growing here originally must have been quite healthy.".
living-room is north from green-house. garden-room is south from green-house. store-room is west from green-house.

store-room is a room. store-room is dark. The printed name of store-room is "Store Room".
The description of store-room is "This is a very tiny store room that has a large hole in the floor on the western side of the room, and an exit to the east.".
green-house is east from store-room. tones-hall is west from store-room. tones-hall is down from store-room.
hole is a backdrop in store-room.
The stool is in store-room.

tones-hall is a room. tones-hall is dark. The printed name of tones-hall is "Hall of Tones".
The description of tones-hall is "You're in the Hall of Tones.  Pleasant tunes can be heard as you decide whether to go west, or up steep steps to the east.".
store-room is east from tones-hall. time-chamber is west from tones-hall. store-room is up from tones-hall.
The hall of tones is a backdrop in tones-hall. The steep steps is a backdrop in tones-hall.
The cello is in tones-hall.
Instead of listening in tones-hall:
	Say "You hear pleasant tones emanating from this room.".

time-chamber is a room. time-chamber is dark. The printed name of time-chamber is "Chamber of Time".
The description of time-chamber is "You are in a very beautiful room, the Chamber of Time.  Exits are to the east and west.".
tones-hall is east from time-chamber. mystery-room is west from time-chamber.
The chamber of time is a backdrop in time-chamber.
The watch is in time-chamber.

slime-room is a room. slime-room is dark. The printed name of slime-room is "Slime Room".
The description of slime-room is "This room's walls are covered with a mixture of blood and slimy ooze. Exists: North and south.".
mystery-room is north from slime-room. waterfall-base is south from slime-room.
mixture is a backdrop in the slime-room. blood is a backdrop in the slime-room. The slimy ooze is a backdrop in the slime-room.
Instead of examining a thing in slime-room:
	If noun is slime or noun is slimy ooze:
		If slime is in slime-room:
			Say "The slime is blocking your ability to pass through the room.";
		Otherwise:
			Say "The walls are quite disgusting looking.";
	Otherwise if noun is mixture or noun is blood:
		Say "The walls are quite disgusting looking.";
	Otherwise:
		Continue the action.
The slime is in slime-room.
Before going a direction (called the path) from slime-room:
	If slime is in slime-room:
		If the room path from slime-room is not last-room:
			Say "You can't get past the slime.";
			Stop the action;
		Otherwise:
			Say "You wisely back away from the slime.";
	Continue the action.
Instead of attacking the slime with a weapon (called the weapon):
	Say "The slime dissolves your [weapon] and a small part of your hand.";
	Now the weapon is nowhere;
	Decrease score by points of the weapon.

library-room is a room. The printed name of library-room is "Library".
The description of library-room is "You're in a library.  The only apparent exists to the room are: A passage to the south and an archway to the east.".
maze1 is south from library-room. kitchen-room is east from library-room.
passage is a backdrop in library-room. archway is a backdrop in library-room. library is a backdrop in library-room.
Instead of examining the passage in library-room: Say "Other than leading to the south, there is nothing else you can tell from here.".
Instead of examining the archway in library-room: Say "There is nothing else visible through the archway to the east.".
Instead of examining the library in library-room:
	If book is in library-room:
		 Say "Other than the yellow book, there are no other books left.";
	Otherwise:
		Say "The library is empty, all the books appear to have been taken.".
The book is in library-room.

kitchen-room is a room. The printed name of kitchen-room is "Kitchen".
The description of kitchen-room is "You're in a kitchen.  There are two exits, one to the west and one to the south.  The scent of food is in the air.".
living-room is south from kitchen-room. library-room is west from kitchen-room.
kitchen is a backdrop in kitchen-room.
Instead of smelling in kitchen-room: Say "The smell is making you hungry.".
The knife and pizza slice are in kitchen-room.

living-room is a room. The printed name of living-room is "Living Room".
The description of living-room is "You are in the living room of the house.  Exits: North, south, east, and a very narrow passage to the west.".
kitchen-room is north from living-room. green-house is south from living-room. foyer-entrance is east from living-room. maze1 is west from living-room.
The narrow passage is a backdrop in living-room.
The living room is a backdrop in living-room. The description of the living is "living room".
Instead of examining the narrow passage in living-room: Say "It leads to the west.  What is beyond it is not obvious from here.".
Instead of examining the living room in living-room: Say "The living room is devoid of any furnishings.".
The parchment is in living-room.

foyer-entrance is a room. The printed name of foyer-entrance is "Foyer".
The description of foyer-entrance is "You are in a small foyer, barren of any furnishings, except for a large glass cubicle to the south, which is filled with shimmering red light. Exits: East and west, and a northern exit leading upstairs.".
hall-way is north from foyer-entrance. red-cubicle is south from foyer-entrance. front-yard is east from foyer-entrance.
living-room is west from foyer-entrance. hall-way is up from foyer-entrance. red-cubicle is inside from foyer-entrance.
cubicle is a backdrop in foyer-entrance. foyer is a backdrop in foyer-entrance. stairs is a backdrop in foyer-entrance.
red-glow is a privately-named backdrop in foyer-entrance. The printed name of the red-glow is "red glow". 
Instead of examining the cubicle in foyer-entrance: Say "Other than the red glow, there is nothing else you can see from here.".
Instead of examining the red-glow in foyer-entrance: Say "It is coming from the cubicle.".
The foyer-door is a privately-named backdrop in foyer-entrance. The printed name of the foyer-door is "door to the house".
Instead of opening the foyer-door in foyer-entrance: Say "The door is already open.".
Instead of closing the foyer-door in foyer-entrance: Say "The door appears to be stuck open.".

red-cubicle is a room. The printed name of red-cubicle is "Red Cubicle".
The description of red-cubicle is "You are in a glass cubicle.  Surrounding you is a shimmering red glow, but it is impossible to see the source of it.".
foyer-entrance is north from red-cubicle. foyer-entrance is outside from red-cubicle.
cubicle is a backdrop in red-cubicle.
red-glow is a privately-named backdrop in red-cubicle. The printed name of the red-glow is "red glow".
Instead of examining the cubicle in red-cubicle: Say "It is all around.".
Instead of examining the red-glow in red-cubicle: Say "You can't find the source of the red glow.".
The red-lever is a fixed in place privately-named thing in red-cubicle. "There is a black 6-inch lever embedded in the wall of the cubicle.".
The printed name of the red-lever is "lever".
The staff is in red-cubicle.
Instead of pulling the red-lever in red-cubicle:
	Say "Your molecules shimmer away...";
	Move the player to green-cubicle.

waterfall-base is a room. waterfall-base is diggable. The printed name of waterfall-base is "Waterfall".
The description of waterfall-base is "You're in a cool room with a towering waterfall filling up the eastern part of the room.  You're on a path that bends north and west, and there's a glass cubicle to the south, which is filled with shimmering blue light.".
slime-room is north from waterfall-base. blue-cubicle is south from waterfall-base. mine-field is west from waterfall-base. blue-cubicle is inside from waterfall-base.
cubicle is a backdrop in waterfall-base. light is a backdrop in waterfall-base. waterfall is a backdrop in waterfall-base.
blue-glow is a privately-named backdrop in waterfall-base. The printed name of the blue-glow is "blue glow".
Instead of examining the waterfall in waterfall-base: Say "It is quite beautiful, but so tall you can barely see the top.".
Instead of examining the pool in waterfall-base: Say "It fills a pool underneath the waterfall, but you can't see where it drains out to.".
Instead of examining the cubicle in waterfall-base: Say "Other than the blue glow, there is nothing else you can see from here.".
Instead of examining the blue-glow in waterfall-base: Say "It is coming from the cubicle.".
Carry out looking in waterfall-base:
	Move the pool to waterfall-base;
	Continue the action.
Instead of listening in waterfall-base:
	Say "You hear the sound of cool water splashing all around you.".

mine-field is a room. mine-field is diggable. The printed name of mine-field is "Mine Field".
The description of mine-field is "This room is only five feet high, and has exits to the south and east.".
sewer-north is south from mine-field. waterfall-base is east from mine-field.
The hills is in mine-field.
Before going a direction (called the path) from mine-field:
	If hills is in mine-field:
		If the room path from mine-field is not last-room:
			Say "As you walk across the room, your foot crushes one of the little dirt hills, and you suddenly feel very dead.";
			End the story;
		Otherwise:
			Say "You wisely back away from the mine field.";
	Continue the action.
Instead of waving the staff in mine-field:
	If the hills are in mine-field:
		Say "The little hills are gone!";
		Increase score by 10;
		Now the hills are nowhere;
	Otherwise:
		Continue the action;

blue-cubicle is a room. The printed name of blue-cubicle is "Blue Cubicle".
The description of blue-cubicle is "You are in a glass cubicle.  Surrounding you is a shimmering blue glow, but it is impossible to see the source of it.".
waterfall-base is north from blue-cubicle. waterfall-base is outside from blue-cubicle.
cubicle is a backdrop in blue-cubicle.
Instead of examining the cubicle in blue-cubicle: Say "It is all around.".
blue-glow is a privately-named backdrop in blue-cubicle. The printed name of the blue-glow is "blue glow".
Instead of examining the blue-glow in blue-cubicle: Say "You can't find the source of the blue glow.".
The blue-lever is a fixed in place privately-named thing in blue-cubicle. "There is a black 6-inch lever embedded in the wall of the cubicle.".
The printed name of the blue-lever is "lever".
Instead of pulling the blue-lever in blue-cubicle:
	Say "Your molecules shimmer away...";
	Move the player to red-cubicle.

sewer-north is a room. sewer-north is dark. The printed name of sewer-north is "Sewer Pipe".
The description of sewer-north is "You are at the northern end of a very long sewer pipe.  To the north is a low room, and there are numerous holes in the floor of the pipe.".
mine-field is north from sewer-north. sewer-south is south from sewer-north. treasure-room is down from sewer-north.
hole is a backdrop in sewer-north. pipe is a backdrop in sewer-north. sewer is a backdrop in the sewer-north.
low-room is a privately-named backdrop in sewer-north. The printed name of low-room is "the low room".
Instead of examining the hole in sewer-north: Say "You can't see anything down in the various holes.".
Instead of examining the pipe in sewer-north: Say "It is all around.  You cannot see the end of it from here.".
Instead of examining the low-room in sewer-north: Say "You will need to go north to see more.".
The beast is in sewer-north.
Before going a direction (called the path) from sewer-north:
	If beast is in sewer-north:
		If the room path from sewer-north is not last-room:
			Say "You can't get past the beast.";
			Stop the action;
		Otherwise:
			Say "You wisely back away from the beast.";
	Continue the action.
After playing the cello:
	If the beast is in sewer-north and player is in sewer-north and player has the cello:
		Say "The beast is calmed by your music and leaves.";
		Now the beast is nowhere.
Instead of attacking the beast with a weapon (called the weapon):
	Say "As you thrust toward the beast, he grabs your arm, causing you to release the [weapon].  He then proceeds to break it in half.";
	Now the weapon is nowhere;
	Decrease score by points of the weapon.

treasure-room is a room. treasure-room is dark. The printed name of treasure-room is "Treasure Room".
The description of treasure-room is "This giant room is the home of the most valuable treasure in the cave. In the direct center of the room, a sphere of great beauty was placed many years ago.  The only exits to this room are the stairs above you and a passage to the west.".
sewer-north is up from treasure-room. e-w-passage is west from treasure-room.
stairs is a backdrop in treasure-room.
The globe is in treasure-room.
Instead of taking the globe in treasure-room:
	If weight of zarka is -1:
		If the zarka is in treasure-room:
			Say "The Zarka won't let you have the globe.";
		Otherwise:
			Say "As you reach for the globe, an alarm rings briefly, and a horrible Zarka appears from inside to defend it!";
			Move zarka to treasure-room;
	Otherwise:
		Continue the action.
Before going a direction (called the path) from treasure-room:
	If weight of zarka is -1 and the zarka is in treasure-room:
		If the room path from treasure-room is not last-room:
			Say "You can't get past the zarka.";
			Stop the action;
		Otherwise:
			Say "You wisely back away from the zarka.";
	Continue the action.
Instead of attacking the zarka with a weapon (called the weapon):
	Say "The Zarka grabs the [weapon] from you and breaks it in half.";
	Now the weapon is nowhere;
	Decrease score by points of the weapon.
Instead of giving the pizza slice to the zarka in treasure-room:
	Say "The Zarka becomes you friend for life and shows you an exit on the western wall.";
	Now the pizza slice is nowhere;
	Now the weight of the zarka is 50;

viper-pit is a room. viper-pit is diggable. The printed name of viper-pit is "Viper Pit".
The description of viper-pit is "You're in a deep pit.  The only exit is straight up.".
front-yard is up from viper-pit. front-yard is outside from viper-pit.
pit is a backdrop in viper-pit.
Instead of examining the pit in viper-pit: Say "It is a deep pit and you are in the bottom of it. Climbing out of it the only exit.".
The snake is in viper-pit.
Before going a direction (called the path) from viper-pit:
	If snake is in viper-pit:
		If the room path from viper-pit is not last-room:
			Say "You can't get past the snake.";
			Stop the action;
		Otherwise:
			Say "You wisely back away from the snake.";
	Continue the action.
Instead of attacking the snake with the knife:
	Say "The snake is wounded.  He crawls away to reveal a large number of rare coins!";
	Now the snake is nowhere;
	Increase score by 10;
	Move coins to viper-pit.
[Possible alternate solution for attacking the snake:
Instead of attacking the snake with the knife:
	Say "You can't get close enough to the snake with just a knife. You wisely stop.".
Instead of attacking the snake with the staff:
	Say "The snake is wounded.  He crawls away to reveal a large number of rare coins!";
	Increase score by 10;
	Now the snake is nowhere;
	Move coins to viper-pit.]

front-yard is a room. front-yard is diggable. The printed name of front-yard is "Front Yard".
The description of front-yard is "You're in the front yard of the house. To the west is a door, to the south a dark hole, and meadow everywhere else.".
house-north is north from front-yard. vast-meadow is east from front-yard. foyer-entrance is west from front-yard.
viper-pit is down from front-yard. foyer-entrance is inside from front-yard.
yard is a backdrop in front-yard. hole is a backdrop in front-yard. meadow is a backdrop in front-yard. house is a backdrop in front-yard.
The house-door is a privately-named backdrop in front-yard. The printed name of the house-door is "door to the house".
Instead of opening the house-door in front-yard: Say "The door is already open.".
Instead of closing the house-door in front-yard: Say "The door appears to be stuck open.".

house-north is a room. house-north is diggable. The printed name of house-north is "North of House".
The description of house-north is "You're in a meadow, north of a house.  Far to the north, a tiny oasis is visible.".
burger-land is north from house-north. front-yard is south from house-north. vast-meadow is east from house-north. vast-meadow is west from house-north.
house is a backdrop in house-north. oasis is a backdrop in house-north. meadow is a backdrop in house-north.

burger-land is a room. The printed name of burger-land is "Burgerland".
The description of burger-land is "You're in Burgerland!  A meadow surrounds this tiny oasis, which has no apparent entrance.".
burgl-north is north from burger-land. house-north is south from burger-land. vast-meadow is east from burger-land. vast-meadow is west from burger-land.
The plate and fish and clown are in burger-land.
meadow is a backdrop in burger-land. oasis is a backdrop in burger-land.
Instead of examining the pool in burger-land: Say "There is nothing particularly interesting about it.".
Instead of examining the oasis in burger-land: Say "There does not appear to be very much water in it.".
Before going a direction (called the path) from burger-land:
	If clown is in burger-land:
		If the room path from burger-land is not last-room:
			Say "You can't get past the clown.";
			Stop the action;
		Otherwise:
			Say "You wisely back away from the clown.";
	Continue the action.
Instead of taking something in burger-land:
	If clown is in burger-land:
		If something is the plate or something is the fish:
			Say "The clown prevents you from taking that.";
			Stop the action;
	Continue the action.
Instead of attacking the clown with the knife:
	Say "The clown becomes terrified, drops his french fries, and runs into the meadow.";
	Now the clown is nowhere;
	Move fries to burger-land;
	Increase score by 10.
Instead of attacking the clown with the staff:
	Say "The clown manages to avoid your slow swing with the staff.".

hall-way is a room. The printed name of hall-way is "Hallway".
The description of hall-way is "You're in a hallway.  There are various openings to the north and west, and two stairways: one leading up to the east and one down to the foyer.".
sitting-room is north from hall-way. attic-room is east from hall-way. bath-room is west from hall-way. attic-room is up from hall-way. foyer-entrance is down from hall-way.
stairs is a backdrop in hall-way. hallway is a backdrop in the hall-way.
Instead of examining the stairs in hall-way: Say "One goes up, one goes down.".

attic-room is a room. The printed name of attic-room is "Attic".
The description of attic-room is "You're in the attic.  The only exit is a stairway leading downward.".
hall-way is down from attic-room.
attic is a backdrop in attic-room. stairs is a backdrop in attic-room.
Instead of examining the attic in attic-room: Say "There is not much to see.".
Instead of examining the stairs in attic-room: Say "The stairs lead down.".
The glove is in attic-room.

bath-room is a room. The printed name of bath-room is "Bathroom".
The description of bath-room is "You're in and old-fashioned bathroom, a very tidy place, with exits to the north and east.".
bed-room is north from bath-room. hall-way is east from bath-room.
bathroom is a backdrop in the bath-room.
The can and the toilet and the tub are in bath-room.
The tub is a fixed in place container. "An Old-fashioned bathtub".
The toilet is a fixed in place supporter. "A Porcelain Toilet".
Instead of entering the tub:
	Move player to tub.

bed-room is a room. The printed name of bed-room is "Bedroom".
The description of bed-room is "You're in a large room, probably the master bedroom.  There is an exit to the south, and one to the east.".
bath-room is south from bed-room. sitting-room is east from bed-room.
bedroom is a backdrop in the bed-room.
The bed is in bed-room. The bed is a vehicle. "A King-size bed".
The card is in bed-room.
Instead of going to bed-room:
	If married is false and girl-following is true:
		If the location of the girl is not the location of the player:
			Move girl to location of the player;
			Say "The girl suddenly appears next to you, however:[line break]";
		Say "A mysterious force prevents you from entering the room (leave the girl outside).";
		Try looking;
	Otherwise:
		Continue the action.

sitting-room is a room. The printed name of sitting-room is "Sitting Room".
The description of sitting-room is "You're in the sitting room.  Exits: west and south, and a cubicle to the east, filled with shimmering purple light.".
hall-way is south from sitting-room. purple-cubicle is east from sitting-room. bed-room is west from sitting-room. purple-cubicle is inside from sitting-room.
cubicle is a backdrop in sitting-room. The sitting room is a backdrop in the sitting-room.
purple-glow is a privately-named backdrop in sitting-room. The printed name of the purple-glow is "purple glow".
Instead of examining the cubicle in sitting-room: Say "Other than the purple glow, there is nothing else you can see from here.".
Instead of examining the purple-glow in sitting-room: Say "It is coming from the cubicle.".
The comb is in sitting-room.

purple-cubicle is a room. The printed name of purple-cubicle is "Purple Cubicle".
The description of purple-cubicle is "You're in a cubicle.  A purple glow surrounds you, but you cannot see the source of it.".
sitting-room is west from purple-cubicle. sitting-room is outside from purple-cubicle.
cubicle is a backdrop in purple-cubicle.
purple-glow is a privately-named backdrop in purple-cubicle. The printed name of the purple-glow is "purple glow".
Instead of examining the cubicle in purple-cubicle: Say "It is all around.".
Instead of examining the purple-glow in purple-cubicle: Say "You can't find the source of the purple glow.".
The purple-lever is a fixed in place privately-named thing in purple-cubicle. "There is a black 6-inch lever embedded in the wall of the cubicle.".
The printed name of the purple-lever is "lever".
Instead of pulling the purple-lever in purple-cubicle:
	Say "Your molecules shimmer away...";
	Move the player to blue-cubicle.

e-w-passage is a room. e-w-passage is dark. The printed name of e-w-passage is "East-West Passage".
The description of e-w-passage is "You're in a very tight east-west passageway.  There is also a small hole in the floor on the northern side of the passage.  A freezing wind blows out of the hole.".
cold-room is north from e-w-passage. cold-room is down from e-w-passage. treasure-room is east from e-w-passage. sandy-shore is west from e-w-passage.
hole is a backdrop in e-w-passage. passage is a backdrop in the e-w-passage.

cold-room is a room. cold-room is dark. The printed name of cold-room is "Cold Room".
The description of cold-room is "You're in an extremely cold room.  Icicles hang from the ceiling, and near a particularly large icicle in the southern part of the room, is a hole.".
e-w-passage is south from cold-room. e-w-passage is up from cold-room.
hole is a backdrop in cold-room. icicles is a backdrop in cold-room. icicle is a backdrop in the cold-room.
The block is in cold-room.

sandy-shore is a room. sandy-shore is diggable. The printed name of sandy-shore is "Sandy Shore".
The description of sandy-shore is "You're on a sandy shore.  To the west is some more sand, but it seems to be mixed with water.  There is a tight passage leading east.".
e-w-passage is east from sandy-shore. quicksand-pool is west from sandy-shore.
passage is a backdrop in sandy-shore. shore is a backdrop in sandy-shore. sand is a backdrop in sandy-shore.
sandy-water is a privately-named backdrop in sandy-shore. The printed name of the sandy-water is "water".

quicksand-pool is a room. quicksand-pool is diggable. The printed name of quicksand-pool is "Quicksand".
The description of quicksand-pool is "You're in a pool of sand.  To the west you can see a path leading outside, and to the east, a shore.".
sandy-shore is east from quicksand-pool. rocky-path is west from quicksand-pool.
quicksand is a backdrop in quicksand-pool. path is a backdrop in quicksand-pool. shore is a backdrop in quicksand-pool.
quicksand-frozen is a truth state that varies. quicksand-frozen is initially false.
The quicksand-countdown is a number that varies. quicksand-countdown is 5.
Before going a direction (called the path) from quicksand-pool:
	If quicksand-frozen is false:
		If the room path from quicksand-pool is not last-room:
			Say "The quicksand is too deep to allow going in that direction.";
			Say "[line break]";
			Try silently waiting;
			Say "[run paragraph on]";
			Stop the action;
		Otherwise:
			Say "You manage to pull yourself free.";
			Now quicksand-countdown is 5;
	Continue the action.
After doing something in quicksand-pool:
	If going to quicksand-pool:
		Continue the action;
	Otherwise if quicksand-frozen is false:
		Decrease quicksand-countdown by 1;
		If quicksand-countdown is greater than 0:
			Say "You are sinking in quicksand.";
		Otherwise:
			Say "You are at the bottom of a pool of quicksand.  You have died.";
			End the story;
	Continue the action.
After dropping the block in quicksand-pool:
	If quicksand-frozen is not true:
		Say "As the block sinks, the quicksand instantly freezes over hard enough to support your weight.";
		Now the quicksand-frozen is true;
		Increase score by 25.

rocky-path is a room. The printed name of rocky-path is "Rocky Path".
The description of rocky-path is "The floor here is quite rocky, making your footing quite unsure.  You're on a path with a lighted passage to the south and a dark tunnel to the north. To the east is a somewhat soupy pool of sand.".
archaeology-room is north from rocky-path. base-of-mountain is south from rocky-path. quicksand-pool is east from rocky-path.
passage is a backdrop in rocky-path. tunnel is a backdrop in rocky-path. soupy pool of sand is a backdrop in rocky-path.
rocky path is a backdrop in rocky-path.
Instead of examining the passage in rocky-path: Say "Not much to see other than the fact it leads to the south.".
Instead of examining the tunnel in rocky-path: Say "It leads to the north, but otherwise it is too dark to see where it goes.".
Instead of examining the soupy pool of sand in rocky-path: Say "You can't see any detail from here.".

base-of-mountain is a room. base-of-mountain is diggable. The printed name of base-of-mountain is "Base of Mountain".
The description of base-of-mountain is "You're at the base of a mountain.  It is snowing lightly here, partially covering an assortment of heavy wires.  To the north is a cave leading underground.".
rocky-path is north from base-of-mountain.
mountain is a backdrop in base-of-mountain. snow is a backdrop in base-of-mountain.
wires is a backdrop in base-of-mountain. cave is a backdrop in base-of-mountain.
Instead of examining the mountain in base-of-mountain: Say "It stretches up before you.".
Instead of examining the snow in base-of-mountain: Say "It is lightly snowing, the ground is covered fairly deep already.".
Instead of examining the wires in base-of-mountain: Say "Some of the wires appear to connect the button with the lift.".
Instead of examining the cave in base-of-mountain: Say "You can't make out any details other than it being north of here.".
The post is in base-of-mountain. The post is fixed in place. "Signpost partially covered with snow".
The button is in base-of-mountain. The button is fixed in place. The button can be pushed. "Beige button marked ~ HIGH VOLTAGE ~".
The lift is in base-of-mountain. The lift is fixed in place. The lift is a container. "Strange contraption".
Carry out looking in base-of-mountain:
	Move the button to base-of-mountain; Move the lift to base-of-mountain;
	Continue the action.
Instead of entering the lift:
	Try pushing the button.
Instead of pushing the button:
	Say "The lift lurches forward and carries you swiftly into the sky.  A striking view of the Mt. Frobozz panorama can be seen.[line break][line break]";
	Say "After traveling for several minutes, the lift stops with a jerk and drops you in the snow.[line break]";
	If player is in base-of-mountain:
		Move player to summit-of-mountain;
	Otherwise:
		Move player to base-of-mountain.

archaeology-room is a room. archaeology-room is dark. archaeology-room is diggable. The printed name of archaeology-room is "Archaeology Room".
The description of archaeology-room is "You're in a room filled with cobwebs.  There appear to have been recent archaeological diggings in this area.  Passages exit to the north and south.".
cobwebs is a backdrop in archaeology-room. diggings is a backdrop in archaeology-room.
church-chapel is north from archaeology-room. rocky-path is south from archaeology-room.
The shovel is in archaeology-room.

church-chapel is a room. The printed name of church-chapel is "Chapel".
The description of church-chapel is "You're in a small, but elaborately decorated chapel.  There is a large machine in one corner of the room, and it is covered with dust. The only exit to the room is an archway to the south.".
archaeology-room is south from church-chapel.
dust is a backdrop in church-chapel. archway is a backdrop in church-chapel.
The computer is in church-chapel. The computer is fixed in place. "Large machine".
The knob is in church-chapel. The knob is fixed in place. "Small red knob [bracket]on the machine[close bracket]".
The label is in church-chapel. The label is fixed in place. "Tiny tan label [bracket]on the machine[close bracket]".
Before pulling the knob:
	Try pushing the knob;
	Stop the action.
Before turning the knob:
	Try pushing the knob;
	Stop the action.
Instead of pushing the knob:
	If married is true:
		Say "As you pull the knob, a metallic voice is heard (seemingly emanating from within): 'I cannot join those who are already married.'";
	Otherwise:
		Say "Welcome to the FROBOZZ Automatic Coupler![line break]";
		Say "This machine will perform a wedding ceremony provided that both parties consent.";
		If the girl is not in church-chapel:
			Say "There's only one problem:  I don't see any girl here!";
		Otherwise:
			Say "Dearly beloved, we are gathered here to join this man and this woman in Holy Matrimony.[line break]";
			Say "Do you take this girl to be your wife?";
			If player consents:
				Say "Girl: 'I guess.[line break]";
				Say "Is there anyone here who knows a reason why this couple should not be wed?";
				If player consents:
					Say "This wedding is officially aborted.";
				Otherwise:
					Say "Good...By the power vested in me by the FROBOZZ Magic Computer Company, I now pronounce you man & wife.[line break]";
					Say "[bracket]A sparkling emerald wedding ring drops from a slot in the machine![close bracket][line break]";
					Say "You may kiss the bride.";
					Move ring to church-chapel;
					Now married is true;
					Increase score by 25.

summit-of-mountain is a room. The printed name of summit-of-mountain is "Summit of Mountain".
The description of summit-of-mountain is "You're at the summit of Mount Frobozz.  The eastern slope is impassable, hut there are trails to the north and south.  An inviting, cozy lighted shack is to the west.  It is snowing quite heavily here.".
expert-trail is north from summit-of-mountain. bunny-slope is south from summit-of-mountain. ski-shack is west from summit-of-mountain. ski-shack is inside from summit-of-mountain.
mountain is a backdrop in summit-of-mountain. snow is a backdrop in summit-of-mountain. slope is a backdrop in summit-of-mountain.
Instead of examining the mountain in summit-of-mountain:
	Say "Even through the heavy snow, the view from the summit is breathtaking.".
The board is a fixed in place thing in summit-of-mountain. "Immense bulletin board".
Carry out looking in summit-of-mountain:
	Move the button to summit-of-mountain; Move the lift to summit-of-mountain;
	Continue the action.

expert-trail is a room. The printed name of expert-trail is "Expert Trail".
The description of expert-trail is "You're at the top of the Expert Slope, a sheet of ice plunging downward out of sight at an unpleasant angle.  A small snowy trail leads away south.".
summit-of-mountain is south from expert-trail. expert-trail is down from expert-trail.
slope is a backdrop in expert-trail. ice is a backdrop in expert-trail. snow is a backdrop in expert-trail. snowy trail is a backdrop in expert-trail.
Instead of examining the slope in expert-trail: Say "The slope is extremely steep.  Not only is walking down out of the question, riding down would be ill advised.".
Instead of examining the snowy trail in expert-trail: Say "You can't tell anything else from here, other than it leads to the south.".
Instead of going down from expert-trail:
	Say "Walking down would be suicide.".

bunny-slope is a room. The printed name of bunny-slope is "Bunny Slope".
The description of bunny-slope is "You're at the top of the Bunny Slope!  It seems as though a child would have no problem skiing down, although walking down is out of the question. A path leads away to the north.".
summit-of-mountain is north from bunny-slope. bunny-slope is down from bunny-slope.
slope is a backdrop in bunny-slope. ice is a backdrop in bunny-slope. snow is a backdrop in the bunny-slope.
Instead of examining the slope: Say "While not too steep, riding something is the only way to get to the bottom.".
Instead of going down from bunny-slope:
	Say "Walking down is not possible.".

ski-shack is a room. The printed name of ski-shack is "Ski Shack".
The description of ski-shack is "You are in a comfortable ski shack, apparently a shelter from the cold weather outside.  There's a rickety staircase leading downward in this building.".
summit-of-mountain is east from ski-shack. dark-cave is down from ski-shack. summit-of-mountain is outside from ski-shack.
stairs is a backdrop in ski-shack. shack is a backdrop in ski-shack. weather is a backdrop in the ski-shack.
Instead of examining the stairs in ski-shack: Say "The stairs lead downward.".
Instead of examining the shack in ski-shack: Say "It really helps to protect from the outside cold.".
The disc is in ski-shack.

dark-cave is a room. dark-cave is dark. The printed name of dark-cave is "Cave".
The description of dark-cave is "You're in a dark cave with a rocky floor.  There is a stairway leading up and an eastern passage.".
e-w-crawl is east from dark-cave. ski-shack is up from dark-cave.
stairs is a backdrop in dark-cave. rocky floor is a backdrop in dark-cave.
Instead of examining the stairs in dark-cave: Say "The stairs lead up.".
The jewel is in dark-cave.

e-w-crawl is a room. e-w-crawl is dark. The printed name of e-w-crawl is "East-West Crawl".
The description of e-w-crawl is "You're crawling over rocky cobbles in an east-west passage.  At the eastern end is a formidable wooden door.".
dark-cave is west from e-w-crawl.
cobbles is a backdrop in e-w-crawl.
Instead of going east from e-w-crawl:
	If rocks are in catacomb-room:
		Say "The way is blocked by the huge boulders.";
	Otherwise:
		 Continue the action.

strobe-room is a room. The printed name of strobe-room is "Strobe Room".
The description of strobe-room is "You are in a very peculiar room with no apparent exits.  There is an unusual flashing light that fills the room, seemingly coming from far above you.".
maze2 is down from strobe-room.
flashing-light is a privately-named backdrop in strobe-room. The printed name of flashing-light is "flashing light".
Instead of examining the flashing-light: Say "It is coming from somewhere above, but you can't make out the source.".
The cube is in strobe-room.

sewer-south is a room. sewer-south is dark. The printed name of sewer-south is "Sewer Pipe".
The description of sewer-south is "You're in a very long, north-south sewer pine.  You ran hear a strange, distant, echoing sound, apparently an animal humming to himself.".
sewer-north is north from sewer-south. sewer-south is south from sewer-south. The sewer is a backdrop in the sewer-north.
animal-humming is a privately-named backdrop in sewer-south. The printed name of animal-humming is "animal humming".
Instead of examining the animal-humming in sewer-south:
	Say "You can't see any animal here, but you can here it.".
Instead of listening to animal-humming in sewer-south:
	Try listening.
Instead of listening in sewer-south:
	Say "You hear a strange, distant echoing sound, apparently an animal.".

wet-room is a room. The printed name of wet-room is "Wet Room".
The description of wet-room is "You're in a very wet room on the eastern side of an immense waterfall. There are openings to the north and south, and a small room to the east.".
lab-room is north from wet-room. reactor-room is south from wet-room. closet-room is east from wet-room.
waterfall is a backdrop in wet-room. openings is a backdrop in wet-room.
Instead of examining the waterfall in wet-room: Say "It is quite beautiful, but so tall you can barely see the top.".
Carry out looking in wet-room:
	Move the pool to wet-room;
	Continue the action.
Instead of listening in wet-room:
	Say "You hear the sound of cool water splashing all around you.".

reactor-room is a room. The printed name of reactor-room is "Reactor Room".
The description of reactor-room is "You're in a warm room with an exit to the north.  The walls are covered with large metal slabs, apparently for insulation purposes.  In the center of the room is a low platform with a slot.[if reactor-running is true]  A bright orange glow emanates from a small grating on the southern wall.[end if]".
wet-room is north from reactor-room. reactor-core is south of reactor-room. reactor-core is inside from reactor-room.
slot is a backdrop in reactor-room.
The platform is in reactor-room. The platform is fixed in place. "Low platform with a small slot in it.".
The grate is in reactor-room. The grate is fixed in place. "Small grating on the [if location is reactor-room]southern[otherwise]northern[end if] wall".
The slabs are in reactor-room. The slabs are fixed in place. "metal insulation slabs".
The wheel is in reactor-room. The wheel is fixed in place. "large wheel mounted on the platform".
wheel-turned is a truth state that varies. wheel-turned is initially false.
After going to reactor-room:
	Move grate to reactor-room;
	Continue the action.
Instead of going to reactor-core:
	If wheel-turned is true:
		If player is not wearing the boots:
			Say "The floor of the reactor appears to be covered in water.  You decide to not go in, thus avoiding standing in it unprotected.";
		Otherwise:
			Continue the action;
	Otherwise:
		Say "The grating is blocking your way.";
Instead of turning the wheel:
	If wheel-turned is false:
		Say "The gratings slide away.";
		Now wheel-turned is true;
	Otherwise:
		Say "The grating is now closed.";
		Now wheel-turned is false;
Instead of inserting something into the slot:
	If noun is cylinder:
		Say "As the cylinder goes in, the hum from the reactor ceases.";
		Now reactor-running is false;
		Now the cylinder is nowhere;
		Increase score by 50;
	Otherwise:
		Say "I don't see how to get the [noun] in there!".
Instead of examining the grate:
	If wheel-turned is true:
		Say "The grating is open.";
	Otherwise:
		Say "The grating is closed.";
Instead of listening in reactor-room:
	If the reactor-running is true:
		Say "You hear a humming noise probably coming from the reactor.";
		Stop the action;
	Continue the action.		

lab-room is a room. The printed name of lab-room is "Laboratory".
The description of lab-room is "You're in a mysterious little room that appears to have been a scientific lab-room, judging from the assortment of junk around the room.  Exits are an open passage to the south and an odd thin hole to the east.".
wet-room is south from lab-room. hospital-room is east from lab-room.
hole is a backdrop in lab-room. passage is a backdrop in lab-room.
junk is a backdrop in the lab-room. "There is nothing usable left in the junk.".
lab is a backdrop in the lab-room. "It is mostly filled with junk.".

closet-room is a room. The printed name of closet-room is "Closet".
The description of closet-room is "You're in a small closet, perhaps used for storage of scientific supplies. The exit is to the west.".
closet is a backdrop in closet-room. "It is rather small with no obvious features.".
wet-room is west from closet-room.
The boots are in closet-room.

reactor-core is a room. The printed name of reactor-core is "Reactor".
The description of reactor-core is "You are inside the reactor core, a large, circular room with a reinforced spherical ceiling.  The blinding glare from the reactor makes it difficult to make out any other features of the room.  The floor appears to be covered in several inches of water.  There is an access grating on the northern wall.".
reactor-room is north from reactor-core. reactor-room is outside from reactor-core.
glare is a backdrop in reactor-core. floor is a backdrop in reactor-core.
reactor-water is a privately-named backdrop in reactor-core. The printed name of reactor-water is "water".
Instead of examining the glare in reactor-core: Say "It is too blinding to look at.".
Instead of examining the floor in reactor-core: Say "It is covered in several inches of water.".
The sapphire is in reactor-core.
After going to reactor-core:
	Move grate to reactor-core;
	Continue the action.
After looking in reactor-core:
	If reactor-running is true:
		Say "You're in an active nuclear reactor.  You do not survive.";
		End the story;
	Otherwise:
		Say "The boots protect your feet from the water on the reactor floor.";
		Continue the action.
Instead of taking off the boots in reactor-core:
	Say "It would not be wise to remove the boots here.".
Instead of opening the grate in reactor-core:
	Say "The grating is already open.".
Instead of closing the grate in reactor-core:
	Say "There does not appear to be a way to close it from this side.".

hospital-room is a room. The printed name of hospital-room is "Hospital Room".
The description of hospital-room is "You're in a spotless white room, devoid of any furnishings or windows. Although there is no visible heat source in the room, the air is very warm.  The most interesting feature of this room is the peculiar exit: a tall thin hole on the western wall.".
lab-room is west from hospital-room.
hole is a backdrop in hospital-room.
The nurse and the needle are in hospital-room.
Before going a direction (called the path) from hospital-room:
	If nurse is in hospital-room:
		If the room path from hospital-room is not last-room:
			Say "You can't get past the nurse.";
			Stop the action;
		Otherwise:
			Say "You wisely back away from the nurse.";
	Continue the action.
Instead of taking the needle:
	Say "The nurse won't let you take that.".
Instead of attacking the nurse with the knife:
	Say "The nurse becomes terrified, injects herself with the needle, and suddenly disappears into thin air!";
	Now the nurse is nowhere;
	Now the needle is nowhere;
	Increase score by 10;
[Possible alternate way of solving the nurse puzzle:
Every turn:
	If the nurse is in hospital-room and the zarka is in hospital-room:
		Say "Seeing the zarka, the nurse becomes terrified, injects herself with the needle, and suddenly disappears into thin air!";
		Now the nurse is nowhere;
		Now the needle is nowhere;
		Increase score by 10;
	Continue the action.]

burgl-north is a room. burgl-north is diggable. The printed name of burgl-north is "Burgerland North".
The description of burgl-north is "You're in a grassy arena north of Burgerland.  There is what appears to have been an escalator (now inoperative) leading downward here.".
vast-meadow is north from burgl-north. burger-land is south from burgl-north. vast-meadow is east from burgl-north. vast-meadow is west from burgl-north. burgl-station is down from burgl-north.
arena is a backdrop in burgl-north. escalator is a backdrop in burgl-north.
Instead of examining the escalator in burgl-north: Say "While no longer working, you can still use it to walk down.".
The pillar is a fixed in place thing in burgl-north. "Large black pillar with a bronze F near the top.".

burgl-station is a room. The printed name of burgl-station is "Burgerland Station".
The description of burgl-station is "You're standing in a very long, cylindrical room.  From the objects about the room, it would appear that this is a subway station.  Beyond a gate you can see the open doorway of an abandoned train. There is an non-functioning escalator leading up from here.".
burgl-north is up from burgl-station. in-train is inside from burgl-station.
station is a backdrop in burgl-station. escalator is a backdrop in burgl-station.
Instead of examining the station in burgl-station: Say "Other than the train and related features, the station has nothing else of interest.".
Instead of examining the escalator in burgl-station: Say "While no longer working, you can still use it to walk up.".
The train is a vehicle in burgl-station. "Eighty-foot Froboliner train".
The box is a fixed in place container in burgl-station. "Small box with a slot".
Carry out looking in burgl-station:
	Move train to burgl-station; Move box to burgl-station;
	Continue the action.
Instead of taking the train:
	Say "You need to find a way to activate the train.".
Instead of entering the train:
	Move player to in-train.
Instead of inserting something into the train:
	Say "You can't do that from here.".
Instead of searching the train:
	Say "You can't see anything from here.".
Instead of inserting something into the box:
	If the the noun is the card:
		Let next-stop be "";
		If player is in burgl-station:
			Now next-stop is "Museum";
		Otherwise:
			Now next-stop is "Burgerland";
		Say "The gate swings open as you pass through into the train, taking the card with you.[line break][line break]";
		Say "Doong, doong!  Swoosh!  The doors close and the train immediately starts to move very rapidly.[line break][line break]";
		Say "The sign at the end of the train changes to [quotation mark]Next stop: [next-stop] Station[quotation mark][line break][line break]";
		Say "After about 4 seconds, it stops suddenly.  Swoosh![line break]";
		If player is in burgl-station:
			Move train to museum-station;
		Otherwise:
			Move train to burgl-station;
		Move player to in-train;
	Otherwise:
		Say "I don't see how to do that with the [the noun].".

in-train is a room. The printed name of in-train is "Train".
The description of in-train is "You're in a Froboliner subway train.".
in-train is outside from in-train.
train-interior is a privately-named backdrop in in-train. The printed name of train-interior is "the train interior".
sign is a backdrop in in-train.
Instead of going inside from in-train:
	Say "You are already in the train.".
Instead of entering train-interior:
	Say "You are already in the train.".
After looking in in-train:
	Try examining the sign;
	Continue the action.
Carry out examining the sign in in-train:
	Let this-stop be "";
	If train is in burgl-station:
		Now this-stop is "Burgerland";
	Otherwise:
		Now this-stop is "Museum";
	Say "A sign at the end of the train says [quotation mark]Current stop: [this-stop] Station[quotation mark][line break]";
	Stop the action.
Instead of going from in-train:
	If the train is in burgl-station:
		Move player to burgl-station;
	Otherwise:
		Move player to museum-station.

museum-station is a room. The printed name of museum-station is "Museum Station".
The description of museum-station is "You're standing in a very long, cylindrical room.  From the objects about  the room, it would appear that this is a subway station.  Beyond a gate you can see the open doorway of an abandoned train. There is an non-functioning escalator leading up from here.".
art-museum is up from museum-station. in-train is inside from museum-station.
museum is a backdrop in museum-station. station is a backdrop in museum-station. escalator is a backdrop in museum-station.
Instead of examining the museum in museum-station: Say "The museum itself is up from here.".
Instead of examining the station in museum-station: Say "Other than the train and related features, the station has nothing else of interest.".
Instead of examining the escalator in museum-station: Say "While no longer working, you can still use it to walk up.".
Carry out looking in museum-station:
	Move train to museum-station; Move box to museum-station;
	Continue the action.

art-museum is a room. The printed name of art-museum is "Art Museum".
The description of art-museum is "You are in a museum named for the great leader of Erehwon, King Frobozz II. The only exit is down to Museum Station.".
museum-station is down from art-museum.
museum is a backdrop in art-museum. escalator is a backdrop in art-museum.
Instead of examining the escalator in art-museum: Say "While no longer working, you can still use it to walk down.".
Instead of examining the museum in art-museum: Say "The museum appears to have been all but entirely plundered over the years, there is not much to see.".
The painting is in art-museum.