;**************************
;
;   ANSI Terminal Driver
;   Supports Altos II
;
;**************************
;1.0 02-Oct-84 DFP written at @LMS by David Pallmann.

	ASMMSG	"ANSI Terminal Driver"

	SEARCH	SYS
	SEARCH	SYSSYM
	SEARCH	TRM

	OBJNAM	ANSI.TDV

	TFEATS=TD$LID!TD$CID!TD$DIM!TD$EOS!TD$EOL!TD$BLN!TD$UND!TD$RVA!TD$MLT

	ESC=33

;**********
;   ANSI
;**********
;Terminal driver communications area
ANSI:	WORD	TD$NEW			; terminal attributes
	BR	JMPINP			; input routine
	RTN				; output routine
	BR	ECHO			; echo routine
	BR	JMPCRT			; crt control
	RTN				; no init routine yet
	WORD	0			; no impure area yet
	BYTE	24.			; number of rows
	BYTE	80.			; number of columns
	LWORD	TFEATS			; terminal has:
					;   insert/delete line
					;   insert/delete character
					;   dim video attribute
					;   erase to end of screen
					;   erase to end of line
					;   multi-byte keystrokes

JMPINP:	JMP	INP			; go handle input characters
JMPCRT:	JMP	CRT			; go handle tcrt codes

;********************
;*	 ECHO	    *
;********************
;Special echo processing is performed here
;Rubouts will backspace and erase the previous character
;Control-U will erase the entire line by backspacing and erasing
ECHO:	CMPB	D1,#25			; control-u
	BEQ	CTRLU
	CMPB	D1,#177			; rubout
	BNE	ECHX

;Rubouts are handled by the old backspace-and-erase game
;Special handling must be performed if we are rubbing out a tab
;D6 contains the character being rubbed out
RUBOUT:	CMPB	D6,#11			; was it a tab?
	BEQ	RBTB			;   yes
;Rubout was of a printable character - queue up the backspace sequence
KRTG:	MOV	#3,D3			; set character count
	LEA	A6,ERUB			; set buffer address
	MOV	A6,D1			;   into d1
	TRMBFQ				; queue the backspace sequence
	RTN
ERUB:	BYTE	10,40,10,0
;Rubout was of a tab - we must calculate how big the tab was and backup over it
RBTB:	CLR	D3			; preclear D3
	MOVW	T.POB(A5),D3		; set beginning position count
	MOV	T.ICC(A5),D2		; set input character count
	MOV	T.IBF(A5),A6		; set input buffer base
KRTS:	DEC	D2			; done with scan?
	BMI	KRTQ			;   yes
	MOVB	(A6)+,D1		; scan forward calculating position
	CMPB	D1,#11			;   tab
	BEQ	KRTT
	CMPB	D1,#15			;  cr
	BEQ	KRTC
	CMPB	D1,#ESC			;  altmode
	BEQ	KRTI
	CMPB	D1,#40			;  control-char
	BLO	KRTS
	CMPB	D1,#172
	BHI	KRTS
KRTI:	INC	D3			; increment position for one character
	BR	KRTS
KRTT:	ADD	#10,D3			; adjust position for tab
	AND	#^C7,D3
	BR	KRTS
KRTC:	CLR	D3			; clear position for cr
	BR	KRTS
KRTQ:	COM	D3			; calculate necessary backspaces
	AND	#7,D3
	INC	D3
	MOV	#10,D1			; set immediate backspace character
	TRMBFQ				; queue the backspaces
ECHX:	RTN

;Echo a control-u by erasing the entire line
CTRLU:	TST	D6			; no action if nothing to erase
	BEQ	CTUX
	CLR	D3			; preclear D3
	MOVW	T.POO(A5),D3		; calculate backspace number to erase the line
	SUBW	T.POB(A5),D3
	BEQ	ECHX
	CMP	D3,T.ILS(A5)		; insure not greater than terminal width
	BLOS	CLUA
	MOV	T.ILS(A5),D3
CLUA:	MOV	#10,D1			; queue up backspaces
	TRMBFQ
	ASL	D1,#2			; queue up spaces
	TRMBFQ
	MOV	#10,D1			; queue up backspaces
	TRMBFQ
CTUX:	RTN


;********************
;*	INP	    *
;********************
;Input character processing subroutine
;Return a negative flag to indicate possible multi-byte key codes
;Detect a negative flag which indicates the multi-byte processing return
INP:	BMI	INMLT			; skip if multi-byte processing
	CMPB	D1,#ESC			; escape?
	BEQ	INPM			;   yes - could be multi-byte sequence
	LCC	#0			;   no - normal processing
	RTN

INPM:	LCC	#PS.N			; possible multi-byte - return N flag
	RTN

;Multi-byte processing is done here
;This occurs when TRMSER has accumulated all bytes of a multi-byte keystroke
;D0 contains the character count and A0 indexes the data string
;A5 indexes the terminal definition block and must be preserved
;The translated character must be returned in D1 for storage
;This routine may destroy only A0,A3,A6,D0,D6,D7
INMLT:	MOVB	(A0)+,D1		; get the first character
	DECB	D0			; no translation if single character
	BEQ	INMX
	CMPB	D1,#ESC
	BNE	INMX

;Escape sequences are translated directly by setting bit 7 on
;This will cause them to map to 240-377

ESCAPE:	TSTB	(A0)+			; discard [
	MOVB	(A0)+,D1		; get the second character
	LEA	A0,ESCTBL		;point to translation table
10$:	TSTB	@A0			;end of table?
	BEQ	INMX			; yes - escape sequence is invalid
	CMMB	(A0)+,D1		;match?
	BEQ	20$			; yes
	INC	A0			; no - increment index
	BR	10$			;      and try next table entry
20$:	MOVB	@A0,D1			;put translated char in D1
	BR	INMX			; and return to program

ESCTBL:	BYTE	'A,'K-'@		;UP ARROW     becomes  ^K
	BYTE	'D,'H-'@		;LEFT ARROW   becomes  ^H
	BYTE	'C,'L-'@		;RIGHT ARROW  becomes  ^L
	BYTE	'B,'J-'@		;DOWN ARROW   becomes  ^J
	BYTE	'f,'^-'@		;HOME         becomes  ^^
	BYTE	'M,'Z-'@		;DEL LINE     becomes  ^Z
	BYTE	'P,'D-'@		;DEL CHAR     becomes  ^D
	BYTE	'S,'T-'@		;NEXT SCREEN  becomes  ^T
	BYTE	'L,'B-'@		;INSERT LINE  becomes  ^B
	BYTE	'@,'F-'@		;INSERT CHAR  becomes  ^F
	BYTE	'T,'R-'@		;PREV SCREEN  becomes  ^R
	BYTE	0,0

INMX:	LCC	#0			; reset the flags
INMX2:	RTN

PAGE

;********************
;*	 CRT	    *
;********************
;Special crt control processing
;D1 contains the control code for X,Y positioning or special commands
;If D1 is positive we have screen positioning (row in hi byte, col in lo byte)
;If D1 is negative we have the special command in the low byte
CRT:	TSTW	D1			; is it cursor position?
	BMI	CRTU			;   no

;Cursor positioning - D1 contains X,Y coordinates

	TTYI
	BYTE	ESC,'[,0,0

	SAVE	D0

	MOV	D1,D0
	RORW	D1,#8.
	AND	#377,D1
	DCVT	0,OT$TRM

	TTYI
	BYTE	';,0

	MOV	D0,D1
	AND	#377,D1
	DCVT	0,OT$TRM

	TTYI
	BYTE	'f,0

	REST	D0

	RTN

;Special commands - D1 contains the command code in the low byte
CRTU:	AND	#377,D1			; strip the high byte

;Command processing per director tables
	PUSH	A2			; save A2
	ASL	D1			;  times 2 (word offset).
	CMP	D1,#CRCB-CRCA		; check for valid code
	BHI	CRTX			;   and bypass if bad
	LEA	A2,CRCA			; index the table
	ADD	D1,A2			; add command code
	MOVW	@A2,D1			; pick up data field offset
	ADD	D1,A2			; make absolute data address
	TTYL	@A2			; print the data field
CRTX:	POP	A2			; restore A2
	RTN

;Escape sequence translation table
;
EXTB:	BYTE	67,73,105,111,120,121,122,124,127,131,377,377
	EVEN

;Byte offset and data tables follow for all commands
;
CRCA:	WORD	C0-.,C1-.,C2-.,C3-.,C4-.,C5-.,C6-.,C7-.
	WORD	C8-.,C9-.,C10-.,C11-.,C12-.,C13-.,C14-.,C15-.
	WORD	C16-.,C17-.,C18-.,C19-.,C20-.,C21-.,C22-.,C23-.
	WORD	C24-.,C25-.,C26-.,C27-.,C28-.,C29-.
	WORD	C30-.,C31-.,C32-.,C33-.,C34-.,C35-.,C36-.,C37-.,C38-.,C39-.
	WORD	C40-.,C41-.,C42-.,C43-.,C44-.,C45-.,C46-.,C47-.,C48-.,C49-.
	WORD	C50-.,C51-.,C52-.,C53-.,C54-.,C55-.,C56-.,C57-.,C58-.,C59-.
	WORD	C60-.,C61-.,C62-.,C63-.,C64-.,C65-.,C66-.,C67-.,C68-.,C69-.
	WORD	C70-.,C71-.,C72-.,C73-.,C74-.,C75-.,C76-.,C77-.,C78-.,C79-.
	WORD	C80-.,C81-.,C82-.,C83-.,C84-.,C85-.,C86-.,C87-.,C88-.,C89-.
	WORD	C90-.,C91-.,C92-.,C93-.,C94-.,C95-.,C96-.,C97-.,C98-.,C99-.
	WORD	C100-.,C101-.,C102-.,C103-.,C104-.,C105-.
CRCB:
	PAGE
;***************************
;
;   Special CRT Functions
;
;***************************
;
; NOTE:	special functions blinking/reverse_video/underlining are coded to
;	print an extraneous space.  This makes the driver compatible with
;	such software as AlphaMENU that is coded in expectation of
;	TeleVideo-type graphics that print an attribute character.
;
;	If the space is not desireable for your application, remove all
;	references to the number 40.  For example:
;
;		change  BYTE ESC,'[,'X,40,0  to  BYTE ESC,'[,'X,0
;

C0:	BYTE	ESC,'[,'2,'J		;ED  clear screen
C1:	BYTE	ESC,'[,'0,';,'0,'H,0	;CUP cursor home
C2:	BYTE	ESC,'E,0		;NEL cursor return
C3:	BYTE	ESC,'[,'1,'A,0		;CUU cursor up
C4:	BYTE	ESC,'[,'1,'B,0		;CUD cursor down
C5:	BYTE	ESC,'[,'1,'D,0		;CUB cursor left
C6:	BYTE	ESC,'[,'1,'C,0		;CUF cursor right
C7:					;XXX lock keyboard
C8:	BYTE	0			;XXX unlock keyboard
C9:	BYTE	ESC,'[,'0,'K,0		;EL  erase to end of line
C10:	BYTE	ESC,'[,'0,'J,0		;ED  erase to end of screen
C11:	BYTE	ESC,'[,'2,'m,0		;SGR enter backgroud display mode (reduced intensity).
C12:	BYTE	ESC,'[,'0,'m,0		;SGR enter foreground display mode (normal intensity)
C13:					;XXX enable protected  fields
C14:	BYTE	0			;XXX disable protected fields
C15:	BYTE	ESC,'[,'1,'M,0		;DL  delete line
C16:	BYTE	ESC,'[,'1,'L,0		;IL  insert line
C17:	BYTE	ESC,'[,'1,'P,0		;DCH delete character
C18:	BYTE	ESC,'[,'1,'@,0		;ICH insert character
C19:					;XXX read cursor address
C20:	BYTE	0			;XXX read character at current cursor position
C21:	BYTE	ESC,'[,'5,'m,40,0	;SGR start blink field
C22:	BYTE	ESC,'[,'0,'m,40,0	;SGR end blink field
C23:					;XXX start line drawing mode (enable alternate character set)
C24:					;XXX end line drawing mode (disable alternate character set)
C25:					;XXX set horizontal position
C26:					;XXX set vertical position
C27:	BYTE	0			;XXX set terminal attributes
C28:	BYTE	ESC,'[,'>,'5,'l,0	;RM  cursor on
C29:	BYTE	ESC,'[,'>,'5,'h,0	;SM  cursor off
C30:	BYTE	ESC,'[,'4,'m,40,0	;SGR start underscore			[102]
C31:	BYTE	ESC,'[,'0,'m,40,0	;SGR end underscore			[102
C32:	BYTE	ESC,'[,'7,'m,40,0	;SGR start reverse video			[102]
C33:	BYTE	ESC,'[,'0,'m,40,0	;SGR end reverse video			[102]
C34:	BYTE	ESC,'[,'7,'m,40,0	;SGR start reverse blink			[102]
C35:	BYTE	ESC,'[,'0,'m,40,0	;SGR end reverse blink			[102]
C36:					;XXX turn off screen display		[102]
C37:					;XXX turn on screen display		[102]
C38:					;XXX top left corner
C39:					;XXX top right corner
C40:					;XXX bottom left corner
C41:					;XXX bottom right corner
C42:					;XXX top intersect
C43:					;XXX right intersect
C44:					;XXX left intersect
C45:					;XXX bottom intersect
C46:					;XXX horizontal line
C47:					;XXX vertical line
C48:					;XXX intersection
C49:					;XXX solid block
C50:					;XXX slant block
C51:					;XXX cross-hatch block
C52:					;XXX double line horizontal
C53:					;XXX double line vertical
C54:					;XXX send message to function key line
C55:					;XXX send message to shifted function key line
C56:					;XXX set normal display format
C57:					;XXX set horizontal split (follow with row code)
C58:					;XXX set vertical split (39 char columns)
C59:					;XXX set vertical split (40 char columns)
C60:					;XXX set vertical split column to next char
C61:					;XXX activate split segment 0
C62:					;XXX activate split segment 1
C63:					;XXX send message to host message field
C64:					;XXX up-arrow
C65:					;XXX down-arrow
C66:					;XXX raised dot
C67:					;XXX end of line marker
C68:					;XXX horizontal tab symbol
C69:					;XXX paragraph
C70:					;XXX dagger
C71:					;XXX section
C72:					;XXX cent sign
C73:					;XXX one-quarter
C74:					;XXX one-half
C75:					;XXX degree
C76:					;XXX trademark
C77:					;XXX copyright
C78:					;XXX registered
C79:					;XXX print screen
C80:					;XXX reserved for set to wide mode
C81:					;XXX reserved for set to normal mode
C82:					;XXX enter transparent print mode
C83:					;XXX exit transparent print mode
C84:					;XXX begin writing to alternate page
C85:					;XXX end writing to alternate page
C86:					;XXX toggle page
C87:					;XXX copy to alternate page
C88:					;XXX insert column
C89:					;XXX delete column
C90:					;XXX block fill with attribute
C91:					;XXX block fill with character
C92:					;XXX draw a box
C93:					;XXX scroll box up one line
C94:					;XXX scroll box down one line
C95:					;XXX select jump scroll
C96:					;XXX select fast smooth scroll
C97:					;XXX select med-fast smooth scroll
C98:					;XXX select med-slow smooth scroll
C99:					;XXX select slow smooth scroll
C100:					;XXX start underscore/blink
C101:					;XXX end underscore/blink
C102:					;XXX start underscore/reverse
C103:					;XXX end underscore/reverse
C104:					;XXX start underscore/reverse/blink
C105:	BYTE	0			;XXX end underscore/reverse/blink
	EVEN

	END

.