LAPACK: TESTING/LIN/cchksy.f Source File

00001       SUBROUTINE CCHKSY( DOTYPE, NN, NVAL, NNB, NBVAL, NNS, NSVAL,
00002      $                   THRESH, TSTERR, NMAX, A, AFAC, AINV, B, X,
00003      $                   XACT, WORK, RWORK, IWORK, NOUT )
00004 *
00005 *  -- LAPACK test routine (version 3.1) --
00006 *     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
00007 *     November 2006
00008 *
00009 *     .. Scalar Arguments ..
00010       LOGICAL            TSTERR
00011       INTEGER            NMAX, NN, NNB, NNS, NOUT
00012       REAL               THRESH
00013 *     ..
00014 *     .. Array Arguments ..
00015       LOGICAL            DOTYPE( * )
00016       INTEGER            IWORK( * ), NBVAL( * ), NSVAL( * ), NVAL( * )
00017       REAL               RWORK( * )
00018       COMPLEX            A( * ), AFAC( * ), AINV( * ), B( * ),
00019      $                   WORK( * ), X( * ), XACT( * )
00020 *     ..
00021 *
00022 *  Purpose
00023 *  =======
00024 *
00025 *  CCHKSY tests CSYTRF, -TRI, -TRS, -RFS, and -CON.
00026 *
00027 *  Arguments
00028 *  =========
00029 *
00030 *  DOTYPE  (input) LOGICAL array, dimension (NTYPES)
00031 *          The matrix types to be used for testing.  Matrices of type j
00032 *          (for 1 <= j <= NTYPES) are used for testing if DOTYPE(j) =
00033 *          .TRUE.; if DOTYPE(j) = .FALSE., then type j is not used.
00034 *
00035 *  NN      (input) INTEGER
00036 *          The number of values of N contained in the vector NVAL.
00037 *
00038 *  NVAL    (input) INTEGER array, dimension (NN)
00039 *          The values of the matrix dimension N.
00040 *
00041 *  NNB     (input) INTEGER
00042 *          The number of values of NB contained in the vector NBVAL.
00043 *
00044 *  NBVAL   (input) INTEGER array, dimension (NBVAL)
00045 *          The values of the blocksize NB.
00046 *
00047 *  NNS     (input) INTEGER
00048 *          The number of values of NRHS contained in the vector NSVAL.
00049 *
00050 *  NSVAL   (input) INTEGER array, dimension (NNS)
00051 *          The values of the number of right hand sides NRHS.
00052 *
00053 *  THRESH  (input) REAL
00054 *          The threshold value for the test ratios.  A result is
00055 *          included in the output file if RESULT >= THRESH.  To have
00056 *          every test ratio printed, use THRESH = 0.
00057 *
00058 *  TSTERR  (input) LOGICAL
00059 *          Flag that indicates whether error exits are to be tested.
00060 *
00061 *  NMAX    (input) INTEGER
00062 *          The maximum value permitted for N, used in dimensioning the
00063 *          work arrays.
00064 *
00065 *  A       (workspace) COMPLEX array, dimension (NMAX*NMAX)
00066 *
00067 *  AFAC    (workspace) COMPLEX array, dimension (NMAX*NMAX)
00068 *
00069 *  AINV    (workspace) COMPLEX array, dimension (NMAX*NMAX)
00070 *
00071 *  B       (workspace) COMPLEX array, dimension (NMAX*NSMAX)
00072 *          where NSMAX is the largest entry in NSVAL.
00073 *
00074 *  X       (workspace) COMPLEX array, dimension (NMAX*NSMAX)
00075 *
00076 *  XACT    (workspace) COMPLEX array, dimension (NMAX*NSMAX)
00077 *
00078 *  WORK    (workspace) COMPLEX array, dimension
00079 *                      (NMAX*max(2,NSMAX))
00080 *
00081 *  RWORK   (workspace) REAL array,
00082 *                                 dimension (NMAX+2*NSMAX)
00083 *
00084 *  IWORK   (workspace) INTEGER array, dimension (NMAX)
00085 *
00086 *  NOUT    (input) INTEGER
00087 *          The unit number for output.
00088 *
00089 *  =====================================================================
00090 *
00091 *     .. Parameters ..
00092       REAL               ZERO
00093       PARAMETER          ( ZERO = 0.0E+0 )
00094       INTEGER            NTYPES
00095       PARAMETER          ( NTYPES = 11 )
00096       INTEGER            NTESTS
00097       PARAMETER          ( NTESTS = 8 )
00098 *     ..
00099 *     .. Local Scalars ..
00100       LOGICAL            TRFCON, ZEROT
00101       CHARACTER          DIST, TYPE, UPLO, XTYPE
00102       CHARACTER*3        PATH
00103       INTEGER            I, I1, I2, IMAT, IN, INB, INFO, IOFF, IRHS,
00104      $                   IUPLO, IZERO, J, K, KL, KU, LDA, LWORK, MODE,
00105      $                   N, NB, NERRS, NFAIL, NIMAT, NRHS, NRUN, NT
00106       REAL               ANORM, CNDNUM, RCOND, RCONDC
00107 *     ..
00108 *     .. Local Arrays ..
00109       CHARACTER          UPLOS( 2 )
00110       INTEGER            ISEED( 4 ), ISEEDY( 4 )
00111       REAL               RESULT( NTESTS )
00112 *     ..
00113 *     .. External Functions ..
00114       REAL               CLANSY, SGET06
00115       EXTERNAL           CLANSY, SGET06
00116 *     ..
00117 *     .. External Subroutines ..
00118       EXTERNAL           ALAERH, ALAHD, ALASUM, CERRSY, CGET04, CLACPY,
00119      $                   CLARHS, CLATB4, CLATMS, CLATSY, CPOT05, CSYCON,
00120      $                   CSYRFS, CSYT01, CSYT02, CSYT03, CSYTRF, CSYTRI,
00121      $                   CSYTRS, XLAENV
00122 *     ..
00123 *     .. Intrinsic Functions ..
00124       INTRINSIC          MAX, MIN
00125 *     ..
00126 *     .. Scalars in Common ..
00127       LOGICAL            LERR, OK
00128       CHARACTER*32       SRNAMT
00129       INTEGER            INFOT, NUNIT
00130 *     ..
00131 *     .. Common blocks ..
00132       COMMON             / INFOC / INFOT, NUNIT, OK, LERR
00133       COMMON             / SRNAMC / SRNAMT
00134 *     ..
00135 *     .. Data statements ..
00136       DATA               ISEEDY / 1988, 1989, 1990, 1991 /
00137       DATA               UPLOS / 'U', 'L' /
00138 *     ..
00139 *     .. Executable Statements ..
00140 *
00141 *     Initialize constants and the random number seed.
00142 *
00143       PATH( 1: 1 ) = 'Complex precision'
00144       PATH( 2: 3 ) = 'SY'
00145       NRUN = 0
00146       NFAIL = 0
00147       NERRS = 0
00148       DO 10 I = 1, 4
00149          ISEED( I ) = ISEEDY( I )
00150    10 CONTINUE
00151 *
00152 *     Test the error exits
00153 *
00154       IF( TSTERR )
00155      $   CALL CERRSY( PATH, NOUT )
00156       INFOT = 0
00157 *
00158 *     Do for each value of N in NVAL
00159 *
00160       DO 180 IN = 1, NN
00161          N = NVAL( IN )
00162          LDA = MAX( N, 1 )
00163          XTYPE = 'N'
00164          NIMAT = NTYPES
00165          IF( N.LE.0 )
00166      $      NIMAT = 1
00167 *
00168          IZERO = 0
00169          DO 170 IMAT = 1, NIMAT
00170 *
00171 *           Do the tests only if DOTYPE( IMAT ) is true.
00172 *
00173             IF( .NOT.DOTYPE( IMAT ) )
00174      $         GO TO 170
00175 *
00176 *           Skip types 3, 4, 5, or 6 if the matrix size is too small.
00177 *
00178             ZEROT = IMAT.GE.3 .AND. IMAT.LE.6
00179             IF( ZEROT .AND. N.LT.IMAT-2 )
00180      $         GO TO 170
00181 *
00182 *           Do first for UPLO = 'U', then for UPLO = 'L'
00183 *
00184             DO 160 IUPLO = 1, 2
00185                UPLO = UPLOS( IUPLO )
00186 *
00187                IF( IMAT.NE.NTYPES ) THEN
00188 *
00189 *                 Set up parameters with CLATB4 and generate a test
00190 *                 matrix with CLATMS.
00191 *
00192                   CALL CLATB4( PATH, IMAT, N, N, TYPE, KL, KU, ANORM,
00193      $                         MODE, CNDNUM, DIST )
00194 *
00195                   SRNAMT = 'CLATMS'
00196                   CALL CLATMS( N, N, DIST, ISEED, TYPE, RWORK, MODE,
00197      $                         CNDNUM, ANORM, KL, KU, 'N', A, LDA, WORK,
00198      $                         INFO )
00199 *
00200 *                 Check error code from CLATMS.
00201 *
00202                   IF( INFO.NE.0 ) THEN
00203                      CALL ALAERH( PATH, 'CLATMS', INFO, 0, UPLO, N, N,
00204      $                            -1, -1, -1, IMAT, NFAIL, NERRS, NOUT )
00205                      GO TO 160
00206                   END IF
00207 *
00208 *                 For types 3-6, zero one or more rows and columns of
00209 *                 the matrix to test that INFO is returned correctly.
00210 *
00211                   IF( ZEROT ) THEN
00212                      IF( IMAT.EQ.3 ) THEN
00213                         IZERO = 1
00214                      ELSE IF( IMAT.EQ.4 ) THEN
00215                         IZERO = N
00216                      ELSE
00217                         IZERO = N / 2 + 1
00218                      END IF
00219 *
00220                      IF( IMAT.LT.6 ) THEN
00221 *
00222 *                       Set row and column IZERO to zero.
00223 *
00224                         IF( IUPLO.EQ.1 ) THEN
00225                            IOFF = ( IZERO-1 )*LDA
00226                            DO 20 I = 1, IZERO - 1
00227                               A( IOFF+I ) = ZERO
00228    20                      CONTINUE
00229                            IOFF = IOFF + IZERO
00230                            DO 30 I = IZERO, N
00231                               A( IOFF ) = ZERO
00232                               IOFF = IOFF + LDA
00233    30                      CONTINUE
00234                         ELSE
00235                            IOFF = IZERO
00236                            DO 40 I = 1, IZERO - 1
00237                               A( IOFF ) = ZERO
00238                               IOFF = IOFF + LDA
00239    40                      CONTINUE
00240                            IOFF = IOFF - IZERO
00241                            DO 50 I = IZERO, N
00242                               A( IOFF+I ) = ZERO
00243    50                      CONTINUE
00244                         END IF
00245                      ELSE
00246                         IF( IUPLO.EQ.1 ) THEN
00247 *
00248 *                          Set the first IZERO rows to zero.
00249 *
00250                            IOFF = 0
00251                            DO 70 J = 1, N
00252                               I2 = MIN( J, IZERO )
00253                               DO 60 I = 1, I2
00254                                  A( IOFF+I ) = ZERO
00255    60                         CONTINUE
00256                               IOFF = IOFF + LDA
00257    70                      CONTINUE
00258                         ELSE
00259 *
00260 *                          Set the last IZERO rows to zero.
00261 *
00262                            IOFF = 0
00263                            DO 90 J = 1, N
00264                               I1 = MAX( J, IZERO )
00265                               DO 80 I = I1, N
00266                                  A( IOFF+I ) = ZERO
00267    80                         CONTINUE
00268                               IOFF = IOFF + LDA
00269    90                      CONTINUE
00270                         END IF
00271                      END IF
00272                   ELSE
00273                      IZERO = 0
00274                   END IF
00275                ELSE
00276 *
00277 *                 Use a special block diagonal matrix to test alternate
00278 *                 code for the 2 x 2 blocks.
00279 *
00280                   CALL CLATSY( UPLO, N, A, LDA, ISEED )
00281                END IF
00282 *
00283 *              Do for each value of NB in NBVAL
00284 *
00285                DO 150 INB = 1, NNB
00286                   NB = NBVAL( INB )
00287                   CALL XLAENV( 1, NB )
00288 *
00289 *                 Compute the L*D*L' or U*D*U' factorization of the
00290 *                 matrix.
00291 *
00292                   CALL CLACPY( UPLO, N, N, A, LDA, AFAC, LDA )
00293                   LWORK = MAX( 2, NB )*LDA
00294                   SRNAMT = 'CSYTRF'
00295                   CALL CSYTRF( UPLO, N, AFAC, LDA, IWORK, AINV, LWORK,
00296      $                         INFO )
00297 *
00298 *                 Adjust the expected value of INFO to account for
00299 *                 pivoting.
00300 *
00301                   K = IZERO
00302                   IF( K.GT.0 ) THEN
00303   100                CONTINUE
00304                      IF( IWORK( K ).LT.0 ) THEN
00305                         IF( IWORK( K ).NE.-K ) THEN
00306                            K = -IWORK( K )
00307                            GO TO 100
00308                         END IF
00309                      ELSE IF( IWORK( K ).NE.K ) THEN
00310                         K = IWORK( K )
00311                         GO TO 100
00312                      END IF
00313                   END IF
00314 *
00315 *                 Check error code from CSYTRF.
00316 *
00317                   IF( INFO.NE.K )
00318      $               CALL ALAERH( PATH, 'CSYTRF', INFO, K, UPLO, N, N,
00319      $                            -1, -1, NB, IMAT, NFAIL, NERRS, NOUT )
00320                   IF( INFO.NE.0 ) THEN
00321                      TRFCON = .TRUE.
00322                   ELSE
00323                      TRFCON = .FALSE.
00324                   END IF
00325 *
00326 *+    TEST 1
00327 *                 Reconstruct matrix from factors and compute residual.
00328 *
00329                   CALL CSYT01( UPLO, N, A, LDA, AFAC, LDA, IWORK, AINV,
00330      $                         LDA, RWORK, RESULT( 1 ) )
00331                   NT = 1
00332 *
00333 *+    TEST 2
00334 *                 Form the inverse and compute the residual.
00335 *
00336                   IF( INB.EQ.1 .AND. .NOT.TRFCON ) THEN
00337                      CALL CLACPY( UPLO, N, N, AFAC, LDA, AINV, LDA )
00338                      SRNAMT = 'CSYTRI'
00339                      CALL CSYTRI( UPLO, N, AINV, LDA, IWORK, WORK,
00340      $                            INFO )
00341 *
00342 *                 Check error code from CSYTRI.
00343 *
00344                      IF( INFO.NE.0 )
00345      $                  CALL ALAERH( PATH, 'CSYTRI', INFO, 0, UPLO, N,
00346      $                               N, -1, -1, -1, IMAT, NFAIL, NERRS,
00347      $                               NOUT )
00348 *
00349                      CALL CSYT03( UPLO, N, A, LDA, AINV, LDA, WORK, LDA,
00350      $                            RWORK, RCONDC, RESULT( 2 ) )
00351                      NT = 2
00352                   END IF
00353 *
00354 *                 Print information about the tests that did not pass
00355 *                 the threshold.
00356 *
00357                   DO 110 K = 1, NT
00358                      IF( RESULT( K ).GE.THRESH ) THEN
00359                         IF( NFAIL.EQ.0 .AND. NERRS.EQ.0 )
00360      $                     CALL ALAHD( NOUT, PATH )
00361                         WRITE( NOUT, FMT = 9999 )UPLO, N, NB, IMAT, K,
00362      $                     RESULT( K )
00363                         NFAIL = NFAIL + 1
00364                      END IF
00365   110             CONTINUE
00366                   NRUN = NRUN + NT
00367 *
00368 *                 Skip the other tests if this is not the first block
00369 *                 size.
00370 *
00371                   IF( INB.GT.1 )
00372      $               GO TO 150
00373 *
00374 *                 Do only the condition estimate if INFO is not 0.
00375 *
00376                   IF( TRFCON ) THEN
00377                      RCONDC = ZERO
00378                      GO TO 140
00379                   END IF
00380 *
00381                   DO 130 IRHS = 1, NNS
00382                      NRHS = NSVAL( IRHS )
00383 *
00384 *+    TEST 3
00385 *                 Solve and compute residual for  A * X = B.
00386 *
00387                      SRNAMT = 'CLARHS'
00388                      CALL CLARHS( PATH, XTYPE, UPLO, ' ', N, N, KL, KU,
00389      $                            NRHS, A, LDA, XACT, LDA, B, LDA,
00390      $                            ISEED, INFO )
00391                      CALL CLACPY( 'Full', N, NRHS, B, LDA, X, LDA )
00392 *
00393                      SRNAMT = 'CSYTRS'
00394                      CALL CSYTRS( UPLO, N, NRHS, AFAC, LDA, IWORK, X,
00395      $                            LDA, INFO )
00396 *
00397 *                 Check error code from CSYTRS.
00398 *
00399                      IF( INFO.NE.0 )
00400      $                  CALL ALAERH( PATH, 'CSYTRS', INFO, 0, UPLO, N,
00401      $                               N, -1, -1, NRHS, IMAT, NFAIL,
00402      $                               NERRS, NOUT )
00403 *
00404                      CALL CLACPY( 'Full', N, NRHS, B, LDA, WORK, LDA )
00405                      CALL CSYT02( UPLO, N, NRHS, A, LDA, X, LDA, WORK,
00406      $                            LDA, RWORK, RESULT( 3 ) )
00407 *
00408 *+    TEST 4
00409 *                 Check solution from generated exact solution.
00410 *
00411                      CALL CGET04( N, NRHS, X, LDA, XACT, LDA, RCONDC,
00412      $                            RESULT( 4 ) )
00413 *
00414 *+    TESTS 5, 6, and 7
00415 *                 Use iterative refinement to improve the solution.
00416 *
00417                      SRNAMT = 'CSYRFS'
00418                      CALL CSYRFS( UPLO, N, NRHS, A, LDA, AFAC, LDA,
00419      $                            IWORK, B, LDA, X, LDA, RWORK,
00420      $                            RWORK( NRHS+1 ), WORK,
00421      $                            RWORK( 2*NRHS+1 ), INFO )
00422 *
00423 *                 Check error code from CSYRFS.
00424 *
00425                      IF( INFO.NE.0 )
00426      $                  CALL ALAERH( PATH, 'CSYRFS', INFO, 0, UPLO, N,
00427      $                               N, -1, -1, NRHS, IMAT, NFAIL,
00428      $                               NERRS, NOUT )
00429 *
00430                      CALL CGET04( N, NRHS, X, LDA, XACT, LDA, RCONDC,
00431      $                            RESULT( 5 ) )
00432                      CALL CPOT05( UPLO, N, NRHS, A, LDA, B, LDA, X, LDA,
00433      $                            XACT, LDA, RWORK, RWORK( NRHS+1 ),
00434      $                            RESULT( 6 ) )
00435 *
00436 *                    Print information about the tests that did not pass
00437 *                    the threshold.
00438 *
00439                      DO 120 K = 3, 7
00440                         IF( RESULT( K ).GE.THRESH ) THEN
00441                            IF( NFAIL.EQ.0 .AND. NERRS.EQ.0 )
00442      $                        CALL ALAHD( NOUT, PATH )
00443                            WRITE( NOUT, FMT = 9998 )UPLO, N, NRHS,
00444      $                        IMAT, K, RESULT( K )
00445                            NFAIL = NFAIL + 1
00446                         END IF
00447   120                CONTINUE
00448                      NRUN = NRUN + 5
00449   130             CONTINUE
00450 *
00451 *+    TEST 8
00452 *                 Get an estimate of RCOND = 1/CNDNUM.
00453 *
00454   140             CONTINUE
00455                   ANORM = CLANSY( '1', UPLO, N, A, LDA, RWORK )
00456                   SRNAMT = 'CSYCON'
00457                   CALL CSYCON( UPLO, N, AFAC, LDA, IWORK, ANORM, RCOND,
00458      $                         WORK, INFO )
00459 *
00460 *                 Check error code from CSYCON.
00461 *
00462                   IF( INFO.NE.0 )
00463      $               CALL ALAERH( PATH, 'CSYCON', INFO, 0, UPLO, N, N,
00464      $                            -1, -1, -1, IMAT, NFAIL, NERRS, NOUT )
00465 *
00466                   RESULT( 8 ) = SGET06( RCOND, RCONDC )
00467 *
00468 *                 Print information about the tests that did not pass
00469 *                 the threshold.
00470 *
00471                   IF( RESULT( 8 ).GE.THRESH ) THEN
00472                      IF( NFAIL.EQ.0 .AND. NERRS.EQ.0 )
00473      $                  CALL ALAHD( NOUT, PATH )
00474                      WRITE( NOUT, FMT = 9997 )UPLO, N, IMAT, 8,
00475      $                  RESULT( 8 )
00476                      NFAIL = NFAIL + 1
00477                   END IF
00478                   NRUN = NRUN + 1
00479   150          CONTINUE
00480   160       CONTINUE
00481   170    CONTINUE
00482   180 CONTINUE
00483 *
00484 *     Print a summary of the results.
00485 *
00486       CALL ALASUM( PATH, NOUT, NFAIL, NRUN, NERRS )
00487 *
00488  9999 FORMAT( ' UPLO = ''', A1, ''', N =', I5, ', NB =', I4, ', type ',
00489      $      I2, ', test ', I2, ', ratio =', G12.5 )
00490  9998 FORMAT( ' UPLO = ''', A1, ''', N =', I5, ', NRHS=', I3, ', type ',
00491      $      I2, ', test(', I2, ') =', G12.5 )
00492  9997 FORMAT( ' UPLO = ''', A1, ''', N =', I5, ',', 10X, ' type ', I2,
00493      $      ', test(', I2, ') =', G12.5 )
00494       RETURN
00495 *
00496 *     End of CCHKSY
00497 *
00498       END