;***************************************
; SETUP.M68 - Somewhat like "SET"
;             Shows use of AAA.UNV
; Usage: SETUP
; by Dave Heyliger
;***************************************

       SEARCH SYS                 ; search the norms...
       SEARCH SYSSYM
       SEARCH TRM
       SEARCH AAA                 ; here is something new!  AAA MACROs defined

       PHDR    -1,0,PH$REE!PH$REU

TOP:   CALL    MENU               ; display selections
       CALL    ANALIZ             ; execute selection
       CRLF                       ; RETURN
       EXIT                       ; all done

MENU:  PRTTAB  -1,0               ; clear the screen
       PRTTAB  4,20.              ; cursor here
       TYPE    <SETUP - Sets up your terminal without using SET!>
       PRTTAB  6.20.              ; cursor here
       TYPE    <Choose:  1) set hex  2) set octal  3) no ^C  4) ^C  5) exit>
       PRTTAB  8.,30              ; cursor here
       TYPE    <Users Choice: >
       ONEKEY                     ; one key does it all, D1 holds input
       KBD                        ; wait for user input
       RTN                        ; return from MENU subroutine

ANALIZ:
       CTRLC   FOOLEM             ; "fool 'em" on a ^C
       SUBB    #60,D1             ; create 1,2,3,4, or 5
       CMPB    D1,#1              ; set hex?
       BNE     MO                 ; nope, maybe octal
       HEX                        ; yup, hex set!
       RTN                        ; end of subroutine

MO:    CMPB    D1,#2              ; set octal?
       BNE     MNC                ; nope, maybe no control C
       OCTAL                      ; yup, octal set!
       RTN                        ; end of subroutine

MNC:   CMPB    D1,#3              ; set no control-C?
       BNE     MSC                ; nope, maybe set control-C
       NOCTC                      ; control-C not set!
       RTN                        ; end of routine

MSC:   CMPB    D1,#4              ; set control-C
       BNE     MQ                 ; nope, maybe quit
       CTC                        ; control-C set!
       RTN                        ; end of routine

MQ:    CMPB    D1,#5              ; quit?
       BNE     ERROR              ; nope, error in input
       RTN                        ; else simply return (exit will occur)

ERROR: MOV     #7,D1              ; get a bell
       TTY                        ; "BEEP"
       CRLF                       ; cursor to new line
       TYPE    <Invalid selection>
       RTN                        ; end of routine

FOOLEM:
       CLRCTC                     ; clear out the control-C
       MLTKEY                     ; standard KBD routine
       TYPE    <.>                ; give them the "dot"
       KBD                        ; wait for input.... hehehehe
       TYPECR  <HA-HA - fooled you!>
       ONEKEY                     ; one key input
       TYPE    <Any key to continue... >
       KBD                        ; wait for a keystroke
       CLRCTC                     ; just in case ^C entered
       JMP     TOP                ; back to beginning
       END                        ; end of code

.