$D #USAGE HLP
:S
;
;	FMTHLP.DO
;	Format a SuperVUE document, into an Alpha Micro product format,
;	and rename the .LST to a specified extension (defaults to .HLP).
;	
;	Provided as a shell for SV using AMHELP.PDV.
;
;	Produces help files suitable for the following Alpha Micro Products:
;
;		*   AMOS 2.x HELP facility
;		*   AlphaCALC
;		*   AlphaWRITE
;		*   ESP
;		*   DART
;
; Edit History (most recent listed first):
;
;	Revised:  09-Jul-89 by CAE - Made generic version FMTHLP.
;	Created:  06-Jul-89 by JAJ as FMTAMH/FMTESH
;
GOTO #$0
;##USAGE
:R
XY=11
:<USAGE: >
XY=12
:<FMTHLP>
XY=11
:< filename {out-extension}

	This utility will produce a help file by formatting the specified
	SuperVUE document into the format used by the following:

		AMOS 2.x	AlphaCALC	AlphaWRITE
		ESP		DART

	For example the command "FMTHLP MYFILE USA" will produce a formatted
	help file named MYFILE.USA from the input file MYFILE.T

	Spaces in the command line ARE SIGNIFICANT.

	Only documents with ".T" extension may be used as input files.
	The default output file extension is ".$1"
	
	AMHELP.PDV must be located in System memory, User Memory or resident
	on DSK0:[1,20].
>
XY=12
:S
EXIT
;
;	FORMAT the document specified.
;
;	1) find out if it exists.
;#$0
LOAD SYS:LOOKUP.LIT
LOAD SYS:GOTO.LIT
LOOKUP $0.T/
GOTO @NO-FILE
GOTO #$0
;
;@NO-FILE
:<
?File $:$0.T[$P] was not found for processing.
>
EXIT
;GOTO @EXIT
;
;       2) SEE if filename.HLP already exists.
;          If it does, quit.
;          If it doesn't process file.
;#$0
LOOKUP $0.$1/
GOTO @NOT-HERE
:<
?File $:$0.$1[$P] already exists. FMTHLP will not overwrite it.
 $0.T not processed.
>
; Quit this Do file.
EXIT
;
;@NOT-HERE
LOOKUP RES:AMHELP.PDV/
GOTO @NO-SYS-PDV
GOTO @READY
;
;@NO-SYS-PDV
LOOKUP MEM:AMHELP.PDV/
GOTO @NO-MEM-PDV
GOTO @READY
;
;@NO-MEM-PDV
LOOKUP DSK0:AMHELP.PDV[1,20]/
GOTO @NO-PDV
:<
Loading AMHELP.PDV into user memory.
>
LOAD DSK0:AMHELP.PDV[1,20]
GOTO @READY
;
;@NO-PDV
:<
?Cannot find DSK0:AMHELP.PDV[1,20]
 $0.T not processed.
>
EXIT
;
;@READY
;	3) enter SuperVUE allowing command files and stay quiet.
;	4) always go to command mode.
;	5) start FORMAT.
;	6) default to menu options.
;	7) when format is done, quit.
;
:<
Processing $:$0.T[$P]
>
SV $0.T/C/Q
^S^[
FORMAT^M
^[^[
Q^M
RENAME $0.$1=$0.LST
;
;@EXIT
:<

$:$0.T[$P] has been processed. $:$0.$1[$p] has been created.
>
DEL LOOKUP.LIT
DEL GOTO.LIT