LAPACK 3.12.1
LAPACK: Linear Algebra PACKage
Loading...
Searching...
No Matches

◆ zheevx_2stage()

subroutine zheevx_2stage ( character jobz,
character range,
character uplo,
integer n,
complex*16, dimension( lda, * ) a,
integer lda,
double precision vl,
double precision vu,
integer il,
integer iu,
double precision abstol,
integer m,
double precision, dimension( * ) w,
complex*16, dimension( ldz, * ) z,
integer ldz,
complex*16, dimension( * ) work,
integer lwork,
double precision, dimension( * ) rwork,
integer, dimension( * ) iwork,
integer, dimension( * ) ifail,
integer info )

ZHEEVX_2STAGE computes the eigenvalues and, optionally, the left and/or right eigenvectors for HE matrices

Download ZHEEVX_2STAGE + dependencies [TGZ] [ZIP] [TXT]

Purpose:
!>
!> ZHEEVX_2STAGE computes selected eigenvalues and, optionally, eigenvectors
!> of a complex Hermitian matrix A using the 2stage technique for
!> the reduction to tridiagonal.  Eigenvalues and eigenvectors can
!> be selected by specifying either a range of values or a range of
!> indices for the desired eigenvalues.
!>
Parameters
[in]JOBZ
!>          JOBZ is CHARACTER*1
!>          = 'N':  Compute eigenvalues only;
!>          = 'V':  Compute eigenvalues and eigenvectors.
!>                  Not available in this release.
!>
[in]RANGE
!>          RANGE is CHARACTER*1
!>          = 'A': all eigenvalues will be found.
!>          = 'V': all eigenvalues in the half-open interval (VL,VU]
!>                 will be found.
!>          = 'I': the IL-th through IU-th eigenvalues will be found.
!>
[in]UPLO
!>          UPLO is CHARACTER*1
!>          = 'U':  Upper triangle of A is stored;
!>          = 'L':  Lower triangle of A is stored.
!>
[in]N
!>          N is INTEGER
!>          The order of the matrix A.  N >= 0.
!>
[in,out]A
!>          A is COMPLEX*16 array, dimension (LDA, N)
!>          On entry, the Hermitian matrix A.  If UPLO = 'U', the
!>          leading N-by-N upper triangular part of A contains the
!>          upper triangular part of the matrix A.  If UPLO = 'L',
!>          the leading N-by-N lower triangular part of A contains
!>          the lower triangular part of the matrix A.
!>          On exit, the lower triangle (if UPLO='L') or the upper
!>          triangle (if UPLO='U') of A, including the diagonal, is
!>          destroyed.
!>
[in]LDA
!>          LDA is INTEGER
!>          The leading dimension of the array A.  LDA >= max(1,N).
!>
[in]VL
!>          VL is DOUBLE PRECISION
!>          If RANGE='V', the lower bound of the interval to
!>          be searched for eigenvalues. VL < VU.
!>          Not referenced if RANGE = 'A' or 'I'.
!>
[in]VU
!>          VU is DOUBLE PRECISION
!>          If RANGE='V', the upper bound of the interval to
!>          be searched for eigenvalues. VL < VU.
!>          Not referenced if RANGE = 'A' or 'I'.
!>
[in]IL
!>          IL is INTEGER
!>          If RANGE='I', the index of the
!>          smallest eigenvalue to be returned.
!>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
!>          Not referenced if RANGE = 'A' or 'V'.
!>
[in]IU
!>          IU is INTEGER
!>          If RANGE='I', the index of the
!>          largest eigenvalue to be returned.
!>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
!>          Not referenced if RANGE = 'A' or 'V'.
!>
[in]ABSTOL
!>          ABSTOL is DOUBLE PRECISION
!>          The absolute error tolerance for the eigenvalues.
!>          An approximate eigenvalue is accepted as converged
!>          when it is determined to lie in an interval [a,b]
!>          of width less than or equal to
!>
!>                  ABSTOL + EPS *   max( |a|,|b| ) ,
!>
!>          where EPS is the machine precision.  If ABSTOL is less than
!>          or equal to zero, then  EPS*|T|  will be used in its place,
!>          where |T| is the 1-norm of the tridiagonal matrix obtained
!>          by reducing A to tridiagonal form.
!>
!>          Eigenvalues will be computed most accurately when ABSTOL is
!>          set to twice the underflow threshold 2*DLAMCH('S'), not zero.
!>          If this routine returns with INFO>0, indicating that some
!>          eigenvectors did not converge, try setting ABSTOL to
!>          2*DLAMCH('S').
!>
!>          See  by Demmel and
!>          Kahan, LAPACK Working Note #3.
!>
[out]M
!>          M is INTEGER
!>          The total number of eigenvalues found.  0 <= M <= N.
!>          If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
!>
[out]W
!>          W is DOUBLE PRECISION array, dimension (N)
!>          On normal exit, the first M elements contain the selected
!>          eigenvalues in ascending order.
!>
[out]Z
!>          Z is COMPLEX*16 array, dimension (LDZ, max(1,M))
!>          If JOBZ = 'V', then if INFO = 0, the first M columns of Z
!>          contain the orthonormal eigenvectors of the matrix A
!>          corresponding to the selected eigenvalues, with the i-th
!>          column of Z holding the eigenvector associated with W(i).
!>          If an eigenvector fails to converge, then that column of Z
!>          contains the latest approximation to the eigenvector, and the
!>          index of the eigenvector is returned in IFAIL.
!>          If JOBZ = 'N', then Z is not referenced.
!>          Note: the user must ensure that at least max(1,M) columns are
!>          supplied in the array Z; if RANGE = 'V', the exact value of M
!>          is not known in advance and an upper bound must be used.
!>
[in]LDZ
!>          LDZ is INTEGER
!>          The leading dimension of the array Z.  LDZ >= 1, and if
!>          JOBZ = 'V', LDZ >= max(1,N).
!>
[out]WORK
!>          WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
!>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
!>
[in]LWORK
!>          LWORK is INTEGER
!>          The length of the array WORK. LWORK >= 1, when N <= 1;
!>          otherwise
!>          If JOBZ = 'N' and N > 1, LWORK must be queried.
!>                                   LWORK = MAX(1, 8*N, dimension) where
!>                                   dimension = max(stage1,stage2) + (KD+1)*N + N
!>                                             = N*KD + N*max(KD+1,FACTOPTNB)
!>                                               + max(2*KD*KD, KD*NTHREADS)
!>                                               + (KD+1)*N + N
!>                                   where KD is the blocking size of the reduction,
!>                                   FACTOPTNB is the blocking used by the QR or LQ
!>                                   algorithm, usually FACTOPTNB=128 is a good choice
!>                                   NTHREADS is the number of threads used when
!>                                   openMP compilation is enabled, otherwise =1.
!>          If JOBZ = 'V' and N > 1, LWORK must be queried. Not yet available
!>
!>          If LWORK = -1, then a workspace query is assumed; the routine
!>          only calculates the optimal size of the WORK array, returns
!>          this value as the first entry of the WORK array, and no error
!>          message related to LWORK is issued by XERBLA.
!>
[out]RWORK
!>          RWORK is DOUBLE PRECISION array, dimension (7*N)
!>
[out]IWORK
!>          IWORK is INTEGER array, dimension (5*N)
!>
[out]IFAIL
!>          IFAIL is INTEGER array, dimension (N)
!>          If JOBZ = 'V', then if INFO = 0, the first M elements of
!>          IFAIL are zero.  If INFO > 0, then IFAIL contains the
!>          indices of the eigenvectors that failed to converge.
!>          If JOBZ = 'N', then IFAIL is not referenced.
!>
[out]INFO
!>          INFO is INTEGER
!>          = 0:  successful exit
!>          < 0:  if INFO = -i, the i-th argument had an illegal value
!>          > 0:  if INFO = i, then i eigenvectors failed to converge.
!>                Their indices are stored in array IFAIL.
!>
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Further Details:
!>
!>  All details about the 2stage techniques are available in:
!>
!>  Azzam Haidar, Hatem Ltaief, and Jack Dongarra.
!>  Parallel reduction to condensed forms for symmetric eigenvalue problems
!>  using aggregated fine-grained and memory-aware kernels. In Proceedings
!>  of 2011 International Conference for High Performance Computing,
!>  Networking, Storage and Analysis (SC '11), New York, NY, USA,
!>  Article 8 , 11 pages.
!>  http://doi.acm.org/10.1145/2063384.2063394
!>
!>  A. Haidar, J. Kurzak, P. Luszczek, 2013.
!>  An improved parallel singular value algorithm and its implementation
!>  for multicore hardware, In Proceedings of 2013 International Conference
!>  for High Performance Computing, Networking, Storage and Analysis (SC '13).
!>  Denver, Colorado, USA, 2013.
!>  Article 90, 12 pages.
!>  http://doi.acm.org/10.1145/2503210.2503292
!>
!>  A. Haidar, R. Solca, S. Tomov, T. Schulthess and J. Dongarra.
!>  A novel hybrid CPU-GPU generalized eigensolver for electronic structure
!>  calculations based on fine-grained memory aware tasks.
!>  International Journal of High Performance Computing Applications.
!>  Volume 28 Issue 2, Pages 196-209, May 2014.
!>  http://hpc.sagepub.com/content/28/2/196
!>
!>

Definition at line 301 of file zheevx_2stage.f.

304*
305 IMPLICIT NONE
306*
307* -- LAPACK driver routine --
308* -- LAPACK is a software package provided by Univ. of Tennessee, --
309* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
310*
311* .. Scalar Arguments ..
312 CHARACTER JOBZ, RANGE, UPLO
313 INTEGER IL, INFO, IU, LDA, LDZ, LWORK, M, N
314 DOUBLE PRECISION ABSTOL, VL, VU
315* ..
316* .. Array Arguments ..
317 INTEGER IFAIL( * ), IWORK( * )
318 DOUBLE PRECISION RWORK( * ), W( * )
319 COMPLEX*16 A( LDA, * ), WORK( * ), Z( LDZ, * )
320* ..
321*
322* =====================================================================
323*
324* .. Parameters ..
325 DOUBLE PRECISION ZERO, ONE
326 parameter( zero = 0.0d+0, one = 1.0d+0 )
327 COMPLEX*16 CONE
328 parameter( cone = ( 1.0d+0, 0.0d+0 ) )
329* ..
330* .. Local Scalars ..
331 LOGICAL ALLEIG, INDEIG, LOWER, LQUERY, TEST, VALEIG,
332 $ WANTZ
333 CHARACTER ORDER
334 INTEGER I, IINFO, IMAX, INDD, INDE, INDEE, INDIBL,
335 $ INDISP, INDIWK, INDRWK, INDTAU, INDWRK, ISCALE,
336 $ ITMP1, J, JJ, LLWORK,
337 $ NSPLIT, LWMIN, LHTRD, LWTRD, KD, IB, INDHOUS
338 DOUBLE PRECISION ABSTLL, ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN,
339 $ SIGMA, SMLNUM, TMP1, VLL, VUU
340* ..
341* .. External Functions ..
342 LOGICAL LSAME
343 INTEGER ILAENV2STAGE
344 DOUBLE PRECISION DLAMCH, ZLANHE
345 EXTERNAL lsame, dlamch, zlanhe, ilaenv2stage
346* ..
347* .. External Subroutines ..
348 EXTERNAL dcopy, dscal, dstebz, dsterf, xerbla,
349 $ zdscal,
350 $ zlacpy, zstein, zsteqr, zswap, zungtr, zunmtr,
351 $ zhetrd_2stage
352* ..
353* .. Intrinsic Functions ..
354 INTRINSIC dble, max, min, sqrt
355* ..
356* .. Executable Statements ..
357*
358* Test the input parameters.
359*
360 lower = lsame( uplo, 'L' )
361 wantz = lsame( jobz, 'V' )
362 alleig = lsame( range, 'A' )
363 valeig = lsame( range, 'V' )
364 indeig = lsame( range, 'I' )
365 lquery = ( lwork.EQ.-1 )
366*
367 info = 0
368 IF( .NOT.( lsame( jobz, 'N' ) ) ) THEN
369 info = -1
370 ELSE IF( .NOT.( alleig .OR. valeig .OR. indeig ) ) THEN
371 info = -2
372 ELSE IF( .NOT.( lower .OR. lsame( uplo, 'U' ) ) ) THEN
373 info = -3
374 ELSE IF( n.LT.0 ) THEN
375 info = -4
376 ELSE IF( lda.LT.max( 1, n ) ) THEN
377 info = -6
378 ELSE
379 IF( valeig ) THEN
380 IF( n.GT.0 .AND. vu.LE.vl )
381 $ info = -8
382 ELSE IF( indeig ) THEN
383 IF( il.LT.1 .OR. il.GT.max( 1, n ) ) THEN
384 info = -9
385 ELSE IF( iu.LT.min( n, il ) .OR. iu.GT.n ) THEN
386 info = -10
387 END IF
388 END IF
389 END IF
390 IF( info.EQ.0 ) THEN
391 IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
392 info = -15
393 END IF
394 END IF
395*
396 IF( info.EQ.0 ) THEN
397 IF( n.LE.1 ) THEN
398 lwmin = 1
399 work( 1 ) = lwmin
400 ELSE
401 kd = ilaenv2stage( 1, 'ZHETRD_2STAGE', jobz,
402 $ n, -1, -1, -1 )
403 ib = ilaenv2stage( 2, 'ZHETRD_2STAGE', jobz,
404 $ n, kd, -1, -1 )
405 lhtrd = ilaenv2stage( 3, 'ZHETRD_2STAGE', jobz,
406 $ n, kd, ib, -1 )
407 lwtrd = ilaenv2stage( 4, 'ZHETRD_2STAGE', jobz,
408 $ n, kd, ib, -1 )
409 lwmin = n + lhtrd + lwtrd
410 work( 1 ) = lwmin
411 END IF
412*
413 IF( lwork.LT.lwmin .AND. .NOT.lquery )
414 $ info = -17
415 END IF
416*
417 IF( info.NE.0 ) THEN
418 CALL xerbla( 'ZHEEVX_2STAGE', -info )
419 RETURN
420 ELSE IF( lquery ) THEN
421 RETURN
422 END IF
423*
424* Quick return if possible
425*
426 m = 0
427 IF( n.EQ.0 ) THEN
428 RETURN
429 END IF
430*
431 IF( n.EQ.1 ) THEN
432 IF( alleig .OR. indeig ) THEN
433 m = 1
434 w( 1 ) = dble( a( 1, 1 ) )
435 ELSE IF( valeig ) THEN
436 IF( vl.LT.dble( a( 1, 1 ) ) .AND. vu.GE.dble( a( 1, 1 ) ) )
437 $ THEN
438 m = 1
439 w( 1 ) = dble( a( 1, 1 ) )
440 END IF
441 END IF
442 IF( wantz )
443 $ z( 1, 1 ) = cone
444 RETURN
445 END IF
446*
447* Get machine constants.
448*
449 safmin = dlamch( 'Safe minimum' )
450 eps = dlamch( 'Precision' )
451 smlnum = safmin / eps
452 bignum = one / smlnum
453 rmin = sqrt( smlnum )
454 rmax = min( sqrt( bignum ), one / sqrt( sqrt( safmin ) ) )
455*
456* Scale matrix to allowable range, if necessary.
457*
458 iscale = 0
459 abstll = abstol
460 IF( valeig ) THEN
461 vll = vl
462 vuu = vu
463 END IF
464 anrm = zlanhe( 'M', uplo, n, a, lda, rwork )
465 IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
466 iscale = 1
467 sigma = rmin / anrm
468 ELSE IF( anrm.GT.rmax ) THEN
469 iscale = 1
470 sigma = rmax / anrm
471 END IF
472 IF( iscale.EQ.1 ) THEN
473 IF( lower ) THEN
474 DO 10 j = 1, n
475 CALL zdscal( n-j+1, sigma, a( j, j ), 1 )
476 10 CONTINUE
477 ELSE
478 DO 20 j = 1, n
479 CALL zdscal( j, sigma, a( 1, j ), 1 )
480 20 CONTINUE
481 END IF
482 IF( abstol.GT.0 )
483 $ abstll = abstol*sigma
484 IF( valeig ) THEN
485 vll = vl*sigma
486 vuu = vu*sigma
487 END IF
488 END IF
489*
490* Call ZHETRD_2STAGE to reduce Hermitian matrix to tridiagonal form.
491*
492 indd = 1
493 inde = indd + n
494 indrwk = inde + n
495 indtau = 1
496 indhous = indtau + n
497 indwrk = indhous + lhtrd
498 llwork = lwork - indwrk + 1
499*
500 CALL zhetrd_2stage( jobz, uplo, n, a, lda, rwork( indd ),
501 $ rwork( inde ), work( indtau ),
502 $ work( indhous ), lhtrd, work( indwrk ),
503 $ llwork, iinfo )
504*
505* If all eigenvalues are desired and ABSTOL is less than or equal to
506* zero, then call DSTERF or ZUNGTR and ZSTEQR. If this fails for
507* some eigenvalue, then try DSTEBZ.
508*
509 test = .false.
510 IF( indeig ) THEN
511 IF( il.EQ.1 .AND. iu.EQ.n ) THEN
512 test = .true.
513 END IF
514 END IF
515 IF( ( alleig .OR. test ) .AND. ( abstol.LE.zero ) ) THEN
516 CALL dcopy( n, rwork( indd ), 1, w, 1 )
517 indee = indrwk + 2*n
518 IF( .NOT.wantz ) THEN
519 CALL dcopy( n-1, rwork( inde ), 1, rwork( indee ), 1 )
520 CALL dsterf( n, w, rwork( indee ), info )
521 ELSE
522 CALL zlacpy( 'A', n, n, a, lda, z, ldz )
523 CALL zungtr( uplo, n, z, ldz, work( indtau ),
524 $ work( indwrk ), llwork, iinfo )
525 CALL dcopy( n-1, rwork( inde ), 1, rwork( indee ), 1 )
526 CALL zsteqr( jobz, n, w, rwork( indee ), z, ldz,
527 $ rwork( indrwk ), info )
528 IF( info.EQ.0 ) THEN
529 DO 30 i = 1, n
530 ifail( i ) = 0
531 30 CONTINUE
532 END IF
533 END IF
534 IF( info.EQ.0 ) THEN
535 m = n
536 GO TO 40
537 END IF
538 info = 0
539 END IF
540*
541* Otherwise, call DSTEBZ and, if eigenvectors are desired, ZSTEIN.
542*
543 IF( wantz ) THEN
544 order = 'B'
545 ELSE
546 order = 'E'
547 END IF
548 indibl = 1
549 indisp = indibl + n
550 indiwk = indisp + n
551 CALL dstebz( range, order, n, vll, vuu, il, iu, abstll,
552 $ rwork( indd ), rwork( inde ), m, nsplit, w,
553 $ iwork( indibl ), iwork( indisp ), rwork( indrwk ),
554 $ iwork( indiwk ), info )
555*
556 IF( wantz ) THEN
557 CALL zstein( n, rwork( indd ), rwork( inde ), m, w,
558 $ iwork( indibl ), iwork( indisp ), z, ldz,
559 $ rwork( indrwk ), iwork( indiwk ), ifail, info )
560*
561* Apply unitary matrix used in reduction to tridiagonal
562* form to eigenvectors returned by ZSTEIN.
563*
564 CALL zunmtr( 'L', uplo, 'N', n, m, a, lda, work( indtau ),
565 $ z,
566 $ ldz, work( indwrk ), llwork, iinfo )
567 END IF
568*
569* If matrix was scaled, then rescale eigenvalues appropriately.
570*
571 40 CONTINUE
572 IF( iscale.EQ.1 ) THEN
573 IF( info.EQ.0 ) THEN
574 imax = m
575 ELSE
576 imax = info - 1
577 END IF
578 CALL dscal( imax, one / sigma, w, 1 )
579 END IF
580*
581* If eigenvalues are not in order, then sort them, along with
582* eigenvectors.
583*
584 IF( wantz ) THEN
585 DO 60 j = 1, m - 1
586 i = 0
587 tmp1 = w( j )
588 DO 50 jj = j + 1, m
589 IF( w( jj ).LT.tmp1 ) THEN
590 i = jj
591 tmp1 = w( jj )
592 END IF
593 50 CONTINUE
594*
595 IF( i.NE.0 ) THEN
596 itmp1 = iwork( indibl+i-1 )
597 w( i ) = w( j )
598 iwork( indibl+i-1 ) = iwork( indibl+j-1 )
599 w( j ) = tmp1
600 iwork( indibl+j-1 ) = itmp1
601 CALL zswap( n, z( 1, i ), 1, z( 1, j ), 1 )
602 IF( info.NE.0 ) THEN
603 itmp1 = ifail( i )
604 ifail( i ) = ifail( j )
605 ifail( j ) = itmp1
606 END IF
607 END IF
608 60 CONTINUE
609 END IF
610*
611* Set WORK(1) to optimal complex workspace size.
612*
613 work( 1 ) = lwmin
614*
615 RETURN
616*
617* End of ZHEEVX_2STAGE
618*
xerbla
subroutine xerbla(srname, info)
Definition cblat2.f:3285
dcopy
subroutine dcopy(n, dx, incx, dy, incy)
DCOPY
Definition dcopy.f:82
zhetrd_2stage
subroutine zhetrd_2stage(vect, uplo, n, a, lda, d, e, tau, hous2, lhous2, work, lwork, info)
ZHETRD_2STAGE
Definition zhetrd_2stage.f:227
ilaenv2stage
integer function ilaenv2stage(ispec, name, opts, n1, n2, n3, n4)
ILAENV2STAGE
Definition ilaenv2stage.f:148
zlacpy
subroutine zlacpy(uplo, m, n, a, lda, b, ldb)
ZLACPY copies all or part of one two-dimensional array to another.
Definition zlacpy.f:101
dlamch
double precision function dlamch(cmach)
DLAMCH
Definition dlamch.f:69
zlanhe
double precision function zlanhe(norm, uplo, n, a, lda, work)
ZLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition zlanhe.f:122
lsame
logical function lsame(ca, cb)
LSAME
Definition lsame.f:48
dscal
subroutine dscal(n, da, dx, incx)
DSCAL
Definition dscal.f:79
zdscal
subroutine zdscal(n, da, zx, incx)
ZDSCAL
Definition zdscal.f:78
dstebz
subroutine dstebz(range, order, n, vl, vu, il, iu, abstol, d, e, m, nsplit, w, iblock, isplit, work, iwork, info)
DSTEBZ
Definition dstebz.f:272
zstein
subroutine zstein(n, d, e, m, w, iblock, isplit, z, ldz, work, iwork, ifail, info)
ZSTEIN
Definition zstein.f:180
zsteqr
subroutine zsteqr(compz, n, d, e, z, ldz, work, info)
ZSTEQR
Definition zsteqr.f:130
dsterf
subroutine dsterf(n, d, e, info)
DSTERF
Definition dsterf.f:84
zswap
subroutine zswap(n, zx, incx, zy, incy)
ZSWAP
Definition zswap.f:81
zungtr
subroutine zungtr(uplo, n, a, lda, tau, work, lwork, info)
ZUNGTR
Definition zungtr.f:121
zunmtr
subroutine zunmtr(side, uplo, trans, m, n, a, lda, tau, c, ldc, work, lwork, info)
ZUNMTR
Definition zunmtr.f:170
Here is the call graph for this function:
Here is the caller graph for this function: