!DONATED BY BYTE COMPUTER SERVICES

10	PRINT TAB(-1,0)
20	PRINT TAB(26);"THE GAME OF CAMEL"
30	PRINT
40	PRINT "WOULD YOU LIKE INSTRUCTIONS";
50	INPUT D$
60	IF LEFT(D$,1)<>"Y" THEN 260
70	PRINT TAB(-1,0)
80	PRINT TAB(8);"WELCOME TO THE GAME OF CAMEL. THE OBJECT IS TO TRAVEL"
90	PRINT TAB(8);"200 MILES ACROSS THE GREAT GOBI DESERT.  A TRIBE OF"
100	PRINT TAB(8);"KNOCKED KNEED PIGMIES WILL BE CHASING YOU.  YOU WILL"
110	PRINT TAB(8);"BE ASKED FOR COMMANDS EVERY SO OFTEN."
120	PRINT
130 	PRINT TAB(28);"C O M M A N D S  "
140	PRINT
150	PRINT TAB(21);"#1 DRINK FROM YOUR CANTEEN"
160	PRINT TAB(21);"#2 AHEAD MODERATE SPEED"
170	PRINT TAB(21);"#3 AHEAD FULL SPEED"
180	PRINT TAB(21);"#4 STOP FOR THE NIGHT"
190	PRINT TAB(21);"#5 STATUS CHECK"
200	PRINT TAB(21);"#6 HOPE FOR HELP"
210	PRINT         
220	PRINT TAB(8);"YOU HAVE ONE QUART OF WATER WHICH WILL LAST YOU SIX DRINKS."
230	PRINT TAB(8);"YOU MAY RENEW YOUR WATER SUPPLY COMPLETELY AT AN OASES. YOU"
240	PRINT TAB(8);"GET A HALF A QUART IF FOUND BY HELP.  IF HELP DOES NOT FIND"
250	PRINT TAB(8);"YOU AFTER THE USE OF  COMMAND SIX, YOU LOSE."
260	PRINT
270	PRINT TAB(18);"GOOD LUCK AND GOOD CAMELING !!"
280	PRINT TAB(8);"YOU ARE IN THE MIDDLE OF THE DESERT AT AN OASIS."
290	GOSUB 2000
300	IF C>199 THEN 1270
310	Z=Z-1
320	IF Z=1 THEN PRINT TAB(8);"----------W A R N I N G---------- GET A DRINK"
330	IF Z<0 THEN 1760
340	P=P+1
350	X2=INT(10*RND(0)+2.5)
360	IF Q>0 THEN 940
370	IF P<4 THEN 440
380	C1=C1+X2
390	IF C1<C THEN 430
400	PRINT TAB(8);"THE PYGMIES HAVE CAPTURED YOU.  CAMEL AND PEOPLE SOUP IS"
410	PRINT TAB(8);"THEIR FAVORITE DISH !!!!!"
420	GOTO 1680
430	PRINT TAB(8);"THE PYGMIES ARE"C-C1;"MILES BEHIND YOU."
440	PRINT TAB(8);"YOU HAVE TRAVELLED";C;"MILES ALL TOGETHER."
450	PRINT
460	PRINT TAB(8);"WHAT IS YOUR COMMAND";
470	INPUT Y$(1)
480	Y=VAL(Y$(1))   !         ,I1)
490	IF I1=1 THEN 450
500	IF Y<1 THEN 450
518	IF Y>6 THEN 450
520	IF Y=6 THEN 540
530	ON Y GOTO 810,600,670,750,780
540	T=INT(10*RND(0))
550	IF T<>1 THEN 1260
560	PRINT TAB(8);"HELP HAS FOUND YOU IN A STATE OF UNCONSCIOUSNESS."
570	S=3
580	Z=4
590 	GOTO 300
600	F=F+1
610	IF F=8 THEN 1250
620	GOSUB 860
630	X1=INT(10*RND(0))
640	C=C+X1
650 	PRINT TAB(8);"YOU CAMEL LIKES THIS PACE."
660	GOTO 300
670	F=F+3
680	IF F>7 THEN 1250
690	GOSUB 860
700	X1=2*INT(10*RND(0))
710	C=C+X1
720	PRINT TAB(8);"YOUR CAMEL IS BURNING ACROSS THE DESERT SANDS."
730	PRINT
740	GOTO 300
750	PRINT TAB(8);"YOUR CAMEL THANKS YOU!"
760	F=0
770	GOTO 310
780	PRINT TAB(8);"YOUR CAMEL HAS";7-F;"GOOD DAYS LEFT."
790	PRINT TAB(8);"YOU HAVE";S;"DRINKS LEFT IN YOUR CANTEEN."
800	PRINT TAB(8);"YOU CAN GO";Z;"COMMANDS WITHOUT DRINKING."
810	S=S-1
820	IF S<0 THEN 1260
830	PRINT TAB(8);"BETTER WATCH FOR AN OASES  !"
840	Z=4
850	GOTO 450
860	A=INT(100*RND(0))
870	IF A>5 THEN 1180
880	PRINT TAB(8);"WILD BERBERS HIDDEN IN THE SAND HAVE CAPTURED YOU."
890	PRINT TAB(8);"LUCKILY THE LOCAL SHEIK HAS AGREED TO THEIR RANSOM-"
900	PRINT TAB(8);"DEMANDS.......BUT.......WATCH FOR THE PYGMIES !!!"
910	PRINT
920	PRINT TAB(8);"YOU HAVE A NEW CHOICE OF SUB-COMMANDS:"
930	PRINT
940	PRINT TAB(21);"#7 ATTEMPT AN ESCAPE"
950	PRINT TAB(21);"#8 WAIT FOR PAYMENT"
960	PRINT
970	PRINT TAB(8);"YOUR SUB-COMMAND ";
980	INPUT X$(1)
990	X=VAL(X$(1))
1000	IF I1=1 THEN 970
1010	IF X=8 THEN 1110
1020	IF X=7 THEN 1040
1030	GOTO 970
1040	X1=INT(10*RND(0))
1050	IF X1<5 THEN 1040
1060	PRINT TAB(8);"CONGRADULATIONS, YOU SUCCESSFULLY ESCAPED !!!!"
1070	Q=0
1080	GOTO 300
1090	PRINT TAB(8);"YOU WERE MORTALLY WOUNDED BY A PIG STABBER WHILE ESCAPING."
1100	GOTO 1530
1110	X1=INT(100*RND(0))
1120	IF X1>24 THEN 1160
1130	PRINT TAB(8);"YOUR RANSOM HAS BEEN PAID AND YOU ARE FREE TO GO."
1140	Q=0
1150	GOTO 300
1160	PRINT TAB(8);"THE LOCAL SULTAN IS COLLECTING......JUST WAIT......."
1170	GOTO 300
1180	A=INT(10*RND(0))
1190	IF A>2 THEN 1360
1200	PRINT TAB(8);"YOU HAVE ARRIVED AT AN OASES-------YOUR FILLING"
1210	PRINT TAB(8);"YOUR CANTEEN AND YOUR CAMEL IS EATING FIGS"
1220	Z=4
1230	S=6
1240	RETURN
1250	PRINT TAB(8);"YOU DIRTY RAPSCALLION! YOU RAN YOUR POOR CAMEL TO DEATH !!"
1260	GOTO 1530
1270	PRINT TAB(8);"YOU WIN, A PARTY IS BEING GIVEN IN YOUR HONOR......."
1280	PRINT 
1290	PRINT TAB(8);"DO YOU WANT TO KNOW WHO IS COMING TO THE PARTY";
1300	INPUT A$
1310	IF LEFT$(A$,1)="Y" THEN 1450
1320	IF LEFT$(A$,1)="N" THEN 1470
1330	PRINT
1340	PRINT TAB(12);".......THE PYGMIES ARE PLANNING TO ATTEND......."
1350	GOTO 1680
1360	X1=INT(100*RND(0))
1370	IF X1>5 THEN 1470
1380	PRINT TAB(8);"YOU HAVE BEEN CAUGHT IN A SANDSTORM......GOOD LUCK!"
1390	X5=INT(10*RND(0))
1400	X6=INT(10*RND(0))
1410	IF X6<5 THEN 1440
1420	C=C+X5
1430	GOTO 1450
1440	C=C-X5
1450	PRINT TAB(8);"YOUR NEW POSITION IS";C;"MILES SO FAR!"
1460	RETURN
1470	X1=INT(100*RND(0))
1480	IF X1>5 THEN RETURN
1490	C1=C1+1
1500	PRINT TAB(8);"YOUR CAMEL HURT HIS HUMP."
1510	PRINT TAB(8);"LUCKILY THE PYGMIES WERE FOOTWEARY !!!"
1520	RETURN
1530	U=INT(10*RND(0))
1540	PRINT TAB(8);"YOU DIED IN THE DESERT"
1550	IF U>1 THEN 1580
1560	PRINT TAB(8);"THE NATIONAL CAMEL'S UNION IS NOT ATTENDING YOUR FUNERAL!!!"
1570	GOTO 1680
1580	IF U>3 THEN 1610
1590	PRINT TAB(8);"YOUR BODY WAS EATEN BY VULTURES AND IMPORTED CANNINBALS !!!"
1600	GOTO 1680
1610	IF U>5 THEN 1640
1620	PRINT TAB(8);"THE LOCAL SHEIK NOW USES YOUR SKULL FOR A CHANGE PURSE !!!"
1630	GOTO 1680
1640	IF U>7 THEN 1670
1650	PRINT TAB(8);"PEOPLE WITH LITTLE INTELLIGENCE SHOULD STAY OUT OF THE DESERT"
1660	GOTO 1680
1670	PRINT TAB(8);"TURKEYS SHOULD FLY, NOT RIDE CAMELS !!!!!!"
1680	PRINT
1690	PRINT
1700	PRINT TAB(8);"WANT A NEW CAMEL AND A NEW GAME ";
1710	INPUT D$
1720	PRINT
1730	IF LEFT(D$,1)="Y" THEN 280
1740	IF LEFT(D$,1)="N" THEN 1860
1750	GOTO 1530
1760	PRINT TAB(8);"YOU RAN OUT OF WATER......SORRY CHUM!!!"
1770	GOTO 1530
1860	CHAIN "GMENU"
	END
2000	Z=4
2010	S=6
2020	C=0
2030	C1=0
2040	Q=0
2050	F=0
2060	P=0
2070	RETURN