!*********************************** FIXOVR *********************************
 ! Fix overlays that use a "+" in position [2,2] for overprint - DKM  12/14/83
 !----------------------------------------------------------------------------
 !   DATE     INI   DESCRIPTION
 ! --------   ---   ----------------------------------------------------------
 ! 12/14/83   DKM   This program was created by Darrin Miller of Cormac, Inc.,
 !                  P.O. Box 21644, Billings, MT  59102 - This program is for
 !                  all Amus Users
 !****************************************************************************
 MAP1 VERSION,S,14, "VERSION 01.014"
 MAP1 FIX'FILENAME,S,10
 MAP1 NEW'FILENAME,S,10
 MAP1 THE'LINE,S,132
 MAP1 KILL'FILE,S,1
 MAP1 FOUND,F,6
 !****************************************************************************
	XCALL ECHO : SIGNIFICANCE 11
	ON ERROR GOTO ERROR'TRAP
	PRINT TAB(-1,00);
 FIX'FILENAME:
	PRINT TAB(03,01); TAB(-1,10); "ENTER NAME OF FILE TO FIX: ";
	FIX'FILENAME = "" : INPUT "", FIX'FILENAME
	LOOKUP FIX'FILENAME, FOUND
	IF FOUND <= 0 GOTO FIX'FILENAME
 NEW'FILENAME:
	PRINT TAB(05,01); TAB(-1,10); "ENTER NAME OF NEW FILE: ";
	NEW'FILENAME = "" : INPUT "", NEW'FILENAME
	IF NEW'FILENAME = FIX'FILENAME GOTO SAME'FILENAME
	LOOKUP NEW'FILENAME, FOUND
	IF FOUND = 0 GOTO OPEN'FILES
 KILL'NEW'FILENAME:
	PRINT TAB(07,01); TAB(-1,10); NEW'FILENAME; " EXISTS, KILL ANYWAY? ";
	KILL'FILE = "" : INPUT "", KILL'FILE
	IF KILL'FILE = "Y" GOTO OPEN'FILES
	IF KILL'FILE # "N" GOTO KILL'NEW'FILENAME
	GOTO NEW'FILENAME
 SAME'FILENAME:
	PRINT TAB(07,01); TAB(-1,10); "OLD FILENAME IS THE SAME AS THE NEW FILENAME";
	PRINT TAB(09,01); TAB(-1,10); "ENTER <CR> TO CONTINUE ";
	KILL'FILE = "" : INPUT "", KILL'FILE
	GOTO NEW'FILENAME
 OPEN'FILES:
	OPEN #1, FIX'FILENAME, INPUT
	OPEN #2, NEW'FILENAME, OUTPUT
	PRINT TAB(07,01); TAB(-1,10);
 INPUT'FIX'FILE:
	INPUT LINE #1, THE'LINE
	PRINT ".";
	IF EOF(1) GOTO CLOSE'FILES
	IF THE'LINE[2,2] = "+" GOTO OVER'PRINT
	PRINT #2
	PRINT #2, THE'LINE; CHR$(13);
	GOTO INPUT'FIX'FILE
 OVER'PRINT:
	PRINT #2, THE'LINE[3,132]; CHR$(13);
	GOTO INPUT'FIX'FILE
 CLOSE'FILES:
	CLOSE #1
	CLOSE #2
	PRINT
	END
 ERROR'TRAP:
	PRINT TAB(22,01); TAB(-1,09); "FATAL ERROR # "; ERR(0);
	PRINT TAB(23,01); TAB(-1,09); "    IN LINE # "; ERR(1)
	INPUT "ENTER <CR> TO CONTINUE"; KILL'FILE
	END