LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ ssygv_2stage()

subroutine ssygv_2stage ( integer itype,
character jobz,
character uplo,
integer n,
real, dimension( lda, * ) a,
integer lda,
real, dimension( ldb, * ) b,
integer ldb,
real, dimension( * ) w,
real, dimension( * ) work,
integer lwork,
integer info )

SSYGV_2STAGE

Download SSYGV_2STAGE + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> SSYGV_2STAGE computes all the eigenvalues, and optionally, the eigenvectors
!> of a real generalized symmetric-definite eigenproblem, of the form
!> A*x=(lambda)*B*x,  A*Bx=(lambda)*x,  or B*A*x=(lambda)*x.
!> Here A and B are assumed to be symmetric and B is also
!> positive definite.
!> This routine use the 2stage technique for the reduction to tridiagonal
!> which showed higher performance on recent architecture and for large
!> sizes N>2000.
!>
Parameters
[in]ITYPE
!>          ITYPE is INTEGER
!>          Specifies the problem type to be solved:
!>          = 1:  A*x = (lambda)*B*x
!>          = 2:  A*B*x = (lambda)*x
!>          = 3:  B*A*x = (lambda)*x
!>
[in]JOBZ
!>          JOBZ is CHARACTER*1
!>          = 'N':  Compute eigenvalues only;
!>          = 'V':  Compute eigenvalues and eigenvectors.
!>                  Not available in this release.
!>
[in]UPLO
!>          UPLO is CHARACTER*1
!>          = 'U':  Upper triangles of A and B are stored;
!>          = 'L':  Lower triangles of A and B are stored.
!>
[in]N
!>          N is INTEGER
!>          The order of the matrices A and B.  N >= 0.
!>
[in,out]A
!>          A is REAL array, dimension (LDA, N)
!>          On entry, the symmetric matrix A.  If UPLO = 'U', the
!>          leading N-by-N upper triangular part of A contains the
!>          upper triangular part of the matrix A.  If UPLO = 'L',
!>          the leading N-by-N lower triangular part of A contains
!>          the lower triangular part of the matrix A.
!>
!>          On exit, if JOBZ = 'V', then if INFO = 0, A contains the
!>          matrix Z of eigenvectors.  The eigenvectors are normalized
!>          as follows:
!>          if ITYPE = 1 or 2, Z**T*B*Z = I;
!>          if ITYPE = 3, Z**T*inv(B)*Z = I.
!>          If JOBZ = 'N', then on exit the upper triangle (if UPLO='U')
!>          or the lower triangle (if UPLO='L') of A, including the
!>          diagonal, is destroyed.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.  LDA >= max(1,N).
!>
[in,out]B
!>          B is REAL array, dimension (LDB, N)
!>          On entry, the symmetric positive definite matrix B.
!>          If UPLO = 'U', the leading N-by-N upper triangular part of B
!>          contains the upper triangular part of the matrix B.
!>          If UPLO = 'L', the leading N-by-N lower triangular part of B
!>          contains the lower triangular part of the matrix B.
!>
!>          On exit, if INFO <= N, the part of B containing the matrix is
!>          overwritten by the triangular factor U or L from the Cholesky
!>          factorization B = U**T*U or B = L*L**T.
!>
[in]LDB
!>          LDB is INTEGER
!>          The leading dimension of the array B.  LDB >= max(1,N).
!>
[out]W
!>          W is REAL array, dimension (N)
!>          If INFO = 0, the eigenvalues in ascending order.
!>
[out]WORK
!>          WORK is REAL array, dimension (MAX(1,LWORK))
!>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The length of the array WORK. LWORK >= 1, when N <= 1;
!>          otherwise
!>          If JOBZ = 'N' and N > 1, LWORK must be queried.
!>                                   LWORK = MAX(1, dimension) where
!>                                   dimension = max(stage1,stage2) + (KD+1)*N + 2*N
!>                                             = N*KD + N*max(KD+1,FACTOPTNB)
!>                                               + max(2*KD*KD, KD*NTHREADS)
!>                                               + (KD+1)*N + 2*N
!>                                   where KD is the blocking size of the reduction,
!>                                   FACTOPTNB is the blocking used by the QR or LQ
!>                                   algorithm, usually FACTOPTNB=128 is a good choice
!>                                   NTHREADS is the number of threads used when
!>                                   openMP compilation is enabled, otherwise =1.
!>          If JOBZ = 'V' and N > 1, LWORK must be queried. Not yet available
!>
!>          If LWORK = -1, then a workspace query is assumed; the routine
!>          only calculates the optimal size of the WORK array, returns
!>          this value as the first entry of the WORK array, and no error
!>          message related to LWORK is issued by XERBLA.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>          > 0:  SPOTRF or SSYEV returned an error code:
!>             <= N:  if INFO = i, SSYEV failed to converge;
!>                    i off-diagonal elements of an intermediate
!>                    tridiagonal form did not converge to zero;
!>             > N:   if INFO = N + i, for 1 <= i <= N, then the leading
!>                    principal minor of order i of B is not positive.
!>                    The factorization of B could not be completed and
!>                    no eigenvalues or eigenvectors were computed.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!>
!>  All details about the 2stage techniques are available in:
!>
!>  Azzam Haidar, Hatem Ltaief, and Jack Dongarra.
!>  Parallel reduction to condensed forms for symmetric eigenvalue problems
!>  using aggregated fine-grained and memory-aware kernels. In Proceedings
!>  of 2011 International Conference for High Performance Computing,
!>  Networking, Storage and Analysis (SC '11), New York, NY, USA,
!>  Article 8 , 11 pages.
!>  http://doi.acm.org/10.1145/2063384.2063394
!>
!>  A. Haidar, J. Kurzak, P. Luszczek, 2013.
!>  An improved parallel singular value algorithm and its implementation
!>  for multicore hardware, In Proceedings of 2013 International Conference
!>  for High Performance Computing, Networking, Storage and Analysis (SC '13).
!>  Denver, Colorado, USA, 2013.
!>  Article 90, 12 pages.
!>  http://doi.acm.org/10.1145/2503210.2503292
!>
!>  A. Haidar, R. Solca, S. Tomov, T. Schulthess and J. Dongarra.
!>  A novel hybrid CPU-GPU generalized eigensolver for electronic structure
!>  calculations based on fine-grained memory aware tasks.
!>  International Journal of High Performance Computing Applications.
!>  Volume 28 Issue 2, Pages 196-209, May 2014.
!>  http://hpc.sagepub.com/content/28/2/196
!>
!>

Definition at line 222 of file ssygv_2stage.f.

225*
226 IMPLICIT NONE
227*
228* -- LAPACK driver routine --
229* -- LAPACK is a software package provided by Univ. of Tennessee, --
230* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
231*
232* .. Scalar Arguments ..
233 CHARACTER JOBZ, UPLO
234 INTEGER INFO, ITYPE, LDA, LDB, LWORK, N
235* ..
236* .. Array Arguments ..
237 REAL A( LDA, * ), B( LDB, * ), W( * ), WORK( * )
238* ..
239*
240* =====================================================================
241*
242* .. Parameters ..
243 REAL ONE
244 parameter( one = 1.0e+0 )
245* ..
246* .. Local Scalars ..
247 LOGICAL LQUERY, UPPER, WANTZ
248 CHARACTER TRANS
249 INTEGER NEIG, LWMIN, LHTRD, LWTRD, KD, IB
250* ..
251* .. External Functions ..
252 LOGICAL LSAME
253 INTEGER ILAENV2STAGE
254 REAL SROUNDUP_LWORK
255 EXTERNAL lsame, ilaenv2stage, sroundup_lwork
256* ..
257* .. External Subroutines ..
258 EXTERNAL spotrf, ssygst, strmm, strsm,
259 $ xerbla,
260 $ ssyev_2stage
261* ..
262* .. Intrinsic Functions ..
263 INTRINSIC max
264* ..
265* .. Executable Statements ..
266*
267* Test the input parameters.
268*
269 wantz = lsame( jobz, 'V' )
270 upper = lsame( uplo, 'U' )
271 lquery = ( lwork.EQ.-1 )
272*
273 info = 0
274 IF( itype.LT.1 .OR. itype.GT.3 ) THEN
275 info = -1
276 ELSE IF( .NOT.( lsame( jobz, 'N' ) ) ) THEN
277 info = -2
278 ELSE IF( .NOT.( upper .OR. lsame( uplo, 'L' ) ) ) THEN
279 info = -3
280 ELSE IF( n.LT.0 ) THEN
281 info = -4
282 ELSE IF( lda.LT.max( 1, n ) ) THEN
283 info = -6
284 ELSE IF( ldb.LT.max( 1, n ) ) THEN
285 info = -8
286 END IF
287*
288 IF( info.EQ.0 ) THEN
289 kd = ilaenv2stage( 1, 'SSYTRD_2STAGE', jobz, n, -1, -1,
290 $ -1 )
291 ib = ilaenv2stage( 2, 'SSYTRD_2STAGE', jobz, n, kd, -1,
292 $ -1 )
293 lhtrd = ilaenv2stage( 3, 'SSYTRD_2STAGE', jobz, n, kd, ib,
294 $ -1 )
295 lwtrd = ilaenv2stage( 4, 'SSYTRD_2STAGE', jobz, n, kd, ib,
296 $ -1 )
297 lwmin = 2*n + lhtrd + lwtrd
298 work( 1 ) = real( lwmin )
299*
300 IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
301 info = -11
302 END IF
303 END IF
304*
305 IF( info.NE.0 ) THEN
306 CALL xerbla( 'SSYGV_2STAGE ', -info )
307 RETURN
308 ELSE IF( lquery ) THEN
309 RETURN
310 END IF
311*
312* Quick return if possible
313*
314 IF( n.EQ.0 )
315 $ RETURN
316*
317* Form a Cholesky factorization of B.
318*
319 CALL spotrf( uplo, n, b, ldb, info )
320 IF( info.NE.0 ) THEN
321 info = n + info
322 RETURN
323 END IF
324*
325* Transform problem to standard eigenvalue problem and solve.
326*
327 CALL ssygst( itype, uplo, n, a, lda, b, ldb, info )
328 CALL ssyev_2stage( jobz, uplo, n, a, lda, w, work, lwork,
329 $ info )
330*
331 IF( wantz ) THEN
332*
333* Backtransform eigenvectors to the original problem.
334*
335 neig = n
336 IF( info.GT.0 )
337 $ neig = info - 1
338 IF( itype.EQ.1 .OR. itype.EQ.2 ) THEN
339*
340* For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
341* backtransform eigenvectors: x = inv(L)**T*y or inv(U)*y
342*
343 IF( upper ) THEN
344 trans = 'N'
345 ELSE
346 trans = 'T'
347 END IF
348*
349 CALL strsm( 'Left', uplo, trans, 'Non-unit', n, neig,
350 $ one,
351 $ b, ldb, a, lda )
352*
353 ELSE IF( itype.EQ.3 ) THEN
354*
355* For B*A*x=(lambda)*x;
356* backtransform eigenvectors: x = L*y or U**T*y
357*
358 IF( upper ) THEN
359 trans = 'T'
360 ELSE
361 trans = 'N'
362 END IF
363*
364 CALL strmm( 'Left', uplo, trans, 'Non-unit', n, neig,
365 $ one,
366 $ b, ldb, a, lda )
367 END IF
368 END IF
369*
370 work( 1 ) = sroundup_lwork(lwmin)
371 RETURN
372*
373* End of SSYGV_2STAGE
374*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
ssyev_2stage
subroutine ssyev_2stage(jobz, uplo, n, a, lda, w, work, lwork, info)
SSYEV_2STAGE computes the eigenvalues and, optionally, the left and/or right eigenvectors for SY matr...
Definition ssyev_2stage.f:181
ssygst
subroutine ssygst(itype, uplo, n, a, lda, b, ldb, info)
SSYGST
Definition ssygst.f:125
ilaenv2stage
integer function ilaenv2stage(ispec, name, opts, n1, n2, n3, n4)
ILAENV2STAGE
Definition ilaenv2stage.f:148
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
spotrf
subroutine spotrf(uplo, n, a, lda, info)
SPOTRF
Definition spotrf.f:105
sroundup_lwork
real function sroundup_lwork(lwork)
SROUNDUP_LWORK
Definition sroundup_lwork.f:59
strmm
subroutine strmm(side, uplo, transa, diag, m, n, alpha, a, lda, b, ldb)
STRMM
Definition strmm.f:177
strsm
subroutine strsm(side, uplo, transa, diag, m, n, alpha, a, lda, b, ldb)
STRSM
Definition strsm.f:181
Here is the call graph for this function:
Here is the caller graph for this function: