LAPACK  3.7.1
LAPACK: Linear Algebra PACKage
dlamtsqr.f
Go to the documentation of this file.
1 *
2 * Definition:
3 * ===========
4 *
5 * SUBROUTINE DLAMTSQR( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T,
6 * $ LDT, C, LDC, WORK, LWORK, INFO )
7 *
8 *
9 * .. Scalar Arguments ..
10 * CHARACTER SIDE, TRANS
11 * INTEGER INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
12 * ..
13 * .. Array Arguments ..
14 * DOUBLE A( LDA, * ), WORK( * ), C(LDC, * ),
15 * $ T( LDT, * )
16 *> \par Purpose:
17 * =============
18 *>
19 *> \verbatim
20 *>
21 *> DLAMTSQR overwrites the general real M-by-N matrix C with
22 *>
23 *>
24 *> SIDE = 'L' SIDE = 'R'
25 *> TRANS = 'N': Q * C C * Q
26 *> TRANS = 'T': Q**T * C C * Q**T
27 *> where Q is a real orthogonal matrix defined as the product
28 *> of blocked elementary reflectors computed by tall skinny
29 *> QR factorization (DLATSQR)
30 *> \endverbatim
31 *
32 * Arguments:
33 * ==========
34 *
35 *> \param[in] SIDE
36 *> \verbatim
37 *> SIDE is CHARACTER*1
38 *> = 'L': apply Q or Q**T from the Left;
39 *> = 'R': apply Q or Q**T from the Right.
40 *> \endverbatim
41 *>
42 *> \param[in] TRANS
43 *> \verbatim
44 *> TRANS is CHARACTER*1
45 *> = 'N': No transpose, apply Q;
46 *> = 'T': Transpose, apply Q**T.
47 *> \endverbatim
48 *>
49 *> \param[in] M
50 *> \verbatim
51 *> M is INTEGER
52 *> The number of rows of the matrix A. M >=0.
53 *> \endverbatim
54 *>
55 *> \param[in] N
56 *> \verbatim
57 *> N is INTEGER
58 *> The number of columns of the matrix C. M >= N >= 0.
59 *> \endverbatim
60 *>
61 *> \param[in] K
62 *> \verbatim
63 *> K is INTEGER
64 *> The number of elementary reflectors whose product defines
65 *> the matrix Q.
66 *> N >= K >= 0;
67 *>
68 *> \endverbatim
69 *>
70 *> \param[in] MB
71 *> \verbatim
72 *> MB is INTEGER
73 *> The block size to be used in the blocked QR.
74 *> MB > N. (must be the same as DLATSQR)
75 *> \endverbatim
76 *>
77 *> \param[in] NB
78 *> \verbatim
79 *> NB is INTEGER
80 *> The column block size to be used in the blocked QR.
81 *> N >= NB >= 1.
82 *> \endverbatim
83 *>
84 *> \param[in] A
85 *> \verbatim
86 *> A is DOUBLE PRECISION array, dimension (LDA,K)
87 *> The i-th column must contain the vector which defines the
88 *> blockedelementary reflector H(i), for i = 1,2,...,k, as
89 *> returned by DLATSQR in the first k columns of
90 *> its array argument A.
91 *> \endverbatim
92 *>
93 *> \param[in] LDA
94 *> \verbatim
95 *> LDA is INTEGER
96 *> The leading dimension of the array A.
97 *> If SIDE = 'L', LDA >= max(1,M);
98 *> if SIDE = 'R', LDA >= max(1,N).
99 *> \endverbatim
100 *>
101 *> \param[in] T
102 *> \verbatim
103 *> T is DOUBLE PRECISION array, dimension
104 *> ( N * Number of blocks(CEIL(M-K/MB-K)),
105 *> The blocked upper triangular block reflectors stored in compact form
106 *> as a sequence of upper triangular blocks. See below
107 *> for further details.
108 *> \endverbatim
109 *>
110 *> \param[in] LDT
111 *> \verbatim
112 *> LDT is INTEGER
113 *> The leading dimension of the array T. LDT >= NB.
114 *> \endverbatim
115 *>
116 *> \param[in,out] C
117 *> \verbatim
118 *> C is DOUBLE PRECISION array, dimension (LDC,N)
119 *> On entry, the M-by-N matrix C.
120 *> On exit, C is overwritten by Q*C or Q**T*C or C*Q**T or C*Q.
121 *> \endverbatim
122 *>
123 *> \param[in] LDC
124 *> \verbatim
125 *> LDC is INTEGER
126 *> The leading dimension of the array C. LDC >= max(1,M).
127 *> \endverbatim
128 *>
129 *> \param[out] WORK
130 *> \verbatim
131 *> (workspace) DOUBLE PRECISION array, dimension (MAX(1,LWORK))
132 *>
133 *> \endverbatim
134 *> \param[in] LWORK
135 *> \verbatim
136 *> LWORK is INTEGER
137 *> The dimension of the array WORK.
138 *>
139 *> If SIDE = 'L', LWORK >= max(1,N)*NB;
140 *> if SIDE = 'R', LWORK >= max(1,MB)*NB.
141 *> If LWORK = -1, then a workspace query is assumed; the routine
142 *> only calculates the optimal size of the WORK array, returns
143 *> this value as the first entry of the WORK array, and no error
144 *> message related to LWORK is issued by XERBLA.
145 *>
146 *> \endverbatim
147 *> \param[out] INFO
148 *> \verbatim
149 *> INFO is INTEGER
150 *> = 0: successful exit
151 *> < 0: if INFO = -i, the i-th argument had an illegal value
152 *> \endverbatim
153 *
154 * Authors:
155 * ========
156 *
157 *> \author Univ. of Tennessee
158 *> \author Univ. of California Berkeley
159 *> \author Univ. of Colorado Denver
160 *> \author NAG Ltd.
161 *
162 *> \par Further Details:
163 * =====================
164 *>
165 *> \verbatim
166 *> Tall-Skinny QR (TSQR) performs QR by a sequence of orthogonal transformations,
167 *> representing Q as a product of other orthogonal matrices
168 *> Q = Q(1) * Q(2) * . . . * Q(k)
169 *> where each Q(i) zeros out subdiagonal entries of a block of MB rows of A:
170 *> Q(1) zeros out the subdiagonal entries of rows 1:MB of A
171 *> Q(2) zeros out the bottom MB-N rows of rows [1:N,MB+1:2*MB-N] of A
172 *> Q(3) zeros out the bottom MB-N rows of rows [1:N,2*MB-N+1:3*MB-2*N] of A
173 *> . . .
174 *>
175 *> Q(1) is computed by GEQRT, which represents Q(1) by Householder vectors
176 *> stored under the diagonal of rows 1:MB of A, and by upper triangular
177 *> block reflectors, stored in array T(1:LDT,1:N).
178 *> For more information see Further Details in GEQRT.
179 *>
180 *> Q(i) for i>1 is computed by TPQRT, which represents Q(i) by Householder vectors
181 *> stored in rows [(i-1)*(MB-N)+N+1:i*(MB-N)+N] of A, and by upper triangular
182 *> block reflectors, stored in array T(1:LDT,(i-1)*N+1:i*N).
183 *> The last Q(k) may use fewer rows.
184 *> For more information see Further Details in TPQRT.
185 *>
186 *> For more details of the overall algorithm, see the description of
187 *> Sequential TSQR in Section 2.2 of [1].
188 *>
189 *> [1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,”
190 *> J. Demmel, L. Grigori, M. Hoemmen, J. Langou,
191 *> SIAM J. Sci. Comput, vol. 34, no. 1, 2012
192 *> \endverbatim
193 *>
194 * =====================================================================
195  SUBROUTINE dlamtsqr( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T,
196  $ LDT, C, LDC, WORK, LWORK, INFO )
197 *
198 * -- LAPACK computational routine (version 3.7.1) --
199 * -- LAPACK is a software package provided by Univ. of Tennessee, --
200 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
201 * June 2017
202 *
203 * .. Scalar Arguments ..
204  CHARACTER SIDE, TRANS
205  INTEGER INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
206 * ..
207 * .. Array Arguments ..
208  DOUBLE PRECISION A( lda, * ), WORK( * ), C(ldc, * ),
209  $ t( ldt, * )
210 * ..
211 *
212 * =====================================================================
213 *
214 * ..
215 * .. Local Scalars ..
216  LOGICAL LEFT, RIGHT, TRAN, NOTRAN, LQUERY
217  INTEGER I, II, KK, LW, CTR
218 * ..
219 * .. External Functions ..
220  LOGICAL LSAME
221  EXTERNAL lsame
222 * .. External Subroutines ..
223  EXTERNAL dgemqrt, dtpmqrt, xerbla
224 * ..
225 * .. Executable Statements ..
226 *
227 * Test the input arguments
228 *
229  lquery = lwork.LT.0
230  notran = lsame( trans, 'N' )
231  tran = lsame( trans, 'T' )
232  left = lsame( side, 'L' )
233  right = lsame( side, 'R' )
234  IF (left) THEN
235  lw = n * nb
236  ELSE
237  lw = mb * nb
238  END IF
239 *
240  info = 0
241  IF( .NOT.left .AND. .NOT.right ) THEN
242  info = -1
243  ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
244  info = -2
245  ELSE IF( m.LT.0 ) THEN
246  info = -3
247  ELSE IF( n.LT.0 ) THEN
248  info = -4
249  ELSE IF( k.LT.0 ) THEN
250  info = -5
251  ELSE IF( lda.LT.max( 1, k ) ) THEN
252  info = -9
253  ELSE IF( ldt.LT.max( 1, nb) ) THEN
254  info = -11
255  ELSE IF( ldc.LT.max( 1, m ) ) THEN
256  info = -13
257  ELSE IF(( lwork.LT.max(1,lw)).AND.(.NOT.lquery)) THEN
258  info = -15
259  END IF
260 *
261 * Determine the block size if it is tall skinny or short and wide
262 *
263  IF( info.EQ.0) THEN
264  work(1) = lw
265  END IF
266 *
267  IF( info.NE.0 ) THEN
268  CALL xerbla( 'DLAMTSQR', -info )
269  RETURN
270  ELSE IF (lquery) THEN
271  RETURN
272  END IF
273 *
274 * Quick return if possible
275 *
276  IF( min(m,n,k).EQ.0 ) THEN
277  RETURN
278  END IF
279 *
280  IF((mb.LE.k).OR.(mb.GE.max(m,n,k))) THEN
281  CALL dgemqrt( side, trans, m, n, k, nb, a, lda,
282  $ t, ldt, c, ldc, work, info)
283  RETURN
284  END IF
285 *
286  IF(left.AND.notran) THEN
287 *
288 * Multiply Q to the last block of C
289 *
290  kk = mod((m-k),(mb-k))
291  ctr = (m-k)/(mb-k)
292  IF (kk.GT.0) THEN
293  ii=m-kk+1
294  CALL dtpmqrt('L','N',kk , n, k, 0, nb, a(ii,1), lda,
295  $ t(1,ctr*k+1),ldt , c(1,1), ldc,
296  $ c(ii,1), ldc, work, info )
297  ELSE
298  ii=m+1
299  END IF
300 *
301  DO i=ii-(mb-k),mb+1,-(mb-k)
302 *
303 * Multiply Q to the current block of C (I:I+MB,1:N)
304 *
305  ctr = ctr - 1
306  CALL dtpmqrt('L','N',mb-k , n, k, 0,nb, a(i,1), lda,
307  $ t(1,ctr*k+1),ldt, c(1,1), ldc,
308  $ c(i,1), ldc, work, info )
309 *
310  END DO
311 *
312 * Multiply Q to the first block of C (1:MB,1:N)
313 *
314  CALL dgemqrt('L','N',mb , n, k, nb, a(1,1), lda, t
315  $ ,ldt ,c(1,1), ldc, work, info )
316 *
317  ELSE IF (left.AND.tran) THEN
318 *
319 * Multiply Q to the first block of C
320 *
321  kk = mod((m-k),(mb-k))
322  ii=m-kk+1
323  ctr = 1
324  CALL dgemqrt('L','T',mb , n, k, nb, a(1,1), lda, t
325  $ ,ldt ,c(1,1), ldc, work, info )
326 *
327  DO i=mb+1,ii-mb+k,(mb-k)
328 *
329 * Multiply Q to the current block of C (I:I+MB,1:N)
330 *
331  CALL dtpmqrt('L','T',mb-k , n, k, 0,nb, a(i,1), lda,
332  $ t(1,ctr * k + 1),ldt, c(1,1), ldc,
333  $ c(i,1), ldc, work, info )
334  ctr = ctr + 1
335 *
336  END DO
337  IF(ii.LE.m) THEN
338 *
339 * Multiply Q to the last block of C
340 *
341  CALL dtpmqrt('L','T',kk , n, k, 0,nb, a(ii,1), lda,
342  $ t(1,ctr * k + 1), ldt, c(1,1), ldc,
343  $ c(ii,1), ldc, work, info )
344 *
345  END IF
346 *
347  ELSE IF(right.AND.tran) THEN
348 *
349 * Multiply Q to the last block of C
350 *
351  kk = mod((n-k),(mb-k))
352  ctr = (n-k)/(mb-k)
353  IF (kk.GT.0) THEN
354  ii=n-kk+1
355  CALL dtpmqrt('R','T',m , kk, k, 0, nb, a(ii,1), lda,
356  $ t(1,ctr*k+1), ldt, c(1,1), ldc,
357  $ c(1,ii), ldc, work, info )
358  ELSE
359  ii=n+1
360  END IF
361 *
362  DO i=ii-(mb-k),mb+1,-(mb-k)
363 *
364 * Multiply Q to the current block of C (1:M,I:I+MB)
365 *
366  ctr = ctr - 1
367  CALL dtpmqrt('R','T',m , mb-k, k, 0,nb, a(i,1), lda,
368  $ t(1,ctr*k+1), ldt, c(1,1), ldc,
369  $ c(1,i), ldc, work, info )
370 *
371  END DO
372 *
373 * Multiply Q to the first block of C (1:M,1:MB)
374 *
375  CALL dgemqrt('R','T',m , mb, k, nb, a(1,1), lda, t
376  $ ,ldt ,c(1,1), ldc, work, info )
377 *
378  ELSE IF (right.AND.notran) THEN
379 *
380 * Multiply Q to the first block of C
381 *
382  kk = mod((n-k),(mb-k))
383  ii=n-kk+1
384  ctr = 1
385  CALL dgemqrt('R','N', m, mb , k, nb, a(1,1), lda, t
386  $ ,ldt ,c(1,1), ldc, work, info )
387 *
388  DO i=mb+1,ii-mb+k,(mb-k)
389 *
390 * Multiply Q to the current block of C (1:M,I:I+MB)
391 *
392  CALL dtpmqrt('R','N', m, mb-k, k, 0,nb, a(i,1), lda,
393  $ t(1, ctr * k + 1),ldt, c(1,1), ldc,
394  $ c(1,i), ldc, work, info )
395  ctr = ctr + 1
396 *
397  END DO
398  IF(ii.LE.n) THEN
399 *
400 * Multiply Q to the last block of C
401 *
402  CALL dtpmqrt('R','N', m, kk , k, 0,nb, a(ii,1), lda,
403  $ t(1, ctr * k + 1),ldt, c(1,1), ldc,
404  $ c(1,ii), ldc, work, info )
405 *
406  END IF
407 *
408  END IF
409 *
410  work(1) = lw
411  RETURN
412 *
413 * End of DLAMTSQR
414 *
415  END
dtpmqrt
subroutine dtpmqrt(SIDE, TRANS, M, N, K, L, NB, V, LDV, T, LDT, A, LDA, B, LDB, WORK, INFO)
DTPMQRT
Definition: dtpmqrt.f:218
dlamtsqr
subroutine dlamtsqr(SIDE, TRANS, M, N, K, MB, NB, A, LDA, T, LDT, C, LDC, WORK, LWORK, INFO)
Definition: dlamtsqr.f:197
dgemqrt
subroutine dgemqrt(SIDE, TRANS, M, N, K, NB, V, LDV, T, LDT, C, LDC, WORK, INFO)
DGEMQRT
Definition: dgemqrt.f:170
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62