cbdt02()

subroutine cbdt02	(	integer	M,
		integer	N,
		complex, dimension( ldb, * )	B,
		integer	LDB,
		complex, dimension( ldc, * )	C,
		integer	LDC,
		complex, dimension( ldu, * )	U,
		integer	LDU,
		complex, dimension( * )	WORK,
		real, dimension( * )	RWORK,
		real	RESID
	)

CBDT02

Purpose:

 CBDT02 tests the change of basis C = U' * B by computing the residual

    RESID = norm( B - U * C ) / ( max(m,n) * norm(B) * EPS ),

 where B and C are M by N matrices, U is an M by M orthogonal matrix,
 and EPS is the machine precision.

Parameters

[in]	M	M is INTEGER The number of rows of the matrices B and C and the order of the matrix Q.
[in]	N	N is INTEGER The number of columns of the matrices B and C.
[in]	B	B is COMPLEX array, dimension (LDB,N) The m by n matrix B.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,M).
[in]	C	C is COMPLEX array, dimension (LDC,N) The m by n matrix C, assumed to contain U' * B.
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >= max(1,M).
[in]	U	U is COMPLEX array, dimension (LDU,M) The m by m orthogonal matrix U.
[in]	LDU	LDU is INTEGER The leading dimension of the array U. LDU >= max(1,M).
[out]	WORK	WORK is COMPLEX array, dimension (M)
[out]	RWORK	RWORK is REAL array, dimension (M)
[out]	RESID	RESID is REAL RESID = norm( B - U * C ) / ( max(m,n) * norm(B) * EPS ),

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 117 of file cbdt02.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            LDB, LDC, LDU, M, N
      REAL               RESID
*     ..
*     .. Array Arguments ..
      REAL               RWORK( * )
      COMPLEX            B( LDB, * ), C( LDC, * ), U( LDU, * ),
     $                   WORK( * )
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            J
      REAL               BNORM, EPS, REALMN
*     ..
*     .. External Functions ..
      REAL               CLANGE, SCASUM, SLAMCH
      EXTERNAL           clange, scasum, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           ccopy, cgemv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min, real
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      resid = zero
      IF( m.LE.0 .OR. n.LE.0 )
     $   RETURN
      realmn = real( max( m, n ) )
      eps = slamch( 'Precision' )
*
*     Compute norm( B - U * C )
*
      DO 10 j = 1, n
         CALL ccopy( m, b( 1, j ), 1, work, 1 )
         CALL cgemv( 'No transpose', m, m, -cmplx( one ), u, ldu,
     $               c( 1, j ), 1, cmplx( one ), work, 1 )
         resid = max( resid, scasum( m, work, 1 ) )
   10 CONTINUE
*
*     Compute norm of B.
*
      bnorm = clange( '1', m, n, b, ldb, rwork )
*
      IF( bnorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         IF( bnorm.GE.resid ) THEN
            resid = ( resid / bnorm ) / ( realmn*eps )
         ELSE
            IF( bnorm.LT.one ) THEN
               resid = ( min( resid, realmn*bnorm ) / bnorm ) /
     $                 ( realmn*eps )
            ELSE
               resid = min( resid / bnorm, realmn ) / ( realmn*eps )
            END IF
         END IF
      END IF
      RETURN
*
*     End of CBDT02
*

Here is the call graph for this function:

Here is the caller graph for this function: