LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ zhbevx_2stage()

subroutine zhbevx_2stage ( character jobz,
character range,
character uplo,
integer n,
integer kd,
complex*16, dimension( ldab, * ) ab,
integer ldab,
complex*16, dimension( ldq, * ) q,
integer ldq,
double precision vl,
double precision vu,
integer il,
integer iu,
double precision abstol,
integer m,
double precision, dimension( * ) w,
complex*16, dimension( ldz, * ) z,
integer ldz,
complex*16, dimension( * ) work,
integer lwork,
double precision, dimension( * ) rwork,
integer, dimension( * ) iwork,
integer, dimension( * ) ifail,
integer info )

ZHBEVX_2STAGE computes the eigenvalues and, optionally, the left and/or right eigenvectors for OTHER matrices

Download ZHBEVX_2STAGE + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> ZHBEVX_2STAGE computes selected eigenvalues and, optionally, eigenvectors
!> of a complex Hermitian band matrix A using the 2stage technique for
!> the reduction to tridiagonal.  Eigenvalues and eigenvectors
!> can be selected by specifying either a range of values or a range of
!> indices for the desired eigenvalues.
!>
Parameters
[in]JOBZ
!>          JOBZ is CHARACTER*1
!>          = 'N':  Compute eigenvalues only;
!>          = 'V':  Compute eigenvalues and eigenvectors.
!>                  Not available in this release.
!>
[in]RANGE
!>          RANGE is CHARACTER*1
!>          = 'A': all eigenvalues will be found;
!>          = 'V': all eigenvalues in the half-open interval (VL,VU]
!>                 will be found;
!>          = 'I': the IL-th through IU-th eigenvalues will be found.
!>
[in]UPLO
!>          UPLO is CHARACTER*1
!>          = 'U':  Upper triangle of A is stored;
!>          = 'L':  Lower triangle of A is stored.
!>
[in]N
!>          N is INTEGER
!>          The order of the matrix A.  N >= 0.
!>
[in]KD
!>          KD is INTEGER
!>          The number of superdiagonals of the matrix A if UPLO = 'U',
!>          or the number of subdiagonals if UPLO = 'L'.  KD >= 0.
!>
[in,out]AB
!>          AB is COMPLEX*16 array, dimension (LDAB, N)
!>          On entry, the upper or lower triangle of the Hermitian band
!>          matrix A, stored in the first KD+1 rows of the array.  The
!>          j-th column of A is stored in the j-th column of the array AB
!>          as follows:
!>          if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j;
!>          if UPLO = 'L', AB(1+i-j,j)    = A(i,j) for j<=i<=min(n,j+kd).
!>
!>          On exit, AB is overwritten by values generated during the
!>          reduction to tridiagonal form.
!>
[in]LDAB
!>          LDAB is INTEGER
!>          The leading dimension of the array AB.  LDAB >= KD + 1.
!>
[out]Q
!>          Q is COMPLEX*16 array, dimension (LDQ, N)
!>          If JOBZ = 'V', the N-by-N unitary matrix used in the
!>                          reduction to tridiagonal form.
!>          If JOBZ = 'N', the array Q is not referenced.
!>
[in]LDQ
!>          LDQ is INTEGER
!>          The leading dimension of the array Q.  If JOBZ = 'V', then
!>          LDQ >= max(1,N).
!>
[in]VL
!>          VL is DOUBLE PRECISION
!>          If RANGE='V', the lower bound of the interval to
!>          be searched for eigenvalues. VL < VU.
!>          Not referenced if RANGE = 'A' or 'I'.
!>
[in]VU
!>          VU is DOUBLE PRECISION
!>          If RANGE='V', the upper bound of the interval to
!>          be searched for eigenvalues. VL < VU.
!>          Not referenced if RANGE = 'A' or 'I'.
!>
[in]IL
!>          IL is INTEGER
!>          If RANGE='I', the index of the
!>          smallest eigenvalue to be returned.
!>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
!>          Not referenced if RANGE = 'A' or 'V'.
!>
[in]IU
!>          IU is INTEGER
!>          If RANGE='I', the index of the
!>          largest eigenvalue to be returned.
!>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
!>          Not referenced if RANGE = 'A' or 'V'.
!>
[in]ABSTOL
!>          ABSTOL is DOUBLE PRECISION
!>          The absolute error tolerance for the eigenvalues.
!>          An approximate eigenvalue is accepted as converged
!>          when it is determined to lie in an interval [a,b]
!>          of width less than or equal to
!>
!>                  ABSTOL + EPS *   max( |a|,|b| ) ,
!>
!>          where EPS is the machine precision.  If ABSTOL is less than
!>          or equal to zero, then  EPS*|T|  will be used in its place,
!>          where |T| is the 1-norm of the tridiagonal matrix obtained
!>          by reducing AB to tridiagonal form.
!>
!>          Eigenvalues will be computed most accurately when ABSTOL is
!>          set to twice the underflow threshold 2*DLAMCH('S'), not zero.
!>          If this routine returns with INFO>0, indicating that some
!>          eigenvectors did not converge, try setting ABSTOL to
!>          2*DLAMCH('S').
!>
!>          See  by Demmel and
!>          Kahan, LAPACK Working Note #3.
!>
[out]M
!>          M is INTEGER
!>          The total number of eigenvalues found.  0 <= M <= N.
!>          If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
!>
[out]W
!>          W is DOUBLE PRECISION array, dimension (N)
!>          The first M elements contain the selected eigenvalues in
!>          ascending order.
!>
[out]Z
!>          Z is COMPLEX*16 array, dimension (LDZ, max(1,M))
!>          If JOBZ = 'V', then if INFO = 0, the first M columns of Z
!>          contain the orthonormal eigenvectors of the matrix A
!>          corresponding to the selected eigenvalues, with the i-th
!>          column of Z holding the eigenvector associated with W(i).
!>          If an eigenvector fails to converge, then that column of Z
!>          contains the latest approximation to the eigenvector, and the
!>          index of the eigenvector is returned in IFAIL.
!>          If JOBZ = 'N', then Z is not referenced.
!>          Note: the user must ensure that at least max(1,M) columns are
!>          supplied in the array Z; if RANGE = 'V', the exact value of M
!>          is not known in advance and an upper bound must be used.
!>
[in]LDZ
!>          LDZ is INTEGER
!>          The leading dimension of the array Z.  LDZ >= 1, and if
!>          JOBZ = 'V', LDZ >= max(1,N).
!>
[out]WORK
!>          WORK is COMPLEX*16 array, dimension (LWORK)
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The length of the array WORK. LWORK >= 1, when N <= 1;
!>          otherwise
!>          If JOBZ = 'N' and N > 1, LWORK must be queried.
!>                                   LWORK = MAX(1, dimension) where
!>                                   dimension = (2KD+1)*N + KD*NTHREADS
!>                                   where KD is the size of the band.
!>                                   NTHREADS is the number of threads used when
!>                                   openMP compilation is enabled, otherwise =1.
!>          If JOBZ = 'V' and N > 1, LWORK must be queried. Not yet available.
!>
!>          If LWORK = -1, then a workspace query is assumed; the routine
!>          only calculates the optimal sizes of the WORK, RWORK and
!>          IWORK arrays, returns these values as the first entries of
!>          the WORK, RWORK and IWORK arrays, and no error message
!>          related to LWORK or LRWORK or LIWORK is issued by XERBLA.
!>
[out]RWORK
!>          RWORK is DOUBLE PRECISION array, dimension (7*N)
!>
[out]IWORK
!>          IWORK is INTEGER array, dimension (5*N)
!>
[out]IFAIL
!>          IFAIL is INTEGER array, dimension (N)
!>          If JOBZ = 'V', then if INFO = 0, the first M elements of
!>          IFAIL are zero.  If INFO > 0, then IFAIL contains the
!>          indices of the eigenvectors that failed to converge.
!>          If JOBZ = 'N', then IFAIL is not referenced.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>          > 0:  if INFO = i, then i eigenvectors failed to converge.
!>                Their indices are stored in array IFAIL.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!>
!>  All details about the 2stage techniques are available in:
!>
!>  Azzam Haidar, Hatem Ltaief, and Jack Dongarra.
!>  Parallel reduction to condensed forms for symmetric eigenvalue problems
!>  using aggregated fine-grained and memory-aware kernels. In Proceedings
!>  of 2011 International Conference for High Performance Computing,
!>  Networking, Storage and Analysis (SC '11), New York, NY, USA,
!>  Article 8 , 11 pages.
!>  http://doi.acm.org/10.1145/2063384.2063394
!>
!>  A. Haidar, J. Kurzak, P. Luszczek, 2013.
!>  An improved parallel singular value algorithm and its implementation
!>  for multicore hardware, In Proceedings of 2013 International Conference
!>  for High Performance Computing, Networking, Storage and Analysis (SC '13).
!>  Denver, Colorado, USA, 2013.
!>  Article 90, 12 pages.
!>  http://doi.acm.org/10.1145/2503210.2503292
!>
!>  A. Haidar, R. Solca, S. Tomov, T. Schulthess and J. Dongarra.
!>  A novel hybrid CPU-GPU generalized eigensolver for electronic structure
!>  calculations based on fine-grained memory aware tasks.
!>  International Journal of High Performance Computing Applications.
!>  Volume 28 Issue 2, Pages 196-209, May 2014.
!>  http://hpc.sagepub.com/content/28/2/196
!>
!>

Definition at line 321 of file zhbevx_2stage.f.

325*
326 IMPLICIT NONE
327*
328* -- LAPACK driver routine --
329* -- LAPACK is a software package provided by Univ. of Tennessee, --
330* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
331*
332* .. Scalar Arguments ..
333 CHARACTER JOBZ, RANGE, UPLO
334 INTEGER IL, INFO, IU, KD, LDAB, LDQ, LDZ, M, N, LWORK
335 DOUBLE PRECISION ABSTOL, VL, VU
336* ..
337* .. Array Arguments ..
338 INTEGER IFAIL( * ), IWORK( * )
339 DOUBLE PRECISION RWORK( * ), W( * )
340 COMPLEX*16 AB( LDAB, * ), Q( LDQ, * ), WORK( * ),
341 $ Z( LDZ, * )
342* ..
343*
344* =====================================================================
345*
346* .. Parameters ..
347 DOUBLE PRECISION ZERO, ONE
348 parameter( zero = 0.0d0, one = 1.0d0 )
349 COMPLEX*16 CZERO, CONE
350 parameter( czero = ( 0.0d0, 0.0d0 ),
351 $ cone = ( 1.0d0, 0.0d0 ) )
352* ..
353* .. Local Scalars ..
354 LOGICAL ALLEIG, INDEIG, LOWER, TEST, VALEIG, WANTZ,
355 $ LQUERY
356 CHARACTER ORDER
357 INTEGER I, IINFO, IMAX, INDD, INDE, INDEE, INDIBL,
358 $ INDISP, INDIWK, INDRWK, INDWRK, ISCALE, ITMP1,
359 $ LLWORK, LWMIN, LHTRD, LWTRD, IB, INDHOUS,
360 $ J, JJ, NSPLIT
361 DOUBLE PRECISION ABSTLL, ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN,
362 $ SIGMA, SMLNUM, TMP1, VLL, VUU
363 COMPLEX*16 CTMP1
364* ..
365* .. External Functions ..
366 LOGICAL LSAME
367 INTEGER ILAENV2STAGE
368 DOUBLE PRECISION DLAMCH, ZLANHB
369 EXTERNAL lsame, dlamch, zlanhb, ilaenv2stage
370* ..
371* .. External Subroutines ..
372 EXTERNAL dcopy, dscal, dstebz, dsterf, xerbla,
373 $ zcopy,
374 $ zgemv, zlacpy, zlascl, zstein, zsteqr,
375 $ zswap, zhetrd_hb2st
376* ..
377* .. Intrinsic Functions ..
378 INTRINSIC dble, max, min, sqrt
379* ..
380* .. Executable Statements ..
381*
382* Test the input parameters.
383*
384 wantz = lsame( jobz, 'V' )
385 alleig = lsame( range, 'A' )
386 valeig = lsame( range, 'V' )
387 indeig = lsame( range, 'I' )
388 lower = lsame( uplo, 'L' )
389 lquery = ( lwork.EQ.-1 )
390*
391 info = 0
392 IF( .NOT.( lsame( jobz, 'N' ) ) ) THEN
393 info = -1
394 ELSE IF( .NOT.( alleig .OR. valeig .OR. indeig ) ) THEN
395 info = -2
396 ELSE IF( .NOT.( lower .OR. lsame( uplo, 'U' ) ) ) THEN
397 info = -3
398 ELSE IF( n.LT.0 ) THEN
399 info = -4
400 ELSE IF( kd.LT.0 ) THEN
401 info = -5
402 ELSE IF( ldab.LT.kd+1 ) THEN
403 info = -7
404 ELSE IF( wantz .AND. ldq.LT.max( 1, n ) ) THEN
405 info = -9
406 ELSE
407 IF( valeig ) THEN
408 IF( n.GT.0 .AND. vu.LE.vl )
409 $ info = -11
410 ELSE IF( indeig ) THEN
411 IF( il.LT.1 .OR. il.GT.max( 1, n ) ) THEN
412 info = -12
413 ELSE IF( iu.LT.min( n, il ) .OR. iu.GT.n ) THEN
414 info = -13
415 END IF
416 END IF
417 END IF
418 IF( info.EQ.0 ) THEN
419 IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) )
420 $ info = -18
421 END IF
422*
423 IF( info.EQ.0 ) THEN
424 IF( n.LE.1 ) THEN
425 lwmin = 1
426 work( 1 ) = lwmin
427 ELSE
428 ib = ilaenv2stage( 2, 'ZHETRD_HB2ST', jobz,
429 $ n, kd, -1, -1 )
430 lhtrd = ilaenv2stage( 3, 'ZHETRD_HB2ST', jobz,
431 $ n, kd, ib, -1 )
432 lwtrd = ilaenv2stage( 4, 'ZHETRD_HB2ST', jobz,
433 $ n, kd, ib, -1 )
434 lwmin = lhtrd + lwtrd
435 work( 1 ) = lwmin
436 ENDIF
437*
438 IF( lwork.LT.lwmin .AND. .NOT.lquery )
439 $ info = -20
440 END IF
441*
442 IF( info.NE.0 ) THEN
443 CALL xerbla( 'ZHBEVX_2STAGE', -info )
444 RETURN
445 ELSE IF( lquery ) THEN
446 RETURN
447 END IF
448*
449* Quick return if possible
450*
451 m = 0
452 IF( n.EQ.0 )
453 $ RETURN
454*
455 IF( n.EQ.1 ) THEN
456 m = 1
457 IF( lower ) THEN
458 ctmp1 = ab( 1, 1 )
459 ELSE
460 ctmp1 = ab( kd+1, 1 )
461 END IF
462 tmp1 = dble( ctmp1 )
463 IF( valeig ) THEN
464 IF( .NOT.( vl.LT.tmp1 .AND. vu.GE.tmp1 ) )
465 $ m = 0
466 END IF
467 IF( m.EQ.1 ) THEN
468 w( 1 ) = dble( ctmp1 )
469 IF( wantz )
470 $ z( 1, 1 ) = cone
471 END IF
472 RETURN
473 END IF
474*
475* Get machine constants.
476*
477 safmin = dlamch( 'Safe minimum' )
478 eps = dlamch( 'Precision' )
479 smlnum = safmin / eps
480 bignum = one / smlnum
481 rmin = sqrt( smlnum )
482 rmax = min( sqrt( bignum ), one / sqrt( sqrt( safmin ) ) )
483*
484* Scale matrix to allowable range, if necessary.
485*
486 iscale = 0
487 abstll = abstol
488 IF( valeig ) THEN
489 vll = vl
490 vuu = vu
491 ELSE
492 vll = zero
493 vuu = zero
494 END IF
495 anrm = zlanhb( 'M', uplo, n, kd, ab, ldab, rwork )
496 IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
497 iscale = 1
498 sigma = rmin / anrm
499 ELSE IF( anrm.GT.rmax ) THEN
500 iscale = 1
501 sigma = rmax / anrm
502 END IF
503 IF( iscale.EQ.1 ) THEN
504 IF( lower ) THEN
505 CALL zlascl( 'B', kd, kd, one, sigma, n, n, ab, ldab,
506 $ info )
507 ELSE
508 CALL zlascl( 'Q', kd, kd, one, sigma, n, n, ab, ldab,
509 $ info )
510 END IF
511 IF( abstol.GT.0 )
512 $ abstll = abstol*sigma
513 IF( valeig ) THEN
514 vll = vl*sigma
515 vuu = vu*sigma
516 END IF
517 END IF
518*
519* Call ZHBTRD_HB2ST to reduce Hermitian band matrix to tridiagonal form.
520*
521 indd = 1
522 inde = indd + n
523 indrwk = inde + n
524*
525 indhous = 1
526 indwrk = indhous + lhtrd
527 llwork = lwork - indwrk + 1
528*
529 CALL zhetrd_hb2st( 'N', jobz, uplo, n, kd, ab, ldab,
530 $ rwork( indd ), rwork( inde ), work( indhous ),
531 $ lhtrd, work( indwrk ), llwork, iinfo )
532*
533* If all eigenvalues are desired and ABSTOL is less than or equal
534* to zero, then call DSTERF or ZSTEQR. If this fails for some
535* eigenvalue, then try DSTEBZ.
536*
537 test = .false.
538 IF (indeig) THEN
539 IF (il.EQ.1 .AND. iu.EQ.n) THEN
540 test = .true.
541 END IF
542 END IF
543 IF ((alleig .OR. test) .AND. (abstol.LE.zero)) THEN
544 CALL dcopy( n, rwork( indd ), 1, w, 1 )
545 indee = indrwk + 2*n
546 IF( .NOT.wantz ) THEN
547 CALL dcopy( n-1, rwork( inde ), 1, rwork( indee ), 1 )
548 CALL dsterf( n, w, rwork( indee ), info )
549 ELSE
550 CALL zlacpy( 'A', n, n, q, ldq, z, ldz )
551 CALL dcopy( n-1, rwork( inde ), 1, rwork( indee ), 1 )
552 CALL zsteqr( jobz, n, w, rwork( indee ), z, ldz,
553 $ rwork( indrwk ), info )
554 IF( info.EQ.0 ) THEN
555 DO 10 i = 1, n
556 ifail( i ) = 0
557 10 CONTINUE
558 END IF
559 END IF
560 IF( info.EQ.0 ) THEN
561 m = n
562 GO TO 30
563 END IF
564 info = 0
565 END IF
566*
567* Otherwise, call DSTEBZ and, if eigenvectors are desired, ZSTEIN.
568*
569 IF( wantz ) THEN
570 order = 'B'
571 ELSE
572 order = 'E'
573 END IF
574 indibl = 1
575 indisp = indibl + n
576 indiwk = indisp + n
577 CALL dstebz( range, order, n, vll, vuu, il, iu, abstll,
578 $ rwork( indd ), rwork( inde ), m, nsplit, w,
579 $ iwork( indibl ), iwork( indisp ), rwork( indrwk ),
580 $ iwork( indiwk ), info )
581*
582 IF( wantz ) THEN
583 CALL zstein( n, rwork( indd ), rwork( inde ), m, w,
584 $ iwork( indibl ), iwork( indisp ), z, ldz,
585 $ rwork( indrwk ), iwork( indiwk ), ifail, info )
586*
587* Apply unitary matrix used in reduction to tridiagonal
588* form to eigenvectors returned by ZSTEIN.
589*
590 DO 20 j = 1, m
591 CALL zcopy( n, z( 1, j ), 1, work( 1 ), 1 )
592 CALL zgemv( 'N', n, n, cone, q, ldq, work, 1, czero,
593 $ z( 1, j ), 1 )
594 20 CONTINUE
595 END IF
596*
597* If matrix was scaled, then rescale eigenvalues appropriately.
598*
599 30 CONTINUE
600 IF( iscale.EQ.1 ) THEN
601 IF( info.EQ.0 ) THEN
602 imax = m
603 ELSE
604 imax = info - 1
605 END IF
606 CALL dscal( imax, one / sigma, w, 1 )
607 END IF
608*
609* If eigenvalues are not in order, then sort them, along with
610* eigenvectors.
611*
612 IF( wantz ) THEN
613 DO 50 j = 1, m - 1
614 i = 0
615 tmp1 = w( j )
616 DO 40 jj = j + 1, m
617 IF( w( jj ).LT.tmp1 ) THEN
618 i = jj
619 tmp1 = w( jj )
620 END IF
621 40 CONTINUE
622*
623 IF( i.NE.0 ) THEN
624 itmp1 = iwork( indibl+i-1 )
625 w( i ) = w( j )
626 iwork( indibl+i-1 ) = iwork( indibl+j-1 )
627 w( j ) = tmp1
628 iwork( indibl+j-1 ) = itmp1
629 CALL zswap( n, z( 1, i ), 1, z( 1, j ), 1 )
630 IF( info.NE.0 ) THEN
631 itmp1 = ifail( i )
632 ifail( i ) = ifail( j )
633 ifail( j ) = itmp1
634 END IF
635 END IF
636 50 CONTINUE
637 END IF
638*
639* Set WORK(1) to optimal workspace size.
640*
641 work( 1 ) = lwmin
642*
643 RETURN
644*
645* End of ZHBEVX_2STAGE
646*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
zcopy
subroutine zcopy(n, zx, incx, zy, incy)
ZCOPY
Definition zcopy.f:81
dcopy
subroutine dcopy(n, dx, incx, dy, incy)
DCOPY
Definition dcopy.f:82
zgemv
subroutine zgemv(trans, m, n, alpha, a, lda, x, incx, beta, y, incy)
ZGEMV
Definition zgemv.f:160
zhetrd_hb2st
subroutine zhetrd_hb2st(stage1, vect, uplo, n, kd, ab, ldab, d, e, hous, lhous, work, lwork, info)
ZHETRD_HB2ST reduces a complex Hermitian band matrix A to real symmetric tridiagonal form T
Definition zhetrd_hb2st.F:233
ilaenv2stage
integer function ilaenv2stage(ispec, name, opts, n1, n2, n3, n4)
ILAENV2STAGE
Definition ilaenv2stage.f:148
zlacpy
subroutine zlacpy(uplo, m, n, a, lda, b, ldb)
ZLACPY copies all or part of one two-dimensional array to another.
Definition zlacpy.f:101
dlamch
double precision function dlamch(cmach)
DLAMCH
Definition dlamch.f:69
zlanhb
double precision function zlanhb(norm, uplo, n, k, ab, ldab, work)
ZLANHB returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition zlanhb.f:130
zlascl
subroutine zlascl(type, kl, ku, cfrom, cto, m, n, a, lda, info)
ZLASCL multiplies a general rectangular matrix by a real scalar defined as cto/cfrom.
Definition zlascl.f:142
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
dscal
subroutine dscal(n, da, dx, incx)
DSCAL
Definition dscal.f:79
dstebz
subroutine dstebz(range, order, n, vl, vu, il, iu, abstol, d, e, m, nsplit, w, iblock, isplit, work, iwork, info)
DSTEBZ
Definition dstebz.f:272
zstein
subroutine zstein(n, d, e, m, w, iblock, isplit, z, ldz, work, iwork, ifail, info)
ZSTEIN
Definition zstein.f:180
zsteqr
subroutine zsteqr(compz, n, d, e, z, ldz, work, info)
ZSTEQR
Definition zsteqr.f:130
dsterf
subroutine dsterf(n, d, e, info)
DSTERF
Definition dsterf.f:84
zswap
subroutine zswap(n, zx, incx, zy, incy)
ZSWAP
Definition zswap.f:81
Here is the call graph for this function:
Here is the caller graph for this function: