sdrvpt.f

Go to the documentation of this file.

*> \brief \b SDRVPT
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SDRVPT( DOTYPE, NN, NVAL, NRHS, THRESH, TSTERR, A, D,
*                          E, B, X, XACT, WORK, RWORK, NOUT )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NN, NOUT, NRHS
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            NVAL( * )
*       REAL               A( * ), B( * ), D( * ), E( * ), RWORK( * ),
*      $                   WORK( * ), X( * ), XACT( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SDRVPT tests SPTSV and -SVX.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix dimension N.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand side vectors to be generated for
*>          each linear system.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[out] A
*> \verbatim
*>          A is REAL array, dimension (NMAX*2)
*> \endverbatim
*>
*> \param[out] D
*> \verbatim
*>          D is REAL array, dimension (NMAX*2)
*> \endverbatim
*>
*> \param[out] E
*> \verbatim
*>          E is REAL array, dimension (NMAX*2)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is REAL array, dimension (NMAX*NRHS)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension
*>                      (NMAX*max(3,NRHS))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension
*>                      (max(NMAX,2*NRHS))
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date December 2016
*
*> \ingroup single_lin
*
*  =====================================================================
      SUBROUTINE sdrvpt( DOTYPE, NN, NVAL, NRHS, THRESH, TSTERR, A, D,
     $                   E, B, X, XACT, WORK, RWORK, NOUT )
*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NN, NOUT, NRHS
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            NVAL( * )
      REAL               A( * ), B( * ), D( * ), E( * ), RWORK( * ),
     $                   work( * ), x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
      INTEGER            NTYPES
      parameter( ntypes = 12 )
      INTEGER            NTESTS
      parameter( ntests = 6 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ZEROT
      CHARACTER          DIST, FACT, TYPE
      CHARACTER*3        PATH
      INTEGER            I, IA, IFACT, IMAT, IN, INFO, IX, IZERO, J, K,
     $                   k1, kl, ku, lda, mode, n, nerrs, nfail, nimat,
     $                   nrun, nt
      REAL               AINVNM, ANORM, COND, DMAX, RCOND, RCONDC
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( ntests ), Z( 3 )
*     ..
*     .. External Functions ..
      INTEGER            ISAMAX
      REAL               SASUM, SGET06, SLANST
      EXTERNAL           isamax, sasum, sget06, slanst
*     ..
*     .. External Subroutines ..
      EXTERNAL           aladhd, alaerh, alasvm, scopy, serrvx, sget04,
     $                   slacpy, slaptm, slarnv, slaset, slatb4, slatms,
     $                   sptsv, sptsvx, sptt01, sptt02, sptt05, spttrf,
     $                   spttrs, sscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, NUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, nunit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseedy / 0, 0, 0, 1 /
*     ..
*     .. Executable Statements ..
*
      path( 1: 1 ) = 'Single precision'
      path( 2: 3 ) = 'PT'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL serrvx( path, nout )
      infot = 0
*
      DO 120 in = 1, nn
*
*        Do for each value of N in NVAL.
*
         n = nval( in )
         lda = max( 1, n )
         nimat = ntypes
         IF( n.LE.0 )
     $      nimat = 1
*
         DO 110 imat = 1, nimat
*
*           Do the tests only if DOTYPE( IMAT ) is true.
*
            IF( n.GT.0 .AND. .NOT.dotype( imat ) )
     $         GO TO 110
*
*           Set up parameters with SLATB4.
*
            CALL slatb4( path, imat, n, n, TYPE, KL, KU, ANORM, MODE,
     $                   cond, dist )
*
            zerot = imat.GE.8 .AND. imat.LE.10
            IF( imat.LE.6 ) THEN
*
*              Type 1-6:  generate a symmetric tridiagonal matrix of
*              known condition number in lower triangular band storage.
*
               srnamt = 'SLATMS'
               CALL slatms( n, n, dist, iseed, TYPE, RWORK, MODE, COND,
     $                      anorm, kl, ku, 'B', a, 2, work, info )
*
*              Check the error code from SLATMS.
*
               IF( info.NE.0 ) THEN
                  CALL alaerh( path, 'SLATMS', info, 0, ' ', n, n, kl,
     $                         ku, -1, imat, nfail, nerrs, nout )
                  GO TO 110
               END IF
               izero = 0
*
*              Copy the matrix to D and E.
*
               ia = 1
               DO 20 i = 1, n - 1
                  d( i ) = a( ia )
                  e( i ) = a( ia+1 )
                  ia = ia + 2
   20          CONTINUE
               IF( n.GT.0 )
     $            d( n ) = a( ia )
            ELSE
*
*              Type 7-12:  generate a diagonally dominant matrix with
*              unknown condition number in the vectors D and E.
*
               IF( .NOT.zerot .OR. .NOT.dotype( 7 ) ) THEN
*
*                 Let D and E have values from [-1,1].
*
                  CALL slarnv( 2, iseed, n, d )
                  CALL slarnv( 2, iseed, n-1, e )
*
*                 Make the tridiagonal matrix diagonally dominant.
*
                  IF( n.EQ.1 ) THEN
                     d( 1 ) = abs( d( 1 ) )
                  ELSE
                     d( 1 ) = abs( d( 1 ) ) + abs( e( 1 ) )
                     d( n ) = abs( d( n ) ) + abs( e( n-1 ) )
                     DO 30 i = 2, n - 1
                        d( i ) = abs( d( i ) ) + abs( e( i ) ) +
     $                           abs( e( i-1 ) )
   30                CONTINUE
                  END IF
*
*                 Scale D and E so the maximum element is ANORM.
*
                  ix = isamax( n, d, 1 )
                  dmax = d( ix )
                  CALL sscal( n, anorm / dmax, d, 1 )
                  IF( n.GT.1 )
     $               CALL sscal( n-1, anorm / dmax, e, 1 )
*
               ELSE IF( izero.GT.0 ) THEN
*
*                 Reuse the last matrix by copying back the zeroed out
*                 elements.
*
                  IF( izero.EQ.1 ) THEN
                     d( 1 ) = z( 2 )
                     IF( n.GT.1 )
     $                  e( 1 ) = z( 3 )
                  ELSE IF( izero.EQ.n ) THEN
                     e( n-1 ) = z( 1 )
                     d( n ) = z( 2 )
                  ELSE
                     e( izero-1 ) = z( 1 )
                     d( izero ) = z( 2 )
                     e( izero ) = z( 3 )
                  END IF
               END IF
*
*              For types 8-10, set one row and column of the matrix to
*              zero.
*
               izero = 0
               IF( imat.EQ.8 ) THEN
                  izero = 1
                  z( 2 ) = d( 1 )
                  d( 1 ) = zero
                  IF( n.GT.1 ) THEN
                     z( 3 ) = e( 1 )
                     e( 1 ) = zero
                  END IF
               ELSE IF( imat.EQ.9 ) THEN
                  izero = n
                  IF( n.GT.1 ) THEN
                     z( 1 ) = e( n-1 )
                     e( n-1 ) = zero
                  END IF
                  z( 2 ) = d( n )
                  d( n ) = zero
               ELSE IF( imat.EQ.10 ) THEN
                  izero = ( n+1 ) / 2
                  IF( izero.GT.1 ) THEN
                     z( 1 ) = e( izero-1 )
                     z( 3 ) = e( izero )
                     e( izero-1 ) = zero
                     e( izero ) = zero
                  END IF
                  z( 2 ) = d( izero )
                  d( izero ) = zero
               END IF
            END IF
*
*           Generate NRHS random solution vectors.
*
            ix = 1
            DO 40 j = 1, nrhs
               CALL slarnv( 2, iseed, n, xact( ix ) )
               ix = ix + lda
   40       CONTINUE
*
*           Set the right hand side.
*
            CALL slaptm( n, nrhs, one, d, e, xact, lda, zero, b, lda )
*
            DO 100 ifact = 1, 2
               IF( ifact.EQ.1 ) THEN
                  fact = 'F'
               ELSE
                  fact = 'N'
               END IF
*
*              Compute the condition number for comparison with
*              the value returned by SPTSVX.
*
               IF( zerot ) THEN
                  IF( ifact.EQ.1 )
     $               GO TO 100
                  rcondc = zero
*
               ELSE IF( ifact.EQ.1 ) THEN
*
*                 Compute the 1-norm of A.
*
                  anorm = slanst( '1', n, d, e )
*
                  CALL scopy( n, d, 1, d( n+1 ), 1 )
                  IF( n.GT.1 )
     $               CALL scopy( n-1, e, 1, e( n+1 ), 1 )
*
*                 Factor the matrix A.
*
                  CALL spttrf( n, d( n+1 ), e( n+1 ), info )
*
*                 Use SPTTRS to solve for one column at a time of
*                 inv(A), computing the maximum column sum as we go.
*
                  ainvnm = zero
                  DO 60 i = 1, n
                     DO 50 j = 1, n
                        x( j ) = zero
   50                CONTINUE
                     x( i ) = one
                     CALL spttrs( n, 1, d( n+1 ), e( n+1 ), x, lda,
     $                            info )
                     ainvnm = max( ainvnm, sasum( n, x, 1 ) )
   60             CONTINUE
*
*                 Compute the 1-norm condition number of A.
*
                  IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                     rcondc = one
                  ELSE
                     rcondc = ( one / anorm ) / ainvnm
                  END IF
               END IF
*
               IF( ifact.EQ.2 ) THEN
*
*                 --- Test SPTSV --
*
                  CALL scopy( n, d, 1, d( n+1 ), 1 )
                  IF( n.GT.1 )
     $               CALL scopy( n-1, e, 1, e( n+1 ), 1 )
                  CALL slacpy( 'Full', n, nrhs, b, lda, x, lda )
*
*                 Factor A as L*D*L' and solve the system A*X = B.
*
                  srnamt = 'SPTSV '
                  CALL sptsv( n, nrhs, d( n+1 ), e( n+1 ), x, lda,
     $                        info )
*
*                 Check error code from SPTSV .
*
                  IF( info.NE.izero )
     $               CALL alaerh( path, 'SPTSV ', info, izero, ' ', n,
     $                            n, 1, 1, nrhs, imat, nfail, nerrs,
     $                            nout )
                  nt = 0
                  IF( izero.EQ.0 ) THEN
*
*                    Check the factorization by computing the ratio
*                       norm(L*D*L' - A) / (n * norm(A) * EPS )
*
                     CALL sptt01( n, d, e, d( n+1 ), e( n+1 ), work,
     $                            result( 1 ) )
*
*                    Compute the residual in the solution.
*
                     CALL slacpy( 'Full', n, nrhs, b, lda, work, lda )
                     CALL sptt02( n, nrhs, d, e, x, lda, work, lda,
     $                            result( 2 ) )
*
*                    Check solution from generated exact solution.
*
                     CALL sget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                            result( 3 ) )
                     nt = 3
                  END IF
*
*                 Print information about the tests that did not pass
*                 the threshold.
*
                  DO 70 k = 1, nt
                     IF( result( k ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL aladhd( nout, path )
                        WRITE( nout, fmt = 9999 )'SPTSV ', n, imat, k,
     $                     result( k )
                        nfail = nfail + 1
                     END IF
   70             CONTINUE
                  nrun = nrun + nt
               END IF
*
*              --- Test SPTSVX ---
*
               IF( ifact.GT.1 ) THEN
*
*                 Initialize D( N+1:2*N ) and E( N+1:2*N ) to zero.
*
                  DO 80 i = 1, n - 1
                     d( n+i ) = zero
                     e( n+i ) = zero
   80             CONTINUE
                  IF( n.GT.0 )
     $               d( n+n ) = zero
               END IF
*
               CALL slaset( 'Full', n, nrhs, zero, zero, x, lda )
*
*              Solve the system and compute the condition number and
*              error bounds using SPTSVX.
*
               srnamt = 'SPTSVX'
               CALL sptsvx( fact, n, nrhs, d, e, d( n+1 ), e( n+1 ), b,
     $                      lda, x, lda, rcond, rwork, rwork( nrhs+1 ),
     $                      work, info )
*
*              Check the error code from SPTSVX.
*
               IF( info.NE.izero )
     $            CALL alaerh( path, 'SPTSVX', info, izero, fact, n, n,
     $                         1, 1, nrhs, imat, nfail, nerrs, nout )
               IF( izero.EQ.0 ) THEN
                  IF( ifact.EQ.2 ) THEN
*
*                    Check the factorization by computing the ratio
*                       norm(L*D*L' - A) / (n * norm(A) * EPS )
*
                     k1 = 1
                     CALL sptt01( n, d, e, d( n+1 ), e( n+1 ), work,
     $                            result( 1 ) )
                  ELSE
                     k1 = 2
                  END IF
*
*                 Compute the residual in the solution.
*
                  CALL slacpy( 'Full', n, nrhs, b, lda, work, lda )
                  CALL sptt02( n, nrhs, d, e, x, lda, work, lda,
     $                         result( 2 ) )
*
*                 Check solution from generated exact solution.
*
                  CALL sget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                         result( 3 ) )
*
*                 Check error bounds from iterative refinement.
*
                  CALL sptt05( n, nrhs, d, e, b, lda, x, lda, xact, lda,
     $                         rwork, rwork( nrhs+1 ), result( 4 ) )
               ELSE
                  k1 = 6
               END IF
*
*              Check the reciprocal of the condition number.
*
               result( 6 ) = sget06( rcond, rcondc )
*
*              Print information about the tests that did not pass
*              the threshold.
*
               DO 90 k = k1, 6
                  IF( result( k ).GE.thresh ) THEN
                     IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                  CALL aladhd( nout, path )
                     WRITE( nout, fmt = 9998 )'SPTSVX', fact, n, imat,
     $                  k, result( k )
                     nfail = nfail + 1
                  END IF
   90          CONTINUE
               nrun = nrun + 7 - k1
  100       CONTINUE
  110    CONTINUE
  120 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasvm( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( 1x, a, ', N =', i5, ', type ', i2, ', test ', i2,
     $      ', ratio = ', g12.5 )
 9998 FORMAT( 1x, a, ', FACT=''', a1, ''', N =', i5, ', type ', i2,
     $      ', test ', i2, ', ratio = ', g12.5 )
      RETURN
*
*     End of SDRVPT
*
      END