zqrt12()

double precision function zqrt12	(	integer	M,
		integer	N,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( * )	S,
		complex*16, dimension( lwork )	WORK,
		integer	LWORK,
		double precision, dimension( * )	RWORK
	)

ZQRT12

Purpose:

 ZQRT12 computes the singular values `svlues' of the upper trapezoid
 of A(1:M,1:N) and returns the ratio

      || s - svlues||/(||svlues||*eps*max(M,N))

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A.
[in]	N	N is INTEGER The number of columns of the matrix A.
[in]	A	A is COMPLEX*16 array, dimension (LDA,N) The M-by-N matrix A. Only the upper trapezoid is referenced.
[in]	LDA	LDA is INTEGER The leading dimension of the array A.
[in]	S	S is DOUBLE PRECISION array, dimension (min(M,N)) The singular values of the matrix A.
[out]	WORK	WORK is COMPLEX*16 array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= M*N + 2*min(M,N) + max(M,N).
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (2*min(M,N))

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 99 of file zqrt12.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            lda, lwork, m, n
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   rwork( * ), s( * )
      COMPLEX*16         a( lda, * ), work( lwork )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   zero, one
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, info, iscl, j, mn
      DOUBLE PRECISION   anrm, bignum, nrmsvl, smlnum
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   dummy( 1 )
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   dasum, dlamch, dnrm2, zlange
      EXTERNAL           dasum, dlamch, dnrm2, zlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           daxpy, dbdsqr, dlabad, dlascl, xerbla, zgebd2,
     $                   zlascl, zlaset
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, max, min
*     ..
*     .. Executable Statements ..
*
      zqrt12 = zero
*
*     Test that enough workspace is supplied
*
      IF( lwork.LT.m*n+2*min( m, n )+max( m, n ) ) THEN
         CALL xerbla( 'ZQRT12', 7 )
         RETURN
      END IF
*
*     Quick return if possible
*
      mn = min( m, n )
      IF( mn.LE.zero )
     $   RETURN
*
      nrmsvl = dnrm2( mn, s, 1 )
*
*     Copy upper triangle of A into work
*
      CALL zlaset( 'Full', m, n, dcmplx( zero ), dcmplx( zero ), work,
     $             m )
      DO 20 j = 1, n
         DO 10 i = 1, min( j, m )
            work( ( j-1 )*m+i ) = a( i, j )
   10    CONTINUE
   20 CONTINUE
*
*     Get machine parameters
*
      smlnum = dlamch( 'S' ) / dlamch( 'P' )
      bignum = one / smlnum
      CALL dlabad( smlnum, bignum )
*
*     Scale work if max entry outside range [SMLNUM,BIGNUM]
*
      anrm = zlange( 'M', m, n, work, m, dummy )
      iscl = 0
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL zlascl( 'G', 0, 0, anrm, smlnum, m, n, work, m, info )
         iscl = 1
      ELSE IF( anrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL zlascl( 'G', 0, 0, anrm, bignum, m, n, work, m, info )
         iscl = 1
      END IF
*
      IF( anrm.NE.zero ) THEN
*
*        Compute SVD of work
*
         CALL zgebd2( m, n, work, m, rwork( 1 ), rwork( mn+1 ),
     $                work( m*n+1 ), work( m*n+mn+1 ),
     $                work( m*n+2*mn+1 ), info )
         CALL dbdsqr( 'Upper', mn, 0, 0, 0, rwork( 1 ), rwork( mn+1 ),
     $                dummy, mn, dummy, 1, dummy, mn, rwork( 2*mn+1 ),
     $                info )
*
         IF( iscl.EQ.1 ) THEN
            IF( anrm.GT.bignum ) THEN
               CALL dlascl( 'G', 0, 0, bignum, anrm, mn, 1, rwork( 1 ),
     $                      mn, info )
            END IF
            IF( anrm.LT.smlnum ) THEN
               CALL dlascl( 'G', 0, 0, smlnum, anrm, mn, 1, rwork( 1 ),
     $                      mn, info )
            END IF
         END IF
*
      ELSE
*
         DO 30 i = 1, mn
            rwork( i ) = zero
   30    CONTINUE
      END IF
*
*     Compare s and singular values of work
*
      CALL daxpy( mn, -one, s, 1, rwork( 1 ), 1 )
      zqrt12 = dasum( mn, rwork( 1 ), 1 ) /
     $         ( dlamch( 'Epsilon' )*dble( max( m, n ) ) )
      IF( nrmsvl.NE.zero )
     $   zqrt12 = zqrt12 / nrmsvl
*
      RETURN
*
*     End of ZQRT12
*

Here is the call graph for this function: