schktb.f

Go to the documentation of this file.

*> \brief \b SCHKTB
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SCHKTB( DOTYPE, NN, NVAL, NNS, NSVAL, THRESH, TSTERR,
*                          NMAX, AB, AINV, B, X, XACT, WORK, RWORK, IWORK,
*                          NOUT )
*
*       .. Scalar Arguments ..
*       LOGICAL            TSTERR
*       INTEGER            NMAX, NN, NNS, NOUT
*       REAL               THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            IWORK( * ), NSVAL( * ), NVAL( * )
*       REAL               AB( * ), AINV( * ), B( * ), RWORK( * ),
*      $                   WORK( * ), X( * ), XACT( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SCHKTB tests STBTRS, -RFS, and -CON, and SLATBS.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          The matrix types to be used for testing.  Matrices of type j
*>          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
*>          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER
*>          The number of values of N contained in the vector NVAL.
*> \endverbatim
*>
*> \param[in] NVAL
*> \verbatim
*>          NVAL is INTEGER array, dimension (NN)
*>          The values of the matrix column dimension N.
*> \endverbatim
*>
*> \param[in] NNS
*> \verbatim
*>          NNS is INTEGER
*>          The number of values of NRHS contained in the vector NSVAL.
*> \endverbatim
*>
*> \param[in] NSVAL
*> \verbatim
*>          NSVAL is INTEGER array, dimension (NNS)
*>          The values of the number of right hand sides NRHS.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is REAL
*>          The threshold value for the test ratios.  A result is
*>          included in the output file if RESULT >= THRESH.  To have
*>          every test ratio printed, use THRESH = 0.
*> \endverbatim
*>
*> \param[in] TSTERR
*> \verbatim
*>          TSTERR is LOGICAL
*>          Flag that indicates whether error exits are to be tested.
*> \endverbatim
*>
*> \param[in] NMAX
*> \verbatim
*>          NMAX is INTEGER
*>          The leading dimension of the work arrays.
*>          NMAX >= the maximum value of N in NVAL.
*> \endverbatim
*>
*> \param[out] AB
*> \verbatim
*>          AB is REAL array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] AINV
*> \verbatim
*>          AINV is REAL array, dimension (NMAX*NMAX)
*> \endverbatim
*>
*> \param[out] B
*> \verbatim
*>          B is REAL array, dimension (NMAX*NSMAX)
*>          where NSMAX is the largest entry in NSVAL.
*> \endverbatim
*>
*> \param[out] X
*> \verbatim
*>          X is REAL array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] XACT
*> \verbatim
*>          XACT is REAL array, dimension (NMAX*NSMAX)
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension
*>                      (NMAX*max(3,NSMAX))
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is REAL array, dimension
*>                      (max(NMAX,2*NSMAX))
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (NMAX)
*> \endverbatim
*>
*> \param[in] NOUT
*> \verbatim
*>          NOUT is INTEGER
*>          The unit number for output.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date December 2016
*
*> \ingroup single_lin
*
*  =====================================================================
      SUBROUTINE schktb( DOTYPE, NN, NVAL, NNS, NSVAL, THRESH, TSTERR,
     $                   NMAX, AB, AINV, B, X, XACT, WORK, RWORK, IWORK,
     $                   NOUT )
*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      LOGICAL            TSTERR
      INTEGER            NMAX, NN, NNS, NOUT
      REAL               THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            IWORK( * ), NSVAL( * ), NVAL( * )
      REAL               AB( * ), AINV( * ), B( * ), RWORK( * ),
     $                   work( * ), x( * ), xact( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      INTEGER            NTYPE1, NTYPES
      parameter( ntype1 = 9, ntypes = 17 )
      INTEGER            NTESTS
      parameter( ntests = 8 )
      INTEGER            NTRAN
      parameter( ntran = 3 )
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      CHARACTER          DIAG, NORM, TRANS, UPLO, XTYPE
      CHARACTER*3        PATH
      INTEGER            I, IDIAG, IK, IMAT, IN, INFO, IRHS, ITRAN,
     $                   iuplo, j, k, kd, lda, ldab, n, nerrs, nfail,
     $                   nimat, nimat2, nk, nrhs, nrun
      REAL               AINVNM, ANORM, RCOND, RCONDC, RCONDI, RCONDO,
     $                   scale
*     ..
*     .. Local Arrays ..
      CHARACTER          TRANSS( ntran ), UPLOS( 2 )
      INTEGER            ISEED( 4 ), ISEEDY( 4 )
      REAL               RESULT( ntests )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLANTB, SLANTR
      EXTERNAL           lsame, slantb, slantr
*     ..
*     .. External Subroutines ..
      EXTERNAL           alaerh, alahd, alasum, scopy, serrtr, sget04,
     $                   slacpy, slarhs, slaset, slatbs, slattb, stbcon,
     $                   stbrfs, stbsv, stbt02, stbt03, stbt05, stbt06,
     $                   stbtrs
*     ..
*     .. Scalars in Common ..
      LOGICAL            LERR, OK
      CHARACTER*32       SRNAMT
      INTEGER            INFOT, IOUNIT
*     ..
*     .. Common blocks ..
      COMMON             / infoc / infot, iounit, ok, lerr
      COMMON             / srnamc / srnamt
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Data statements ..
      DATA               iseedy / 1988, 1989, 1990, 1991 /
      DATA               uplos / 'U', 'L' / , transs / 'N', 'T', 'C' /
*     ..
*     .. Executable Statements ..
*
*     Initialize constants and the random number seed.
*
      path( 1: 1 ) = 'Single precision'
      path( 2: 3 ) = 'TB'
      nrun = 0
      nfail = 0
      nerrs = 0
      DO 10 i = 1, 4
         iseed( i ) = iseedy( i )
   10 CONTINUE
*
*     Test the error exits
*
      IF( tsterr )
     $   CALL serrtr( path, nout )
      infot = 0
*
      DO 140 in = 1, nn
*
*        Do for each value of N in NVAL
*
         n = nval( in )
         lda = max( 1, n )
         xtype = 'N'
         nimat = ntype1
         nimat2 = ntypes
         IF( n.LE.0 ) THEN
            nimat = 1
            nimat2 = ntype1 + 1
         END IF
*
         nk = min( n+1, 4 )
         DO 130 ik = 1, nk
*
*           Do for KD = 0, N, (3N-1)/4, and (N+1)/4. This order makes
*           it easier to skip redundant values for small values of N.
*
            IF( ik.EQ.1 ) THEN
               kd = 0
            ELSE IF( ik.EQ.2 ) THEN
               kd = max( n, 0 )
            ELSE IF( ik.EQ.3 ) THEN
               kd = ( 3*n-1 ) / 4
            ELSE IF( ik.EQ.4 ) THEN
               kd = ( n+1 ) / 4
            END IF
            ldab = kd + 1
*
            DO 90 imat = 1, nimat
*
*              Do the tests only if DOTYPE( IMAT ) is true.
*
               IF( .NOT.dotype( imat ) )
     $            GO TO 90
*
               DO 80 iuplo = 1, 2
*
*                 Do first for UPLO = 'U', then for UPLO = 'L'
*
                  uplo = uplos( iuplo )
*
*                 Call SLATTB to generate a triangular test matrix.
*
                  srnamt = 'SLATTB'
                  CALL slattb( imat, uplo, 'No transpose', diag, iseed,
     $                         n, kd, ab, ldab, x, work, info )
*
*                 Set IDIAG = 1 for non-unit matrices, 2 for unit.
*
                  IF( lsame( diag, 'N' ) ) THEN
                     idiag = 1
                  ELSE
                     idiag = 2
                  END IF
*
*                 Form the inverse of A so we can get a good estimate
*                 of RCONDC = 1/(norm(A) * norm(inv(A))).
*
                  CALL slaset( 'Full', n, n, zero, one, ainv, lda )
                  IF( lsame( uplo, 'U' ) ) THEN
                     DO 20 j = 1, n
                        CALL stbsv( uplo, 'No transpose', diag, j, kd,
     $                              ab, ldab, ainv( ( j-1 )*lda+1 ), 1 )
   20                CONTINUE
                  ELSE
                     DO 30 j = 1, n
                        CALL stbsv( uplo, 'No transpose', diag, n-j+1,
     $                              kd, ab( ( j-1 )*ldab+1 ), ldab,
     $                              ainv( ( j-1 )*lda+j ), 1 )
   30                CONTINUE
                  END IF
*
*                 Compute the 1-norm condition number of A.
*
                  anorm = slantb( '1', uplo, diag, n, kd, ab, ldab,
     $                    rwork )
                  ainvnm = slantr( '1', uplo, diag, n, n, ainv, lda,
     $                     rwork )
                  IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                     rcondo = one
                  ELSE
                     rcondo = ( one / anorm ) / ainvnm
                  END IF
*
*                 Compute the infinity-norm condition number of A.
*
                  anorm = slantb( 'I', uplo, diag, n, kd, ab, ldab,
     $                    rwork )
                  ainvnm = slantr( 'I', uplo, diag, n, n, ainv, lda,
     $                     rwork )
                  IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
                     rcondi = one
                  ELSE
                     rcondi = ( one / anorm ) / ainvnm
                  END IF
*
                  DO 60 irhs = 1, nns
                     nrhs = nsval( irhs )
                     xtype = 'N'
*
                     DO 50 itran = 1, ntran
*
*                    Do for op(A) = A, A**T, or A**H.
*
                        trans = transs( itran )
                        IF( itran.EQ.1 ) THEN
                           norm = 'O'
                           rcondc = rcondo
                        ELSE
                           norm = 'I'
                           rcondc = rcondi
                        END IF
*
*+    TEST 1
*                    Solve and compute residual for op(A)*x = b.
*
                        srnamt = 'SLARHS'
                        CALL slarhs( path, xtype, uplo, trans, n, n, kd,
     $                               idiag, nrhs, ab, ldab, xact, lda,
     $                               b, lda, iseed, info )
                        xtype = 'C'
                        CALL slacpy( 'Full', n, nrhs, b, lda, x, lda )
*
                        srnamt = 'STBTRS'
                        CALL stbtrs( uplo, trans, diag, n, kd, nrhs, ab,
     $                               ldab, x, lda, info )
*
*                    Check error code from STBTRS.
*
                        IF( info.NE.0 )
     $                     CALL alaerh( path, 'STBTRS', info, 0,
     $                                  uplo // trans // diag, n, n, kd,
     $                                  kd, nrhs, imat, nfail, nerrs,
     $                                  nout )
*
                        CALL stbt02( uplo, trans, diag, n, kd, nrhs, ab,
     $                               ldab, x, lda, b, lda, work,
     $                               result( 1 ) )
*
*+    TEST 2
*                    Check solution from generated exact solution.
*
                        CALL sget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 2 ) )
*
*+    TESTS 3, 4, and 5
*                    Use iterative refinement to improve the solution
*                    and compute error bounds.
*
                        srnamt = 'STBRFS'
                        CALL stbrfs( uplo, trans, diag, n, kd, nrhs, ab,
     $                               ldab, b, lda, x, lda, rwork,
     $                               rwork( nrhs+1 ), work, iwork,
     $                               info )
*
*                    Check error code from STBRFS.
*
                        IF( info.NE.0 )
     $                     CALL alaerh( path, 'STBRFS', info, 0,
     $                                  uplo // trans // diag, n, n, kd,
     $                                  kd, nrhs, imat, nfail, nerrs,
     $                                  nout )
*
                        CALL sget04( n, nrhs, x, lda, xact, lda, rcondc,
     $                               result( 3 ) )
                        CALL stbt05( uplo, trans, diag, n, kd, nrhs, ab,
     $                               ldab, b, lda, x, lda, xact, lda,
     $                               rwork, rwork( nrhs+1 ),
     $                               result( 4 ) )
*
*                       Print information about the tests that did not
*                       pass the threshold.
*
                        DO 40 k = 1, 5
                           IF( result( k ).GE.thresh ) THEN
                              IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                           CALL alahd( nout, path )
                              WRITE( nout, fmt = 9999 )uplo, trans,
     $                           diag, n, kd, nrhs, imat, k, result( k )
                              nfail = nfail + 1
                           END IF
   40                   CONTINUE
                        nrun = nrun + 5
   50                CONTINUE
   60             CONTINUE
*
*+    TEST 6
*                    Get an estimate of RCOND = 1/CNDNUM.
*
                  DO 70 itran = 1, 2
                     IF( itran.EQ.1 ) THEN
                        norm = 'O'
                        rcondc = rcondo
                     ELSE
                        norm = 'I'
                        rcondc = rcondi
                     END IF
                     srnamt = 'STBCON'
                     CALL stbcon( norm, uplo, diag, n, kd, ab, ldab,
     $                            rcond, work, iwork, info )
*
*                    Check error code from STBCON.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'STBCON', info, 0,
     $                               norm // uplo // diag, n, n, kd, kd,
     $                               -1, imat, nfail, nerrs, nout )
*
                     CALL stbt06( rcond, rcondc, uplo, diag, n, kd, ab,
     $                            ldab, rwork, result( 6 ) )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     IF( result( 6 ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9998 ) 'STBCON', norm, uplo,
     $                     diag, n, kd, imat, 6, result( 6 )
                        nfail = nfail + 1
                     END IF
                     nrun = nrun + 1
   70             CONTINUE
   80          CONTINUE
   90       CONTINUE
*
*           Use pathological test matrices to test SLATBS.
*
            DO 120 imat = ntype1 + 1, nimat2
*
*              Do the tests only if DOTYPE( IMAT ) is true.
*
               IF( .NOT.dotype( imat ) )
     $            GO TO 120
*
               DO 110 iuplo = 1, 2
*
*                 Do first for UPLO = 'U', then for UPLO = 'L'
*
                  uplo = uplos( iuplo )
                  DO 100 itran = 1, ntran
*
*                    Do for op(A) = A, A**T, and A**H.
*
                     trans = transs( itran )
*
*                    Call SLATTB to generate a triangular test matrix.
*
                     srnamt = 'SLATTB'
                     CALL slattb( imat, uplo, trans, diag, iseed, n, kd,
     $                            ab, ldab, x, work, info )
*
*+    TEST 7
*                    Solve the system op(A)*x = b
*
                     srnamt = 'SLATBS'
                     CALL scopy( n, x, 1, b, 1 )
                     CALL slatbs( uplo, trans, diag, 'N', n, kd, ab,
     $                            ldab, b, scale, rwork, info )
*
*                    Check error code from SLATBS.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'SLATBS', info, 0,
     $                               uplo // trans // diag // 'N', n, n,
     $                               kd, kd, -1, imat, nfail, nerrs,
     $                               nout )
*
                     CALL stbt03( uplo, trans, diag, n, kd, 1, ab, ldab,
     $                            scale, rwork, one, b, lda, x, lda,
     $                            work, result( 7 ) )
*
*+    TEST 8
*                    Solve op(A)*x = b again with NORMIN = 'Y'.
*
                     CALL scopy( n, x, 1, b, 1 )
                     CALL slatbs( uplo, trans, diag, 'Y', n, kd, ab,
     $                            ldab, b, scale, rwork, info )
*
*                    Check error code from SLATBS.
*
                     IF( info.NE.0 )
     $                  CALL alaerh( path, 'SLATBS', info, 0,
     $                               uplo // trans // diag // 'Y', n, n,
     $                               kd, kd, -1, imat, nfail, nerrs,
     $                               nout )
*
                     CALL stbt03( uplo, trans, diag, n, kd, 1, ab, ldab,
     $                            scale, rwork, one, b, lda, x, lda,
     $                            work, result( 8 ) )
*
*                    Print information about the tests that did not pass
*                    the threshold.
*
                     IF( result( 7 ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9997 )'SLATBS', uplo, trans,
     $                     diag, 'N', n, kd, imat, 7, result( 7 )
                        nfail = nfail + 1
                     END IF
                     IF( result( 8 ).GE.thresh ) THEN
                        IF( nfail.EQ.0 .AND. nerrs.EQ.0 )
     $                     CALL alahd( nout, path )
                        WRITE( nout, fmt = 9997 )'SLATBS', uplo, trans,
     $                     diag, 'Y', n, kd, imat, 8, result( 8 )
                        nfail = nfail + 1
                     END IF
                     nrun = nrun + 2
  100             CONTINUE
  110          CONTINUE
  120       CONTINUE
  130    CONTINUE
  140 CONTINUE
*
*     Print a summary of the results.
*
      CALL alasum( path, nout, nfail, nrun, nerrs )
*
 9999 FORMAT( ' UPLO=''', a1, ''', TRANS=''', a1, ''',
     $      DIAG=''', a1, ''', N=', i5, ', KD=', i5, ', NRHS=', i5,
     $      ', type ', i2, ', test(', i2, ')=', g12.5 )
 9998 FORMAT( 1x, a, '( ''', a1, ''', ''', a1, ''', ''', a1, ''',',
     $      i5, ',', i5, ',  ... ), type ', i2, ', test(', i2, ')=',
     $      g12.5 )
 9997 FORMAT( 1x, a, '( ''', a1, ''', ''', a1, ''', ''', a1, ''', ''',
     $      a1, ''',', i5, ',', i5, ', ...  ),  type ', i2, ', test(',
     $      i1, ')=', g12.5 )
      RETURN
*
*     End of SCHKTB
*
      END