zlarz()

subroutine zlarz	(	character	SIDE,
		integer	M,
		integer	N,
		integer	L,
		complex*16, dimension( * )	V,
		integer	INCV,
		complex*16	TAU,
		complex*16, dimension( ldc, * )	C,
		integer	LDC,
		complex*16, dimension( * )	WORK
	)

ZLARZ applies an elementary reflector (as returned by stzrzf) to a general matrix.

Download ZLARZ + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLARZ applies a complex elementary reflector H to a complex
 M-by-N matrix C, from either the left or the right. H is represented
 in the form

       H = I - tau * v * v**H

 where tau is a complex scalar and v is a complex vector.

 If tau = 0, then H is taken to be the unit matrix.

 To apply H**H (the conjugate transpose of H), supply conjg(tau) instead
 tau.

 H is a product of k elementary reflectors as returned by ZTZRZF.

Parameters

[in]	SIDE	SIDE is CHARACTER*1 = 'L': form H * C = 'R': form C * H
[in]	M	M is INTEGER The number of rows of the matrix C.
[in]	N	N is INTEGER The number of columns of the matrix C.
[in]	L	L is INTEGER The number of entries of the vector V containing the meaningful part of the Householder vectors. If SIDE = 'L', M >= L >= 0, if SIDE = 'R', N >= L >= 0.
[in]	V	V is COMPLEX*16 array, dimension (1+(L-1)*abs(INCV)) The vector v in the representation of H as returned by ZTZRZF. V is not used if TAU = 0.
[in]	INCV	INCV is INTEGER The increment between elements of v. INCV <> 0.
[in]	TAU	TAU is COMPLEX*16 The value tau in the representation of H.
[in,out]	C	C is COMPLEX*16 array, dimension (LDC,N) On entry, the M-by-N matrix C. On exit, C is overwritten by the matrix H * C if SIDE = 'L', or C * H if SIDE = 'R'.
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >= max(1,M).
[out]	WORK	WORK is COMPLEX*16 array, dimension (N) if SIDE = 'L' or (M) if SIDE = 'R'

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Contributors:

A. Petitet, Computer Science Dept., Univ. of Tenn., Knoxville, USA

Further Details:

Definition at line 146 of file zlarz.f.

*
*  -- LAPACK computational routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          SIDE
      INTEGER            INCV, L, LDC, M, N
      COMPLEX*16         TAU
*     ..
*     .. Array Arguments ..
      COMPLEX*16         C( LDC, * ), V( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16         ONE, ZERO
      parameter( one = ( 1.0d+0, 0.0d+0 ),
     $                   zero = ( 0.0d+0, 0.0d+0 ) )
*     ..
*     .. External Subroutines ..
      EXTERNAL           zaxpy, zcopy, zgemv, zgerc, zgeru, zlacgv
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Executable Statements ..
*
      IF( lsame( side, 'L' ) ) THEN
*
*        Form  H * C
*
         IF( tau.NE.zero ) THEN
*
*           w( 1:n ) = conjg( C( 1, 1:n ) )
*
            CALL zcopy( n, c, ldc, work, 1 )
            CALL zlacgv( n, work, 1 )
*
*           w( 1:n ) = conjg( w( 1:n ) + C( m-l+1:m, 1:n )**H * v( 1:l ) )
*
            CALL zgemv( 'Conjugate transpose', l, n, one, c( m-l+1, 1 ),
     $                  ldc, v, incv, one, work, 1 )
            CALL zlacgv( n, work, 1 )
*
*           C( 1, 1:n ) = C( 1, 1:n ) - tau * w( 1:n )
*
            CALL zaxpy( n, -tau, work, 1, c, ldc )
*
*           C( m-l+1:m, 1:n ) = C( m-l+1:m, 1:n ) - ...
*                               tau * v( 1:l ) * w( 1:n )**H
*
            CALL zgeru( l, n, -tau, v, incv, work, 1, c( m-l+1, 1 ),
     $                  ldc )
         END IF
*
      ELSE
*
*        Form  C * H
*
         IF( tau.NE.zero ) THEN
*
*           w( 1:m ) = C( 1:m, 1 )
*
            CALL zcopy( m, c, 1, work, 1 )
*
*           w( 1:m ) = w( 1:m ) + C( 1:m, n-l+1:n, 1:n ) * v( 1:l )
*
            CALL zgemv( 'No transpose', m, l, one, c( 1, n-l+1 ), ldc,
     $                  v, incv, one, work, 1 )
*
*           C( 1:m, 1 ) = C( 1:m, 1 ) - tau * w( 1:m )
*
            CALL zaxpy( m, -tau, work, 1, c, 1 )
*
*           C( 1:m, n-l+1:n ) = C( 1:m, n-l+1:n ) - ...
*                               tau * w( 1:m ) * v( 1:l )**H
*
            CALL zgerc( m, l, -tau, work, 1, v, incv, c( 1, n-l+1 ),
     $                  ldc )
*
         END IF
*
      END IF
*
      RETURN
*
*     End of ZLARZ
*

Here is the call graph for this function:

Here is the caller graph for this function: