;Reply and Post Script for Qterm
;See QTMES.SCR - by Rob Friedman
;
;--updated 2/4/90
;
;Remember to edit to your specs. as in Phone numbers, UID, and Password
;edit out all lines with the ";"
;  Enjoy..
;	      Rob Friedman (Sysop ADAM CP/M)
--------------------------------------------
!b2400 8n1				    ;sets baud and parity
!k2Rob Friedman(Sysop Adam CP/M)	    ;sets keys
!k5Rob Friedman				    ;"
!k176072,417\r				    ;"
%ATZ\r%OK\r\n%%5%			    ;resets Modem to make sure
%ATDT2944190\r%CONNECT 2400\r\n%%%9%7	    ;dials 1st # and checks
%ATZ\r%OK\r\n%%5%			    ;resets if 1st # n/g
%ATDT9322088\r%CONNECT 2400\r\n%%%	    ;dials 2nd #
%\d\x03%\r\n%				    ;hits ^C
%%D: %					    ;waits for I.D: prompt
%76702,417\r%ord: %			    ;sends# ,looks for PW
%PASS/WORD\r\n\r\n%!%			    ;sends PW, looks for !
%g club\r%Forum	!%30%			    ;sends G CLUB, looks for Forum !
                                            ;and waits 30 sec if CIS is slow
%rep 85285\r%done)%%                        ;tells CIS it will REPLY to
                                            ;mess. 85285, and waits for done)
!p ronmes.rep                               ;sends the reply-message
%%action !%%                                ;waits for the read action prompt
%post\r%Forum !%                            ;posts the message, looks for !
%off\r%NO CARRIER\r\n%			    ;Logs off CIS, waits for NO
					    ;CARRIER from modem
!,					    ;hangs up via ATH0 string
!a					    ;rings bell to wake you up
--------------------------------------------
;and poof!
;
;The whole idea of this is to automate the sending of messages, and
;shorten your time on CIS and save $$. Be sure to read the QTERM.DOC, 
;as well as the SCRIPTS.QTM file, both in the QTERM LBRs.
;
;
;Here's another section.. used for Composing new messages.
--------------------------------------------
%g club\r%Forum !%30%                       ;same as above
%compose\r%done)%%                          ;tells your doing a new message
!p new.mes                                  ;sends the new message
%%action !%%                                ;waits for read action prompt
%post to:all sec:9 sub:co\r%Forum !%        ;all-in-one command, tells how
                                            ;and where to post the message
%off\r%NO CARRIER\r\n%                      ;like before.. signs off
--------------------------------------------
;
;Be aware that the numbers in the reply need to be edited every time
;you send a reply. As well as the name of the reply. To send several 
;replies, simply repeat the reply section starting with the rep # and 
;ending with the Post.
;
;The following is the same as the original QTMES.SCR . Please be aware
;that these commands CAN be used for any Modem program:
;
;Well.. I hope this helps some of you and you get to be proficient with 
;QTERM. Even though ZMP runs more options, I've found QTERM's scripts to 
;be really fast when dialing in.. and a real timesaver for use on CIS, as 
;well as a timesaver for dialing into Starlink. What with all those numbers
;and ID's to dial..whew. 
;
;A note here for NON-QTERM users who are on CIS. Please look at the CIS scripts.
;The commands I'm using are standard CIS commands, and can be used with ANY 
;modem program for fast capture or sending of messages. Again.. having an 
;external modem running at 1200b or 2400b really helps. And again.. these 
;scripts for QTERM are for use with an external modem <unless you have 
;adapted it for the Sydmodem 1200 internal modem>.
;
;Enjoy it!
;Rob Friedman- Sysop ADAM CP/M 
;CompuServe Computer Club Forum
;


.