slavsy.f

Go to the documentation of this file.

*> \brief \b SLAVSY
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SLAVSY( UPLO, TRANS, DIAG, N, NRHS, A, LDA, IPIV, B,
*                          LDB, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          DIAG, TRANS, UPLO
*       INTEGER            INFO, LDA, LDB, N, NRHS
*       ..
*       .. Array Arguments ..
*       INTEGER            IPIV( * )
*       REAL               A( LDA, * ), B( LDB, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SLAVSY  performs one of the matrix-vector operations
*>    x := A*x  or  x := A'*x,
*> where x is an N element vector and A is one of the factors
*> from the block U*D*U' or L*D*L' factorization computed by SSYTRF.
*>
*> If TRANS = 'N', multiplies by U  or U * D  (or L  or L * D)
*> If TRANS = 'T', multiplies by U' or D * U' (or L' or D * L')
*> If TRANS = 'C', multiplies by U' or D * U' (or L' or D * L')
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the factor stored in A is upper or lower
*>          triangular.
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>          Specifies the operation to be performed:
*>          = 'N':  x := A*x
*>          = 'T':  x := A'*x
*>          = 'C':  x := A'*x
*> \endverbatim
*>
*> \param[in] DIAG
*> \verbatim
*>          DIAG is CHARACTER*1
*>          Specifies whether or not the diagonal blocks are unit
*>          matrices.  If the diagonal blocks are assumed to be unit,
*>          then A = U or A = L, otherwise A = U*D or A = L*D.
*>          = 'U':  Diagonal blocks are assumed to be unit matrices.
*>          = 'N':  Diagonal blocks are assumed to be non-unit matrices.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of rows and columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of vectors
*>          x to be multiplied by A.  NRHS >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is REAL array, dimension (LDA,N)
*>          The block diagonal matrix D and the multipliers used to
*>          obtain the factor U or L as computed by SSYTRF.
*>          Stored as a 2-D triangular matrix.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] IPIV
*> \verbatim
*>          IPIV is INTEGER array, dimension (N)
*>          Details of the interchanges and the block structure of D,
*>          as determined by SSYTRF.
*>
*>          If UPLO = 'U':
*>               If IPIV(k) > 0, then rows and columns k and IPIV(k)
*>               were interchanged and D(k,k) is a 1-by-1 diagonal block.
*>               (If IPIV( k ) = k, no interchange was done).
*>
*>               If IPIV(k) = IPIV(k-1) < 0, then rows and
*>               columns k-1 and -IPIV(k) were interchanged,
*>               D(k-1:k,k-1:k) is a 2-by-2 diagonal block.
*>
*>          If UPLO = 'L':
*>               If IPIV(k) > 0, then rows and columns k and IPIV(k)
*>               were interchanged and D(k,k) is a 1-by-1 diagonal block.
*>               (If IPIV( k ) = k, no interchange was done).
*>
*>               If IPIV(k) = IPIV(k+1) < 0, then rows and
*>               columns k+1 and -IPIV(k) were interchanged,
*>               D(k:k+1,k:k+1) is a 2-by-2 diagonal block.
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is REAL array, dimension (LDB,NRHS)
*>          On entry, B contains NRHS vectors of length N.
*>          On exit, B is overwritten with the product A * B.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B.  LDB >= max(1,N).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: successful exit
*>          < 0: if INFO = -k, the k-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date November 2013
*
*> \ingroup single_lin
*
*  =====================================================================
      SUBROUTINE slavsy( UPLO, TRANS, DIAG, N, NRHS, A, LDA, IPIV, B,
     $                   LDB, INFO )
*
*  -- LAPACK test routine (version 3.5.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2013
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, TRANS, UPLO
      INTEGER            INFO, LDA, LDB, N, NRHS
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      REAL               A( lda, * ), B( ldb, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            NOUNIT
      INTEGER            J, K, KP
      REAL               D11, D12, D21, D22, T1, T2
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemv, sger, sscal, sswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( .NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( .NOT.lsame( trans, 'N' ) .AND. .NOT.
     $         lsame( trans, 'T' ) .AND. .NOT.lsame( trans, 'C' ) ) THEN
         info = -2
      ELSE IF( .NOT.lsame( diag, 'U' ) .AND. .NOT.lsame( diag, 'N' ) )
     $          THEN
         info = -3
      ELSE IF( n.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -6
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SLAVSY ', -info )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( n.EQ.0 )
     $   RETURN
*
      nounit = lsame( diag, 'N' )
*------------------------------------------
*
*     Compute  B := A * B  (No transpose)
*
*------------------------------------------
      IF( lsame( trans, 'N' ) ) THEN
*
*        Compute  B := U*B
*        where U = P(m)*inv(U(m))* ... *P(1)*inv(U(1))
*
         IF( lsame( uplo, 'U' ) ) THEN
*
*        Loop forward applying the transformations.
*
            k = 1
   10       CONTINUE
            IF( k.GT.n )
     $         GO TO 30
            IF( ipiv( k ).GT.0 ) THEN
*
*              1 x 1 pivot block
*
*              Multiply by the diagonal element if forming U * D.
*
               IF( nounit )
     $            CALL sscal( nrhs, a( k, k ), b( k, 1 ), ldb )
*
*              Multiply by  P(K) * inv(U(K))  if K > 1.
*
               IF( k.GT.1 ) THEN
*
*                 Apply the transformation.
*
                  CALL sger( k-1, nrhs, one, a( 1, k ), 1, b( k, 1 ),
     $                       ldb, b( 1, 1 ), ldb )
*
*                 Interchange if P(K) .ne. I.
*
                  kp = ipiv( k )
                  IF( kp.NE.k )
     $               CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
               END IF
               k = k + 1
            ELSE
*
*              2 x 2 pivot block
*
*              Multiply by the diagonal block if forming U * D.
*
               IF( nounit ) THEN
                  d11 = a( k, k )
                  d22 = a( k+1, k+1 )
                  d12 = a( k, k+1 )
                  d21 = d12
                  DO 20 j = 1, nrhs
                     t1 = b( k, j )
                     t2 = b( k+1, j )
                     b( k, j ) = d11*t1 + d12*t2
                     b( k+1, j ) = d21*t1 + d22*t2
   20             CONTINUE
               END IF
*
*              Multiply by  P(K) * inv(U(K))  if K > 1.
*
               IF( k.GT.1 ) THEN
*
*                 Apply the transformations.
*
                  CALL sger( k-1, nrhs, one, a( 1, k ), 1, b( k, 1 ),
     $                       ldb, b( 1, 1 ), ldb )
                  CALL sger( k-1, nrhs, one, a( 1, k+1 ), 1,
     $                       b( k+1, 1 ), ldb, b( 1, 1 ), ldb )
*
*                 Interchange if P(K) .ne. I.
*
                  kp = abs( ipiv( k ) )
                  IF( kp.NE.k )
     $               CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
               END IF
               k = k + 2
            END IF
            GO TO 10
   30       CONTINUE
*
*        Compute  B := L*B
*        where L = P(1)*inv(L(1))* ... *P(m)*inv(L(m)) .
*
         ELSE
*
*           Loop backward applying the transformations to B.
*
            k = n
   40       CONTINUE
            IF( k.LT.1 )
     $         GO TO 60
*
*           Test the pivot index.  If greater than zero, a 1 x 1
*           pivot was used, otherwise a 2 x 2 pivot was used.
*
            IF( ipiv( k ).GT.0 ) THEN
*
*              1 x 1 pivot block:
*
*              Multiply by the diagonal element if forming L * D.
*
               IF( nounit )
     $            CALL sscal( nrhs, a( k, k ), b( k, 1 ), ldb )
*
*              Multiply by  P(K) * inv(L(K))  if K < N.
*
               IF( k.NE.n ) THEN
                  kp = ipiv( k )
*
*                 Apply the transformation.
*
                  CALL sger( n-k, nrhs, one, a( k+1, k ), 1, b( k, 1 ),
     $                       ldb, b( k+1, 1 ), ldb )
*
*                 Interchange if a permutation was applied at the
*                 K-th step of the factorization.
*
                  IF( kp.NE.k )
     $               CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
               END IF
               k = k - 1
*
            ELSE
*
*              2 x 2 pivot block:
*
*              Multiply by the diagonal block if forming L * D.
*
               IF( nounit ) THEN
                  d11 = a( k-1, k-1 )
                  d22 = a( k, k )
                  d21 = a( k, k-1 )
                  d12 = d21
                  DO 50 j = 1, nrhs
                     t1 = b( k-1, j )
                     t2 = b( k, j )
                     b( k-1, j ) = d11*t1 + d12*t2
                     b( k, j ) = d21*t1 + d22*t2
   50             CONTINUE
               END IF
*
*              Multiply by  P(K) * inv(L(K))  if K < N.
*
               IF( k.NE.n ) THEN
*
*                 Apply the transformation.
*
                  CALL sger( n-k, nrhs, one, a( k+1, k ), 1, b( k, 1 ),
     $                       ldb, b( k+1, 1 ), ldb )
                  CALL sger( n-k, nrhs, one, a( k+1, k-1 ), 1,
     $                       b( k-1, 1 ), ldb, b( k+1, 1 ), ldb )
*
*                 Interchange if a permutation was applied at the
*                 K-th step of the factorization.
*
                  kp = abs( ipiv( k ) )
                  IF( kp.NE.k )
     $               CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
               END IF
               k = k - 2
            END IF
            GO TO 40
   60       CONTINUE
         END IF
*----------------------------------------
*
*     Compute  B := A' * B  (transpose)
*
*----------------------------------------
      ELSE
*
*        Form  B := U'*B
*        where U  = P(m)*inv(U(m))* ... *P(1)*inv(U(1))
*        and   U' = inv(U'(1))*P(1)* ... *inv(U'(m))*P(m)
*
         IF( lsame( uplo, 'U' ) ) THEN
*
*           Loop backward applying the transformations.
*
            k = n
   70       CONTINUE
            IF( k.LT.1 )
     $         GO TO 90
*
*           1 x 1 pivot block.
*
            IF( ipiv( k ).GT.0 ) THEN
               IF( k.GT.1 ) THEN
*
*                 Interchange if P(K) .ne. I.
*
                  kp = ipiv( k )
                  IF( kp.NE.k )
     $               CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
*
*                 Apply the transformation
*
                  CALL sgemv( 'Transpose', k-1, nrhs, one, b, ldb,
     $                        a( 1, k ), 1, one, b( k, 1 ), ldb )
               END IF
               IF( nounit )
     $            CALL sscal( nrhs, a( k, k ), b( k, 1 ), ldb )
               k = k - 1
*
*           2 x 2 pivot block.
*
            ELSE
               IF( k.GT.2 ) THEN
*
*                 Interchange if P(K) .ne. I.
*
                  kp = abs( ipiv( k ) )
                  IF( kp.NE.k-1 )
     $               CALL sswap( nrhs, b( k-1, 1 ), ldb, b( kp, 1 ),
     $                           ldb )
*
*                 Apply the transformations
*
                  CALL sgemv( 'Transpose', k-2, nrhs, one, b, ldb,
     $                        a( 1, k ), 1, one, b( k, 1 ), ldb )
                  CALL sgemv( 'Transpose', k-2, nrhs, one, b, ldb,
     $                        a( 1, k-1 ), 1, one, b( k-1, 1 ), ldb )
               END IF
*
*              Multiply by the diagonal block if non-unit.
*
               IF( nounit ) THEN
                  d11 = a( k-1, k-1 )
                  d22 = a( k, k )
                  d12 = a( k-1, k )
                  d21 = d12
                  DO 80 j = 1, nrhs
                     t1 = b( k-1, j )
                     t2 = b( k, j )
                     b( k-1, j ) = d11*t1 + d12*t2
                     b( k, j ) = d21*t1 + d22*t2
   80             CONTINUE
               END IF
               k = k - 2
            END IF
            GO TO 70
   90       CONTINUE
*
*        Form  B := L'*B
*        where L  = P(1)*inv(L(1))* ... *P(m)*inv(L(m))
*        and   L' = inv(L'(m))*P(m)* ... *inv(L'(1))*P(1)
*
         ELSE
*
*           Loop forward applying the L-transformations.
*
            k = 1
  100       CONTINUE
            IF( k.GT.n )
     $         GO TO 120
*
*           1 x 1 pivot block
*
            IF( ipiv( k ).GT.0 ) THEN
               IF( k.LT.n ) THEN
*
*                 Interchange if P(K) .ne. I.
*
                  kp = ipiv( k )
                  IF( kp.NE.k )
     $               CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
*
*                 Apply the transformation
*
                  CALL sgemv( 'Transpose', n-k, nrhs, one, b( k+1, 1 ),
     $                        ldb, a( k+1, k ), 1, one, b( k, 1 ), ldb )
               END IF
               IF( nounit )
     $            CALL sscal( nrhs, a( k, k ), b( k, 1 ), ldb )
               k = k + 1
*
*           2 x 2 pivot block.
*
            ELSE
               IF( k.LT.n-1 ) THEN
*
*              Interchange if P(K) .ne. I.
*
                  kp = abs( ipiv( k ) )
                  IF( kp.NE.k+1 )
     $               CALL sswap( nrhs, b( k+1, 1 ), ldb, b( kp, 1 ),
     $                           ldb )
*
*                 Apply the transformation
*
                  CALL sgemv( 'Transpose', n-k-1, nrhs, one,
     $                        b( k+2, 1 ), ldb, a( k+2, k+1 ), 1, one,
     $                        b( k+1, 1 ), ldb )
                  CALL sgemv( 'Transpose', n-k-1, nrhs, one,
     $                        b( k+2, 1 ), ldb, a( k+2, k ), 1, one,
     $                        b( k, 1 ), ldb )
               END IF
*
*              Multiply by the diagonal block if non-unit.
*
               IF( nounit ) THEN
                  d11 = a( k, k )
                  d22 = a( k+1, k+1 )
                  d21 = a( k+1, k )
                  d12 = d21
                  DO 110 j = 1, nrhs
                     t1 = b( k, j )
                     t2 = b( k+1, j )
                     b( k, j ) = d11*t1 + d12*t2
                     b( k+1, j ) = d21*t1 + d22*t2
  110             CONTINUE
               END IF
               k = k + 2
            END IF
            GO TO 100
  120       CONTINUE
         END IF
*
      END IF
      RETURN
*
*     End of SLAVSY
*
      END