dsyevx_2stage.f

Go to the documentation of this file.

*> \brief <b> DSYEVX_2STAGE computes the eigenvalues and, optionally, the left and/or right eigenvectors for SY matrices</b>
*
*  @precisions fortran d -> s
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download DSYEVX_2STAGE + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dsyevx_2stage.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dsyevx_2stage.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dsyevx_2stage.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE DSYEVX_2STAGE( JOBZ, RANGE, UPLO, N, A, LDA, VL, VU,
*                                 IL, IU, ABSTOL, M, W, Z, LDZ, WORK,
*                                 LWORK, IWORK, IFAIL, INFO )
*
*       IMPLICIT NONE
*
*       .. Scalar Arguments ..
*       CHARACTER          JOBZ, RANGE, UPLO
*       INTEGER            IL, INFO, IU, LDA, LDZ, LWORK, M, N
*       DOUBLE PRECISION   ABSTOL, VL, VU
*       ..
*       .. Array Arguments ..
*       INTEGER            IFAIL( * ), IWORK( * )
*       DOUBLE PRECISION   A( LDA, * ), W( * ), WORK( * ), Z( LDZ, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DSYEVX_2STAGE computes selected eigenvalues and, optionally, eigenvectors
*> of a real symmetric matrix A using the 2stage technique for
*> the reduction to tridiagonal.  Eigenvalues and eigenvectors can be
*> selected by specifying either a range of values or a range of indices
*> for the desired eigenvalues.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] JOBZ
*> \verbatim
*>          JOBZ is CHARACTER*1
*>          = 'N':  Compute eigenvalues only;
*>          = 'V':  Compute eigenvalues and eigenvectors.
*>                  Not available in this release.
*> \endverbatim
*>
*> \param[in] RANGE
*> \verbatim
*>          RANGE is CHARACTER*1
*>          = 'A': all eigenvalues will be found.
*>          = 'V': all eigenvalues in the half-open interval (VL,VU]
*>                 will be found.
*>          = 'I': the IL-th through IU-th eigenvalues will be found.
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          = 'U':  Upper triangle of A is stored;
*>          = 'L':  Lower triangle of A is stored.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is DOUBLE PRECISION array, dimension (LDA, N)
*>          On entry, the symmetric matrix A.  If UPLO = 'U', the
*>          leading N-by-N upper triangular part of A contains the
*>          upper triangular part of the matrix A.  If UPLO = 'L',
*>          the leading N-by-N lower triangular part of A contains
*>          the lower triangular part of the matrix A.
*>          On exit, the lower triangle (if UPLO='L') or the upper
*>          triangle (if UPLO='U') of A, including the diagonal, is
*>          destroyed.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] VL
*> \verbatim
*>          VL is DOUBLE PRECISION
*>          If RANGE='V', the lower bound of the interval to
*>          be searched for eigenvalues. VL < VU.
*>          Not referenced if RANGE = 'A' or 'I'.
*> \endverbatim
*>
*> \param[in] VU
*> \verbatim
*>          VU is DOUBLE PRECISION
*>          If RANGE='V', the upper bound of the interval to
*>          be searched for eigenvalues. VL < VU.
*>          Not referenced if RANGE = 'A' or 'I'.
*> \endverbatim
*>
*> \param[in] IL
*> \verbatim
*>          IL is INTEGER
*>          If RANGE='I', the index of the
*>          smallest eigenvalue to be returned.
*>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
*>          Not referenced if RANGE = 'A' or 'V'.
*> \endverbatim
*>
*> \param[in] IU
*> \verbatim
*>          IU is INTEGER
*>          If RANGE='I', the index of the
*>          largest eigenvalue to be returned.
*>          1 <= IL <= IU <= N, if N > 0; IL = 1 and IU = 0 if N = 0.
*>          Not referenced if RANGE = 'A' or 'V'.
*> \endverbatim
*>
*> \param[in] ABSTOL
*> \verbatim
*>          ABSTOL is DOUBLE PRECISION
*>          The absolute error tolerance for the eigenvalues.
*>          An approximate eigenvalue is accepted as converged
*>          when it is determined to lie in an interval [a,b]
*>          of width less than or equal to
*>
*>                  ABSTOL + EPS *   max( |a|,|b| ) ,
*>
*>          where EPS is the machine precision.  If ABSTOL is less than
*>          or equal to zero, then  EPS*|T|  will be used in its place,
*>          where |T| is the 1-norm of the tridiagonal matrix obtained
*>          by reducing A to tridiagonal form.
*>
*>          Eigenvalues will be computed most accurately when ABSTOL is
*>          set to twice the underflow threshold 2*DLAMCH('S'), not zero.
*>          If this routine returns with INFO>0, indicating that some
*>          eigenvectors did not converge, try setting ABSTOL to
*>          2*DLAMCH('S').
*>
*>          See "Computing Small Singular Values of Bidiagonal Matrices
*>          with Guaranteed High Relative Accuracy," by Demmel and
*>          Kahan, LAPACK Working Note #3.
*> \endverbatim
*>
*> \param[out] M
*> \verbatim
*>          M is INTEGER
*>          The total number of eigenvalues found.  0 <= M <= N.
*>          If RANGE = 'A', M = N, and if RANGE = 'I', M = IU-IL+1.
*> \endverbatim
*>
*> \param[out] W
*> \verbatim
*>          W is DOUBLE PRECISION array, dimension (N)
*>          On normal exit, the first M elements contain the selected
*>          eigenvalues in ascending order.
*> \endverbatim
*>
*> \param[out] Z
*> \verbatim
*>          Z is DOUBLE PRECISION array, dimension (LDZ, max(1,M))
*>          If JOBZ = 'V', then if INFO = 0, the first M columns of Z
*>          contain the orthonormal eigenvectors of the matrix A
*>          corresponding to the selected eigenvalues, with the i-th
*>          column of Z holding the eigenvector associated with W(i).
*>          If an eigenvector fails to converge, then that column of Z
*>          contains the latest approximation to the eigenvector, and the
*>          index of the eigenvector is returned in IFAIL.
*>          If JOBZ = 'N', then Z is not referenced.
*>          Note: the user must ensure that at least max(1,M) columns are
*>          supplied in the array Z; if RANGE = 'V', the exact value of M
*>          is not known in advance and an upper bound must be used.
*> \endverbatim
*>
*> \param[in] LDZ
*> \verbatim
*>          LDZ is INTEGER
*>          The leading dimension of the array Z.  LDZ >= 1, and if
*>          JOBZ = 'V', LDZ >= max(1,N).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
*>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The length of the array WORK. LWORK >= 1, when N <= 1;
*>          otherwise  
*>          If JOBZ = 'N' and N > 1, LWORK must be queried.
*>                                   LWORK = MAX(1, 8*N, dimension) where
*>                                   dimension = max(stage1,stage2) + (KD+1)*N + 3*N
*>                                             = N*KD + N*max(KD+1,FACTOPTNB) 
*>                                               + max(2*KD*KD, KD*NTHREADS) 
*>                                               + (KD+1)*N + 3*N
*>                                   where KD is the blocking size of the reduction,
*>                                   FACTOPTNB is the blocking used by the QR or LQ
*>                                   algorithm, usually FACTOPTNB=128 is a good choice
*>                                   NTHREADS is the number of threads used when
*>                                   openMP compilation is enabled, otherwise =1.
*>          If JOBZ = 'V' and N > 1, LWORK must be queried. Not yet available
*>
*>          If LWORK = -1, then a workspace query is assumed; the routine
*>          only calculates the optimal size of the WORK array, returns
*>          this value as the first entry of the WORK array, and no error
*>          message related to LWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (5*N)
*> \endverbatim
*>
*> \param[out] IFAIL
*> \verbatim
*>          IFAIL is INTEGER array, dimension (N)
*>          If JOBZ = 'V', then if INFO = 0, the first M elements of
*>          IFAIL are zero.  If INFO > 0, then IFAIL contains the
*>          indices of the eigenvectors that failed to converge.
*>          If JOBZ = 'N', then IFAIL is not referenced.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*>          > 0:  if INFO = i, then i eigenvectors failed to converge.
*>                Their indices are stored in array IFAIL.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date June 2016
*
*> \ingroup doubleSYeigen
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  All details about the 2stage techniques are available in:
*>
*>  Azzam Haidar, Hatem Ltaief, and Jack Dongarra.
*>  Parallel reduction to condensed forms for symmetric eigenvalue problems
*>  using aggregated fine-grained and memory-aware kernels. In Proceedings
*>  of 2011 International Conference for High Performance Computing,
*>  Networking, Storage and Analysis (SC '11), New York, NY, USA,
*>  Article 8 , 11 pages.
*>  http://doi.acm.org/10.1145/2063384.2063394
*>
*>  A. Haidar, J. Kurzak, P. Luszczek, 2013.
*>  An improved parallel singular value algorithm and its implementation 
*>  for multicore hardware, In Proceedings of 2013 International Conference
*>  for High Performance Computing, Networking, Storage and Analysis (SC '13).
*>  Denver, Colorado, USA, 2013.
*>  Article 90, 12 pages.
*>  http://doi.acm.org/10.1145/2503210.2503292
*>
*>  A. Haidar, R. Solca, S. Tomov, T. Schulthess and J. Dongarra.
*>  A novel hybrid CPU-GPU generalized eigensolver for electronic structure 
*>  calculations based on fine-grained memory aware tasks.
*>  International Journal of High Performance Computing Applications.
*>  Volume 28 Issue 2, Pages 196-209, May 2014.
*>  http://hpc.sagepub.com/content/28/2/196 
*>
*> \endverbatim
*
*  =====================================================================
      SUBROUTINE dsyevx_2stage( JOBZ, RANGE, UPLO, N, A, LDA, VL, VU,
     $                          IL, IU, ABSTOL, M, W, Z, LDZ, WORK,
     $                          LWORK, IWORK, IFAIL, INFO )
*
      IMPLICIT NONE
*
*  -- LAPACK driver routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     June 2016
*
*     .. Scalar Arguments ..
      CHARACTER          JOBZ, RANGE, UPLO
      INTEGER            IL, INFO, IU, LDA, LDZ, LWORK, M, N
      DOUBLE PRECISION   ABSTOL, VL, VU
*     ..
*     .. Array Arguments ..
      INTEGER            IFAIL( * ), IWORK( * )
      DOUBLE PRECISION   A( lda, * ), W( * ), WORK( * ), Z( ldz, * )
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ALLEIG, INDEIG, LOWER, LQUERY, TEST, VALEIG,
     $                   wantz
      CHARACTER          ORDER
      INTEGER            I, IINFO, IMAX, INDD, INDE, INDEE, INDIBL,
     $                   indisp, indiwo, indtau, indwkn, indwrk, iscale,
     $                   itmp1, j, jj, llwork, llwrkn,
     $                   nsplit, lwmin, lhtrd, lwtrd, kd, ib, indhous
      DOUBLE PRECISION   ABSTLL, ANRM, BIGNUM, EPS, RMAX, RMIN, SAFMIN,
     $                   sigma, smlnum, tmp1, vll, vuu
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      DOUBLE PRECISION   DLAMCH, DLANSY
      EXTERNAL           lsame, ilaenv, dlamch, dlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           dcopy, dlacpy, dorgtr, dormtr, dscal, dstebz,
     $                   dstein, dsteqr, dsterf, dswap, xerbla,
     $                   dsytrd_2stage
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      lower = lsame( uplo, 'L' )
      wantz = lsame( jobz, 'V' )
      alleig = lsame( range, 'A' )
      valeig = lsame( range, 'V' )
      indeig = lsame( range, 'I' )
      lquery = ( lwork.EQ.-1 )
*
      info = 0
      IF( .NOT.( lsame( jobz, 'N' ) ) ) THEN
         info = -1
      ELSE IF( .NOT.( alleig .OR. valeig .OR. indeig ) ) THEN
         info = -2
      ELSE IF( .NOT.( lower .OR. lsame( uplo, 'U' ) ) ) THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -6
      ELSE
         IF( valeig ) THEN
            IF( n.GT.0 .AND. vu.LE.vl )
     $         info = -8
         ELSE IF( indeig ) THEN
            IF( il.LT.1 .OR. il.GT.max( 1, n ) ) THEN
               info = -9
            ELSE IF( iu.LT.min( n, il ) .OR. iu.GT.n ) THEN
               info = -10
            END IF
         END IF
      END IF
      IF( info.EQ.0 ) THEN
         IF( ldz.LT.1 .OR. ( wantz .AND. ldz.LT.n ) ) THEN
            info = -15
         END IF
      END IF
*
      IF( info.EQ.0 ) THEN
         IF( n.LE.1 ) THEN
            lwmin = 1
            work( 1 ) = lwmin
         ELSE
            kd    = ilaenv( 17, 'DSYTRD_2STAGE', jobz, n, -1, -1, -1 )
            ib    = ilaenv( 18, 'DSYTRD_2STAGE', jobz, n, kd, -1, -1 )
            lhtrd = ilaenv( 19, 'DSYTRD_2STAGE', jobz, n, kd, ib, -1 )
            lwtrd = ilaenv( 20, 'DSYTRD_2STAGE', jobz, n, kd, ib, -1 )
            lwmin = max( 8*n, 3*n + lhtrd + lwtrd )
            work( 1 )  = lwmin
         END IF
*
         IF( lwork.LT.lwmin .AND. .NOT.lquery )
     $      info = -17
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DSYEVX_2STAGE', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      m = 0
      IF( n.EQ.0 ) THEN
         RETURN
      END IF
*
      IF( n.EQ.1 ) THEN
         IF( alleig .OR. indeig ) THEN
            m = 1
            w( 1 ) = a( 1, 1 )
         ELSE
            IF( vl.LT.a( 1, 1 ) .AND. vu.GE.a( 1, 1 ) ) THEN
               m = 1
               w( 1 ) = a( 1, 1 )
            END IF
         END IF
         IF( wantz )
     $      z( 1, 1 ) = one
         RETURN
      END IF
*
*     Get machine constants.
*
      safmin = dlamch( 'Safe minimum' )
      eps    = dlamch( 'Precision' )
      smlnum = safmin / eps
      bignum = one / smlnum
      rmin   = sqrt( smlnum )
      rmax   = min( sqrt( bignum ), one / sqrt( sqrt( safmin ) ) )
*
*     Scale matrix to allowable range, if necessary.
*
      iscale = 0
      abstll = abstol
      IF( valeig ) THEN
         vll = vl
         vuu = vu
      END IF
      anrm = dlansy( 'M', uplo, n, a, lda, work )
      IF( anrm.GT.zero .AND. anrm.LT.rmin ) THEN
         iscale = 1
         sigma = rmin / anrm
      ELSE IF( anrm.GT.rmax ) THEN
         iscale = 1
         sigma = rmax / anrm
      END IF
      IF( iscale.EQ.1 ) THEN
         IF( lower ) THEN
            DO 10 j = 1, n
               CALL dscal( n-j+1, sigma, a( j, j ), 1 )
   10       CONTINUE
         ELSE
            DO 20 j = 1, n
               CALL dscal( j, sigma, a( 1, j ), 1 )
   20       CONTINUE
         END IF
         IF( abstol.GT.0 )
     $      abstll = abstol*sigma
         IF( valeig ) THEN
            vll = vl*sigma
            vuu = vu*sigma
         END IF
      END IF
*
*     Call DSYTRD_2STAGE to reduce symmetric matrix to tridiagonal form.
*
      indtau  = 1
      inde    = indtau + n
      indd    = inde + n
      indhous = indd + n
      indwrk  = indhous + lhtrd
      llwork  = lwork - indwrk + 1
*
      CALL dsytrd_2stage( jobz, uplo, n, a, lda, work( indd ), 
     $                    work( inde ), work( indtau ), work( indhous ),
     $                    lhtrd, work( indwrk ), llwork, iinfo )
*
*     If all eigenvalues are desired and ABSTOL is less than or equal to
*     zero, then call DSTERF or DORGTR and SSTEQR.  If this fails for
*     some eigenvalue, then try DSTEBZ.
*
      test = .false.
      IF( indeig ) THEN
         IF( il.EQ.1 .AND. iu.EQ.n ) THEN
            test = .true.
         END IF
      END IF
      IF( ( alleig .OR. test ) .AND. ( abstol.LE.zero ) ) THEN
         CALL dcopy( n, work( indd ), 1, w, 1 )
         indee = indwrk + 2*n
         IF( .NOT.wantz ) THEN
            CALL dcopy( n-1, work( inde ), 1, work( indee ), 1 )
            CALL dsterf( n, w, work( indee ), info )
         ELSE
            CALL dlacpy( 'A', n, n, a, lda, z, ldz )
            CALL dorgtr( uplo, n, z, ldz, work( indtau ),
     $                   work( indwrk ), llwork, iinfo )
            CALL dcopy( n-1, work( inde ), 1, work( indee ), 1 )
            CALL dsteqr( jobz, n, w, work( indee ), z, ldz,
     $                   work( indwrk ), info )
            IF( info.EQ.0 ) THEN
               DO 30 i = 1, n
                  ifail( i ) = 0
   30          CONTINUE
            END IF
         END IF
         IF( info.EQ.0 ) THEN
            m = n
            GO TO 40
         END IF
         info = 0
      END IF
*
*     Otherwise, call DSTEBZ and, if eigenvectors are desired, SSTEIN.
*
      IF( wantz ) THEN
         order = 'B'
      ELSE
         order = 'E'
      END IF
      indibl = 1
      indisp = indibl + n
      indiwo = indisp + n
      CALL dstebz( range, order, n, vll, vuu, il, iu, abstll,
     $             work( indd ), work( inde ), m, nsplit, w,
     $             iwork( indibl ), iwork( indisp ), work( indwrk ),
     $             iwork( indiwo ), info )
*
      IF( wantz ) THEN
         CALL dstein( n, work( indd ), work( inde ), m, w,
     $                iwork( indibl ), iwork( indisp ), z, ldz,
     $                work( indwrk ), iwork( indiwo ), ifail, info )
*
*        Apply orthogonal matrix used in reduction to tridiagonal
*        form to eigenvectors returned by DSTEIN.
*
         indwkn = inde
         llwrkn = lwork - indwkn + 1
         CALL dormtr( 'L', uplo, 'N', n, m, a, lda, work( indtau ), z,
     $                ldz, work( indwkn ), llwrkn, iinfo )
      END IF
*
*     If matrix was scaled, then rescale eigenvalues appropriately.
*
   40 CONTINUE
      IF( iscale.EQ.1 ) THEN
         IF( info.EQ.0 ) THEN
            imax = m
         ELSE
            imax = info - 1
         END IF
         CALL dscal( imax, one / sigma, w, 1 )
      END IF
*
*     If eigenvalues are not in order, then sort them, along with
*     eigenvectors.
*
      IF( wantz ) THEN
         DO 60 j = 1, m - 1
            i = 0
            tmp1 = w( j )
            DO 50 jj = j + 1, m
               IF( w( jj ).LT.tmp1 ) THEN
                  i = jj
                  tmp1 = w( jj )
               END IF
   50       CONTINUE
*
            IF( i.NE.0 ) THEN
               itmp1 = iwork( indibl+i-1 )
               w( i ) = w( j )
               iwork( indibl+i-1 ) = iwork( indibl+j-1 )
               w( j ) = tmp1
               iwork( indibl+j-1 ) = itmp1
               CALL dswap( n, z( 1, i ), 1, z( 1, j ), 1 )
               IF( info.NE.0 ) THEN
                  itmp1 = ifail( i )
                  ifail( i ) = ifail( j )
                  ifail( j ) = itmp1
               END IF
            END IF
   60    CONTINUE
      END IF
*
*     Set WORK(1) to optimal workspace size.
*
      work( 1 ) = lwmin
*
      RETURN
*
*     End of DSYEVX_2STAGE
*
      END