LAPACK: SRC/sgsvj0.f Source File

00001       SUBROUTINE SGSVJ0( JOBV, M, N, A, LDA, D, SVA, MV, V, LDV, EPS,
00002      +                   SFMIN, TOL, NSWEEP, WORK, LWORK, INFO )
00003 *
00004 *  -- LAPACK routine (version 3.2.1)                                    --
00005 *
00006 *  -- Contributed by Zlatko Drmac of the University of Zagreb and     --
00007 *  -- Kresimir Veselic of the Fernuniversitaet Hagen                  --
00008 *  -- April 2009                                                      --
00009 *
00010 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00011 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00012 *
00013 * This routine is also part of SIGMA (version 1.23, October 23. 2008.)
00014 * SIGMA is a library of algorithms for highly accurate algorithms for
00015 * computation of SVD, PSVD, QSVD, (H,K)-SVD, and for solution of the
00016 * eigenvalue problems Hx = lambda M x, H M x = lambda x with H, M > 0.
00017 *
00018       IMPLICIT           NONE
00019 *     ..
00020 *     .. Scalar Arguments ..
00021       INTEGER            INFO, LDA, LDV, LWORK, M, MV, N, NSWEEP
00022       REAL               EPS, SFMIN, TOL
00023       CHARACTER*1        JOBV
00024 *     ..
00025 *     .. Array Arguments ..
00026       REAL               A( LDA, * ), SVA( N ), D( N ), V( LDV, * ),
00027      +                   WORK( LWORK )
00028 *     ..
00029 *
00030 *  Purpose
00031 *  =======
00032 *
00033 *  SGSVJ0 is called from SGESVJ as a pre-processor and that is its main
00034 *  purpose. It applies Jacobi rotations in the same way as SGESVJ does, but
00035 *  it does not check convergence (stopping criterion). Few tuning
00036 *  parameters (marked by [TP]) are available for the implementer.
00037 *
00038 *  Further Details
00039 *  ~~~~~~~~~~~~~~~
00040 *  SGSVJ0 is used just to enable SGESVJ to call a simplified version of
00041 *  itself to work on a submatrix of the original matrix.
00042 *
00043 *  Contributors
00044 *  ~~~~~~~~~~~~
00045 *  Zlatko Drmac (Zagreb, Croatia) and Kresimir Veselic (Hagen, Germany)
00046 *
00047 *  Bugs, Examples and Comments
00048 *  ~~~~~~~~~~~~~~~~~~~~~~~~~~~
00049 *  Please report all bugs and send interesting test examples and comments to
00050 *  drmac@math.hr. Thank you.
00051 *
00052 *  Arguments
00053 *  =========
00054 *
00055 *  JOBV    (input) CHARACTER*1
00056 *          Specifies whether the output from this procedure is used
00057 *          to compute the matrix V:
00058 *          = 'V': the product of the Jacobi rotations is accumulated
00059 *                 by postmulyiplying the N-by-N array V.
00060 *                (See the description of V.)
00061 *          = 'A': the product of the Jacobi rotations is accumulated
00062 *                 by postmulyiplying the MV-by-N array V.
00063 *                (See the descriptions of MV and V.)
00064 *          = 'N': the Jacobi rotations are not accumulated.
00065 *
00066 *  M       (input) INTEGER
00067 *          The number of rows of the input matrix A.  M >= 0.
00068 *
00069 *  N       (input) INTEGER
00070 *          The number of columns of the input matrix A.
00071 *          M >= N >= 0.
00072 *
00073 *  A       (input/output) REAL array, dimension (LDA,N)
00074 *          On entry, M-by-N matrix A, such that A*diag(D) represents
00075 *          the input matrix.
00076 *          On exit,
00077 *          A_onexit * D_onexit represents the input matrix A*diag(D)
00078 *          post-multiplied by a sequence of Jacobi rotations, where the
00079 *          rotation threshold and the total number of sweeps are given in
00080 *          TOL and NSWEEP, respectively.
00081 *          (See the descriptions of D, TOL and NSWEEP.)
00082 *
00083 *  LDA     (input) INTEGER
00084 *          The leading dimension of the array A.  LDA >= max(1,M).
00085 *
00086 *  D       (input/workspace/output) REAL array, dimension (N)
00087 *          The array D accumulates the scaling factors from the fast scaled
00088 *          Jacobi rotations.
00089 *          On entry, A*diag(D) represents the input matrix.
00090 *          On exit, A_onexit*diag(D_onexit) represents the input matrix
00091 *          post-multiplied by a sequence of Jacobi rotations, where the
00092 *          rotation threshold and the total number of sweeps are given in
00093 *          TOL and NSWEEP, respectively.
00094 *          (See the descriptions of A, TOL and NSWEEP.)
00095 *
00096 *  SVA     (input/workspace/output) REAL array, dimension (N)
00097 *          On entry, SVA contains the Euclidean norms of the columns of
00098 *          the matrix A*diag(D).
00099 *          On exit, SVA contains the Euclidean norms of the columns of
00100 *          the matrix onexit*diag(D_onexit).
00101 *
00102 *  MV      (input) INTEGER
00103 *          If JOBV .EQ. 'A', then MV rows of V are post-multipled by a
00104 *                           sequence of Jacobi rotations.
00105 *          If JOBV = 'N',   then MV is not referenced.
00106 *
00107 *  V       (input/output) REAL array, dimension (LDV,N)
00108 *          If JOBV .EQ. 'V' then N rows of V are post-multipled by a
00109 *                           sequence of Jacobi rotations.
00110 *          If JOBV .EQ. 'A' then MV rows of V are post-multipled by a
00111 *                           sequence of Jacobi rotations.
00112 *          If JOBV = 'N',   then V is not referenced.
00113 *
00114 *  LDV     (input) INTEGER
00115 *          The leading dimension of the array V,  LDV >= 1.
00116 *          If JOBV = 'V', LDV .GE. N.
00117 *          If JOBV = 'A', LDV .GE. MV.
00118 *
00119 *  EPS     (input) INTEGER
00120 *          EPS = SLAMCH('Epsilon')
00121 *
00122 *  SFMIN   (input) INTEGER
00123 *          SFMIN = SLAMCH('Safe Minimum')
00124 *
00125 *  TOL     (input) REAL
00126 *          TOL is the threshold for Jacobi rotations. For a pair
00127 *          A(:,p), A(:,q) of pivot columns, the Jacobi rotation is
00128 *          applied only if ABS(COS(angle(A(:,p),A(:,q)))) .GT. TOL.
00129 *
00130 *  NSWEEP  (input) INTEGER
00131 *          NSWEEP is the number of sweeps of Jacobi rotations to be
00132 *          performed.
00133 *
00134 *  WORK    (workspace) REAL array, dimension LWORK.
00135 *
00136 *  LWORK   (input) INTEGER
00137 *          LWORK is the dimension of WORK. LWORK .GE. M.
00138 *
00139 *  INFO    (output) INTEGER
00140 *          = 0 : successful exit.
00141 *          < 0 : if INFO = -i, then the i-th argument had an illegal value
00142 *
00143 *  =====================================================================
00144 *
00145 *     .. Local Parameters ..
00146       REAL               ZERO, HALF, ONE, TWO
00147       PARAMETER          ( ZERO = 0.0E0, HALF = 0.5E0, ONE = 1.0E0,
00148      +                   TWO = 2.0E0 )
00149 *     ..
00150 *     .. Local Scalars ..
00151       REAL               AAPP, AAPP0, AAPQ, AAQQ, APOAQ, AQOAP, BIG,
00152      +                   BIGTHETA, CS, MXAAPQ, MXSINJ, ROOTBIG, ROOTEPS,
00153      +                   ROOTSFMIN, ROOTTOL, SMALL, SN, T, TEMP1, THETA,
00154      +                   THSIGN
00155       INTEGER            BLSKIP, EMPTSW, i, ibr, IERR, igl, IJBLSK, ir1,
00156      +                   ISWROT, jbc, jgl, KBL, LKAHEAD, MVL, NBL,
00157      +                   NOTROT, p, PSKIPPED, q, ROWSKIP, SWBAND
00158       LOGICAL            APPLV, ROTOK, RSVEC
00159 *     ..
00160 *     .. Local Arrays ..
00161       REAL               FASTR( 5 )
00162 *     ..
00163 *     .. Intrinsic Functions ..
00164       INTRINSIC          ABS, AMAX1, AMIN1, FLOAT, MIN0, SIGN, SQRT
00165 *     ..
00166 *     .. External Functions ..
00167       REAL               SDOT, SNRM2
00168       INTEGER            ISAMAX
00169       LOGICAL            LSAME
00170       EXTERNAL           ISAMAX, LSAME, SDOT, SNRM2
00171 *     ..
00172 *     .. External Subroutines ..
00173       EXTERNAL           SAXPY, SCOPY, SLASCL, SLASSQ, SROTM, SSWAP
00174 *     ..
00175 *     .. Executable Statements ..
00176 *
00177 *     Test the input parameters.
00178 *
00179       APPLV = LSAME( JOBV, 'A' )
00180       RSVEC = LSAME( JOBV, 'V' )
00181       IF( .NOT.( RSVEC .OR. APPLV .OR. LSAME( JOBV, 'N' ) ) ) THEN
00182          INFO = -1
00183       ELSE IF( M.LT.0 ) THEN
00184          INFO = -2
00185       ELSE IF( ( N.LT.0 ) .OR. ( N.GT.M ) ) THEN
00186          INFO = -3
00187       ELSE IF( LDA.LT.M ) THEN
00188          INFO = -5
00189       ELSE IF( MV.LT.0 ) THEN
00190          INFO = -8
00191       ELSE IF( LDV.LT.M ) THEN
00192          INFO = -10
00193       ELSE IF( TOL.LE.EPS ) THEN
00194          INFO = -13
00195       ELSE IF( NSWEEP.LT.0 ) THEN
00196          INFO = -14
00197       ELSE IF( LWORK.LT.M ) THEN
00198          INFO = -16
00199       ELSE
00200          INFO = 0
00201       END IF
00202 *
00203 *     #:(
00204       IF( INFO.NE.0 ) THEN
00205          CALL XERBLA( 'SGSVJ0', -INFO )
00206          RETURN
00207       END IF
00208 *
00209       IF( RSVEC ) THEN
00210          MVL = N
00211       ELSE IF( APPLV ) THEN
00212          MVL = MV
00213       END IF
00214       RSVEC = RSVEC .OR. APPLV
00215 
00216       ROOTEPS = SQRT( EPS )
00217       ROOTSFMIN = SQRT( SFMIN )
00218       SMALL = SFMIN / EPS
00219       BIG = ONE / SFMIN
00220       ROOTBIG = ONE / ROOTSFMIN
00221       BIGTHETA = ONE / ROOTEPS
00222       ROOTTOL = SQRT( TOL )
00223 *
00224 *
00225 *     .. Row-cyclic Jacobi SVD algorithm with column pivoting ..
00226 *
00227       EMPTSW = ( N*( N-1 ) ) / 2
00228       NOTROT = 0
00229       FASTR( 1 ) = ZERO
00230 *
00231 *     .. Row-cyclic pivot strategy with de Rijk's pivoting ..
00232 *
00233 
00234       SWBAND = 0
00235 *[TP] SWBAND is a tuning parameter. It is meaningful and effective
00236 *     if SGESVJ is used as a computational routine in the preconditioned
00237 *     Jacobi SVD algorithm SGESVJ. For sweeps i=1:SWBAND the procedure
00238 *     ......
00239 
00240       KBL = MIN0( 8, N )
00241 *[TP] KBL is a tuning parameter that defines the tile size in the
00242 *     tiling of the p-q loops of pivot pairs. In general, an optimal
00243 *     value of KBL depends on the matrix dimensions and on the
00244 *     parameters of the computer's memory.
00245 *
00246       NBL = N / KBL
00247       IF( ( NBL*KBL ).NE.N )NBL = NBL + 1
00248 
00249       BLSKIP = ( KBL**2 ) + 1
00250 *[TP] BLKSKIP is a tuning parameter that depends on SWBAND and KBL.
00251 
00252       ROWSKIP = MIN0( 5, KBL )
00253 *[TP] ROWSKIP is a tuning parameter.
00254 
00255       LKAHEAD = 1
00256 *[TP] LKAHEAD is a tuning parameter.
00257       SWBAND = 0
00258       PSKIPPED = 0
00259 *
00260       DO 1993 i = 1, NSWEEP
00261 *     .. go go go ...
00262 *
00263          MXAAPQ = ZERO
00264          MXSINJ = ZERO
00265          ISWROT = 0
00266 *
00267          NOTROT = 0
00268          PSKIPPED = 0
00269 *
00270          DO 2000 ibr = 1, NBL
00271 
00272             igl = ( ibr-1 )*KBL + 1
00273 *
00274             DO 1002 ir1 = 0, MIN0( LKAHEAD, NBL-ibr )
00275 *
00276                igl = igl + ir1*KBL
00277 *
00278                DO 2001 p = igl, MIN0( igl+KBL-1, N-1 )
00279 
00280 *     .. de Rijk's pivoting
00281                   q = ISAMAX( N-p+1, SVA( p ), 1 ) + p - 1
00282                   IF( p.NE.q ) THEN
00283                      CALL SSWAP( M, A( 1, p ), 1, A( 1, q ), 1 )
00284                      IF( RSVEC )CALL SSWAP( MVL, V( 1, p ), 1,
00285      +                                      V( 1, q ), 1 )
00286                      TEMP1 = SVA( p )
00287                      SVA( p ) = SVA( q )
00288                      SVA( q ) = TEMP1
00289                      TEMP1 = D( p )
00290                      D( p ) = D( q )
00291                      D( q ) = TEMP1
00292                   END IF
00293 *
00294                   IF( ir1.EQ.0 ) THEN
00295 *
00296 *        Column norms are periodically updated by explicit
00297 *        norm computation.
00298 *        Caveat:
00299 *        Some BLAS implementations compute SNRM2(M,A(1,p),1)
00300 *        as SQRT(SDOT(M,A(1,p),1,A(1,p),1)), which may result in
00301 *        overflow for ||A(:,p)||_2 > SQRT(overflow_threshold), and
00302 *        undeflow for ||A(:,p)||_2 < SQRT(underflow_threshold).
00303 *        Hence, SNRM2 cannot be trusted, not even in the case when
00304 *        the true norm is far from the under(over)flow boundaries.
00305 *        If properly implemented SNRM2 is available, the IF-THEN-ELSE
00306 *        below should read "AAPP = SNRM2( M, A(1,p), 1 ) * D(p)".
00307 *
00308                      IF( ( SVA( p ).LT.ROOTBIG ) .AND.
00309      +                   ( SVA( p ).GT.ROOTSFMIN ) ) THEN
00310                         SVA( p ) = SNRM2( M, A( 1, p ), 1 )*D( p )
00311                      ELSE
00312                         TEMP1 = ZERO
00313                         AAPP = ZERO
00314                         CALL SLASSQ( M, A( 1, p ), 1, TEMP1, AAPP )
00315                         SVA( p ) = TEMP1*SQRT( AAPP )*D( p )
00316                      END IF
00317                      AAPP = SVA( p )
00318                   ELSE
00319                      AAPP = SVA( p )
00320                   END IF
00321 
00322 *
00323                   IF( AAPP.GT.ZERO ) THEN
00324 *
00325                      PSKIPPED = 0
00326 *
00327                      DO 2002 q = p + 1, MIN0( igl+KBL-1, N )
00328 *
00329                         AAQQ = SVA( q )
00330 
00331                         IF( AAQQ.GT.ZERO ) THEN
00332 *
00333                            AAPP0 = AAPP
00334                            IF( AAQQ.GE.ONE ) THEN
00335                               ROTOK = ( SMALL*AAPP ).LE.AAQQ
00336                               IF( AAPP.LT.( BIG / AAQQ ) ) THEN
00337                                  AAPQ = ( SDOT( M, A( 1, p ), 1, A( 1,
00338      +                                  q ), 1 )*D( p )*D( q ) / AAQQ )
00339      +                                  / AAPP
00340                               ELSE
00341                                  CALL SCOPY( M, A( 1, p ), 1, WORK, 1 )
00342                                  CALL SLASCL( 'G', 0, 0, AAPP, D( p ),
00343      +                                        M, 1, WORK, LDA, IERR )
00344                                  AAPQ = SDOT( M, WORK, 1, A( 1, q ),
00345      +                                  1 )*D( q ) / AAQQ
00346                               END IF
00347                            ELSE
00348                               ROTOK = AAPP.LE.( AAQQ / SMALL )
00349                               IF( AAPP.GT.( SMALL / AAQQ ) ) THEN
00350                                  AAPQ = ( SDOT( M, A( 1, p ), 1, A( 1,
00351      +                                  q ), 1 )*D( p )*D( q ) / AAQQ )
00352      +                                  / AAPP
00353                               ELSE
00354                                  CALL SCOPY( M, A( 1, q ), 1, WORK, 1 )
00355                                  CALL SLASCL( 'G', 0, 0, AAQQ, D( q ),
00356      +                                        M, 1, WORK, LDA, IERR )
00357                                  AAPQ = SDOT( M, WORK, 1, A( 1, p ),
00358      +                                  1 )*D( p ) / AAPP
00359                               END IF
00360                            END IF
00361 *
00362                            MXAAPQ = AMAX1( MXAAPQ, ABS( AAPQ ) )
00363 *
00364 *        TO rotate or NOT to rotate, THAT is the question ...
00365 *
00366                            IF( ABS( AAPQ ).GT.TOL ) THEN
00367 *
00368 *           .. rotate
00369 *           ROTATED = ROTATED + ONE
00370 *
00371                               IF( ir1.EQ.0 ) THEN
00372                                  NOTROT = 0
00373                                  PSKIPPED = 0
00374                                  ISWROT = ISWROT + 1
00375                               END IF
00376 *
00377                               IF( ROTOK ) THEN
00378 *
00379                                  AQOAP = AAQQ / AAPP
00380                                  APOAQ = AAPP / AAQQ
00381                                  THETA = -HALF*ABS( AQOAP-APOAQ ) / AAPQ
00382 *
00383                                  IF( ABS( THETA ).GT.BIGTHETA ) THEN
00384 *
00385                                     T = HALF / THETA
00386                                     FASTR( 3 ) = T*D( p ) / D( q )
00387                                     FASTR( 4 ) = -T*D( q ) / D( p )
00388                                     CALL SROTM( M, A( 1, p ), 1,
00389      +                                          A( 1, q ), 1, FASTR )
00390                                     IF( RSVEC )CALL SROTM( MVL,
00391      +                                              V( 1, p ), 1,
00392      +                                              V( 1, q ), 1,
00393      +                                              FASTR )
00394                                     SVA( q ) = AAQQ*SQRT( AMAX1( ZERO,
00395      +                                         ONE+T*APOAQ*AAPQ ) )
00396                                     AAPP = AAPP*SQRT( ONE-T*AQOAP*AAPQ )
00397                                     MXSINJ = AMAX1( MXSINJ, ABS( T ) )
00398 *
00399                                  ELSE
00400 *
00401 *                 .. choose correct signum for THETA and rotate
00402 *
00403                                     THSIGN = -SIGN( ONE, AAPQ )
00404                                     T = ONE / ( THETA+THSIGN*
00405      +                                  SQRT( ONE+THETA*THETA ) )
00406                                     CS = SQRT( ONE / ( ONE+T*T ) )
00407                                     SN = T*CS
00408 *
00409                                     MXSINJ = AMAX1( MXSINJ, ABS( SN ) )
00410                                     SVA( q ) = AAQQ*SQRT( AMAX1( ZERO,
00411      +                                         ONE+T*APOAQ*AAPQ ) )
00412                                     AAPP = AAPP*SQRT( AMAX1( ZERO,
00413      +                                     ONE-T*AQOAP*AAPQ ) )
00414 *
00415                                     APOAQ = D( p ) / D( q )
00416                                     AQOAP = D( q ) / D( p )
00417                                     IF( D( p ).GE.ONE ) THEN
00418                                        IF( D( q ).GE.ONE ) THEN
00419                                           FASTR( 3 ) = T*APOAQ
00420                                           FASTR( 4 ) = -T*AQOAP
00421                                           D( p ) = D( p )*CS
00422                                           D( q ) = D( q )*CS
00423                                           CALL SROTM( M, A( 1, p ), 1,
00424      +                                                A( 1, q ), 1,
00425      +                                                FASTR )
00426                                           IF( RSVEC )CALL SROTM( MVL,
00427      +                                        V( 1, p ), 1, V( 1, q ),
00428      +                                        1, FASTR )
00429                                        ELSE
00430                                           CALL SAXPY( M, -T*AQOAP,
00431      +                                                A( 1, q ), 1,
00432      +                                                A( 1, p ), 1 )
00433                                           CALL SAXPY( M, CS*SN*APOAQ,
00434      +                                                A( 1, p ), 1,
00435      +                                                A( 1, q ), 1 )
00436                                           D( p ) = D( p )*CS
00437                                           D( q ) = D( q ) / CS
00438                                           IF( RSVEC ) THEN
00439                                              CALL SAXPY( MVL, -T*AQOAP,
00440      +                                                   V( 1, q ), 1,
00441      +                                                   V( 1, p ), 1 )
00442                                              CALL SAXPY( MVL,
00443      +                                                   CS*SN*APOAQ,
00444      +                                                   V( 1, p ), 1,
00445      +                                                   V( 1, q ), 1 )
00446                                           END IF
00447                                        END IF
00448                                     ELSE
00449                                        IF( D( q ).GE.ONE ) THEN
00450                                           CALL SAXPY( M, T*APOAQ,
00451      +                                                A( 1, p ), 1,
00452      +                                                A( 1, q ), 1 )
00453                                           CALL SAXPY( M, -CS*SN*AQOAP,
00454      +                                                A( 1, q ), 1,
00455      +                                                A( 1, p ), 1 )
00456                                           D( p ) = D( p ) / CS
00457                                           D( q ) = D( q )*CS
00458                                           IF( RSVEC ) THEN
00459                                              CALL SAXPY( MVL, T*APOAQ,
00460      +                                                   V( 1, p ), 1,
00461      +                                                   V( 1, q ), 1 )
00462                                              CALL SAXPY( MVL,
00463      +                                                   -CS*SN*AQOAP,
00464      +                                                   V( 1, q ), 1,
00465      +                                                   V( 1, p ), 1 )
00466                                           END IF
00467                                        ELSE
00468                                           IF( D( p ).GE.D( q ) ) THEN
00469                                              CALL SAXPY( M, -T*AQOAP,
00470      +                                                   A( 1, q ), 1,
00471      +                                                   A( 1, p ), 1 )
00472                                              CALL SAXPY( M, CS*SN*APOAQ,
00473      +                                                   A( 1, p ), 1,
00474      +                                                   A( 1, q ), 1 )
00475                                              D( p ) = D( p )*CS
00476                                              D( q ) = D( q ) / CS
00477                                              IF( RSVEC ) THEN
00478                                                 CALL SAXPY( MVL,
00479      +                                               -T*AQOAP,
00480      +                                               V( 1, q ), 1,
00481      +                                               V( 1, p ), 1 )
00482                                                 CALL SAXPY( MVL,
00483      +                                               CS*SN*APOAQ,
00484      +                                               V( 1, p ), 1,
00485      +                                               V( 1, q ), 1 )
00486                                              END IF
00487                                           ELSE
00488                                              CALL SAXPY( M, T*APOAQ,
00489      +                                                   A( 1, p ), 1,
00490      +                                                   A( 1, q ), 1 )
00491                                              CALL SAXPY( M,
00492      +                                                   -CS*SN*AQOAP,
00493      +                                                   A( 1, q ), 1,
00494      +                                                   A( 1, p ), 1 )
00495                                              D( p ) = D( p ) / CS
00496                                              D( q ) = D( q )*CS
00497                                              IF( RSVEC ) THEN
00498                                                 CALL SAXPY( MVL,
00499      +                                               T*APOAQ, V( 1, p ),
00500      +                                               1, V( 1, q ), 1 )
00501                                                 CALL SAXPY( MVL,
00502      +                                               -CS*SN*AQOAP,
00503      +                                               V( 1, q ), 1,
00504      +                                               V( 1, p ), 1 )
00505                                              END IF
00506                                           END IF
00507                                        END IF
00508                                     END IF
00509                                  END IF
00510 *
00511                               ELSE
00512 *              .. have to use modified Gram-Schmidt like transformation
00513                                  CALL SCOPY( M, A( 1, p ), 1, WORK, 1 )
00514                                  CALL SLASCL( 'G', 0, 0, AAPP, ONE, M,
00515      +                                        1, WORK, LDA, IERR )
00516                                  CALL SLASCL( 'G', 0, 0, AAQQ, ONE, M,
00517      +                                        1, A( 1, q ), LDA, IERR )
00518                                  TEMP1 = -AAPQ*D( p ) / D( q )
00519                                  CALL SAXPY( M, TEMP1, WORK, 1,
00520      +                                       A( 1, q ), 1 )
00521                                  CALL SLASCL( 'G', 0, 0, ONE, AAQQ, M,
00522      +                                        1, A( 1, q ), LDA, IERR )
00523                                  SVA( q ) = AAQQ*SQRT( AMAX1( ZERO,
00524      +                                      ONE-AAPQ*AAPQ ) )
00525                                  MXSINJ = AMAX1( MXSINJ, SFMIN )
00526                               END IF
00527 *           END IF ROTOK THEN ... ELSE
00528 *
00529 *           In the case of cancellation in updating SVA(q), SVA(p)
00530 *           recompute SVA(q), SVA(p).
00531                               IF( ( SVA( q ) / AAQQ )**2.LE.ROOTEPS )
00532      +                            THEN
00533                                  IF( ( AAQQ.LT.ROOTBIG ) .AND.
00534      +                               ( AAQQ.GT.ROOTSFMIN ) ) THEN
00535                                     SVA( q ) = SNRM2( M, A( 1, q ), 1 )*
00536      +                                         D( q )
00537                                  ELSE
00538                                     T = ZERO
00539                                     AAQQ = ZERO
00540                                     CALL SLASSQ( M, A( 1, q ), 1, T,
00541      +                                           AAQQ )
00542                                     SVA( q ) = T*SQRT( AAQQ )*D( q )
00543                                  END IF
00544                               END IF
00545                               IF( ( AAPP / AAPP0 ).LE.ROOTEPS ) THEN
00546                                  IF( ( AAPP.LT.ROOTBIG ) .AND.
00547      +                               ( AAPP.GT.ROOTSFMIN ) ) THEN
00548                                     AAPP = SNRM2( M, A( 1, p ), 1 )*
00549      +                                     D( p )
00550                                  ELSE
00551                                     T = ZERO
00552                                     AAPP = ZERO
00553                                     CALL SLASSQ( M, A( 1, p ), 1, T,
00554      +                                           AAPP )
00555                                     AAPP = T*SQRT( AAPP )*D( p )
00556                                  END IF
00557                                  SVA( p ) = AAPP
00558                               END IF
00559 *
00560                            ELSE
00561 *        A(:,p) and A(:,q) already numerically orthogonal
00562                               IF( ir1.EQ.0 )NOTROT = NOTROT + 1
00563                               PSKIPPED = PSKIPPED + 1
00564                            END IF
00565                         ELSE
00566 *        A(:,q) is zero column
00567                            IF( ir1.EQ.0 )NOTROT = NOTROT + 1
00568                            PSKIPPED = PSKIPPED + 1
00569                         END IF
00570 *
00571                         IF( ( i.LE.SWBAND ) .AND.
00572      +                      ( PSKIPPED.GT.ROWSKIP ) ) THEN
00573                            IF( ir1.EQ.0 )AAPP = -AAPP
00574                            NOTROT = 0
00575                            GO TO 2103
00576                         END IF
00577 *
00578  2002                CONTINUE
00579 *     END q-LOOP
00580 *
00581  2103                CONTINUE
00582 *     bailed out of q-loop
00583 
00584                      SVA( p ) = AAPP
00585 
00586                   ELSE
00587                      SVA( p ) = AAPP
00588                      IF( ( ir1.EQ.0 ) .AND. ( AAPP.EQ.ZERO ) )
00589      +                   NOTROT = NOTROT + MIN0( igl+KBL-1, N ) - p
00590                   END IF
00591 *
00592  2001          CONTINUE
00593 *     end of the p-loop
00594 *     end of doing the block ( ibr, ibr )
00595  1002       CONTINUE
00596 *     end of ir1-loop
00597 *
00598 *........................................................
00599 * ... go to the off diagonal blocks
00600 *
00601             igl = ( ibr-1 )*KBL + 1
00602 *
00603             DO 2010 jbc = ibr + 1, NBL
00604 *
00605                jgl = ( jbc-1 )*KBL + 1
00606 *
00607 *        doing the block at ( ibr, jbc )
00608 *
00609                IJBLSK = 0
00610                DO 2100 p = igl, MIN0( igl+KBL-1, N )
00611 *
00612                   AAPP = SVA( p )
00613 *
00614                   IF( AAPP.GT.ZERO ) THEN
00615 *
00616                      PSKIPPED = 0
00617 *
00618                      DO 2200 q = jgl, MIN0( jgl+KBL-1, N )
00619 *
00620                         AAQQ = SVA( q )
00621 *
00622                         IF( AAQQ.GT.ZERO ) THEN
00623                            AAPP0 = AAPP
00624 *
00625 *     .. M x 2 Jacobi SVD ..
00626 *
00627 *        .. Safe Gram matrix computation ..
00628 *
00629                            IF( AAQQ.GE.ONE ) THEN
00630                               IF( AAPP.GE.AAQQ ) THEN
00631                                  ROTOK = ( SMALL*AAPP ).LE.AAQQ
00632                               ELSE
00633                                  ROTOK = ( SMALL*AAQQ ).LE.AAPP
00634                               END IF
00635                               IF( AAPP.LT.( BIG / AAQQ ) ) THEN
00636                                  AAPQ = ( SDOT( M, A( 1, p ), 1, A( 1,
00637      +                                  q ), 1 )*D( p )*D( q ) / AAQQ )
00638      +                                  / AAPP
00639                               ELSE
00640                                  CALL SCOPY( M, A( 1, p ), 1, WORK, 1 )
00641                                  CALL SLASCL( 'G', 0, 0, AAPP, D( p ),
00642      +                                        M, 1, WORK, LDA, IERR )
00643                                  AAPQ = SDOT( M, WORK, 1, A( 1, q ),
00644      +                                  1 )*D( q ) / AAQQ
00645                               END IF
00646                            ELSE
00647                               IF( AAPP.GE.AAQQ ) THEN
00648                                  ROTOK = AAPP.LE.( AAQQ / SMALL )
00649                               ELSE
00650                                  ROTOK = AAQQ.LE.( AAPP / SMALL )
00651                               END IF
00652                               IF( AAPP.GT.( SMALL / AAQQ ) ) THEN
00653                                  AAPQ = ( SDOT( M, A( 1, p ), 1, A( 1,
00654      +                                  q ), 1 )*D( p )*D( q ) / AAQQ )
00655      +                                  / AAPP
00656                               ELSE
00657                                  CALL SCOPY( M, A( 1, q ), 1, WORK, 1 )
00658                                  CALL SLASCL( 'G', 0, 0, AAQQ, D( q ),
00659      +                                        M, 1, WORK, LDA, IERR )
00660                                  AAPQ = SDOT( M, WORK, 1, A( 1, p ),
00661      +                                  1 )*D( p ) / AAPP
00662                               END IF
00663                            END IF
00664 *
00665                            MXAAPQ = AMAX1( MXAAPQ, ABS( AAPQ ) )
00666 *
00667 *        TO rotate or NOT to rotate, THAT is the question ...
00668 *
00669                            IF( ABS( AAPQ ).GT.TOL ) THEN
00670                               NOTROT = 0
00671 *           ROTATED  = ROTATED + 1
00672                               PSKIPPED = 0
00673                               ISWROT = ISWROT + 1
00674 *
00675                               IF( ROTOK ) THEN
00676 *
00677                                  AQOAP = AAQQ / AAPP
00678                                  APOAQ = AAPP / AAQQ
00679                                  THETA = -HALF*ABS( AQOAP-APOAQ ) / AAPQ
00680                                  IF( AAQQ.GT.AAPP0 )THETA = -THETA
00681 *
00682                                  IF( ABS( THETA ).GT.BIGTHETA ) THEN
00683                                     T = HALF / THETA
00684                                     FASTR( 3 ) = T*D( p ) / D( q )
00685                                     FASTR( 4 ) = -T*D( q ) / D( p )
00686                                     CALL SROTM( M, A( 1, p ), 1,
00687      +                                          A( 1, q ), 1, FASTR )
00688                                     IF( RSVEC )CALL SROTM( MVL,
00689      +                                              V( 1, p ), 1,
00690      +                                              V( 1, q ), 1,
00691      +                                              FASTR )
00692                                     SVA( q ) = AAQQ*SQRT( AMAX1( ZERO,
00693      +                                         ONE+T*APOAQ*AAPQ ) )
00694                                     AAPP = AAPP*SQRT( AMAX1( ZERO,
00695      +                                     ONE-T*AQOAP*AAPQ ) )
00696                                     MXSINJ = AMAX1( MXSINJ, ABS( T ) )
00697                                  ELSE
00698 *
00699 *                 .. choose correct signum for THETA and rotate
00700 *
00701                                     THSIGN = -SIGN( ONE, AAPQ )
00702                                     IF( AAQQ.GT.AAPP0 )THSIGN = -THSIGN
00703                                     T = ONE / ( THETA+THSIGN*
00704      +                                  SQRT( ONE+THETA*THETA ) )
00705                                     CS = SQRT( ONE / ( ONE+T*T ) )
00706                                     SN = T*CS
00707                                     MXSINJ = AMAX1( MXSINJ, ABS( SN ) )
00708                                     SVA( q ) = AAQQ*SQRT( AMAX1( ZERO,
00709      +                                         ONE+T*APOAQ*AAPQ ) )
00710                                     AAPP = AAPP*SQRT( ONE-T*AQOAP*AAPQ )
00711 *
00712                                     APOAQ = D( p ) / D( q )
00713                                     AQOAP = D( q ) / D( p )
00714                                     IF( D( p ).GE.ONE ) THEN
00715 *
00716                                        IF( D( q ).GE.ONE ) THEN
00717                                           FASTR( 3 ) = T*APOAQ
00718                                           FASTR( 4 ) = -T*AQOAP
00719                                           D( p ) = D( p )*CS
00720                                           D( q ) = D( q )*CS
00721                                           CALL SROTM( M, A( 1, p ), 1,
00722      +                                                A( 1, q ), 1,
00723      +                                                FASTR )
00724                                           IF( RSVEC )CALL SROTM( MVL,
00725      +                                        V( 1, p ), 1, V( 1, q ),
00726      +                                        1, FASTR )
00727                                        ELSE
00728                                           CALL SAXPY( M, -T*AQOAP,
00729      +                                                A( 1, q ), 1,
00730      +                                                A( 1, p ), 1 )
00731                                           CALL SAXPY( M, CS*SN*APOAQ,
00732      +                                                A( 1, p ), 1,
00733      +                                                A( 1, q ), 1 )
00734                                           IF( RSVEC ) THEN
00735                                              CALL SAXPY( MVL, -T*AQOAP,
00736      +                                                   V( 1, q ), 1,
00737      +                                                   V( 1, p ), 1 )
00738                                              CALL SAXPY( MVL,
00739      +                                                   CS*SN*APOAQ,
00740      +                                                   V( 1, p ), 1,
00741      +                                                   V( 1, q ), 1 )
00742                                           END IF
00743                                           D( p ) = D( p )*CS
00744                                           D( q ) = D( q ) / CS
00745                                        END IF
00746                                     ELSE
00747                                        IF( D( q ).GE.ONE ) THEN
00748                                           CALL SAXPY( M, T*APOAQ,
00749      +                                                A( 1, p ), 1,
00750      +                                                A( 1, q ), 1 )
00751                                           CALL SAXPY( M, -CS*SN*AQOAP,
00752      +                                                A( 1, q ), 1,
00753      +                                                A( 1, p ), 1 )
00754                                           IF( RSVEC ) THEN
00755                                              CALL SAXPY( MVL, T*APOAQ,
00756      +                                                   V( 1, p ), 1,
00757      +                                                   V( 1, q ), 1 )
00758                                              CALL SAXPY( MVL,
00759      +                                                   -CS*SN*AQOAP,
00760      +                                                   V( 1, q ), 1,
00761      +                                                   V( 1, p ), 1 )
00762                                           END IF
00763                                           D( p ) = D( p ) / CS
00764                                           D( q ) = D( q )*CS
00765                                        ELSE
00766                                           IF( D( p ).GE.D( q ) ) THEN
00767                                              CALL SAXPY( M, -T*AQOAP,
00768      +                                                   A( 1, q ), 1,
00769      +                                                   A( 1, p ), 1 )
00770                                              CALL SAXPY( M, CS*SN*APOAQ,
00771      +                                                   A( 1, p ), 1,
00772      +                                                   A( 1, q ), 1 )
00773                                              D( p ) = D( p )*CS
00774                                              D( q ) = D( q ) / CS
00775                                              IF( RSVEC ) THEN
00776                                                 CALL SAXPY( MVL,
00777      +                                               -T*AQOAP,
00778      +                                               V( 1, q ), 1,
00779      +                                               V( 1, p ), 1 )
00780                                                 CALL SAXPY( MVL,
00781      +                                               CS*SN*APOAQ,
00782      +                                               V( 1, p ), 1,
00783      +                                               V( 1, q ), 1 )
00784                                              END IF
00785                                           ELSE
00786                                              CALL SAXPY( M, T*APOAQ,
00787      +                                                   A( 1, p ), 1,
00788      +                                                   A( 1, q ), 1 )
00789                                              CALL SAXPY( M,
00790      +                                                   -CS*SN*AQOAP,
00791      +                                                   A( 1, q ), 1,
00792      +                                                   A( 1, p ), 1 )
00793                                              D( p ) = D( p ) / CS
00794                                              D( q ) = D( q )*CS
00795                                              IF( RSVEC ) THEN
00796                                                 CALL SAXPY( MVL,
00797      +                                               T*APOAQ, V( 1, p ),
00798      +                                               1, V( 1, q ), 1 )
00799                                                 CALL SAXPY( MVL,
00800      +                                               -CS*SN*AQOAP,
00801      +                                               V( 1, q ), 1,
00802      +                                               V( 1, p ), 1 )
00803                                              END IF
00804                                           END IF
00805                                        END IF
00806                                     END IF
00807                                  END IF
00808 *
00809                               ELSE
00810                                  IF( AAPP.GT.AAQQ ) THEN
00811                                     CALL SCOPY( M, A( 1, p ), 1, WORK,
00812      +                                          1 )
00813                                     CALL SLASCL( 'G', 0, 0, AAPP, ONE,
00814      +                                           M, 1, WORK, LDA, IERR )
00815                                     CALL SLASCL( 'G', 0, 0, AAQQ, ONE,
00816      +                                           M, 1, A( 1, q ), LDA,
00817      +                                           IERR )
00818                                     TEMP1 = -AAPQ*D( p ) / D( q )
00819                                     CALL SAXPY( M, TEMP1, WORK, 1,
00820      +                                          A( 1, q ), 1 )
00821                                     CALL SLASCL( 'G', 0, 0, ONE, AAQQ,
00822      +                                           M, 1, A( 1, q ), LDA,
00823      +                                           IERR )
00824                                     SVA( q ) = AAQQ*SQRT( AMAX1( ZERO,
00825      +                                         ONE-AAPQ*AAPQ ) )
00826                                     MXSINJ = AMAX1( MXSINJ, SFMIN )
00827                                  ELSE
00828                                     CALL SCOPY( M, A( 1, q ), 1, WORK,
00829      +                                          1 )
00830                                     CALL SLASCL( 'G', 0, 0, AAQQ, ONE,
00831      +                                           M, 1, WORK, LDA, IERR )
00832                                     CALL SLASCL( 'G', 0, 0, AAPP, ONE,
00833      +                                           M, 1, A( 1, p ), LDA,
00834      +                                           IERR )
00835                                     TEMP1 = -AAPQ*D( q ) / D( p )
00836                                     CALL SAXPY( M, TEMP1, WORK, 1,
00837      +                                          A( 1, p ), 1 )
00838                                     CALL SLASCL( 'G', 0, 0, ONE, AAPP,
00839      +                                           M, 1, A( 1, p ), LDA,
00840      +                                           IERR )
00841                                     SVA( p ) = AAPP*SQRT( AMAX1( ZERO,
00842      +                                         ONE-AAPQ*AAPQ ) )
00843                                     MXSINJ = AMAX1( MXSINJ, SFMIN )
00844                                  END IF
00845                               END IF
00846 *           END IF ROTOK THEN ... ELSE
00847 *
00848 *           In the case of cancellation in updating SVA(q)
00849 *           .. recompute SVA(q)
00850                               IF( ( SVA( q ) / AAQQ )**2.LE.ROOTEPS )
00851      +                            THEN
00852                                  IF( ( AAQQ.LT.ROOTBIG ) .AND.
00853      +                               ( AAQQ.GT.ROOTSFMIN ) ) THEN
00854                                     SVA( q ) = SNRM2( M, A( 1, q ), 1 )*
00855      +                                         D( q )
00856                                  ELSE
00857                                     T = ZERO
00858                                     AAQQ = ZERO
00859                                     CALL SLASSQ( M, A( 1, q ), 1, T,
00860      +                                           AAQQ )
00861                                     SVA( q ) = T*SQRT( AAQQ )*D( q )
00862                                  END IF
00863                               END IF
00864                               IF( ( AAPP / AAPP0 )**2.LE.ROOTEPS ) THEN
00865                                  IF( ( AAPP.LT.ROOTBIG ) .AND.
00866      +                               ( AAPP.GT.ROOTSFMIN ) ) THEN
00867                                     AAPP = SNRM2( M, A( 1, p ), 1 )*
00868      +                                     D( p )
00869                                  ELSE
00870                                     T = ZERO
00871                                     AAPP = ZERO
00872                                     CALL SLASSQ( M, A( 1, p ), 1, T,
00873      +                                           AAPP )
00874                                     AAPP = T*SQRT( AAPP )*D( p )
00875                                  END IF
00876                                  SVA( p ) = AAPP
00877                               END IF
00878 *              end of OK rotation
00879                            ELSE
00880                               NOTROT = NOTROT + 1
00881                               PSKIPPED = PSKIPPED + 1
00882                               IJBLSK = IJBLSK + 1
00883                            END IF
00884                         ELSE
00885                            NOTROT = NOTROT + 1
00886                            PSKIPPED = PSKIPPED + 1
00887                            IJBLSK = IJBLSK + 1
00888                         END IF
00889 *
00890                         IF( ( i.LE.SWBAND ) .AND. ( IJBLSK.GE.BLSKIP ) )
00891      +                      THEN
00892                            SVA( p ) = AAPP
00893                            NOTROT = 0
00894                            GO TO 2011
00895                         END IF
00896                         IF( ( i.LE.SWBAND ) .AND.
00897      +                      ( PSKIPPED.GT.ROWSKIP ) ) THEN
00898                            AAPP = -AAPP
00899                            NOTROT = 0
00900                            GO TO 2203
00901                         END IF
00902 *
00903  2200                CONTINUE
00904 *        end of the q-loop
00905  2203                CONTINUE
00906 *
00907                      SVA( p ) = AAPP
00908 *
00909                   ELSE
00910                      IF( AAPP.EQ.ZERO )NOTROT = NOTROT +
00911      +                   MIN0( jgl+KBL-1, N ) - jgl + 1
00912                      IF( AAPP.LT.ZERO )NOTROT = 0
00913                   END IF
00914 
00915  2100          CONTINUE
00916 *     end of the p-loop
00917  2010       CONTINUE
00918 *     end of the jbc-loop
00919  2011       CONTINUE
00920 *2011 bailed out of the jbc-loop
00921             DO 2012 p = igl, MIN0( igl+KBL-1, N )
00922                SVA( p ) = ABS( SVA( p ) )
00923  2012       CONTINUE
00924 *
00925  2000    CONTINUE
00926 *2000 :: end of the ibr-loop
00927 *
00928 *     .. update SVA(N)
00929          IF( ( SVA( N ).LT.ROOTBIG ) .AND. ( SVA( N ).GT.ROOTSFMIN ) )
00930      +       THEN
00931             SVA( N ) = SNRM2( M, A( 1, N ), 1 )*D( N )
00932          ELSE
00933             T = ZERO
00934             AAPP = ZERO
00935             CALL SLASSQ( M, A( 1, N ), 1, T, AAPP )
00936             SVA( N ) = T*SQRT( AAPP )*D( N )
00937          END IF
00938 *
00939 *     Additional steering devices
00940 *
00941          IF( ( i.LT.SWBAND ) .AND. ( ( MXAAPQ.LE.ROOTTOL ) .OR.
00942      +       ( ISWROT.LE.N ) ) )SWBAND = i
00943 *
00944          IF( ( i.GT.SWBAND+1 ) .AND. ( MXAAPQ.LT.FLOAT( N )*TOL ) .AND.
00945      +       ( FLOAT( N )*MXAAPQ*MXSINJ.LT.TOL ) ) THEN
00946             GO TO 1994
00947          END IF
00948 *
00949          IF( NOTROT.GE.EMPTSW )GO TO 1994
00950 
00951  1993 CONTINUE
00952 *     end i=1:NSWEEP loop
00953 * #:) Reaching this point means that the procedure has comleted the given
00954 *     number of iterations.
00955       INFO = NSWEEP - 1
00956       GO TO 1995
00957  1994 CONTINUE
00958 * #:) Reaching this point means that during the i-th sweep all pivots were
00959 *     below the given tolerance, causing early exit.
00960 *
00961       INFO = 0
00962 * #:) INFO = 0 confirms successful iterations.
00963  1995 CONTINUE
00964 *
00965 *     Sort the vector D.
00966       DO 5991 p = 1, N - 1
00967          q = ISAMAX( N-p+1, SVA( p ), 1 ) + p - 1
00968          IF( p.NE.q ) THEN
00969             TEMP1 = SVA( p )
00970             SVA( p ) = SVA( q )
00971             SVA( q ) = TEMP1
00972             TEMP1 = D( p )
00973             D( p ) = D( q )
00974             D( q ) = TEMP1
00975             CALL SSWAP( M, A( 1, p ), 1, A( 1, q ), 1 )
00976             IF( RSVEC )CALL SSWAP( MVL, V( 1, p ), 1, V( 1, q ), 1 )
00977          END IF
00978  5991 CONTINUE
00979 *
00980       RETURN
00981 *     ..
00982 *     .. END OF SGSVJ0
00983 *     ..
00984       END