dtsqr01.f

Go to the documentation of this file.

*> \brief \b DTSQR01
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE DTSQR01(TSSW, M,N, MB, NB, RESULT)
*
*       .. Scalar Arguments ..
*       INTEGER M, N, MB
*       .. Return values ..
*       DOUBLE PRECISION RESULT(6)
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DTSQR01 tests DGEQR , DGELQ, DGEMLQ and DGEMQR.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] TSSW
*> \verbatim
*>          TSSW is CHARACTER
*>          'TS' for testing tall skinny QR
*>               and anything else for testing short wide LQ
*> \endverbatim
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          Number of rows in test matrix.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          Number of columns in test matrix.
*> \endverbatim
*> \param[in] MB
*> \verbatim
*>          MB is INTEGER
*>          Number of row in row block in test matrix.
*> \endverbatim
*>
*> \param[in] NB
*> \verbatim
*>          NB is INTEGER
*>          Number of columns in column block test matrix.
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (6)
*>          Results of each of the six tests below.
*>
*>          RESULT(1) = | A - Q R | or | A - L Q |
*>          RESULT(2) = | I - Q^H Q | or | I - Q Q^H |
*>          RESULT(3) = | Q C - Q C |
*>          RESULT(4) = | Q^H C - Q^H C |
*>          RESULT(5) = | C Q - C Q |
*>          RESULT(6) = | C Q^H - C Q^H |
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date April 2012
*
*> \ingroup double_lin
*
*  =====================================================================
      SUBROUTINE dtsqr01(TSSW, M, N, MB, NB, RESULT)
      IMPLICIT NONE
*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     April 2012
*
*     .. Scalar Arguments ..
      CHARACTER         TSSW
      INTEGER           M, N, MB, NB
*     .. Return values ..
      DOUBLE PRECISION  RESULT(6)
*
*  =====================================================================
*
*     ..
*     .. Local allocatable arrays
      DOUBLE PRECISION, ALLOCATABLE :: AF(:,:), Q(:,:),
     $  r(:,:), rwork(:), work( : ), t(:),
     $  cf(:,:), df(:,:), a(:,:), c(:,:), d(:,:), lq(:,:)
*
*     .. Parameters ..
      DOUBLE PRECISION ONE, ZERO
      parameter( zero = 0.0, one = 1.0 )
*     ..
*     .. Local Scalars ..
      LOGICAL TESTZEROS, TS
      INTEGER INFO, J, K, L, LWORK, TSIZE, MNB
      DOUBLE PRECISION   ANORM, EPS, RESID, CNORM, DNORM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
      DOUBLE PRECISION   TQUERY( 5 ), WORKQUERY
*     ..
*     .. External Functions ..
      DOUBLE PRECISION DLAMCH, DLANGE, DLANSY
      LOGICAL  LSAME
      INTEGER ILAENV
      EXTERNAL dlamch, dlange, dlansy, lsame, ilaenv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC  max, min
*     .. Scalars in Common ..
      CHARACTER*32       srnamt
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA iseed / 1988, 1989, 1990, 1991 /
*
*     TEST TALL SKINNY OR SHORT WIDE
*
      ts = lsame(tssw, 'TS')
*
*     TEST MATRICES WITH HALF OF MATRIX BEING ZEROS
*
      testzeros = .false.
*
      eps = dlamch( 'Epsilon' )
      k = min(m,n)
      l = max(m,n,1)
      mnb = max( mb, nb)
      lwork = max(3,l)*mnb
*
*     Dynamically allocate local arrays
*
      ALLOCATE ( a(m,n), af(m,n), q(l,l), r(m,l), rwork(l),
     $           c(m,n), cf(m,n),
     $           d(n,m), df(n,m), lq(l,n) )
*
*     Put random numbers into A and copy to AF
*
      DO j=1,n
         CALL dlarnv( 2, iseed, m, a( 1, j ) )
      END DO
      IF (testzeros) THEN
         IF (m.GE.4) THEN
            DO j=1,n
               CALL dlarnv( 2, iseed, m/2, a( m/4, j ) )
            END DO
         END IF
      END IF
      CALL dlacpy( 'Full', m, n, a, m, af, m )
*
      IF (ts) THEN
*
*     Factor the matrix A in the array AF.
*
      CALL dgeqr( m, n, af, m, tquery, -1, workquery, -1, info )
      tsize = int( tquery( 1 ) )
      lwork = int( workquery )
      CALL dgemqr( 'L', 'N', m, m, k, af, m, tquery, tsize, cf, m,
     $             workquery, -1, info)
      lwork = max( lwork, int( workquery ) )
      CALL dgemqr( 'L', 'N', m, n, k, af, m, tquery, tsize, cf, m,
     $             workquery, -1, info)
      lwork = max( lwork, int( workquery ) )
      CALL dgemqr( 'L', 'T', m, n, k, af, m, tquery, tsize, cf, m,
     $             workquery, -1, info)
      lwork = max( lwork, int( workquery ) )
      CALL dgemqr( 'R', 'N', n, m, k, af, m, tquery, tsize, df, n,
     $             workquery, -1, info)
      lwork = max( lwork, int( workquery ) )
      CALL dgemqr( 'R', 'T', n, m, k, af, m, tquery, tsize, df, n,
     $             workquery, -1, info)
      lwork = max( lwork, int( workquery ) )
      ALLOCATE ( t( tsize ) )
      ALLOCATE ( work( lwork ) )
      srnamt = 'DGEQR'
      CALL dgeqr( m, n, af, m, t, tsize, work, lwork, info )
*
*     Generate the m-by-m matrix Q
*
      CALL dlaset( 'Full', m, m, zero, one, q, m )
      srnamt = 'DGEMQR'
      CALL dgemqr( 'L', 'N', m, m, k, af, m, t, tsize, q, m,
     $              work, lwork, info )
*
*     Copy R
*
      CALL dlaset( 'Full', m, n, zero, zero, r, m )
      CALL dlacpy( 'Upper', m, n, af, m, r, m )
*
*     Compute |R - Q'*A| / |A| and store in RESULT(1)
*
      CALL dgemm( 'T', 'N', m, n, m, -one, q, m, a, m, one, r, m )
      anorm = dlange( '1', m, n, a, m, rwork )
      resid = dlange( '1', m, n, r, m, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = resid / (eps*max(1,m)*anorm)
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute |I - Q'*Q| and store in RESULT(2)
*
      CALL dlaset( 'Full', m, m, zero, one, r, m )
      CALL dsyrk( 'U', 'C', m, m, -one, q, m, one, r, m )
      resid = dlansy( '1', 'Upper', m, r, m, rwork )
      result( 2 ) = resid / (eps*max(1,m))
*
*     Generate random m-by-n matrix C and a copy CF
*
      DO j=1,n
         CALL dlarnv( 2, iseed, m, c( 1, j ) )
      END DO
      cnorm = dlange( '1', m, n, c, m, rwork)
      CALL dlacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as Q*C
*
      srnamt = 'DGEMQR'
      CALL dgemqr( 'L', 'N', m, n, k, af, m, t, tsize, cf, m,
     $             work, lwork, info)
*
*     Compute |Q*C - Q*C| / |C|
*
      CALL dgemm( 'N', 'N', m, n, m, -one, q, m, c, m, one, cf, m )
      resid = dlange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 3 ) = resid / (eps*max(1,m)*cnorm)
      ELSE
         result( 3 ) = zero
      END IF
*
*     Copy C into CF again
*
      CALL dlacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as QT*C
*
      srnamt = 'DGEMQR'
      CALL dgemqr( 'L', 'T', m, n, k, af, m, t, tsize, cf, m,
     $             work, lwork, info)
*
*     Compute |QT*C - QT*C| / |C|
*
      CALL dgemm( 'T', 'N', m, n, m, -one, q, m, c, m, one, cf, m )
      resid = dlange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 4 ) = resid / (eps*max(1,m)*cnorm)
      ELSE
         result( 4 ) = zero
      END IF
*
*     Generate random n-by-m matrix D and a copy DF
*
      DO j=1,m
         CALL dlarnv( 2, iseed, n, d( 1, j ) )
      END DO
      dnorm = dlange( '1', n, m, d, n, rwork)
      CALL dlacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as D*Q
*
      srnamt = 'DGEMQR'
      CALL dgemqr( 'R', 'N', n, m, k, af, m, t, tsize, df, n,
     $             work, lwork, info)
*
*     Compute |D*Q - D*Q| / |D|
*
      CALL dgemm( 'N', 'N', n, m, m, -one, d, n, q, m, one, df, n )
      resid = dlange( '1', n, m, df, n, rwork )
      IF( dnorm.GT.zero ) THEN
         result( 5 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL dlacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as D*QT
*
      CALL dgemqr( 'R', 'T', n, m, k, af, m, t, tsize, df, n,
     $             work, lwork, info)
*
*     Compute |D*QT - D*QT| / |D|
*
      CALL dgemm( 'N', 'T', n, m, m, -one, d, n, q, m, one, df, n )
      resid = dlange( '1', n, m, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 6 ) = resid / (eps*max(1,m)*dnorm)
      ELSE
         result( 6 ) = zero
      END IF
*
*     Short and wide
*
      ELSE
      CALL dgelq( m, n, af, m, tquery, -1, workquery, -1, info )
      tsize = int( tquery( 1 ) )
      lwork = int( workquery )
      CALL dgemlq( 'R', 'N', n, n, k, af, m, tquery, tsize, q, n,
     $              workquery, -1, info )
      lwork = max( lwork, int( workquery ) )
      CALL dgemlq( 'L', 'N', n, m, k, af, m, tquery, tsize, df, n,
     $             workquery, -1, info)
      lwork = max( lwork, int( workquery ) )
      CALL dgemlq( 'L', 'T', n, m, k, af, m, tquery, tsize, df, n,
     $             workquery, -1, info)
      lwork = max( lwork, int( workquery ) )
      CALL dgemlq( 'R', 'N', m, n, k, af, m, tquery, tsize, cf, m,
     $             workquery, -1, info)
      lwork = max( lwork, int( workquery ) )
      CALL dgemlq( 'R', 'T', m, n, k, af, m, tquery, tsize, cf, m,
     $             workquery, -1, info)
      lwork = max( lwork, int( workquery ) )
      ALLOCATE ( t( tsize ) )
      ALLOCATE ( work( lwork ) )
      srnamt = 'DGELQ'
      CALL dgelq( m, n, af, m, t, tsize, work, lwork, info )
*
*
*     Generate the n-by-n matrix Q
*
      CALL dlaset( 'Full', n, n, zero, one, q, n )
      srnamt = 'DGEMLQ'
      CALL dgemlq( 'R', 'N', n, n, k, af, m, t, tsize, q, n,
     $              work, lwork, info )
*
*     Copy R
*
      CALL dlaset( 'Full', m, n, zero, zero, lq, l )
      CALL dlacpy( 'Lower', m, n, af, m, lq, l )
*
*     Compute |L - A*Q'| / |A| and store in RESULT(1)
*
      CALL dgemm( 'N', 'T', m, n, n, -one, a, m, q, n, one, lq, l )
      anorm = dlange( '1', m, n, a, m, rwork )
      resid = dlange( '1', m, n, lq, l, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = resid / (eps*max(1,n)*anorm)
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute |I - Q'*Q| and store in RESULT(2)
*
      CALL dlaset( 'Full', n, n, zero, one, lq, l )
      CALL dsyrk( 'U', 'C', n, n, -one, q, n, one, lq, l )
      resid = dlansy( '1', 'Upper', n, lq, l, rwork )
      result( 2 ) = resid / (eps*max(1,n))
*
*     Generate random m-by-n matrix C and a copy CF
*
      DO j=1,m
         CALL dlarnv( 2, iseed, n, d( 1, j ) )
      END DO
      dnorm = dlange( '1', n, m, d, n, rwork)
      CALL dlacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to C as Q*C
*
      CALL dgemlq( 'L', 'N', n, m, k, af, m, t, tsize, df, n,
     $             work, lwork, info)
*
*     Compute |Q*D - Q*D| / |D|
*
      CALL dgemm( 'N', 'N', n, m, n, -one, q, n, d, n, one, df, n )
      resid = dlange( '1', n, m, df, n, rwork )
      IF( dnorm.GT.zero ) THEN
         result( 3 ) = resid / (eps*max(1,n)*dnorm)
      ELSE
         result( 3 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL dlacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as QT*D
*
      CALL dgemlq( 'L', 'T', n, m, k, af, m, t, tsize, df, n,
     $             work, lwork, info)
*
*     Compute |QT*D - QT*D| / |D|
*
      CALL dgemm( 'T', 'N', n, m, n, -one, q, n, d, n, one, df, n )
      resid = dlange( '1', n, m, df, n, rwork )
      IF( dnorm.GT.zero ) THEN
         result( 4 ) = resid / (eps*max(1,n)*dnorm)
      ELSE
         result( 4 ) = zero
      END IF
*
*     Generate random n-by-m matrix D and a copy DF
*
      DO j=1,n
         CALL dlarnv( 2, iseed, m, c( 1, j ) )
      END DO
      cnorm = dlange( '1', m, n, c, m, rwork)
      CALL dlacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as C*Q
*
      CALL dgemlq( 'R', 'N', m, n, k, af, m, t, tsize, cf, m,
     $             work, lwork, info)
*
*     Compute |C*Q - C*Q| / |C|
*
      CALL dgemm( 'N', 'N', m, n, n, -one, c, m, q, n, one, cf, m )
      resid = dlange( '1', n, m, df, n, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 5 ) = resid / (eps*max(1,n)*cnorm)
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy C into CF again
*
      CALL dlacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to D as D*QT
*
      CALL dgemlq( 'R', 'T', m, n, k, af, m, t, tsize, cf, m,
     $             work, lwork, info)
*
*     Compute |C*QT - C*QT| / |C|
*
      CALL dgemm( 'N', 'T', m, n, n, -one, c, m, q, n, one, cf, m )
      resid = dlange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 6 ) = resid / (eps*max(1,n)*cnorm)
      ELSE
         result( 6 ) = zero
      END IF
*
      END IF
*
*     Deallocate all arrays
*
      DEALLOCATE ( a, af, q, r, rwork, work, t, c, d, cf, df)
*
      RETURN
      END