sgelqt3.f

Go to the documentation of this file.

*  Definition:
*  ===========
*
*       RECURSIVE SUBROUTINE SGELQT3( M, N, A, LDA, T, LDT, INFO )
*
*       .. Scalar Arguments ..
*       INTEGER   INFO, LDA, M, N, LDT
*       ..
*       .. Array Arguments ..
*       REAL   A( LDA, * ), T( LDT, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> DGELQT3 recursively computes a LQ factorization of a real M-by-N
*> matrix A, using the compact WY representation of Q.
*>
*> Based on the algorithm of Elmroth and Gustavson,
*> IBM J. Res. Develop. Vol 44 No. 4 July 2000.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M =< N.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is REAL array, dimension (LDA,N)
*>          On entry, the real M-by-N matrix A.  On exit, the elements on and
*>          below the diagonal contain the N-by-N lower triangular matrix L; the
*>          elements above the diagonal are the rows of V.  See below for
*>          further details.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,M).
*> \endverbatim
*>
*> \param[out] T
*> \verbatim
*>          T is REAL array, dimension (LDT,N)
*>          The N-by-N upper triangular factor of the block reflector.
*>          The elements on and above the diagonal contain the block
*>          reflector T; the elements below the diagonal are not used.
*>          See below for further details.
*> \endverbatim
*>
*> \param[in] LDT
*> \verbatim
*>          LDT is INTEGER
*>          The leading dimension of the array T.  LDT >= max(1,N).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0: successful exit
*>          < 0: if INFO = -i, the i-th argument had an illegal value
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date June 2017
*
*> \ingroup doubleGEcomputational
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  The matrix V stores the elementary reflectors H(i) in the i-th row
*>  above the diagonal. For example, if M=5 and N=3, the matrix V is
*>
*>               V = (  1  v1 v1 v1 v1 )
*>                   (     1  v2 v2 v2 )
*>                   (     1  v3 v3 v3 )
*>
*>
*>  where the vi's represent the vectors which define H(i), which are returned
*>  in the matrix A.  The 1's along the diagonal of V are not stored in A.  The
*>  block reflector H is then given by
*>
*>               H = I - V * T * V**T
*>
*>  where V**T is the transpose of V.
*>
*>  For details of the algorithm, see Elmroth and Gustavson (cited above).
*> \endverbatim
*>
*  =====================================================================
      RECURSIVE SUBROUTINE sgelqt3( M, N, A, LDA, T, LDT, INFO )
*
*  -- LAPACK computational routine (version 3.7.1) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     June 2017
*
*     .. Scalar Arguments ..
      INTEGER   INFO, LDA, M, N, LDT
*     ..
*     .. Array Arguments ..
      REAL      A( lda, * ), T( ldt, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL   ONE
      parameter( one = 1.0e+00 )
*     ..
*     .. Local Scalars ..
      INTEGER   I, I1, J, J1, M1, M2, N1, N2, IINFO
*     ..
*     .. External Subroutines ..
      EXTERNAL  dlarfg, dtrmm, dgemm, xerbla
*     ..
*     .. Executable Statements ..
*
      info = 0
      IF( m .LT. 0 ) THEN
         info = -1
      ELSE IF( n .LT. m ) THEN
         info = -2
      ELSE IF( lda .LT. max( 1, m ) ) THEN
         info = -4
      ELSE IF( ldt .LT. max( 1, m ) ) THEN
         info = -6
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SGELQT3', -info )
         RETURN
      END IF
*
      IF( m.EQ.1 ) THEN
*
*        Compute Householder transform when N=1
*
         CALL slarfg( n, a, a( 1, min( 2, n ) ), lda, t )
*
      ELSE
*
*        Otherwise, split A into blocks...
*
         m1 = m/2
         m2 = m-m1
         i1 = min( m1+1, m )
         j1 = min( m+1, n )
*
*        Compute A(1:M1,1:N) <- (Y1,R1,T1), where Q1 = I - Y1 T1 Y1^H
*
         CALL sgelqt3( m1, n, a, lda, t, ldt, iinfo )
*
*        Compute A(J1:M,1:N) = Q1^H A(J1:M,1:N) [workspace: T(1:N1,J1:N)]
*
         DO i=1,m2
            DO j=1,m1
               t(  i+m1, j ) = a( i+m1, j )
            END DO
         END DO
         CALL strmm( 'R', 'U', 'T', 'U', m2, m1, one,
     &               a, lda, t( i1, 1 ), ldt )
*
         CALL sgemm( 'N', 'T', m2, m1, n-m1, one, a( i1, i1 ), lda,
     &               a( 1, i1 ), lda, one, t( i1, 1 ), ldt)
*
         CALL strmm( 'R', 'U', 'N', 'N', m2, m1, one,
     &               t, ldt, t( i1, 1 ), ldt )
*
         CALL sgemm( 'N', 'N', m2, n-m1, m1, -one, t( i1, 1 ), ldt,
     &                a( 1, i1 ), lda, one, a( i1, i1 ), lda )
*
         CALL strmm( 'R', 'U', 'N', 'U', m2, m1 , one,
     &               a, lda, t( i1, 1 ), ldt )
*
         DO i=1,m2
            DO j=1,m1
               a(  i+m1, j ) = a( i+m1, j ) - t( i+m1, j )
               t( i+m1, j )=0
            END DO
         END DO
*
*        Compute A(J1:M,J1:N) <- (Y2,R2,T2) where Q2 = I - Y2 T2 Y2^H
*
         CALL sgelqt3( m2, n-m1, a( i1, i1 ), lda,
     &                t( i1, i1 ), ldt, iinfo )
*
*        Compute T3 = T(J1:N1,1:N) = -T1 Y1^H Y2 T2
*
         DO i=1,m2
            DO j=1,m1
               t( j, i+m1  ) = (a( j, i+m1 ))
            END DO
         END DO
*
         CALL strmm( 'R', 'U', 'T', 'U', m1, m2, one,
     &               a( i1, i1 ), lda, t( 1, i1 ), ldt )
*
         CALL sgemm( 'N', 'T', m1, m2, n-m, one, a( 1, j1 ), lda,
     &               a( i1, j1 ), lda, one, t( 1, i1 ), ldt )
*
         CALL strmm( 'L', 'U', 'N', 'N', m1, m2, -one, t, ldt,
     &               t( 1, i1 ), ldt )
*
         CALL strmm( 'R', 'U', 'N', 'N', m1, m2, one,
     &               t( i1, i1 ), ldt, t( 1, i1 ), ldt )
*
*
*
*        Y = (Y1,Y2); L = [ L1            0  ];  T = [T1 T3]
*                         [ A(1:N1,J1:N)  L2 ]       [ 0 T2]
*
      END IF
*
      RETURN
*
*     End of SGELQT3
*
      END