zstt22()

subroutine zstt22	(	integer	N,
		integer	M,
		integer	KBAND,
		double precision, dimension( * )	AD,
		double precision, dimension( * )	AE,
		double precision, dimension( * )	SD,
		double precision, dimension( * )	SE,
		complex*16, dimension( ldu, * )	U,
		integer	LDU,
		complex*16, dimension( ldwork, * )	WORK,
		integer	LDWORK,
		double precision, dimension( * )	RWORK,
		double precision, dimension( 2 )	RESULT
	)

ZSTT22

Purpose:

 ZSTT22  checks a set of M eigenvalues and eigenvectors,

     A U = U S

 where A is Hermitian tridiagonal, the columns of U are unitary,
 and S is diagonal (if KBAND=0) or Hermitian tridiagonal (if KBAND=1).
 Two tests are performed:

    RESULT(1) = | U* A U - S | / ( |A| m ulp )

    RESULT(2) = | I - U*U | / ( m ulp )

Parameters

[in]	N	N is INTEGER The size of the matrix. If it is zero, ZSTT22 does nothing. It must be at least zero.
[in]	M	M is INTEGER The number of eigenpairs to check. If it is zero, ZSTT22 does nothing. It must be at least zero.
[in]	KBAND	KBAND is INTEGER The bandwidth of the matrix S. It may only be zero or one. If zero, then S is diagonal, and SE is not referenced. If one, then S is Hermitian tri-diagonal.
[in]	AD	AD is DOUBLE PRECISION array, dimension (N) The diagonal of the original (unfactored) matrix A. A is assumed to be Hermitian tridiagonal.
[in]	AE	AE is DOUBLE PRECISION array, dimension (N) The off-diagonal of the original (unfactored) matrix A. A is assumed to be Hermitian tridiagonal. AE(1) is ignored, AE(2) is the (1,2) and (2,1) element, etc.
[in]	SD	SD is DOUBLE PRECISION array, dimension (N) The diagonal of the (Hermitian tri-) diagonal matrix S.
[in]	SE	SE is DOUBLE PRECISION array, dimension (N) The off-diagonal of the (Hermitian tri-) diagonal matrix S. Not referenced if KBSND=0. If KBAND=1, then AE(1) is ignored, SE(2) is the (1,2) and (2,1) element, etc.
[in]	U	U is DOUBLE PRECISION array, dimension (LDU, N) The unitary matrix in the decomposition.
[in]	LDU	LDU is INTEGER The leading dimension of U. LDU must be at least N.
[out]	WORK	WORK is COMPLEX*16 array, dimension (LDWORK, M+1)
[in]	LDWORK	LDWORK is INTEGER The leading dimension of WORK. LDWORK must be at least max(1,M).
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (N)
[out]	RESULT	RESULT is DOUBLE PRECISION array, dimension (2) The values computed by the two tests described above. The values are currently limited to 1/ulp, to avoid overflow.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 143 of file zstt22.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            KBAND, LDU, LDWORK, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AD( * ), AE( * ), RESULT( 2 ), RWORK( * ),
     $                   SD( * ), SE( * )
      COMPLEX*16         U( LDU, * ), WORK( LDWORK, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
      COMPLEX*16         CZERO, CONE
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, K
      DOUBLE PRECISION   ANORM, ULP, UNFL, WNORM
      COMPLEX*16         AUKJ
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, ZLANGE, ZLANSY
      EXTERNAL           dlamch, zlange, zlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, max, min
*     ..
*     .. Executable Statements ..
*
      result( 1 ) = zero
      result( 2 ) = zero
      IF( n.LE.0 .OR. m.LE.0 )
     $   RETURN
*
      unfl = dlamch( 'Safe minimum' )
      ulp = dlamch( 'Epsilon' )
*
*     Do Test 1
*
*     Compute the 1-norm of A.
*
      IF( n.GT.1 ) THEN
         anorm = abs( ad( 1 ) ) + abs( ae( 1 ) )
         DO 10 j = 2, n - 1
            anorm = max( anorm, abs( ad( j ) )+abs( ae( j ) )+
     $              abs( ae( j-1 ) ) )
   10    CONTINUE
         anorm = max( anorm, abs( ad( n ) )+abs( ae( n-1 ) ) )
      ELSE
         anorm = abs( ad( 1 ) )
      END IF
      anorm = max( anorm, unfl )
*
*     Norm of U*AU - S
*
      DO 40 i = 1, m
         DO 30 j = 1, m
            work( i, j ) = czero
            DO 20 k = 1, n
               aukj = ad( k )*u( k, j )
               IF( k.NE.n )
     $            aukj = aukj + ae( k )*u( k+1, j )
               IF( k.NE.1 )
     $            aukj = aukj + ae( k-1 )*u( k-1, j )
               work( i, j ) = work( i, j ) + u( k, i )*aukj
   20       CONTINUE
   30    CONTINUE
         work( i, i ) = work( i, i ) - sd( i )
         IF( kband.EQ.1 ) THEN
            IF( i.NE.1 )
     $         work( i, i-1 ) = work( i, i-1 ) - se( i-1 )
            IF( i.NE.n )
     $         work( i, i+1 ) = work( i, i+1 ) - se( i )
         END IF
   40 CONTINUE
*
      wnorm = zlansy( '1', 'L', m, work, m, rwork )
*
      IF( anorm.GT.wnorm ) THEN
         result( 1 ) = ( wnorm / anorm ) / ( m*ulp )
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( wnorm, m*anorm ) / anorm ) / ( m*ulp )
         ELSE
            result( 1 ) = min( wnorm / anorm, dble( m ) ) / ( m*ulp )
         END IF
      END IF
*
*     Do Test 2
*
*     Compute  U*U - I
*
      CALL zgemm( 'T', 'N', m, m, n, cone, u, ldu, u, ldu, czero, work,
     $            m )
*
      DO 50 j = 1, m
         work( j, j ) = work( j, j ) - one
   50 CONTINUE
*
      result( 2 ) = min( dble( m ), zlange( '1', m, m, work, m,
     $              rwork ) ) / ( m*ulp )
*
      RETURN
*
*     End of ZSTT22
*

Here is the call graph for this function:

Here is the caller graph for this function: