"Sarvegne" by Eric Forgeot

  [ -- Description du jeu ] 

The story headline is "Une visite qui conduit loin."
The story genre is "Aventure". 
The story creation year is 2006.
The release number is 2.
The story description is "Aventure dans un monde parallele : Ce jour-la, vous etiez decide a aller lui rendre visite, dans la mythique cite de Sarvegne protegee du monde exterieur et de ceux qui fouillent un peu trop dans ses affaires politiques... <br><br><small>Aventure realisee initialement a l'occasion du concours de fiction interactive francophone, avec le systeme Inform 7. Preferez le fichier en version glulx, qui presente des images et des musiques. Le fichier zblorb est la meme chose avec une extension differente.</small>".

Release along with the source text, cover art, a website,  a file of "Version glulx" called "sarvegne.blb" , a file of "Version z5" called "sarvegne.z5", a file of "Solution" called "sarvegne-solution-rec.txt", a file of "Plan" called "sarvegne-plan.pdf" [solution, the introductory booklet].

  [ -- Ajustements techniques ]

Use MAX_PROP_TABLE_SIZE of 60000.
Use MAX_ZCODE_SIZE of 60000.
Use MAX_VERBSPACE of 8000.

Use MAX_ARRAYS of 1500.
Use MAX_CLASSES of 200.
Use MAX_VERBS of 300.
Use MAX_STATIC_DATA of 30000.
Use MAX_INDIV_PROP_TABLE_SIZE of 20000.
Use MAX_VERBSPACE of 8000.

Procedural rule: ignore the print final score rule.
Use full-length room descriptions.

Figure of lettrage is the file "lettres.png".
Figure of sarvegne is the file "sarvegne.jpg".
Figure of sarvegne2 is the file "sarvegne2.jpg".
Figure of titre is the file "sarvegne-titre.jpg".
Figure of plansarvegne is the file "sarvegne-plan.png".


Include French by Eric Forgeot. 

 [ -- divers ]

Instead of waiting:
	choose a random row in the Table of Attente;
	say "[response entry][paragraph break]";
	continue the action.

Table of Attente
response
"Vous baillez."
"Vous attendez un peu en meditant sur vos actions passees."
"Vous passez d'un pied sur l'autre pour occuper votre temps."


[Check quitting the game: 
    say "Etes vous certain de vouloir quitter cette aventure ?";
    if player consents
	begin;
		end the game saying "[line break]A bientot.[line break]";
    	otherwise;
		stop the action;
    end if.]

[When play begins: 
    change left hand status line to "Proche : [if a room is adjacent][the list of adjacent rooms][end if][if a room is adjacent and a door is visible] et [end if][if a door is visible][the list of visible doors][end if]"; 
    change right hand status line to "".


Rule for printing the name of an unvisited room (called the target) while constructing the status line: 
    let aim be the best route from the location to the target; 
    say "un endroit au [aim]".


After printing the name of a visited room (called the target) while constructing the status line: 
    let aim be the best route from the location to the target; 
    say " ([aim])".



Rule for printing the name of a direction (called the aim) while constructing the status line: 
    choose row with a heading of the aim in the Table of Abbreviation; 
    say "[shortcut entry]".

Table of Abbreviation 
heading   	shortcut   
north   	"N"   
northeast   	"NE"   
northwest   	"NW"   
east   	"E"   
southeast   	"SE"   
south   	"S"   
southwest   	"SW"   
west   	"W"   
up   	"U"   
down   	"D"   
inside   	"dedans"   
outside   	"dehors"   ]



[Understand "recommencer" as restarting the game.]


Understand "effrayer [someone]" as attacking.

Understand "chercher [something]" as searching.


[Understand "tell [someone] about [something]" as asking someone about something.]

	
 [ -- smart can't go ]

Instead of going nowhere: 
    let place be location; 
    let count of exits be 0; 
    repeat with way running through directions 
    begin; 
        let place be the room way from the location; 
        if place is a room, increase count of exits by 1; 
    end repeat; 
    if the count of exits is 0, say "Vous semblez etre piege ici." instead; 
    if the count of exits is 1, say "La seule sortie est"; 
    otherwise say "Les directions possibles sont"; 
    say exit list with a total of count of exits.

To say exit list with a total of (sum - a number): 
    let place be location; 
    let index be sum; 
    repeat with way running through directions 
    begin; 
        let place be the room way from the location; 
        if place is a room 
        begin; 
            say " [way]"; 
            decrease index by 1; 
        if index is 1 
            begin; 
                if sum is 2, say " et"; 
                otherwise say ", et"; 
            otherwise; 
                if index is 0, say "."; 
                otherwise say ","; 
            end if; 
        end if; 
    end repeat.

 [ -- way back]

The former location is a room that varies.

First carry out going rule: 
    change the former location to the location.


Understand "revenir" as retreating. Understand "retour" or "return" or "retreat" as retreating.

Retreating is an action applying to nothing.

Carry out retreating: 
    let way be the best route from the location to the former location, using doors; 
    if way is a direction, try going way; 
    otherwise say "Vous ne pouvez voir de voie libre."


Understand "ask [someone] about [something]" as asking it about specified object. Understand "tell [someone] about [something]" as asking it about specified object. Asking it about specified object is an action applying to two visible things. Carry out asking it about specified object: say "[The noun] just shrugs." [Asking something about specified object something is useless action. ]







The sacdos is a player's holdall. The printed name of sacdos is "sac a dos". Understand "sac" or "sac a dos" or "sac a dos" as sacdos. The player is wearing the sacdos.

The carrying capacity of the player is always 4.

[ -- Atmospheric Effects start -- ]
Include Atmospheric Effects by Mikael Segercrantz.

Table of Dehors effects
	atmospheric message	used
	"Des navettes passent rapidement dans le ciel."	2
	"Des nuages gris s'amoncellent au dessus de la region." 1
	"Le vent souffle legerement." 2
	"Un avion fait un peu de bruit en traversant le ciel avant de disparaitre au loin." 1
	"Un oiseau de proie essaye d'attraper un serpent, mais ce dernier est plus rapide et parvient a s'echapper." 1
	"Le soleil commence a revenir." 1
	
The atmospheric table of Dehors is the Table of Dehors effects.
The initial chance of Dehors is 25.

[ --Atmospheric Effects stop -- ]

Part 1 - Au dehors


Dehors is a region. Sentier,  Sentier2, EntreeVille, DerriereVille, DerriereVille2, DerriereVille3, DevantPorteVille and DerriereVille4 are in Dehors.

Arrivee is a scene. Arrivee begins when the player is in Sentier for the first turn. Arrivee ends when the player is in bibliotheque for the first turn.

Rencontre is a scene. Rencontre begins when the player is in bibliotheque for the first turn. 



[RendezVous is a backdrop. Rendezvous is everywhere. Rendezvous is scenery.]

[Understand "rendez-vous/rendez vous" as RendezVous. Instead of examining RendezVous, say "Vous ne pouvez le voir, mais peut-etre pouvez-vous y penser..."]

[Thinking is being pensif.
Understand the command "penser [text]" as think.]

Instead of thinking during arrivee, say "Vous avez rendez-vous avec une jeune fille qui s'appelle Anita. Vous ne l'avez jamais rencontree, mais vous savez qu'elle pourra vous aider.[line break]"

Instead of thinking in DerriereVille, say "Vous vous rappelez lorsque vous passiez pres du grand mur gris de votre ecole. Votre memoire a particulierement imprime l'eclat de la neige qui contrastait avec la grisaille du mur. Ensuite vous etes reparti vers le sud et c'est la poussiere du desert qui a remplace la neige. Mais Sarvegne est une belle oasis au milieu de ces espaces arides.[line break]"

Instead of thinking in Dehors: [location in Ville:]
	if Bibliotheque is not visited, say "Votre contact dans cette ville est une jeune fille qui travaille au conseil du Margrave. Vos divers echanges epistolaires ont permis de vous familiariser un peu avec elle, mais comment sera la realite ? Elle vous a demande de la rejoindre, mais n'a pu vous laisser qu'une adresse imprecise ou vous pourriez la trouver.[line break]".


[When thinking to rendezvous during arrivee, say "Vous avez rendez-vous avec une jeune fille qui s'appelle Anita. Vous ne l'avez jamais rencontree encore, mais vous savez qu'elle pourra vous aider par la suite."]




Instead of listening to Dehors, say "Le vent, le bruit de la nature, parfois quelques oiseaux que vous ne pouvez meme pas voir..."

[unix is a backdrop.] unix is in bibliotheque. unix is scenery. The printed name of unix is "unix". Understand "unix/linux/freebsd/openbsd/netbsd/solaris/polaris" as unix.
The description of unix is "Le systeme unix est un standard dans l'informatique de la confederation, on le retrouve dans tous les appareils embarques, les serveurs, ainsi que les ordinateurs personnels.[if player has calculateur and calculateur is switched on]Le noyau du systeme que vous avez sous les yeux affiche 'Polaris Kernel 4.84 smp 20 cores, 03/02/26 release'.[end if]".


ville_scenario is in dehors. The printed name of ville_scenario is "des details de la ville". Ville_scenario is a backdrop. Understand "sentier/chemin/ville/tours/tour/statues/statue/muraille/murailles" as ville_scenario.



Instead of examining ville_scenario when in dehors, say "Votre chemin vous conduira immanquablement a la ville et ses constructions etonnantes. Vous devriez avant tout essayer d'y entrer le plus vite possible.".


soleil is in dehors. The printed name of soleil is "soleil". Soleil is a backdrop. Understand "soleil/orange/vert" as soleil.

Instead of examining soleil when in dehors, say "Il y a deux soleils dans le ciel, l'un est orange, l'autre est vert.".
Instead of examining soleil when in ville, say "Les soleils donnent des teintes etranges mais agreables aux batiments de la ville.".

Sentier is a room. The printed name of Sentier is "Sentier". "Le sentier ou vous vous trouvez mene vers la ville."
The Sentier has a number called nbvisite. nbvisite is 1. 


Instead of examining the Sentier for the second time, say "Au loin, vers le nord, vous voyez l'aura d'une ville qui vous attire depuis de nombreuses annees : Sarvegne.[line break]"


Before looking in sentier:
	if sentier2 is not visited
	begin;
		display the Figure of lettrage;
	[	display the Figure of titre;]
		say "[line break]Votre voyage fut tres long. Mais vous voila enfin en route vers la mysterieuse cite qui est le but de votre voyage. Au loin, vers le nord, vous percevez l'aura de cette ville qui vous attire depuis de nombreuses annees : Sarvegne.[line break]";
	Otherwise;
		 say  "Vous etes sur un petit chemin peu frequente.";
	end if;
		
Sentier3 is south of Sentier.

[TestRoom is east of Sentier.
the objet1 is here. The objet2 is here. The objet3 is here. The table is here.  The table is a female supporter. ]

Sentier2 is north of Sentier.  The printed name of Sentier2 is  "Au bout du chemin.". "La ville est encore a une certaine distance, mais ses contours se font plus precis. L'atmosphere de cette region desertique est fraiche et pure, et le soleil un peu voile ne vous affecte pas. Vous pouvez presque apercevoir les tours de la ville, mais elles restent toujours indistinctes. [line break]Plus proche de vous, a quelques pas, vous pouvez voir un buisson encore assez vert.".


After going in sentier2:
	if sentier2 is not visited
	begin;
		say "Ce chemin serpente doucement pour vous rapprocher de votre destination. Un certain nombre de routes menent a Sarvegne, mais celle que vous avez empruntee n'est pas la plus utilisee. Apres avoir quitte votre famille vous avez pris une navette rapide pour vous conduire a l'aerogare la plus proche. Il n'etait alors pas possible d'entrer dans la ville directement, pour des raisons que vous ignorez encore."; continue the action;
	Otherwise;
		 say  ""; continue the action;
	end if;
		


The buisson is scenery in sentier2. The buisson is a container.
The cube is in buisson. 


A thing has a number called charge. The charge of a thing is usually 0. 

instead of examining cube:
	if player is in sentier2 and cube is not in player then say "Le cube est couvert de la poussiere du sol.";
	if charge of the cube is less than 1 then say "Le cube semble vide et froid.";
	otherwise say "Le cube semble charge d'une energie puissante.".
	
After taking cube:
	if player is in sentier2 then say "C'est un cube de metal qui se trouvait sur le bord du chemin. Vous ne pouviez le manquer, sans doute est-il tombe d'un vehicule. Ce genre d'objet sert habituellement pour stocker de l'energie. Celui-ci est sans doute vide, mais il pourra vous servir quand meme, d'autant plus que c'est un objet relativement rare.";
	otherwise say "Ok[line break]".
Understand "carre/pave" as cube. 



klitt is a thing. The printed name of klitt is "du klitt". Understand "argent/monnaie/sous/pognon/fric" as klitt.

Instead of giving klitt to EmployeeCentreInfo, try showing klitt to EmployeeCentreInfo.

Instead of showing klitt to EmployeeCentreInfo, say "La femme vous confirme que cet argent n'a pas cours ici, aussi il vous faudrait le changer, vous pouvez d'ailleurs le faire dans ce bureau."

glutt is a thing. The printed name of glutt is "du glutt". Understand "argent/monnaie/sous/pognon/fric" as glutt.

Argent is a kind of value. 5 pieces specifies an argent.
klitt has an argent.
glutt has an argent.

Instead of examining the klitt : 
    say "Vous avez [argent of the klitt] de klitt. C'est la monnaie de chez vous."

Instead of examining the glutt : 
    say "Vous avez [argent of the glutt] de glutt. C'est la monnaie locale."

When play begins:
	move klitt to player;
	change the argent of the klitt to 9 pieces.


Instead of going south from sentier, say "Cette route vous ramenera vers chez vous, mais ce n'est pas la direction que vous souhaitez prendre pour le moment."

Before going nowhere from dehors:
	if bibliotheque is not visited
	begin;
		say "Si vous quittez ce chemin maintenant, vous risquez d'etre en retard pour votre rendez-vous.";
	otherwise;
		say "Vous avez peur de vous perdre si vous allez dans cette direction.";
	end if.


EntreeVille is north of Sentier2. "Vous etes face a une des murailles de Sarvegne. Des statues fantasmagoriques ornent tout le pourtour de ce mur, mais vous ne connaissez pas leur histoire". The printed name of EntreeVille is "Entree de la ville". 
After going in EntreeVille:
	if EntreeVille is not visited
	begin;
		display the Figure of sarvegne2;
		say "Vous arrivez devant la ville. Vous pouvez essayer d'entrer par la porte principale qui se trouve toute proche de la au nord-ouest ou contourner la ville par le nord-est pour trouver une entree plus discrete."; continue the action;
	Otherwise;
		 say  "" ; continue the action;
	end if;

an affiche is in EntreeVille. Affiche is a female thing. The description of affiche is "Un panneau annoncant les restrictions en vigueur pour entrer dans la ville.". The printed name of affiche is "affiche".
Understand "affiche/poster/panneau" as affiche.
	

Instead of going north from EntreeVille, say "Il y a un mur devant vous, prenez a gauche ou a droite.".


DevantPorteVille is northwest of EntreeVille. DevantPorteVille is north of EntreeVille. 
DevantPorteVille is west of EntreeVille. The printed name of DevantPorteVille is "Devant la porte de la ville". "Vous imaginiez cette ville beaucoup plus animee, mais pour le moment la porte est close et vous ne voyez personne."
DerriereVille is northeast of EntreeVille. The printed name of DerriereVille is "Derriere la ville". DerriereVille is east of EntreeVille.


DerriereVille2 is northeast of DerriereVille.  DerriereVille2 is east of DerriereVille. The printed name of DerriereVille2 is "Derriere la ville".  "Vous etes en dehors de la ville, derriere celle-ci.". Instead of examining DerriereVille2 for the second time, say "Vous etes encore derriere la ville."

DerriereVille3 is northeast of DerriereVille2.  The printed name of DerriereVille3 is "Derriere la ville". "Vous etre maintenant diametralement oppose a l'entree principale.".


DerriereVille4 is northwest of DerriereVille3.  The printed name of DerriereVille4 is "Derriere la ville". "Si vous continuez autour de la ville, vous pouvez rejoindre la porte principale au sud-ouest, ou revenir sur vos pas au sud-est. Ailleurs il n'y a rien d'interessant.".

DevantPorteVille is southwest of DerriereVille4. 


Before going southwest from DerriereVille4, say "Apres une heure de marche vous revenez au point de depart."

Instead of going northeast from DevantPorteVille, say "C'est trop loin de continuer par cette voie.".





[After going in DerriereVille2:
	if DerriereVille2 is not visited, say "Le chemin est long et monotone, vous ne trouvez rien de notable a cet endroit. Pendant que vous marchez, vous vous rememorer vos souvenirs. A la limite de votre champs de vision, la muraille en pierres de taille est tres haute et lisse, ce qui en empeche toute escalade, et donc toute entree par ce moyen.";
	otherwise say "bli ."]

Before going to DerriereVille for the first time, say "Le chemin est long et monotone, vous ne trouvez rien de notable a cet endroit. Pendant que vous marchez, vous vous rememorer vos souvenirs. A la limite de votre champs de vision, la muraille en pierres de taille est tres haute et reste lisse a hauteur d'homme, ce qui en empeche toute escalade, et donc toute entree par ce moyen.". 


Before going to DerriereVille2 for the first time, say "Vous longez la peripherie de la ville. Vous ne pouvez voir si l'activite de celle-ci est grande ou pas, car une protection entoure toute la ville, neanmoins vous pouvez le deviner avec la vision des vaisseaux qui vont dans toutes les directions. La plupart de ceux-ci etant destines a la communication intra-muros, ils n'ont souvent pas de toiture."

Before going to DerriereVille3 for the first time, say "Vous continuez a contourner la ville. Les murailles en pierres sont toujours infranchissables de ce cote, mais a partir de cet endroit, moins entretenu que les abords de la grande entree, de la mousse commence a recouvrir les murs."

Before going to DerriereVille4 for the first time, say "Vous commencez a fatiguer, vous avez deja parcouru un long chemin."



mousse is a kind of supporter. a mousse is usually female. The description of mousse is "C'est une mousse verte un peu lumineuse, comme phosphorescente". The printed name of mousse is "de la mousse".
Understand "mousse/verte/herbe" as mousse.

After putting cube on mousse:
	say "Le cube devient subitement brillant.";
	change charge to 1.
	
Instead of taking mousse, say "Vous ne pouvez pas l'arracher ainsi."

mousse1 is a mousse. It is in DerriereVille3. 
Mousse2 is a mousse. It is in ParcCentreVille.

The trappe is in DerriereVille2. The trappe is a female door. The trappe is north of DerriereVille2 and south of CaveauVille. CaveauVille is inside from DerriereVille2. The description of trappe is "C'est une trappe rouillee et sale. Pourtant vous voyez qu'il y a comme des restes de technologie qui s'inscrivent sur la surface de cette trappe, et notamment une sorte de plaque en metal." The trappe is lockable and locked and closed. 

instead of pushing trappe, try opening trappe.
instead of pulling trappe, try opening trappe.

DansVille is up from CaveauVille.

Before going to CaveauVille: 
	if trappe is locked
		begin;
		say "Vous ne pouvez pas passer tant que cette trappe sera fermee.";
		stop the action;
	end if.

The plaque is in DerriereVille2. The plaque is a female scenery supporter. The description of plaque is "Cette plaque est toute rayee, mais elle ne semble pas avoir ete touchee depuis des annees. Elle est situee pres de la trappe." Understand "plaque en metal" or "plaque de metal" or "plaque en metal" or "plaque en metal" as plaque.

instead of taking plaque, say "C'est fixe sur une partie de la trappe.".

after examining trappe, change the plaque to not scenery.

after putting cube on plaque:
	if charge of the cube is greater than 0
		begin;
		change the trappe to not locked;
		change the charge of cube to 0;
		say "Vous entendez un petit bruit.[line break]";
	otherwise ;
		say "ok[line break]";
	end if.
	


 The PorteEntreeVille door is south of DansVille and north of DevantPorteVille. It is a door and scenery. PorteEntreeVille is female, locked and closed. The printed name of PorteEntreeVille is "porte de la ville". The description of PorteEntreeVille is "Le portail principal de la ville est gigantesque, a l'image de la citee qu'elle protege. Depuis plusieurs siecles ou il n'y a pas eu de siege, cette porte a eu plus un role d'apparat que de defense, mais neanmoins elle empeche tous les rodeurs et voleurs d'y entrer facilement." 
Understand "portail/porte/seuil/entree" as PorteEntreeVille.

Some gardes are a man. Understand "[gardes]" as the gardes. The description of the gardes is "Les gardes n'ont pas l'air concilliants. Ils portent de belles armures dorees, avec des motifs richement ouvrages sur leur poitrine. Le dessin central represente un aigle imperial, et vous ne pouvez voir le reste a cette distance." Understand "gardes/garde/molosse/armure/plastron/hallebarde/cotte/de/mailles/motifs/ouvrages/ poitrine/aigle/imperial" as "[gardes]".


Instead of pushing or pulling or attacking the PorteEntreeVille for the first time:
	 say "Vous approchez de la porte et tentez de la manipuler. A cet instant des gardes apparaissent entre deux creneaux.";
	move 2 gardes to DevantPorteVille.

Every turn when in DevantPorteVille:
	if PorteEntreeVille is locked and closed
	begin;
		if a random chance of 20 in 100 succeeds 
		begin;
			say "La porte s'ouvre pour laisser passer un vehicule blinde, mais se referme aussitot.";
			[change PorteEntreeVille to unlocked;
			change PorteEntreeVille to open;]	
		otherwise;
			say "";
		end if;
	otherwise;
		if a random chance of 33 in 100 succeeds 
		begin;
			say "La porte se referme.";
			change PorteEntreeVille to locked;
			change PorteEntreeVille to closed;	
		otherwise;
			say "";
		end if;
	end if.

Instead of pushing or pulling or attacking the PorteEntreeVille for the second time, say "Les gardes vous demandent de vous tenir tranquille."

Instead of pushing or pulling or attacking the PorteEntreeVille for the third time:
	say "Les gardes vous attrapent et vous emprisonnent.";
	move player to prison.

Instead of attacking the gardes: 
	say "Les gardes ne se laissent pas faire et vous emprisonnent.";
	move player to prison.

[Instead of talking to the gardes:
	 say "Les gardes ne bougent meme pas."]
[Instead of asking the gardes for the second time, say "Pas de reponse."]

Part 2 - Inside

RetrouveChien is a scene. RetrouveChien begins when the mecanicien is in location for the first time.
RetrouveChien ends when the location of RobotChien is Gare.

When RetrouveChien begins:
	move RobotChien to MaisonAnita.
When RetrouveChien ends:
	say "Le mecanicien vous remercie pour avoir retrouve son chien.".
	
ChienFidele is a scene. ChienFidele begins when robotchien is fidele for the first time and the location is MaisonAnita. ChienFidele ends when the location of RobotChien is Gare.

Every turn when RobotChien is fidele:
	say "Le chien vous suit fidelement.";
	 move RobotChien to location.

When ChienFidele begins:
	move RobotChien to location.
	
When ChienFidele ends:
	now RobotChien is not fidele.
	
VoyagePlateau is a scene. VoyagePlateau begins when RetrouveChien ends. VoyagePlateau ends when the location is Plateau.

When VoyagePlateau begins:
	say "Pour vous remercier de vos efforts, le mecanicien vous raconte que sa femme est friande de baies jaunes qui ne poussent que sur le plateau de Sarvegne. Ce plateau est normalement interdit de visite, mais depuis quelques annees les controles sont moins stricts, aussi il va la-bas de temps en temps. L'homme vous explique que l'ancien centre de Sarvegne se trouvait la. Il peut vous y conduire si vous voulez. Voulez-vous y aller ?[line break]";
	if player consents
	begin;
		say "Vous suivez le mecanicien et son chien dans un couloir sortant de la gare, et vous arrivez a un espace un peu desert ou se trouve une petite navette datant de plusieurs dizaines d'annees. Vous montez dedans, en esperant qu'elle tienne le voyage, et vous vous envolez au-dela de la ville. Le trajet est malgre tout confortable, et la vue du paysage agreable, sous un des soleils couchant. Apres quelques dizaines de minutes de voyage, vous atterrissez sur un plateau.";
		move mecanicien to Plateau;
		move robotchien to Plateau;
		now RobotChien is not fidele;
		move the player to Plateau;
	otherwise;
		say "Comme vous voulez.";
		remove mecanicien from play;
		remove robotchien from play;
	end if.
		
[Going to (the goal) is an action.
 
instead of going to a room when in Ville:
	if location is in Ville
	begin;
		say "hello";
		move player to the goal;
	otherwise;
		say "no";
	end if.]

Ville is a region.

Ville2 is a region.



Before going nowhere from Ville for the first time, say "Cette ville est gigantesque, et vous ne pouvez malheureusement pas l'explorer en detail. Il vous faut aller a l'essentiel."

Before going nowhere from Ville for the second time, say "Cela vous menerait trop loin d'aller dans cette direction."

DansVille, Prison, CaveauVille, ParcCentreVille, CentreVille, Rues1, CentreInfo, Gare, MaisonAnita are in Ville.

Bibliotheque and Rues2 are in Ville2.

Prison is a room.
CaveauVille is a room.


CentreInfo is a room. CentreInfo is northeast from DansVille. DansVille is outside from CentreInfo. The printed name of CentreInfo is "Centre d'information".
The description of CentreInfo is "Vous arrivez au centre d'information, qui est un lieu habituellement frequente par les nouveaux arrivants. [if CentreInfo is unvisited] Vous patientez un peu que l'on puisse vous recevoir, et apres avoir indique le but de votre visite dans la ville, en omettant de dire que vous n'avez pas d'acces autorise car vous n'etes pas citoyen de la Federation, on vous explique ou se trouve l'adresse que vous leur demandez, dans une zone residentielle un peu plus au nord d'ici. [end if] [if MaisonAnita is visited]Apres une rapide verification, vous comprenez que la bibliotheque est bien plus a l'est d'ici.[end if]"

EmployeeCentreInfo is a woman. She is in CentreInfo. The description of EmployeeCentreInfo is "Une femme jeune d'allure affable.". The printed name of EmployeeCentreInfo is "l'employee du centre d'information". Understand "employee/femme/guichetiere" as EmployeeCentreInfo.


A person has a table-name called conversation. 
The conversation of EmployeeCentreInfo is the Table of EmployeeCentreInfo Conversation.
The conversation of Anita is the Table of Anita Conversation.
The conversation of Chauffeur is the Table of Chauffeur Conversation.

Instead of asking someone about something:
	let the source be the conversation of the noun;
	if topic understood is a topic listed in source
	begin;
		[if there is a cle entry and there is a turn_stamp entry
			say "";
		otherwise;
			say "";
		end if;]
		if there is a turn_stamp entry
		begin;
			say "[The noun] vous a dit [summary entry][paragraph break]";
		otherwise;
			change turn_stamp entry to the turn count;
			say "[reply entry][paragraph break]";
		end if;
	otherwise;
		say "[The noun] vous regarde sans comprendre.";
	end if. 

[Instead of going south from bibliotheque:
	[let the source be the conversation of anita;]
	if there is a turn_stamp corresponding to a cle of 2 in the Table of Anita Conversation
	[choose row with cle of "2" in the Table of Anita Conversation; 
	if there is a turn_stamp entry]
		begin;
			say "Vous devez maintenant trouver un moyen pour rejoindre ce plateau en dehors de la ville.";
			continue the action;
		otherwise;
			continue the action;
	end if.]


	

Understand "parler a [someone]" as chatting.

Understand "parler avec [someone]" as chatting.

[Understand "parler a [someone]" as a mistake ("Utilisez 'questionner' quelqu'un au sujet de quelque chose.").]


Understand "talk to [someone]" as a mistake ("Utilisez 'questionner' quelqu'un au sujet de quelque chose.").

Understand "talk [someone]" as chatting.
[Understand "parler avec [someone]" as chatting.]


[Understand the command "parler" as talk.]

Understand the command "bavarder" as parler avec.
[Understand the command "questionner" as parler avec.]


[Understand the command "parler avec/parler a" as talk.]


chatting is an action applying to one thing. 

Carry out chatting:
	say "Vous ne savez pas quoi dire."


Instead of chatting mecanicien for the first time:
	if there is a turn_stamp corresponding to a cle of 2 in the  Table of Anita Conversation
		begin;
			say "Vous dites au mecanicien qu'un chauffeur de taxi vous avait parle de lui, et qu'il etait possible de rejoindre le plateau a l'est de la ville. Il vous dit qu'il vous conduira volontiers la-bas, mais qu'il a perdu son chien recemment et qu'il ne veut pas faire de deplacement tant qu'il n'aura pas le coproce-coeur tranquille a ce sujet. Si vous savez comment l'aider il vous en sera d'ailleurs fort reconnaissant.";
		otherwise;
			say "Vous ne savez pas trop quoi lui dire.";
	end if.
	


Instead of chatting mecanicien:
	if the location is Plateau
	begin;
			if player carries a relique 
			begin;
			say "L'homme regarde ce que vous avez en main, et ne semble pas tres heureux de devoir vous ramenez en ville avec ces objets compromettants.";
			stop the action;
			end if;
		say "Le mecanicien semble avoir fait une bonne recolte de baies. Voulez-vous repartir en ville avec lui ?";
				if player consents
					begin;
					say "Vous remontez dans la navette pour quitter ce plateau tranquille et retrouver la cite animee de Sarvegne. L'homme vous depose pres de la gare et repart ensuite on ne sait ou.";
					move Player to Gare;
				end if;
	otherwise;
		say "Vous ne savez pas trop quoi lui dire.";
	end if.
	
[Instead of chatting chauffeur:
	if there is a turn_stamp corresponding to a cle of 2 in the  Table of Anita Conversation
		begin;
			say "Vous demandez au taxi s'il sait comment rejoindre le plateau a l'est de la ville. Il vous parle d'un de ses amis qui travaille a la gare et qui pourra vous obtenir un billet pour y aller.";
			choose row 3 in the Table of Chauffeur Conversation;
			change turn_stamp entry to 2;
		otherwise;
			say "Vous ne savez pas trop quoi lui dire.";
	end if.]
	
Instead of chatting chauffeur:
	if there is a turn_stamp corresponding to a cle of 2 in the  Table of Anita Conversation
		begin;
			choose row 3 in the Table of Chauffeur Conversation;
			change libelle entry to "le plateau"; 
		end if;
	say "Vous pouvez questionner [the noun] a propos de ces sujets : ";
	let the source be the conversation of the noun;
	repeat with N running from 1 to the number of rows in the conversation
	begin;
	say " [libelle in row N of the table of Chauffeur Conversation], ";
	end repeat;
	say " et vous ne voyez pas trop quoi d'autre pour le moment.[paragraph break]".


Table of Chauffeur Conversation
libelle	topic	reply	summary	cle	turn_stamp
"la ville"	"Ville"	" Il ne vous raconte rien de special sur la ville. "	"des choses banales sur la ville."	1	a number
"argent"	"Argent/pieces/piece/monnaie"	"Le chauffeur explique qu'il est mefiant avec les pieces qu'on lui donne, en effet certaines n'ont pas cours a Sarvegne, et il ne peut pas tout accepter comme cela."	"qu'il ne voulait pas certain type de pieces."	2	 
"--"	"plateau/grottes"	"Vous demandez au taxi s'il sait comment rejoindre le plateau a l'est de la ville. Il vous parle d'un de ses amis qui travaille a la gare et qui pourra vous obtenir un billet pour y aller."	"que vous deviez demander un ami a lui a la gare."	3


Table of EmployeeCentreInfo Conversation
libelle	topic	reply	summary	cle	turn_stamp
"la ville"	"Ville"	" 'Que voulez-vous savoir precisement sur la ville ?' "	"que vous pouviez la questionner sur des sujets precis"	1	a number
"votre argent"	"Argent/pieces/piece/monnaie"	"La femme regarde les pieces que vous lui montrez, et vous signale que cet argent n'a pas cours ici, aussi elle vous propose de faire changer ici votre monnaie si vous le desirez."	"qu'elle vous propose de changer votre argent." 	
"--"	"plateau/grottes"	"Vous demandez a la femme si elle sait comment rejoindre le plateau a l'est de la ville. Elle vous dit que la ville n'organise pas officielle de visite guidee de cette region plus ou moins interdite, et que vous devriez plutot demander a des transporteurs independants si vous tenez vraiment a ce genre d'aventure."	"que vous devriez demander a quelqu'un d'autre tout ce qui concerne ce genre de sujet."	3	


Instead of chatting EmployeeCentreInfo :
	if there is a turn_stamp corresponding to a cle of 2 in the  Table of Anita Conversation
		begin;
			choose row 3 in the Table of EmployeeCentreInfo Conversation;
			change libelle entry to "le plateau"; 
		end if;
	say "Vous pouvez questionner [the noun] a propos de ces sujets : ";
	let the source be the conversation of the noun;
	repeat with N running from 1 to the number of rows in the conversation
	begin;
	say " [libelle in row N of the table of EmployeeCentreInfo Conversation], ";
	end repeat;
	say " et vous ne voyez pas trop quoi d'autre pour le moment.[paragraph break]".
	

Table of Anita Conversation
libelle	topic	reply	summary	cle	turn_stamp
"la ville de Sarvegne"	"Ville/Sarvegne"	" Elle n'a pas grand chose de precis a vous raconter sur cette ville. Elle n'est pas nee dans Sarvegne mais dans un village d'a cote. Puis ses parents sont alles habiter dans la ville lorsqu'elle etait encore toute jeune. Elle a prefere rester la par la suite du fait des nombreuses opportunites que la ville offre. "	"que Sarvegne n'etait pas sa ville natale."	1	a number
"le site archeologique"	"site/archeologique/grottes/grotte"	"Elle a decouvert une grotte a l'exterieur de la ville. Cette grotte contient d'anciens artefacts, et elle aimerait bien les rapporter chez elle pour les etudier plus facilement, mais alors elle se trouverait dans l'illegalite, et se ferait immediatement reperer par les scientifiques qui viennent avec elle lors de ces sorties. Elle a depose ces pieces dans une salle, parmi d'autres pieces de moindre valeur. Elle vous explique comment atteindre la grotte, qui se trouve sur un plateau. Elle sort alors sur le parvis de la bibliotheque pour vous montrer la direction de ce site, vers l'est, et vous revenez ensuite a l'interieur."	"qu'il fallait trouver certains anciens objets dans un site archeologique en dehors de la ville."	2	--	
"..."	"artefacts"	"Ces artefacts parlent d'une civilisation oubliee, et les ressortir au grand jour lui permettrait de mettre a mal le regime totalitaire des despotes qui controlent la ville et la region."	"que ces artefacts lui etaient necessaire pour que les siens reprennent le pouvoir."	3 	--
"..."	"peuple/tribus/paiens/peuple ancien"	"Effectivement, elle avait presque oublie l'existence de ces tribus paiennes qui vivaient pres de la ville. Peut-etre que si vous essayez de les contacter ils pourront vous renseigner et vous conduire aux artefacts, mais cela sera sans doute plus long qu'en navette."	"que vous pouviez essayer de contacter cet ancien peuple."	4	--

Instead of chatting Anita :
	if final is happening
		begin;
		say "Anita est tres curieuse de voir ce que vous avez pu ramener.";
		stop the action;
	end if;
	if there is a turn_stamp corresponding to a cle of 2 in the Table of Anita Conversation
		begin;
			choose row 3 in the Table of Anita Conversation;
			change libelle entry to "les artefacts";
	end if;
	say "Vous pouvez questionner [the noun] a propos de ces sujets : ";
	let the source be the conversation of the noun;
	repeat with N running from 1 to the number of rows in the conversation
	begin;
	say " [libelle in row N of the table of Anita Conversation], ";
	end repeat;
	say " et vous ne voyez pas trop quoi d'autre pour le moment.[paragraph break]".
	
Understand "changer [something]" as changing.

Understand the command "causer" as ask.

changing is an action applying to one thing. 

Carry out changing:
	say "Pas pour cela."
	
Instead of changing klitt:
	if  the player has klitt and the player is in CentreInfo
	begin;
			say "Vous changez votre argent.";
			change the argent of the glutt to the argent of the klitt  / 2 pieces ;
			move glutt to player; 
			change the argent of the klitt to 0 pieces;
			remove klitt from play; 
	otherwise;
			say "Vous pourriez faire cela si le contexte etait meilleur, mais il manque quelque chose.";
	end if.

Instead of changing glutt, say "On vous signale que cet argent a tout a fait cours ici, aussi il n'est pas necessaire de le changer. De plus, si vous vouliez une monnaie exterieure, les frais de change seraient trop eleves par rapport a ce vous avez en poche."


MaisonAnita is a room. MaisonAnita is north from Rues1. The printed name of MaisonAnita is "Les quartiers nord". The description of MaisonAnita is "[if MaisonAnita is not visited]Vous marchez quelques kilometres dans des quartiers calmes et ensoleilles. Le temps est frais et agreable, mais vous commencez a fatiguer un peu. Les batisses alentours sont assez basses en comparaison des immeubles de la ville. Vous arrivez bientot devant l'adresse que l'on vous a indique. C'est une petite maison avec de grandes baies vitrees, et de nombreuses plantes a l'interieur.[end if][if MaisonAnita is visited]Vous etes dans des quartiers residentiels aises.[end if][if final is happening]Anita sort sur le seuil de sa maison lorsque vous approchez.[end if]".

a RobotChien is in MaisonAnita. Understand "robot/chien" as RobotChien. The printed name of RobotChien is "chien de garde". The description of RobotChien is "Un chien de garde cybernetique.". RobotChien is scenery. RobotChien can be fidele.

maisonobjet is in MaisonAnita. maisonobjet is female. maisonobjet is scenery. 

Understand "porte/petite/maison/baies/vitrees/plantes/cloture" as maisonobjet. The printed name of maisonobjet is "la maison". The description of maisonobjet is "Une petite batisse propre et simple."



Instead of attacking maisonobjet, try going inside. 


Before going to MaisonAnita:
	if CentreInfo is unvisited, say "Cette zone pavillonaire est trop grande pour que vous y erriez sans renseignements precis." instead;
	otherwise continue the activity.

DansMaisonAnita is a room. DansMaisonAnita is inside from MaisonAnita.


Instead of going inside from MaisonAnita for the first time:
	change RobotChien to not scenery;
	say "Un chien de garde surgit a ce moment-la et vous empeche d'approcher.[paragraph break]".

Instead of going inside from MaisonAnita[ for the second time]:
	if RobotChien is not in location
	begin;
		say "[if final is not happening]Vous frappez a la porte, et une vieille femme vous ouvre. Elle vous explique que la personne que vous recherchez se trouve certainement a la grande bibliotheque de Sarvegne en ce moment, car elle travaille a temps presque complet la-bas. 
Ce n'est pas tout pres d'ici, mais a l'ouest de la ville, aussi vous aurez besoin de trouver un vehicule pour vous y rendre.[end if][if final is happening]Anita vous propose plutot une balade en ville.[end if]";
	Otherwise;
		say "Le chien est toujours la.";
	end if.

Instead of attacking RobotChien:
	say "Il est vraiment plus fort que vous ne l'etes, ses yeux etincellent d'une haine froide et desincarnee, et il ne fait qu'une bouchee de vous.";
	end the game in death.

Instead of taking RobotChien, try touching RobotChien.
	
Instead of touching RobotChien:
	say "Il grogne doucement mais surement en vous regardant, un peu d'huile noire bave de sa gueule d'acier, cela ne serait vraiment pas raisonnable de jouer avec lui.".
	
Instead of throwing cube at robotchien:
	say "Vous lancer ce precieux objet comme si c'etait un vulgaire projectile, il touche sa cible mais ne produit aucun degat notable. En revanche le chien va sans doute en faire de visibles sur vous.";
	end the game in death.
	
Instead of putting cube on robotchien:
	say "Lorsque vous approchez un peu, le chien vous fait comprendre que vous n'etes pas le bienvenu a faire quoi que ce soit contre lui.".
	

Instead of throwing tube at robotchien for the first time:
	say "Vous lancez le tube vers le chien qui s'en empare satisfait, et vient le poser a vos pieds.  Il ne vous derangera sans doute plus maintenant. Il s'eloigne en passant sous la cloture derriere la maison.";
	move the tube to location;
	remove robotchien from play.
	
Instead of throwing tube at robotchien for the second time:
	say "Vous lancez de nouveau le tube vers le chien qui s'en empare, et vient pres de vous en remuant la queue. Il veut certainement continuer a jouer avec vous maintenant.";
	now the RobotChien is fidele;
	move the tube to location.
	


[Instead of going inside from MaisonAnita for the third time, say "Vous frappez a la porte, et la vieille femme vous ouvre de nouveau. Elle vous explique encore une fois ce qu'elle vous a deja dit, a propos de la grande bibliotheque de Sarvegne, et de la direction de celle-ci a l'ouest de la ville."

Instead of going inside from MaisonAnita, say "Cela ne repond pas."]

Gare is a room. Gare is west from DansVille. The description of Gare is "[if location is not visited] Une gare gigantesque comme vous n'en avez jamais vue auparavant. Il n'y a plus de trafic aerien et les communications en navettes terrestres ont ete reduite depuis quelques mois, mais cela n'empeche pas a la batisse de garder tout son prestige. [end if][if location is visited]La gare de Sarvegne vous impressionne toujours autant.[end if] "

Mecanicien is a man. The printed name of Mecanicien is "un mecanicien". The description of mecanicien is "[if location is Gare]Un mecanicien comme on en trouve beaucoup de nos jours, avec un habit rouge orange et un ecusson aux couleurs de la ville. Vous soupconnez celui-ci d'etre un robot, mais vous n'avez pas de preuve visible de cette impression.[End if][if location is Plateau]Le mecanicien est en train de cueillir des baies avec delicatesse et attention.[end if]".

After going in Gare:
	if there is a turn_stamp corresponding to a cle of 3 in the  Table of Chauffeur Conversation and Mecanicien is not in location
	begin;
		say "Vous rencontrez l'ami du chauffeur qui est un des mecaniciens de la station."; 
		move Mecanicien to location;
		continue the action;
	Otherwise;
		 say  ""; continue the action;
	end if;




Rues1 is a room. Rues1 is north from DansVille. The printed name of Rues1 is "Avenue principale - Quartiers Ouest."
The description of Rues1 is "Vous vous trouvez dans la rue principale de Sarvegne. [if Rues1 is not visited]Vous etres pensif. Votre contact dans cette ville est une jeune fille qui travaille au conseil du Margrave. Vos divers echanges epistolaires ont permis de vous familiariser un peu avec elle, mais comment sera la realite ? Elle vous a demande de la rejoindre, mais n'a pu vous laisser qu'une adresse imprecise ou vous pourriez la trouver.[end if][line break]".


CentreVille is a room. CentreVille is east from Rues1. The printed name of CentreVille is "Centre ville".
The description of CentreVille is "Le centre ville de Sarvegne est un endroit tres bruyant. Differentes avenues menent dans divers coins de la ville, et le bourdonnement incessants des navettes et voitures vous donne le tournis. Il y a egalement nombre de commerces et de passants, mais vous n'avez pas envie d'aller visiter ce genre d'attraction.".


Instead of going east from CentreVille, say "Cette avenue est trop longue et surtout trop passagere pour que vous puissiez la suivre a pied, en plus vous risqueriez de vous faire renverser.".

ParcCentreVille is a room. ParcCentreVille is southeast from CentreVille.
The description of ParcCentreVille is "[if location is not visited]Vous arrivez au parc. [end if]Ce parc sert un peu de poumon pour la ville, il est tres vaste, et filtre la plupart de la pollution occasionnee par les hommes, bien que le reste de la ville soit tres vert. La faune et la flore qui sont la vous emerveillent le temps de votre visite."

The description of CaveauVille is "A cet endroit qui sert visiblement pour l'assainissement de la ville, une petite ouverture cachee est dissimulee aux regards de tous. Une sortie remonte ensuite vers l'interieur de la ville.". Understand "ouverture/trappe" as CaveauVille.The printed name of CaveauVille is "Un caveau dans la ville".

a tube is in CaveauVille. The description of tube is "Un tube un peu rouille, un peu moins long qu'une coudee."

The description of DansVille is "Vous etes dans les rues de Sarvegne. [if DansVille is unvisited]Cette ville est emplie d'un melange de technologie et de traditions, des domes multicolores brillent au loin sous l'influences des deux soleils orange et vert, et certaines partie de murs en cristal refletent les couleurs du desert qui s'etend au dela de l'enceinte de la cite.[end if] Le centre d'information de la ville est au nord-est, et vous pouvez voir les batiments imposants de la gare a l'ouest. Il reste egalement d'autres coins a explorer.".
The printed name of DansVille is "Dans la ville.".

[taxi dans rues1 et centreville -> rues2 autre bout de la ville]

In CentreVille is a vehicle called a taxi. The description of taxi is "Un vehicule rapide [if a random chance of 1 in 2 succeeds]sur coussin d'air [end if]qui n'a pas grand chose a voir avec ceux de la petite ville d'ou vous provenez."
Understand "coussin d'air/coussin/coussins/voiture/vehicule" as Taxi.

Rues2 is a room. The printed name of Rues2 is "Avenue principale - Quartiers Est". The description of Rues2 is "Bien que Sarvegne soit une cite prospere, cette partie de la ville semble plus riche que l'autre. La bibliotheque n'est pas loin, un peu plus au nord."
	
TaxiBiblio is a scene. TaxiBiblio begins when the player is in taxi and the location is in Ville.
TaxiBiblio ends when the player is in Rues2 or in CentreVille.

TaxiBiblio2 is a scene. TaxiBiblio2 begins when the player is in taxi and the location is in Ville2.
TaxiBiblio2 ends when the player is in Rues2 or in CentreVille.


When TaxiBiblio ends:
	say "Vous ressortez du taxi et vous vous retrouvez au bord du trottoir."

When TaxiBiblio begins:
	say "Le chauffeur vous regarde et vous demande ou vous voulez aller.";
	if MaisonAnita is unvisited
		begin;
			say "Vous n'avez pas de destination precise en tete, aussi vous decidez de ressortir rapidement du taxi.";
			move player to location;
		otherwise;
			say "Vous demandez a aller pres de la bibliotheque. Le vehicule se souleve alors a quatre pieds de haut, et part vers la destination choisie.";
			if player has glutt 				begin;
					move the taxi to Rues2;
					move player to Rues2;
					change the argent of the glutt to the argent of the glutt - 1 pieces ;
					say "Vous donnez une piece au conducteur en paiement du transport." ;
				otherwise;
					say "Le chauffeur vous regarde d'un air soupconneux, et vous demande si vous avez de quoi payer la course. Vous lui tendez quelques pieces, mais elles lui sont inconnues et il n'en veut pas.";
					move player to location;
			end if;
	end if.


When TaxiBiblio2 begins:
	if player has glutt
		begin;
		say "Le chauffeur vous regarde et vous demande ou vous voulez aller.";
			if there is a turn_stamp corresponding to a cle of 2 in the Table of Anita Conversation
				begin;
				if there is a turn_stamp corresponding to a cle of 5 in the Table of Chauffeur Conversation
					begin;
						say "Vous lui demandez de vous conduire a la gare.";
						move the taxi to DansVille;
						say "Vous donnez une piece au conducteur en paiement du transport." ;
						change the argent of the glutt to the argent of the glutt - 1 pieces ;
						move player to Gare;
				otherwise;
					say "Vous demandez a retourner dans le centre de la ville.";
					move the taxi to CentreVille;
					change the argent of the glutt to the argent of the glutt - 1 pieces ;
					say "Vous donnez une piece au conducteur en paiement du transport." ;
					move player to CentreVille;		
				end if;
			otherwise;
				say "Voulez-vous retourner au centre-ville ?";
				if player consents
					begin;
						move the taxi to CentreVille;
						move player to CentreVille;
						change the argent of the glutt to the argent of the glutt - 1 pieces ;
						say "Vous donnez une piece au conducteur en paiement du transport." ;
					otherwise;
						move player to location;
				end if;
			end if;					
	otherwise;
		say "Le chauffeur vous regarde d'un air soupconneux, et vous demande si vous avez de quoi payer la course. Comme vous n'en avez plus, il refuse de vous conduire.";
		move player to location;
	end if.

When TaxiBiblio2 ends:
	say "Vous ressortez du taxi et vous vous retrouvez au bord du trottoir."

	
[Understand the command "sortir" as something new.
Understand "sortir du taxi" as a mistake ("Pour sortir d'un vehicule, il suffit juste de 'sortir'") when the player is in a vehicle.]

Chauffeur is a man. Chauffeur is in taxi. The printed name of Chauffeur is "le chauffeur".

Sortir is an action applying to nothing.
Understand the command "sortir" as something new.
Understand "quitter le taxi" as exiting.

Instead of going somewhere when the player is in a vehicle, say "Ce n'est pas vous qui conduisez ce vehicule.".

[Instead of leaving [vehicle], try exiting.]

[Some Taxis are a vehicle. Understand "[taxis]" as the taxis. The description of the taxis is "Un vehicule rapide qui n'a pas grand chose a voir avec ceux de la petite ville d'ou vous provenez."
 Understand "taxi/navettes" as "[taxis]". 

When the player enters DansVille, move 2 taxis to CentreVille.]


Bibliotheque is a room. Bibliotheque is north from Rues2. Bibliotheque is inside from Rues2.
The printed name of bibliotheque is "Bibliotheque".
The description of bibliotheque is "La bibliotheque de Sarvegne est un beau et vaste batiment de marbre clair[if location is unvisited], sur lequel est inscrit au fronton 'Vuy Arkjoda Vreffel - Vuy Arkjata Vrill', la devise de Sarvegne, et qui signifie 'Soit attire par la connaissance, soit volontaire de ton destin'[end if].".

Anita is a woman. Understand "jeune fille/fille" as Anita. The description of Anita is "Anita est une tres belle jeune fille aux cheveux noirs. Elle n'est pas tres grande, mais semble avoir beaucoup de determination. Ses habits sont raffines, en accord avec sa caste."

Instead of taking Anita, say "Elle n'est pas transportable et vous la vexeriez certainement !"

Anita is in Bibliotheque. Instead of telling Anita about something, try asking Anita about it.


Instead of going outside from bibliotheque or going south from bibliotheque:
	if the player has mallette
	begin;
		continue the action;
	otherwise;
	if there is a turn_stamp corresponding to a cle of 2 in the Table of Anita Conversation
		begin;
			say "'N'oubliez pas cette mallette, elle vous servira a rapporter discretement les reliques. Il n'y a de la place que pour quatre d'entre elles, aussi vous ne prendrez que les plus importantes pour moi. Vous les identifierez grace a un programme dans mon ordinateur.' Elle vous remet une petite valise sombre.";
			move the mallette to player;
			say "Vous devez maintenant trouver un moyen pour rejoindre ce plateau en dehors de la ville.";
			continue the action;
		otherwise;
			say "Vous devez maintenant trouver un moyen pour rejoindre ce plateau en dehors de la ville.";
			continue the action;
	end if;
	end if.

Before going to bibliotheque for the first time:
	say "Vous parcourez sous les allees ombragee les quelques metres qui vous restent pour atteindre l'entree de la bibliotheque. Les trottoirs ici ont des circuits imprimes a l'air libre, sans doute que la municipalite est en train d'installer de nouveaux capteurs pour un usage dont vous ignorez tout.";
	display the figure of sarvegne;
	say "Lorsque vous entrez elle sait que c'est vous qu'elle attend, et elle quitte sa place pour venir vous saluer. Elle vous explique qu'elle est presente ici tous les jours, mais elle partage ce temps avec un site archeologique qui vient d'etre decouvert recemment.".


The mallette is in bibliotheque. The mallette is a female container. The mallette is scenery. The carrying capacity of the mallette is 4. Understand "mallette" or "valise" as mallette. The description of mallette is "une petite mallette noire.".

instead of inserting mallette into sacdos, say "Votre sac a dos ne peut contenir cette valise.".

Instead of showing mallette to Anita, try giving mallette to Anita.

instead of giving mallette to Anita:
	if final is happening
		begin;
		if artefact2 is in mallette and artefact4  is in mallette and artefact5  is in mallette and artefact7 is in mallette
			begin;
			say "Elle semble tres heureuse de votre collecte. Felicitation.[line break]Vous retournez ensemble a la bibliotheque ou elle va rechercher quelques documents qui pourront lui servir pour la confrontation finale avec les membres corrompus du gouvernement. En effet, la preuve historique de ce foyer de peuplement sur le sol de la region de Sarvegne permettra de confondre le groupe d'usurpateurs qui a pris le pouvoir autoritairement il y a quelques dizaines d'annee. Elle doit avant cela terminer d'analyser les precieuses pieces que vous lui avez ramenees. Mais ceci est une autre histoire...";
			display the Figure of titre;
			say "Anita ouvre le petit coffret en lapis-lazuli. Elle en sort une plaque de cuivre grave qu'elle lit puis qu'elle vous tend. Il y figure ces lignes :[line break][line break][italic type]
Je garde avec moi ce bouclier d'etoiles[line break]
Qui nous protege d'une banniere etoilee[line break]
Situee alors si loin qu'elle nous paraissait inoffensive[line break]
Mais nous avons traverse des lieues dans l'espace[line break]
Puis conquit des terres hospitalieres et libres[line break]
Nos chariots roulant inlassablement sur l'herbe et le sable[line break]
Nos arcs et nos fleches toujours a notre portee[line break]
Des ennemis veulent nous passer au fil de leur epee[line break]
et nous imposer une religion nouvelle[line break]
Mais quoi qu'il en soit nous resterons toujours nous-meme.[line break][roman type]";
			end the game in victory;
		otherwise;
			say "Certains des artefacts dans la valise n'ont pas supporte le voyage et se sont abimes, mais ce n'est pas si grave dans un sens puisque ce n'est pas exactement ce qu'elle attendait de vous. Quelle deception, elle ne pourra pas continuer son travail de rehabilitation et de recherche. Sans doute fera-t-elle appel par la suite a quelqu'un de plus doue pour reussir cette mission.";
			end the game saying "[line break]** Vous avez perdu **.[line break]";
		end if;
	otherwise;
		say "Vous en aurez encore besoin.";
	end if.


The calculateur is in bibliotheque. The calculateur is a device. The charge of the calculateur is 6.

		
after switching on calculateur:
	if location is Grottes2
	begin;
		if charge of the calculateur is greater than 7
		begin;
		say "Vous allumez l'ordinateur, et utilisez le programme d'analyse qu'on vous a montre, pour comparer les piles d'objets presents et degager ceux qui correspondent a la collection d'Anita.";
		change artefact1 to not scenery;
		change artefact2 to not scenery;
		change artefact3 to not scenery;
		change artefact4 to not scenery;
		change artefact5 to not scenery;
		change artefact6 to not scenery;
		change artefact7 to not scenery;
		move Anita to MaisonAnita;
		remove tube from play;
		say "Malheureusement, entre-temps certains de ses collegues ont apportes d'autres pieces de moindre importance, et il va vous falloir les separer du reste pour savoir quoi ramener.";
		otherwise;
		say "Vous allumez l'ordinateur, et voulez utiliser le programme d'analyse, mais la batterie semble trop faible pour cela.";
		end if;
	otherwise;
		continue the action;
	end if.
	

instead of examining calculateur:
	if player is in bibliotheque and player is not carrying calculateur then say "Cet ordinateur portable appartient visiblement a Anita.";
	if charge of the calculateur is less than 1 then say "Il semble decharge.";
	if the calculateur is switched on, say "L'ordinateur semble operationnel. Il fonctionne sous un environnement de type Unix auquel vous n'etes pas trop habitue, mais affiche un programme d'analyse de donnees archeologiques qui semble convivial et facile a utiliser.";	
	if location is grottes2 
		begin;
			if artefact2 is not scenery, say "Vous consultez le manuel du programme, et il affiche egalement une nomenclature detaillee des types de reliques que l'on peut trouver. Vous trouvez aussi une note, sans doute d'Anita, qui indique ce petit poeme : [line break][line break] [italic type]
			Je regarde vers les etoiles, [line break]
			representation fidele de nos dieux, [line break]
			Je regarde vers les forets, les mers et leurs habitants,[line break]
			symboles de force et de liberte,[line break]
			Le soleil et les saisons, cycles recurrents,[line break]
			Rythment nos vies et nos rites.[line break]
			L'arc tendu, comme le fil de l'existence,[line break]
			Est hors de porte de ce qui pourrait le remplacer.[line break] [roman type]";
		otherwise;
			say "C'est un ordinateur portable.";
	end if.
	
	
After taking calculateur:
	if Anita is in location then say "Anita vous dit que vous pouvez emprunter son ordinateur portable si vous pensez en avoir besoin. Il pourra vous aider a identifier les artefacts, mais elle vous previent que sa batterie se decharge vite. [line break]";
	otherwise say "Ok[line break]".
Understand "ordinateur/laptop/portable" as calculateur.


Every turn when the player has calculateur and the calculateur is switched on: 
                decrease the charge of the calculateur by 1; 
	move unix to location;
	if the charge of the calculateur is 2 then say "L'ordinateur va sans doute s'eteindre bientot."; 
	if the charge of the calculateur is less than 1
		begin;	
		say "L'ordinateur n'a plus d'energie et s'eteint ![line break]"; 
		silently try switching off the calculateur;
		end if.

		

instead of putting cube on calculateur:
	if calculateur is switched on, say "Vous devriez eteindre l'ordinateur pour le recharger, sinon cela pourrait l'endommager.";
    if charge of the cube is greater than 0
        begin;
        change the charge of calculateur to 30;
        change the charge of cube to 0;
        say "Vous touchez l'ordinateur avec le cube. Un petit bourdonnement et de faibles vibrations se font ressentir, et le cube communique de son energie a l'ordinateur.";
    otherwise ;
        say "Le cube est deja vide et il ne peut rien faire de plus pour le moment, aussi vous le reprenez avec vous.";
    end if. 

The livres are scenery in bibliotheque. The description of livres is "Cette bibliotheque est emplie de livres, de papier ou electronique.". Understand "livre/livres/bibliotheque/endroit" as livres.

The borne is scenery in bibliotheque. The borne is female. The description of borne is "Une simple borne de consultation des fonds documentaires de cette bibliotheque.". Understand "borne" and "borne interactive" as borne.

Instead of searching livres:
	say "Vous consultez rapidement sur une borne interactive la notice generale des documents qui pourraient vous interesser ici. Vous prenez un des livres en question et vous y apprenez qu'un peuple respectant encore les anciens rites interdits habite a l'est de Sarvegne.";
	change the east exit of DerriereVille3 to CampAncien;
	change the west exit  of CampAncien to DerriereVille3;
	choose row 4 in the Table of Anita Conversation;
			change libelle entry to "le peuple ancien".
	

Part 3 - Au dela


Final is a scene. Final begins when Anita is in maisonanita for the first time.


ReseauGrottes is a region. Grottes and Grottes2 are in ReseauGrottes.

Before going nowhere from ReseauGrottes:
	if bibliotheque is not visited
	begin;
		say "";
	otherwise;
		say "Vous risquez de vous perdre si vous allez en dehors des lieux repertories et balises par Anita.";
	end if.


CampAncien is a room. The printed name of CampAncien is "Un camp".
The description of CampAncien is "[if location is not visited]Apres plusieures lieues de marche, vous arrivez a proximite d'un campement.[end if]Vous etes dans un camp, cache dans le desert, mais en bordure d'une foret. Il n'y a plus personne ici, mais vous voyez des chariots et des arcs abandonnes.".

accessoiresCamp is scenery in campancien. Understand "chariot/chariots/camp/arc/arcs" as accessoiresCamp. The description of accessoirescamps is "Divers objets appartenant a la tribu qui habitait la.".
Instead of taking accessoirescamp, say "Ce genre d'objet un peu archaique ne vous sera d'aucune utilite dans le moment present.".

Plateau is a room. The printed name of Plateau is "Le plateau de l'ancien site de Sarvegne".
The description of Plateau is "Vous etes sur le plateau qui correspondait a l'ancienne ville de Sarvegne, aux temps antiques. [if Plateau is not visited]Ce plateau fait environ la taille d'un stade, et presente quelques traces de vegetation. Il y a egalement quelques gros rochers de taille imposante, mais vous ne venez pas ici pour faire de la geologie.[end if] Des trous descendent vers le reseau de grotte sous le plateau.".

PlateauFake is scenery in Plateau.
Understand "grottes/grotte/plateau/trou/foyer/sarvegne/ruines/plantes/arbustes/trous/vegetation/rochers/roche" as plateauFake. The printed name of PlateauFake is "plateau". The description of plateaufake is "Ce plateau ainsi que le reseau de grottes qui passe en dessous representaient le premier foyer de peuplement de la cite de Sarvegne. Mais la cite a depuis completement disparu, le plateau est entierement vide a l'exception de quelques arbustes, plantes et baies qui restent la.".

Navette is in Plateau. Navette is a female vehicle. The printed name of navette is "la navette".

Instead of entering navette, try chatting mecanicien.

baie is a kind of thing. BaieJaune is a baie. The printed name of BaieJaune is "des baies jaunes". BaieJaune is in plateau. The description of BaieJaune is "Ces baies jaunes sont presque lumineuses.". Understand "baies/baie/jaune/jaunes" or "baies jaunes" as baiejaune.
 
Instead of taking baiejaune, say "Vous n'avez pas le temps de deguster les specialites locales."

Grottes is down from Plateau.
The description of Grottes is "[if Grottes is not visited]L'entree principale descend en pente douce. Anita vous a explique ou elle avait cache les artefacts, et vous reconnaissez facilement les lieux qu'elle vous a decrits. [end if]Vous etes dans une salle qui fut autrefois un grand hall d'accueil princier. Le reseau de grottes s'etend bien au-dela de ce que vous voyez, et des ouvertures partent un peu partout. Mais Anita vous a dit de ne pas quitter le chemin qui s'etend sur votre gauche tout a l'entree, et vous atteindrez directement les artefacts. La sortie se trouve en remontant la rampe[if Grottes is not visited] que vous venez d'emprunter[end if]."

Grottes2 is west from Grottes.

The description of grottes2 is "[if location is not visited]Cette partie se prolonge encore jusqu'a aboutir a [end if]une salle de taille moyenne[if location is not visited], mais emplie d'objets heteroclites. Visiblement les scientifiques ont decide de stocker la certaines de leurs diverses decouvertes en attendant que la situation vis a vis du gouvernement de Sarvegne se debloque[end if].". 
The printed name of grottes2 is "La salle de stockage des reliques.".

a relique is a kind of thing. 

Instead of attacking a relique, say "Ce sont des objets anciens, vous devez normalement les respecter."

Instead of touching a relique, say "Vous retournez l'objet dans tous les sens, mais pour vous qui n'etes pas un specialiste, il ne vous livrera pas facilement son secret.".

Instead of inserting a relique into sacdos, say "Vous ne pouvez mettre ce genre d'objet ancien dans un sac a dos sans aucune protection, vous devriez utiliser une valise capitonnee a la place.".

artefake is scenery relique in grottes2. The description of artefake is "Divers artefacts.". The printed name of artefake is "des artefacts anciens". Understand "artefact" or "tout" as artefake. 


the artefact1 is female scenery relique in grottes2. The description of artefact1 is "Une carte hexagonale, en cuir rouge, avec seulement six points cardinaux, d'un territoire inconnu.". The printed name of artefact1 is "carte ancienne". Understand "carte/cuir" or "carte ancienne" as artefact1. 

the artefact2 is scenery relique in grottes2. The description of artefact2 is "Ceci n'est qu'une petite partie d'un bouclier ancien, ou on trouve des incrustations dans un autre metal, sans doute de l'argent, qui forment des points semblant disposes aleatoirement.".The printed name of artefact2 is "fragment de bouclier ancien". Understand "bouclier/points/argent" or "bouclier ancien" as artefact2. 


the artefact3 is scenery relique in grottes2. The description of artefact3 is "Ce couteau a sur son manche et sa lame une serie de pentagrammes et de croissants occultes graves. La lame est torsadee, il semble utilise pour accomplir des rituels anciens.".The printed name of artefact3 is "couteau". Understand "couteau" or "lame/pentagrammes" as artefact3. 


the artefact4 is female scenery relique in grottes2. The description of artefact4 is "Une boite en lapis-lazuli et avec des decorations ainsi que le fermoir en bronze, on y voit des motifs geometriques en forme de roues qui donnent l'impression de tournoyer de facon hypnotique.".The printed name of artefact4 is "petite boite". Understand "boite/lazuli" or "petite boite" as artefact4. 

Instead of opening artefact4, say "Elle est fermee par un dispositif dont vous ignorez tout.".


the artefact5 is scenery relique in grottes2. The description of artefact5 is "Un vase en terre cuite, sur lequel est peint un sanglier dore.".The printed name of artefact5 is "vase". Understand "vase en terre cuite" or "terre/vase/sanglier" as artefact5. 


the artefact6 is female scenery relique in grottes2. The description of artefact6 is "Une croix miniature, dans le genre de celle que l'on utilisait dans les anciens temps pour crucifier les criminels.".The printed name of artefact6 is "croix". Understand "croix" or "crucifix" as artefact6. 

	
the artefact7 is female scenery relique in grottes2. The description of artefact7 is "Une pointe de fleche en bronze.".The printed name of artefact7 is "pointe de fleche". Understand "pointe" or "fleche" or "pointe de fleche" as artefact7. 


[Include Basic Screen Effects by Emily Short. Include Menus by Emily Short.

Table of Amusing Matter 
title   	subtable   	description   	toggle   
"Epilogue"   	a table-name   	"Anita ouvre le petit coffret en lapis-lazuli. Elle en sort une plaque de cuivre grave qu'elle lit puis qu'elle vous tend. Il y figure ces lignes :[line break][line break][italic type]
Je garde avec moi ce bouclier d'etoiles[line break]
Qui nous protege d'une banniere etoilee[line break]
Situee alors si loin qu'elle nous paraissait inoffensive[line break]
Mais nous avons traverse des lieues dans l'espace[line break]
Puis conquit des terres hospitalieres et libres[line break]
Nos chariots roulant inlassablement sur l'herbe et le sable[line break]
Nos arcs et nos fleches toujours a notre portee[line break]
Des ennemis veulent nous passer au fil de leur epee[line break]
et nous imposer une religion nouvelle[line break]
Mais quoi qu'il en soit nous resterons toujours nous-meme.[line break][roman type]"   	a rule   
"Military Revisions"   	a table-name   	"Did you try... [paragraph break] allying a Greek city-state with the Persians? (try >MEDIZE) [line break] playing Athens as a land-based power?"   	a rule   

Rule for amusing a victorious player: 
    change the current menu to the Table of Amusing Matter; 
    change the current menu title to "Epilogue"; 
    carry out the displaying activity; 
    clear the screen.]


Rule for amusing a victorious player: say "Anita ouvre le petit coffret en lapis-lazuli. Elle en sort une plaque de cuivre grave qu'elle lit puis qu'elle vous tend. Il y figure ces lignes :[line break][line break][italic type]
Je garde avec moi ce bouclier d'etoiles[line break]
Qui nous protege d'une banniere etoilee[line break]
Situee alors si loin qu'elle nous paraissait inoffensive[line break]
Mais nous avons traverse des lieues dans l'espace[line break]
Puis conquit des terres hospitalieres et libres[line break]
Nos chariots roulant inlassablement sur l'herbe et le sable[line break]
Nos arcs et nos fleches toujours a notre portee[line break]
Des ennemis veulent nous passer au fil de leur epee[line break]
et nous imposer une religion nouvelle[line break]
Mais quoi qu'il en soit nous resterons toujours nous-meme.[line break][roman type]".


Index map with EPS file,
  room-name-length set to 15, 
    route-thickness set to 2, 
    room-outline set to off, 
    map-outline set to off, 
    route-colour set to "Chocolate", 
    room-colour set to "Burly Wood", 
    title set to "Sarvegne", 
    font set to "Baskerville".


[nouveaux verbes]

Include (- 

Extend 'frapper' first
        * 'a'/'a' noun -> GoIn; 

-).


Include (- 

		
Extend 'questionner' first
		* creature -> ask;

-).


Mendier is an action applying to nothing.
Understand "mendier" as mendier.

[Understand "take [everything]" as a mistake ("Vous ne pouvez pas posseder tout le monde qui vous entoure juste sur une lubie...").]

Understand "aide" or "help" or "hints" or "astuces" as a mistake ("Ce jeu est une aventure textuelle, vous devez entrer des commandes pour decrire ce que vous voulez faire. Veuillez vous referer aux fichiers d'aide joints, ou taper 'solution' pour la liste complete des commandes a entrer si vous etes vraiment bloque, ou 'plan' pour visualiser un plan rapide. Si vous avez des problemes pour parler 'avec' quelqu'un, utilisez la commande 'questionner' untel 'au sujet de...', et veuillez abreger certaines formes non comprises. Au sujet des directions, pour des raisons de clarte il est possible d'ecrire 'n' pour 'nord', mais 'nord-ouest' s'ecrira ainsi et non pas 'no'[line break]
	Dans ce jeu votre but est d'arriver a recuperer des objets dans un lieu a l'ecart de la ville. Vous devez tout d'abord rencontrer Anita, votre contact. Pour arriver a elle, vous devrez avant cela entrer dans la ville par un passage detourne, ouvrir la trappe qui en bloque l'entree avec un objet energise par un vegetal, aller au centre d'information du centre ville pour trouver son habitation, ensuite detourner avec un tube qui fera office de jouet un molosse qui garde la maison, apprendre que la jeune fille se trouve a la bibliotheque pour y etudier, changer son argent pour la monnaie locale pour pouvoir prendre un taxi, et arriver a destination. Ensuite il faudra emprunter une malette et un ordinateur, apprendre du chauffeur de taxi comment aller dans un endroit interdit, rencontrer son ami mecanicien a la gare, retrouver le molosse decidement assez joueur de celui-ci, et arriver sur le plateau en dehors de la ville. L'ordinateur permettra d'identifier des artefacts perdus, en etudia
nt quelques notes qui devraient permettre par elimination de mettre de cote ce qui n'est pas l'objet d'etude d'Anita, et de rapporter les bons artefacts a votre contact. Si ces indications ne sont pas suffisantes, vous pouvez obtenir le cheminement complet avec la commande 'solution'
").

Plan is an action applying to nothing.
Understand "plan" or "carte" as plan.

check plan:
	display the figure of plansarvegne.

Carry out plan:
	display the figure of plansarvegne.

Understand "credits" or "info" as a mistake ("Jeu cree pour la competition ifiction.free.fr. Ceci est la version amelioree.[line break] 
(c) droits reserves - 2006[line break]").

Understand "cheminement" or "solution" or "walkthrough" as a mistake ("

Aller au nord / fouiller le buisson / prendre le cube / nord / nord-est / penser / est / regarder trappe / nord-est / regarder la mousse / poser le cube sur la mousse / regarder le cube / nord-ouest

revenir / prendre le cube / sud-ouest / regarder la plaque / poser le cube sur la plaque / ouvrir la trappe / prendre le cube / nord-est / poser le cube sur la mousse / prendre le cube / revenir / entrer/ prendre le tube / monter / nord-est /sortir

nord / nord / frapper a la porte / lancer tube sur le chien / frapper a la porte / sud / sud / nord-est / parler avec la femme / questionner la femme au sujet de argent / changer argent / sortir

nord / est / entrer dans le taxi / aller au nord / regarder Anita / parler avec Anita

questionner Anita au sujet du site / questionner Anita au sujet des artefacts / chercher les livres / questionner anita au sujet du peuple ancien / prendre ordinateur / sortir / questionner chauffeur au sujet du plateau / entrer dans le taxi 

ouest / sud / ouest  / parler avec mecanicien / est / nord / nord / prendre tube / lancer tube sur le chien / sud / sud / ouest / oui

descendre / ouest / allumer ordinateur / eteindre ordinateur / poser le cube sur l'ordinateur / allumer ordinateur / regarder

examiner la carte / examiner le bouclier / examiner couteau / examiner boite / examiner vase / examiner la croix / examiner la pointe / regarder l'ordinateur

prendre bouclier / mettre le bouclier dans la valise / prendre boite / mettre la boite dans la valise / prendre vase  / mettre le vase dans la valise / prendre pointe / mettre la pointe dans la valise

eteindre ordinateur / est / remonter / entrer dans la navette / oui / est / nord / nord / parler avec Anita / donner valise a Anita
").

Check mendier:
	if location is in ville, say "Vous ne pouvez vous resoudre a faire cela ici." instead.
Carry out mendier:
	say "Vous ne voyez pas l'interet de faire cela ici."


Test un with "Aller au nord / fouiller le buisson / prendre le cube / nord / nord-est / penser / est / regarder trappe / nord-est / regarder la mousse / poser le cube sur la mousse / regarder le cube / nord-ouest" 

Test deux with "revenir / prendre le cube / sud-ouest / regarder la plaque / poser le cube sur la plaque / ouvrir la trappe / prendre le cube / nord-est / poser le cube sur la mousse / prendre le cube / revenir / entrer/ prendre le tube / monter / nord-est /sortir"

Test trois with "nord / nord / frapper a la porte / lancer tube sur le chien / frapper a la porte / sud / sud / nord-est / parler avec la femme / questionner la femme au sujet de argent / changer argent / sortir"

Test quatre with "nord / est / entrer dans le taxi / aller au nord / regarder Anita / parler avec Anita"

Test cinq with "questionner Anita au sujet du site / questionner Anita au sujet des artefacts / chercher les livres / questionner anita au sujet du peuple ancien / prendre ordinateur / sortir / questionner chauffeur au sujet du plateau / entrer dans le taxi /"

Test sept with "ouest / sud / ouest  / parler avec mecanicien / est / nord / nord / prendre tube / lancer tube sur le chien / sud / sud / ouest / oui"

Test huit with "descendre / ouest / allumer ordinateur / eteindre ordinateur / poser le cube sur l'ordinateur / allumer ordinateur / regarder"

Test neuf with "examiner la carte / examiner le bouclier / examiner couteau / examiner boite / examiner vase / examiner la croix / examiner la pointe / regarder l'ordinateur"

Test dix with " prendre bouclier / mettre le bouclier dans la valise / prendre boite / mettre la boite dans la valise / prendre vase  / mettre le vase dans la valise / prendre pointe / mettre la pointe dans la valise"

Test onze with "eteindre ordinateur / est / remonter / entrer dans la navette / oui / est / nord / nord / parler avec Anita "

Test tout with "test un / test deux / test trois / test quatre / test cinq / test sept / test huit / test neuf / test dix / test onze"

Test tout2 with "test un / test deux / test trois / test quatre / test cinq / test six"
	
Test six with " ouest / sud / bas / sud  / nord-est / est "

Test sixbis with "test un / test deux / test trois / test quatre "

[bug : parler au chauffeur <> parler avec chauffeur
lancer tube ?vers? le chien

a device can't be a supporter ! (can't you put a cup of tea on a computer tower ?)
auto line break...
apostrophes pb avec guillemets
split screen
can't use composed word in dialogue
supporter and backdrop are incompatible.
female scenery supporter = pb affichage : on laplaque est ...
disable "take all"
add Constant AMUSING_PROVIDED;

]