cppt01.f

Go to the documentation of this file.

*> \brief \b CPPT01
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CPPT01( UPLO, N, A, AFAC, RWORK, RESID )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            N
*       REAL               RESID
*       ..
*       .. Array Arguments ..
*       REAL               RWORK( * )
*       COMPLEX            A( * ), AFAC( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CPPT01 reconstructs a Hermitian positive definite packed matrix A
*> from its L*L' or U'*U factorization and computes the residual
*>    norm( L*L' - A ) / ( N * norm(A) * EPS ) or
*>    norm( U'*U - A ) / ( N * norm(A) * EPS ),
*> where EPS is the machine epsilon, L' is the conjugate transpose of
*> L, and U' is the conjugate transpose of U.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          Hermitian matrix A is stored:
*>          = 'U':  Upper triangular
*>          = 'L':  Lower triangular
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of rows and columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is COMPLEX array, dimension (N*(N+1)/2)
*>          The original Hermitian matrix A, stored as a packed
*>          triangular matrix.
*> \endverbatim
*>
*> \param[in,out] AFAC
*> \verbatim
*>          AFAC is COMPLEX array, dimension (N*(N+1)/2)
*>          On entry, the factor L or U from the L*L' or U'*U
*>          factorization of A, stored as a packed triangular matrix.
*>          Overwritten with the reconstructed matrix, and then with the
*>          difference L*L' - A (or U'*U - A).
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension (N)
*> \endverbatim
*>
*> \param[out] RESID
*> \verbatim
*>          RESID is REAL
*>          If UPLO = 'L', norm(L*L' - A) / ( N * norm(A) * EPS )
*>          If UPLO = 'U', norm(U'*U - A) / ( N * norm(A) * EPS )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date December 2016
*
*> \ingroup complex_lin
*
*  =====================================================================
      SUBROUTINE cppt01( UPLO, N, A, AFAC, RWORK, RESID )
*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            N
      REAL               RESID
*     ..
*     .. Array Arguments ..
      REAL               RWORK( * )
      COMPLEX            A( * ), AFAC( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, K, KC
      REAL               ANORM, EPS, TR
      COMPLEX            TC
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               CLANHP, SLAMCH
      COMPLEX            CDOTC
      EXTERNAL           lsame, clanhp, slamch, cdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           chpr, cscal, ctpmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          aimag, real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = slamch( 'Epsilon' )
      anorm = clanhp( '1', uplo, n, a, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Check the imaginary parts of the diagonal elements and return with
*     an error code if any are nonzero.
*
      kc = 1
      IF( lsame( uplo, 'U' ) ) THEN
         DO 10 k = 1, n
            IF( aimag( afac( kc ) ).NE.zero ) THEN
               resid = one / eps
               RETURN
            END IF
            kc = kc + k + 1
   10    CONTINUE
      ELSE
         DO 20 k = 1, n
            IF( aimag( afac( kc ) ).NE.zero ) THEN
               resid = one / eps
               RETURN
            END IF
            kc = kc + n - k + 1
   20    CONTINUE
      END IF
*
*     Compute the product U'*U, overwriting U.
*
      IF( lsame( uplo, 'U' ) ) THEN
         kc = ( n*( n-1 ) ) / 2 + 1
         DO 30 k = n, 1, -1
*
*           Compute the (K,K) element of the result.
*
            tr = cdotc( k, afac( kc ), 1, afac( kc ), 1 )
            afac( kc+k-1 ) = tr
*
*           Compute the rest of column K.
*
            IF( k.GT.1 ) THEN
               CALL ctpmv( 'Upper', 'Conjugate', 'Non-unit', k-1, afac,
     $                     afac( kc ), 1 )
               kc = kc - ( k-1 )
            END IF
   30    CONTINUE
*
*        Compute the difference  L*L' - A
*
         kc = 1
         DO 50 k = 1, n
            DO 40 i = 1, k - 1
               afac( kc+i-1 ) = afac( kc+i-1 ) - a( kc+i-1 )
   40       CONTINUE
            afac( kc+k-1 ) = afac( kc+k-1 ) - REAL( A( KC+K-1 ) )
            kc = kc + k
   50    CONTINUE
*
*     Compute the product L*L', overwriting L.
*
      ELSE
         kc = ( n*( n+1 ) ) / 2
         DO 60 k = n, 1, -1
*
*           Add a multiple of column K of the factor L to each of
*           columns K+1 through N.
*
            IF( k.LT.n )
     $         CALL chpr( 'Lower', n-k, one, afac( kc+1 ), 1,
     $                    afac( kc+n-k+1 ) )
*
*           Scale column K by the diagonal element.
*
            tc = afac( kc )
            CALL cscal( n-k+1, tc, afac( kc ), 1 )
*
            kc = kc - ( n-k+2 )
   60    CONTINUE
*
*        Compute the difference  U'*U - A
*
         kc = 1
         DO 80 k = 1, n
            afac( kc ) = afac( kc ) - REAL( A( KC ) )
            DO 70 i = k + 1, n
               afac( kc+i-k ) = afac( kc+i-k ) - a( kc+i-k )
   70       CONTINUE
            kc = kc + n - k + 1
   80    CONTINUE
      END IF
*
*     Compute norm( L*U - A ) / ( N * norm(A) * EPS )
*
      resid = clanhp( '1', uplo, n, afac, rwork )
*
      resid = ( ( resid / REAL( N ) ) / anorm ) / eps
*
      RETURN
*
*     End of CPPT01
*
      END