LAPACK: SRC/sgejsv.f Source File

00001       SUBROUTINE SGEJSV( JOBA, JOBU, JOBV, JOBR, JOBT, JOBP,
00002      &                   M, N, A, LDA, SVA, U, LDU, V, LDV,
00003      &                   WORK, LWORK, IWORK, INFO )
00004 *
00005 *  -- LAPACK routine (version 3.2.1)                                    --
00006 *
00007 *  -- Contributed by Zlatko Drmac of the University of Zagreb and     --
00008 *  -- Kresimir Veselic of the Fernuniversitaet Hagen                  --
00009 *  -- April 2009                                                      --
00010 *
00011 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00012 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00013 *
00014 * This routine is also part of SIGMA (version 1.23, October 23. 2008.)
00015 * SIGMA is a library of algorithms for highly accurate algorithms for
00016 * computation of SVD, PSVD, QSVD, (H,K)-SVD, and for solution of the
00017 * eigenvalue problems Hx = lambda M x, H M x = lambda x with H, M > 0.
00018 *
00019 *     .. Scalar Arguments ..
00020 *
00021       IMPLICIT    NONE
00022       INTEGER     INFO, LDA, LDU, LDV, LWORK, M, N
00023 *
00024 *     .. Array Arguments ..
00025 *
00026       REAL        A( LDA, * ), SVA( N ), U( LDU, * ), V( LDV, * ),
00027      &            WORK( LWORK )
00028       INTEGER     IWORK( * )
00029       CHARACTER*1 JOBA, JOBP, JOBR, JOBT, JOBU, JOBV
00030 *     ..
00031 *
00032 *  Purpose
00033 *  =======
00034 *  SGEJSV computes the singular value decomposition (SVD) of a real M-by-N
00035 *  matrix [A], where M >= N. The SVD of [A] is written as
00036 *
00037 *               [A] = [U] * [SIGMA] * [V]^t,
00038 *
00039 *  where [SIGMA] is an N-by-N (M-by-N) matrix which is zero except for its N
00040 *  diagonal elements, [U] is an M-by-N (or M-by-M) orthonormal matrix, and
00041 *  [V] is an N-by-N orthogonal matrix. The diagonal elements of [SIGMA] are
00042 *  the singular values of [A]. The columns of [U] and [V] are the left and
00043 *  the right singular vectors of [A], respectively. The matrices [U] and [V]
00044 *  are computed and stored in the arrays U and V, respectively. The diagonal
00045 *  of [SIGMA] is computed and stored in the array SVA.
00046 *
00047 *  Arguments
00048 *  =========
00049 *
00050 *  JOBA   (input) CHARACTER*1
00051 *         Specifies the level of accuracy:
00052 *       = 'C': This option works well (high relative accuracy) if A = B * D,
00053 *              with well-conditioned B and arbitrary diagonal matrix D.
00054 *              The accuracy cannot be spoiled by COLUMN scaling. The
00055 *              accuracy of the computed output depends on the condition of
00056 *              B, and the procedure aims at the best theoretical accuracy.
00057 *              The relative error max_{i=1:N}|d sigma_i| / sigma_i is
00058 *              bounded by f(M,N)*epsilon* cond(B), independent of D.
00059 *              The input matrix is preprocessed with the QRF with column
00060 *              pivoting. This initial preprocessing and preconditioning by
00061 *              a rank revealing QR factorization is common for all values of
00062 *              JOBA. Additional actions are specified as follows:
00063 *       = 'E': Computation as with 'C' with an additional estimate of the
00064 *              condition number of B. It provides a realistic error bound.
00065 *       = 'F': If A = D1 * C * D2 with ill-conditioned diagonal scalings
00066 *              D1, D2, and well-conditioned matrix C, this option gives
00067 *              higher accuracy than the 'C' option. If the structure of the
00068 *              input matrix is not known, and relative accuracy is
00069 *              desirable, then this option is advisable. The input matrix A
00070 *              is preprocessed with QR factorization with FULL (row and
00071 *              column) pivoting.
00072 *       = 'G'  Computation as with 'F' with an additional estimate of the
00073 *              condition number of B, where A=D*B. If A has heavily weighted
00074 *              rows, then using this condition number gives too pessimistic
00075 *              error bound.
00076 *       = 'A': Small singular values are the noise and the matrix is treated
00077 *              as numerically rank defficient. The error in the computed
00078 *              singular values is bounded by f(m,n)*epsilon*||A||.
00079 *              The computed SVD A = U * S * V^t restores A up to
00080 *              f(m,n)*epsilon*||A||.
00081 *              This gives the procedure the licence to discard (set to zero)
00082 *              all singular values below N*epsilon*||A||.
00083 *       = 'R': Similar as in 'A'. Rank revealing property of the initial
00084 *              QR factorization is used do reveal (using triangular factor)
00085 *              a gap sigma_{r+1} < epsilon * sigma_r in which case the
00086 *              numerical RANK is declared to be r. The SVD is computed with
00087 *              absolute error bounds, but more accurately than with 'A'.
00088 * 
00089 *  JOBU   (input) CHARACTER*1
00090 *         Specifies whether to compute the columns of U:
00091 *       = 'U': N columns of U are returned in the array U.
00092 *       = 'F': full set of M left sing. vectors is returned in the array U.
00093 *       = 'W': U may be used as workspace of length M*N. See the description
00094 *              of U.
00095 *       = 'N': U is not computed.
00096 * 
00097 *  JOBV   (input) CHARACTER*1
00098 *         Specifies whether to compute the matrix V:
00099 *       = 'V': N columns of V are returned in the array V; Jacobi rotations
00100 *              are not explicitly accumulated.
00101 *       = 'J': N columns of V are returned in the array V, but they are
00102 *              computed as the product of Jacobi rotations. This option is
00103 *              allowed only if JOBU .NE. 'N', i.e. in computing the full SVD.
00104 *       = 'W': V may be used as workspace of length N*N. See the description
00105 *              of V.
00106 *       = 'N': V is not computed.
00107 * 
00108 *  JOBR   (input) CHARACTER*1
00109 *         Specifies the RANGE for the singular values. Issues the licence to
00110 *         set to zero small positive singular values if they are outside
00111 *         specified range. If A .NE. 0 is scaled so that the largest singular
00112 *         value of c*A is around SQRT(BIG), BIG=SLAMCH('O'), then JOBR issues
00113 *         the licence to kill columns of A whose norm in c*A is less than
00114 *         SQRT(SFMIN) (for JOBR.EQ.'R'), or less than SMALL=SFMIN/EPSLN,
00115 *         where SFMIN=SLAMCH('S'), EPSLN=SLAMCH('E').
00116 *       = 'N': Do not kill small columns of c*A. This option assumes that
00117 *              BLAS and QR factorizations and triangular solvers are
00118 *              implemented to work in that range. If the condition of A
00119 *              is greater than BIG, use SGESVJ.
00120 *       = 'R': RESTRICTED range for sigma(c*A) is [SQRT(SFMIN), SQRT(BIG)]
00121 *              (roughly, as described above). This option is recommended.
00122 *                                             ===========================
00123 *         For computing the singular values in the FULL range [SFMIN,BIG]
00124 *         use SGESVJ.
00125 * 
00126 *  JOBT   (input) CHARACTER*1
00127 *         If the matrix is square then the procedure may determine to use
00128 *         transposed A if A^t seems to be better with respect to convergence.
00129 *         If the matrix is not square, JOBT is ignored. This is subject to
00130 *         changes in the future.
00131 *         The decision is based on two values of entropy over the adjoint
00132 *         orbit of A^t * A. See the descriptions of WORK(6) and WORK(7).
00133 *       = 'T': transpose if entropy test indicates possibly faster
00134 *         convergence of Jacobi process if A^t is taken as input. If A is
00135 *         replaced with A^t, then the row pivoting is included automatically.
00136 *       = 'N': do not speculate.
00137 *         This option can be used to compute only the singular values, or the
00138 *         full SVD (U, SIGMA and V). For only one set of singular vectors
00139 *         (U or V), the caller should provide both U and V, as one of the
00140 *         matrices is used as workspace if the matrix A is transposed.
00141 *         The implementer can easily remove this constraint and make the
00142 *         code more complicated. See the descriptions of U and V.
00143 * 
00144 *  JOBP   (input) CHARACTER*1
00145 *         Issues the licence to introduce structured perturbations to drown
00146 *         denormalized numbers. This licence should be active if the
00147 *         denormals are poorly implemented, causing slow computation,
00148 *         especially in cases of fast convergence (!). For details see [1,2].
00149 *         For the sake of simplicity, this perturbations are included only
00150 *         when the full SVD or only the singular values are requested. The
00151 *         implementer/user can easily add the perturbation for the cases of
00152 *         computing one set of singular vectors.
00153 *       = 'P': introduce perturbation
00154 *       = 'N': do not perturb
00155 *
00156 *  M      (input) INTEGER
00157 *         The number of rows of the input matrix A.  M >= 0.
00158 *
00159 *  N      (input) INTEGER
00160 *         The number of columns of the input matrix A. M >= N >= 0.
00161 *
00162 *  A       (input/workspace) REAL array, dimension (LDA,N)
00163 *          On entry, the M-by-N matrix A.
00164 *
00165 *  LDA     (input) INTEGER
00166 *          The leading dimension of the array A.  LDA >= max(1,M).
00167 *
00168 *  SVA     (workspace/output) REAL array, dimension (N)
00169 *          On exit,
00170 *          - For WORK(1)/WORK(2) = ONE: The singular values of A. During the
00171 *            computation SVA contains Euclidean column norms of the
00172 *            iterated matrices in the array A.
00173 *          - For WORK(1) .NE. WORK(2): The singular values of A are
00174 *            (WORK(1)/WORK(2)) * SVA(1:N). This factored form is used if
00175 *            sigma_max(A) overflows or if small singular values have been
00176 *            saved from underflow by scaling the input matrix A.
00177 *          - If JOBR='R' then some of the singular values may be returned
00178 *            as exact zeros obtained by "set to zero" because they are
00179 *            below the numerical rank threshold or are denormalized numbers.
00180 *
00181 *  U       (workspace/output) REAL array, dimension ( LDU, N )
00182 *          If JOBU = 'U', then U contains on exit the M-by-N matrix of
00183 *                         the left singular vectors.
00184 *          If JOBU = 'F', then U contains on exit the M-by-M matrix of
00185 *                         the left singular vectors, including an ONB
00186 *                         of the orthogonal complement of the Range(A).
00187 *          If JOBU = 'W'  .AND. (JOBV.EQ.'V' .AND. JOBT.EQ.'T' .AND. M.EQ.N),
00188 *                         then U is used as workspace if the procedure
00189 *                         replaces A with A^t. In that case, [V] is computed
00190 *                         in U as left singular vectors of A^t and then
00191 *                         copied back to the V array. This 'W' option is just
00192 *                         a reminder to the caller that in this case U is
00193 *                         reserved as workspace of length N*N.
00194 *          If JOBU = 'N'  U is not referenced.
00195 *
00196 * LDU      (input) INTEGER
00197 *          The leading dimension of the array U,  LDU >= 1.
00198 *          IF  JOBU = 'U' or 'F' or 'W',  then LDU >= M.
00199 *
00200 *  V       (workspace/output) REAL array, dimension ( LDV, N )
00201 *          If JOBV = 'V', 'J' then V contains on exit the N-by-N matrix of
00202 *                         the right singular vectors;
00203 *          If JOBV = 'W', AND (JOBU.EQ.'U' AND JOBT.EQ.'T' AND M.EQ.N),
00204 *                         then V is used as workspace if the pprocedure
00205 *                         replaces A with A^t. In that case, [U] is computed
00206 *                         in V as right singular vectors of A^t and then
00207 *                         copied back to the U array. This 'W' option is just
00208 *                         a reminder to the caller that in this case V is
00209 *                         reserved as workspace of length N*N.
00210 *          If JOBV = 'N'  V is not referenced.
00211 *
00212 *  LDV     (input) INTEGER
00213 *          The leading dimension of the array V,  LDV >= 1.
00214 *          If JOBV = 'V' or 'J' or 'W', then LDV >= N.
00215 *
00216 *  WORK    (workspace/output) REAL array, dimension at least LWORK.
00217 *          On exit,
00218 *          WORK(1) = SCALE = WORK(2) / WORK(1) is the scaling factor such
00219 *                    that SCALE*SVA(1:N) are the computed singular values
00220 *                    of A. (See the description of SVA().)
00221 *          WORK(2) = See the description of WORK(1).
00222 *          WORK(3) = SCONDA is an estimate for the condition number of
00223 *                    column equilibrated A. (If JOBA .EQ. 'E' or 'G')
00224 *                    SCONDA is an estimate of SQRT(||(R^t * R)^(-1)||_1).
00225 *                    It is computed using SPOCON. It holds
00226 *                    N^(-1/4) * SCONDA <= ||R^(-1)||_2 <= N^(1/4) * SCONDA
00227 *                    where R is the triangular factor from the QRF of A.
00228 *                    However, if R is truncated and the numerical rank is
00229 *                    determined to be strictly smaller than N, SCONDA is
00230 *                    returned as -1, thus indicating that the smallest
00231 *                    singular values might be lost.
00232 *
00233 *          If full SVD is needed, the following two condition numbers are
00234 *          useful for the analysis of the algorithm. They are provied for
00235 *          a developer/implementer who is familiar with the details of
00236 *          the method.
00237 *
00238 *          WORK(4) = an estimate of the scaled condition number of the
00239 *                    triangular factor in the first QR factorization.
00240 *          WORK(5) = an estimate of the scaled condition number of the
00241 *                    triangular factor in the second QR factorization.
00242 *          The following two parameters are computed if JOBT .EQ. 'T'.
00243 *          They are provided for a developer/implementer who is familiar
00244 *          with the details of the method.
00245 *
00246 *          WORK(6) = the entropy of A^t*A :: this is the Shannon entropy
00247 *                    of diag(A^t*A) / Trace(A^t*A) taken as point in the
00248 *                    probability simplex.
00249 *          WORK(7) = the entropy of A*A^t.
00250 *
00251 *  LWORK   (input) INTEGER
00252 *          Length of WORK to confirm proper allocation of work space.
00253 *          LWORK depends on the job:
00254 *
00255 *          If only SIGMA is needed ( JOBU.EQ.'N', JOBV.EQ.'N' ) and
00256 *            -> .. no scaled condition estimate required ( JOBE.EQ.'N'):
00257 *               LWORK >= max(2*M+N,4*N+1,7). This is the minimal requirement.
00258 *               For optimal performance (blocked code) the optimal value
00259 *               is LWORK >= max(2*M+N,3*N+(N+1)*NB,7). Here NB is the optimal
00260 *               block size for xGEQP3/xGEQRF.
00261 *            -> .. an estimate of the scaled condition number of A is
00262 *               required (JOBA='E', 'G'). In this case, LWORK is the maximum
00263 *               of the above and N*N+4*N, i.e. LWORK >= max(2*M+N,N*N+4N,7).
00264 *
00265 *          If SIGMA and the right singular vectors are needed (JOBV.EQ.'V'),
00266 *            -> the minimal requirement is LWORK >= max(2*N+M,7).
00267 *            -> For optimal performance, LWORK >= max(2*N+M,2*N+N*NB,7),
00268 *               where NB is the optimal block size.
00269 *
00270 *          If SIGMA and the left singular vectors are needed
00271 *            -> the minimal requirement is LWORK >= max(2*N+M,7).
00272 *            -> For optimal performance, LWORK >= max(2*N+M,2*N+N*NB,7),
00273 *               where NB is the optimal block size.
00274 *
00275 *          If full SVD is needed ( JOBU.EQ.'U' or 'F', JOBV.EQ.'V' ) and
00276 *            -> .. the singular vectors are computed without explicit
00277 *               accumulation of the Jacobi rotations, LWORK >= 6*N+2*N*N
00278 *            -> .. in the iterative part, the Jacobi rotations are
00279 *               explicitly accumulated (option, see the description of JOBV),
00280 *               then the minimal requirement is LWORK >= max(M+3*N+N*N,7).
00281 *               For better performance, if NB is the optimal block size,
00282 *               LWORK >= max(3*N+N*N+M,3*N+N*N+N*NB,7).
00283 *
00284 *  IWORK   (workspace/output) INTEGER array, dimension M+3*N.
00285 *          On exit,
00286 *          IWORK(1) = the numerical rank determined after the initial
00287 *                     QR factorization with pivoting. See the descriptions
00288 *                     of JOBA and JOBR.
00289 *          IWORK(2) = the number of the computed nonzero singular values
00290 *          IWORK(3) = if nonzero, a warning message:
00291 *                     If IWORK(3).EQ.1 then some of the column norms of A
00292 *                     were denormalized floats. The requested high accuracy
00293 *                     is not warranted by the data.
00294 *
00295 *  INFO    (output) INTEGER
00296 *           < 0  : if INFO = -i, then the i-th argument had an illegal value.
00297 *           = 0 :  successfull exit;
00298 *           > 0 :  SGEJSV  did not converge in the maximal allowed number
00299 *                  of sweeps. The computed values may be inaccurate.
00300 *
00301 *  Further Details
00302 *  ===============
00303 *
00304 *  SGEJSV implements a preconditioned Jacobi SVD algorithm. It uses SGEQP3,
00305 *  SGEQRF, and SGELQF as preprocessors and preconditioners. Optionally, an
00306 *  additional row pivoting can be used as a preprocessor, which in some
00307 *  cases results in much higher accuracy. An example is matrix A with the
00308 *  structure A = D1 * C * D2, where D1, D2 are arbitrarily ill-conditioned
00309 *  diagonal matrices and C is well-conditioned matrix. In that case, complete
00310 *  pivoting in the first QR factorizations provides accuracy dependent on the
00311 *  condition number of C, and independent of D1, D2. Such higher accuracy is
00312 *  not completely understood theoretically, but it works well in practice.
00313 *  Further, if A can be written as A = B*D, with well-conditioned B and some
00314 *  diagonal D, then the high accuracy is guaranteed, both theoretically and
00315 *  in software, independent of D. For more details see [1], [2].
00316 *     The computational range for the singular values can be the full range
00317 *  ( UNDERFLOW,OVERFLOW ), provided that the machine arithmetic and the BLAS
00318 *  & LAPACK routines called by SGEJSV are implemented to work in that range.
00319 *  If that is not the case, then the restriction for safe computation with
00320 *  the singular values in the range of normalized IEEE numbers is that the
00321 *  spectral condition number kappa(A)=sigma_max(A)/sigma_min(A) does not
00322 *  overflow. This code (SGEJSV) is best used in this restricted range,
00323 *  meaning that singular values of magnitude below ||A||_2 / SLAMCH('O') are
00324 *  returned as zeros. See JOBR for details on this.
00325 *     Further, this implementation is somewhat slower than the one described
00326 *  in [1,2] due to replacement of some non-LAPACK components, and because
00327 *  the choice of some tuning parameters in the iterative part (SGESVJ) is
00328 *  left to the implementer on a particular machine.
00329 *     The rank revealing QR factorization (in this code: SGEQP3) should be
00330 *  implemented as in [3]. We have a new version of SGEQP3 under development
00331 *  that is more robust than the current one in LAPACK, with a cleaner cut in
00332 *  rank defficient cases. It will be available in the SIGMA library [4].
00333 *  If M is much larger than N, it is obvious that the inital QRF with
00334 *  column pivoting can be preprocessed by the QRF without pivoting. That
00335 *  well known trick is not used in SGEJSV because in some cases heavy row
00336 *  weighting can be treated with complete pivoting. The overhead in cases
00337 *  M much larger than N is then only due to pivoting, but the benefits in
00338 *  terms of accuracy have prevailed. The implementer/user can incorporate
00339 *  this extra QRF step easily. The implementer can also improve data movement
00340 *  (matrix transpose, matrix copy, matrix transposed copy) - this
00341 *  implementation of SGEJSV uses only the simplest, naive data movement.
00342 *
00343 *  Contributors
00344 *
00345 *  Zlatko Drmac (Zagreb, Croatia) and Kresimir Veselic (Hagen, Germany)
00346 *
00347 *  References
00348 *
00349 * [1] Z. Drmac and K. Veselic: New fast and accurate Jacobi SVD algorithm I.
00350 *     SIAM J. Matrix Anal. Appl. Vol. 35, No. 2 (2008), pp. 1322-1342.
00351 *     LAPACK Working note 169.
00352 * [2] Z. Drmac and K. Veselic: New fast and accurate Jacobi SVD algorithm II.
00353 *     SIAM J. Matrix Anal. Appl. Vol. 35, No. 2 (2008), pp. 1343-1362.
00354 *     LAPACK Working note 170.
00355 * [3] Z. Drmac and Z. Bujanovic: On the failure of rank-revealing QR
00356 *     factorization software - a case study.
00357 *     ACM Trans. math. Softw. Vol. 35, No 2 (2008), pp. 1-28.
00358 *     LAPACK Working note 176.
00359 * [4] Z. Drmac: SIGMA - mathematical software library for accurate SVD, PSV,
00360 *     QSVD, (H,K)-SVD computations.
00361 *     Department of Mathematics, University of Zagreb, 2008.
00362 *
00363 *  Bugs, examples and comments
00364 *
00365 *  Please report all bugs and send interesting examples and/or comments to
00366 *  drmac@math.hr. Thank you.
00367 *
00368 *  ===========================================================================
00369 *
00370 *     .. Local Parameters ..
00371       REAL        ZERO,         ONE
00372       PARAMETER ( ZERO = 0.0E0, ONE = 1.0E0 )
00373 *     ..
00374 *     .. Local Scalars ..
00375       REAL    AAPP,   AAQQ,   AATMAX, AATMIN, BIG,    BIG1,   COND_OK,
00376      &        CONDR1, CONDR2, ENTRA,  ENTRAT, EPSLN,  MAXPRJ, SCALEM,
00377      &        SCONDA, SFMIN,  SMALL,  TEMP1,  USCAL1, USCAL2, XSC
00378       INTEGER IERR,   N1,     NR,     NUMRANK,        p, q,   WARNING
00379       LOGICAL ALMORT, DEFR,   ERREST, GOSCAL, JRACC,  KILL,   LSVEC,
00380      &        L2ABER, L2KILL, L2PERT, L2RANK, L2TRAN,
00381      &        NOSCAL, ROWPIV, RSVEC,  TRANSP
00382 *     ..
00383 *     .. Intrinsic Functions ..
00384       INTRINSIC ABS,  ALOG, AMAX1, AMIN1, FLOAT,
00385      &          MAX0, MIN0, NINT,  SIGN,  SQRT
00386 *     ..
00387 *     .. External Functions ..
00388       REAL      SLAMCH, SNRM2
00389       INTEGER   ISAMAX
00390       LOGICAL   LSAME
00391       EXTERNAL  ISAMAX, LSAME, SLAMCH, SNRM2
00392 *     ..
00393 *     .. External Subroutines ..
00394       EXTERNAL  SCOPY,  SGELQF, SGEQP3, SGEQRF, SLACPY, SLASCL,
00395      &          SLASET, SLASSQ, SLASWP, SORGQR, SORMLQ,
00396      &          SORMQR, SPOCON, SSCAL,  SSWAP,  STRSM,  XERBLA
00397 *
00398       EXTERNAL  SGESVJ
00399 *     ..
00400 *
00401 *     Test the input arguments
00402 *
00403       LSVEC  = LSAME( JOBU, 'U' ) .OR. LSAME( JOBU, 'F' )
00404       JRACC  = LSAME( JOBV, 'J' )
00405       RSVEC  = LSAME( JOBV, 'V' ) .OR. JRACC
00406       ROWPIV = LSAME( JOBA, 'F' ) .OR. LSAME( JOBA, 'G' )
00407       L2RANK = LSAME( JOBA, 'R' )
00408       L2ABER = LSAME( JOBA, 'A' )
00409       ERREST = LSAME( JOBA, 'E' ) .OR. LSAME( JOBA, 'G' )
00410       L2TRAN = LSAME( JOBT, 'T' )
00411       L2KILL = LSAME( JOBR, 'R' )
00412       DEFR   = LSAME( JOBR, 'N' )
00413       L2PERT = LSAME( JOBP, 'P' )
00414 *
00415       IF ( .NOT.(ROWPIV .OR. L2RANK .OR. L2ABER .OR.
00416      &     ERREST .OR. LSAME( JOBA, 'C' ) )) THEN
00417          INFO = - 1
00418       ELSE IF ( .NOT.( LSVEC  .OR. LSAME( JOBU, 'N' ) .OR.
00419      &                             LSAME( JOBU, 'W' )) ) THEN
00420          INFO = - 2
00421       ELSE IF ( .NOT.( RSVEC .OR. LSAME( JOBV, 'N' ) .OR.
00422      &   LSAME( JOBV, 'W' )) .OR. ( JRACC .AND. (.NOT.LSVEC) ) ) THEN
00423          INFO = - 3
00424       ELSE IF ( .NOT. ( L2KILL .OR. DEFR ) )    THEN
00425          INFO = - 4
00426       ELSE IF ( .NOT. ( L2TRAN .OR. LSAME( JOBT, 'N' ) ) ) THEN
00427          INFO = - 5
00428       ELSE IF ( .NOT. ( L2PERT .OR. LSAME( JOBP, 'N' ) ) ) THEN
00429          INFO = - 6
00430       ELSE IF ( M .LT. 0 ) THEN
00431          INFO = - 7
00432       ELSE IF ( ( N .LT. 0 ) .OR. ( N .GT. M ) ) THEN
00433          INFO = - 8
00434       ELSE IF ( LDA .LT. M ) THEN
00435          INFO = - 10
00436       ELSE IF ( LSVEC .AND. ( LDU .LT. M ) ) THEN
00437          INFO = - 13
00438       ELSE IF ( RSVEC .AND. ( LDV .LT. N ) ) THEN
00439          INFO = - 14
00440       ELSE IF ( (.NOT.(LSVEC .OR. RSVEC .OR. ERREST).AND.
00441      &                           (LWORK .LT. MAX0(7,4*N+1,2*M+N))) .OR.
00442      & (.NOT.(LSVEC .OR. LSVEC) .AND. ERREST .AND.
00443      &                         (LWORK .LT. MAX0(7,4*N+N*N,2*M+N))) .OR.
00444      & (LSVEC .AND. (.NOT.RSVEC) .AND. (LWORK .LT. MAX0(7,2*N+M))) .OR.
00445      & (RSVEC .AND. (.NOT.LSVEC) .AND. (LWORK .LT. MAX0(7,2*N+M))) .OR.
00446      & (LSVEC .AND. RSVEC .AND. .NOT.JRACC .AND. (LWORK.LT.6*N+2*N*N))
00447      & .OR. (LSVEC.AND.RSVEC.AND.JRACC.AND.LWORK.LT.MAX0(7,M+3*N+N*N)))
00448      &   THEN
00449          INFO = - 17
00450       ELSE
00451 *        #:)
00452          INFO = 0
00453       END IF
00454 *
00455       IF ( INFO .NE. 0 ) THEN
00456 *       #:(
00457          CALL XERBLA( 'SGEJSV', - INFO )
00458       END IF
00459 *
00460 *     Quick return for void matrix (Y3K safe)
00461 * #:)
00462       IF ( ( M .EQ. 0 ) .OR. ( N .EQ. 0 ) ) RETURN
00463 *
00464 *     Determine whether the matrix U should be M x N or M x M
00465 *
00466       IF ( LSVEC ) THEN
00467          N1 = N
00468          IF ( LSAME( JOBU, 'F' ) ) N1 = M
00469       END IF
00470 *
00471 *     Set numerical parameters
00472 *
00473 *!    NOTE: Make sure SLAMCH() does not fail on the target architecture.
00474 *
00475       EPSLN = SLAMCH('Epsilon')
00476       SFMIN = SLAMCH('SafeMinimum')
00477       SMALL = SFMIN / EPSLN
00478       BIG   = SLAMCH('O')
00479 *
00480 *     Initialize SVA(1:N) = diag( ||A e_i||_2 )_1^N
00481 *
00482 *(!)  If necessary, scale SVA() to protect the largest norm from
00483 *     overflow. It is possible that this scaling pushes the smallest
00484 *     column norm left from the underflow threshold (extreme case).
00485 *
00486       SCALEM  = ONE / SQRT(FLOAT(M)*FLOAT(N))
00487       NOSCAL  = .TRUE.
00488       GOSCAL  = .TRUE.
00489       DO 1874 p = 1, N
00490          AAPP = ZERO
00491          AAQQ = ZERO
00492          CALL SLASSQ( M, A(1,p), 1, AAPP, AAQQ )
00493          IF ( AAPP .GT. BIG ) THEN
00494             INFO = - 9
00495             CALL XERBLA( 'SGEJSV', -INFO )
00496             RETURN
00497          END IF
00498          AAQQ = SQRT(AAQQ)
00499          IF ( ( AAPP .LT. (BIG / AAQQ) ) .AND. NOSCAL  ) THEN
00500             SVA(p)  = AAPP * AAQQ
00501          ELSE
00502             NOSCAL  = .FALSE.
00503             SVA(p)  = AAPP * ( AAQQ * SCALEM )
00504             IF ( GOSCAL ) THEN
00505                GOSCAL = .FALSE.
00506                CALL SSCAL( p-1, SCALEM, SVA, 1 )
00507             END IF
00508          END IF
00509  1874 CONTINUE
00510 *
00511       IF ( NOSCAL ) SCALEM = ONE
00512 *
00513       AAPP = ZERO
00514       AAQQ = BIG
00515       DO 4781 p = 1, N
00516          AAPP = AMAX1( AAPP, SVA(p) )
00517          IF ( SVA(p) .NE. ZERO ) AAQQ = AMIN1( AAQQ, SVA(p) )
00518  4781 CONTINUE
00519 *
00520 *     Quick return for zero M x N matrix
00521 * #:)
00522       IF ( AAPP .EQ. ZERO ) THEN
00523          IF ( LSVEC ) CALL SLASET( 'G', M, N1, ZERO, ONE, U, LDU )
00524          IF ( RSVEC ) CALL SLASET( 'G', N, N,  ZERO, ONE, V, LDV )
00525          WORK(1) = ONE
00526          WORK(2) = ONE
00527          IF ( ERREST ) WORK(3) = ONE
00528          IF ( LSVEC .AND. RSVEC ) THEN
00529             WORK(4) = ONE
00530             WORK(5) = ONE
00531          END IF
00532          IF ( L2TRAN ) THEN
00533             WORK(6) = ZERO
00534             WORK(7) = ZERO
00535          END IF
00536          IWORK(1) = 0
00537          IWORK(2) = 0
00538          RETURN
00539       END IF
00540 *
00541 *     Issue warning if denormalized column norms detected. Override the
00542 *     high relative accuracy request. Issue licence to kill columns
00543 *     (set them to zero) whose norm is less than sigma_max / BIG (roughly).
00544 * #:(
00545       WARNING = 0
00546       IF ( AAQQ .LE. SFMIN ) THEN
00547          L2RANK = .TRUE.
00548          L2KILL = .TRUE.
00549          WARNING = 1
00550       END IF
00551 *
00552 *     Quick return for one-column matrix
00553 * #:)
00554       IF ( N .EQ. 1 ) THEN
00555 *
00556          IF ( LSVEC ) THEN
00557             CALL SLASCL( 'G',0,0,SVA(1),SCALEM, M,1,A(1,1),LDA,IERR )
00558             CALL SLACPY( 'A', M, 1, A, LDA, U, LDU )
00559 *           computing all M left singular vectors of the M x 1 matrix
00560             IF ( N1 .NE. N  ) THEN
00561                CALL SGEQRF( M, N, U,LDU, WORK, WORK(N+1),LWORK-N,IERR )
00562                CALL SORGQR( M,N1,1, U,LDU,WORK,WORK(N+1),LWORK-N,IERR )
00563                CALL SCOPY( M, A(1,1), 1, U(1,1), 1 )
00564             END IF
00565          END IF
00566          IF ( RSVEC ) THEN
00567              V(1,1) = ONE
00568          END IF
00569          IF ( SVA(1) .LT. (BIG*SCALEM) ) THEN
00570             SVA(1)  = SVA(1) / SCALEM
00571             SCALEM  = ONE
00572          END IF
00573          WORK(1) = ONE / SCALEM
00574          WORK(2) = ONE
00575          IF ( SVA(1) .NE. ZERO ) THEN
00576             IWORK(1) = 1
00577             IF ( ( SVA(1) / SCALEM) .GE. SFMIN ) THEN
00578                IWORK(2) = 1
00579             ELSE
00580                IWORK(2) = 0
00581             END IF
00582          ELSE
00583             IWORK(1) = 0
00584             IWORK(2) = 0
00585          END IF
00586          IF ( ERREST ) WORK(3) = ONE
00587          IF ( LSVEC .AND. RSVEC ) THEN
00588             WORK(4) = ONE
00589             WORK(5) = ONE
00590          END IF
00591          IF ( L2TRAN ) THEN
00592             WORK(6) = ZERO
00593             WORK(7) = ZERO
00594          END IF
00595          RETURN
00596 *
00597       END IF
00598 *
00599       TRANSP = .FALSE.
00600       L2TRAN = L2TRAN .AND. ( M .EQ. N )
00601 *
00602       AATMAX = -ONE
00603       AATMIN =  BIG
00604       IF ( ROWPIV .OR. L2TRAN ) THEN
00605 *
00606 *     Compute the row norms, needed to determine row pivoting sequence
00607 *     (in the case of heavily row weighted A, row pivoting is strongly
00608 *     advised) and to collect information needed to compare the
00609 *     structures of A * A^t and A^t * A (in the case L2TRAN.EQ..TRUE.).
00610 *
00611          IF ( L2TRAN ) THEN
00612             DO 1950 p = 1, M
00613                XSC   = ZERO
00614                TEMP1 = ZERO
00615                CALL SLASSQ( N, A(p,1), LDA, XSC, TEMP1 )
00616 *              SLASSQ gets both the ell_2 and the ell_infinity norm
00617 *              in one pass through the vector
00618                WORK(M+N+p)  = XSC * SCALEM
00619                WORK(N+p)    = XSC * (SCALEM*SQRT(TEMP1))
00620                AATMAX = AMAX1( AATMAX, WORK(N+p) )
00621                IF (WORK(N+p) .NE. ZERO) AATMIN = AMIN1(AATMIN,WORK(N+p))
00622  1950       CONTINUE
00623          ELSE
00624             DO 1904 p = 1, M
00625                WORK(M+N+p) = SCALEM*ABS( A(p,ISAMAX(N,A(p,1),LDA)) )
00626                AATMAX = AMAX1( AATMAX, WORK(M+N+p) )
00627                AATMIN = AMIN1( AATMIN, WORK(M+N+p) )
00628  1904       CONTINUE
00629          END IF
00630 *
00631       END IF
00632 *
00633 *     For square matrix A try to determine whether A^t  would be  better
00634 *     input for the preconditioned Jacobi SVD, with faster convergence.
00635 *     The decision is based on an O(N) function of the vector of column
00636 *     and row norms of A, based on the Shannon entropy. This should give
00637 *     the right choice in most cases when the difference actually matters.
00638 *     It may fail and pick the slower converging side.
00639 *
00640       ENTRA  = ZERO
00641       ENTRAT = ZERO
00642       IF ( L2TRAN ) THEN
00643 *
00644          XSC   = ZERO
00645          TEMP1 = ZERO
00646          CALL SLASSQ( N, SVA, 1, XSC, TEMP1 )
00647          TEMP1 = ONE / TEMP1
00648 *
00649          ENTRA = ZERO
00650          DO 1113 p = 1, N
00651             BIG1  = ( ( SVA(p) / XSC )**2 ) * TEMP1
00652             IF ( BIG1 .NE. ZERO ) ENTRA = ENTRA + BIG1 * ALOG(BIG1)
00653  1113    CONTINUE
00654          ENTRA = - ENTRA / ALOG(FLOAT(N))
00655 *
00656 *        Now, SVA().^2/Trace(A^t * A) is a point in the probability simplex.
00657 *        It is derived from the diagonal of  A^t * A.  Do the same with the
00658 *        diagonal of A * A^t, compute the entropy of the corresponding
00659 *        probability distribution. Note that A * A^t and A^t * A have the
00660 *        same trace.
00661 *
00662          ENTRAT = ZERO
00663          DO 1114 p = N+1, N+M
00664             BIG1 = ( ( WORK(p) / XSC )**2 ) * TEMP1
00665             IF ( BIG1 .NE. ZERO ) ENTRAT = ENTRAT + BIG1 * ALOG(BIG1)
00666  1114    CONTINUE
00667          ENTRAT = - ENTRAT / ALOG(FLOAT(M))
00668 *
00669 *        Analyze the entropies and decide A or A^t. Smaller entropy
00670 *        usually means better input for the algorithm.
00671 *
00672          TRANSP = ( ENTRAT .LT. ENTRA )
00673 *
00674 *        If A^t is better than A, transpose A.
00675 *
00676          IF ( TRANSP ) THEN
00677 *           In an optimal implementation, this trivial transpose
00678 *           should be replaced with faster transpose.
00679             DO 1115 p = 1, N - 1
00680                DO 1116 q = p + 1, N
00681                    TEMP1 = A(q,p)
00682                   A(q,p) = A(p,q)
00683                   A(p,q) = TEMP1
00684  1116          CONTINUE
00685  1115       CONTINUE
00686             DO 1117 p = 1, N
00687                WORK(M+N+p) = SVA(p)
00688                SVA(p)      = WORK(N+p)
00689  1117       CONTINUE
00690             TEMP1  = AAPP
00691             AAPP   = AATMAX
00692             AATMAX = TEMP1
00693             TEMP1  = AAQQ
00694             AAQQ   = AATMIN
00695             AATMIN = TEMP1
00696             KILL   = LSVEC
00697             LSVEC  = RSVEC
00698             RSVEC  = KILL
00699 *
00700             ROWPIV = .TRUE.
00701          END IF
00702 *
00703       END IF
00704 *     END IF L2TRAN
00705 *
00706 *     Scale the matrix so that its maximal singular value remains less
00707 *     than SQRT(BIG) -- the matrix is scaled so that its maximal column
00708 *     has Euclidean norm equal to SQRT(BIG/N). The only reason to keep
00709 *     SQRT(BIG) instead of BIG is the fact that SGEJSV uses LAPACK and
00710 *     BLAS routines that, in some implementations, are not capable of
00711 *     working in the full interval [SFMIN,BIG] and that they may provoke
00712 *     overflows in the intermediate results. If the singular values spread
00713 *     from SFMIN to BIG, then SGESVJ will compute them. So, in that case,
00714 *     one should use SGESVJ instead of SGEJSV.
00715 *
00716       BIG1   = SQRT( BIG )
00717       TEMP1  = SQRT( BIG / FLOAT(N) )
00718 *
00719       CALL SLASCL( 'G', 0, 0, AAPP, TEMP1, N, 1, SVA, N, IERR )
00720       IF ( AAQQ .GT. (AAPP * SFMIN) ) THEN
00721           AAQQ = ( AAQQ / AAPP ) * TEMP1
00722       ELSE
00723           AAQQ = ( AAQQ * TEMP1 ) / AAPP
00724       END IF
00725       TEMP1 = TEMP1 * SCALEM
00726       CALL SLASCL( 'G', 0, 0, AAPP, TEMP1, M, N, A, LDA, IERR )
00727 *
00728 *     To undo scaling at the end of this procedure, multiply the
00729 *     computed singular values with USCAL2 / USCAL1.
00730 *
00731       USCAL1 = TEMP1
00732       USCAL2 = AAPP
00733 *
00734       IF ( L2KILL ) THEN
00735 *        L2KILL enforces computation of nonzero singular values in
00736 *        the restricted range of condition number of the initial A,
00737 *        sigma_max(A) / sigma_min(A) approx. SQRT(BIG)/SQRT(SFMIN).
00738          XSC = SQRT( SFMIN )
00739       ELSE
00740          XSC = SMALL
00741 *
00742 *        Now, if the condition number of A is too big,
00743 *        sigma_max(A) / sigma_min(A) .GT. SQRT(BIG/N) * EPSLN / SFMIN,
00744 *        as a precaution measure, the full SVD is computed using SGESVJ
00745 *        with accumulated Jacobi rotations. This provides numerically
00746 *        more robust computation, at the cost of slightly increased run
00747 *        time. Depending on the concrete implementation of BLAS and LAPACK
00748 *        (i.e. how they behave in presence of extreme ill-conditioning) the
00749 *        implementor may decide to remove this switch.
00750          IF ( ( AAQQ.LT.SQRT(SFMIN) ) .AND. LSVEC .AND. RSVEC ) THEN
00751             JRACC = .TRUE.
00752          END IF
00753 *
00754       END IF
00755       IF ( AAQQ .LT. XSC ) THEN
00756          DO 700 p = 1, N
00757             IF ( SVA(p) .LT. XSC ) THEN
00758                CALL SLASET( 'A', M, 1, ZERO, ZERO, A(1,p), LDA )
00759                SVA(p) = ZERO
00760             END IF
00761  700     CONTINUE
00762       END IF
00763 *
00764 *     Preconditioning using QR factorization with pivoting
00765 *
00766       IF ( ROWPIV ) THEN
00767 *        Optional row permutation (Bjoerck row pivoting):
00768 *        A result by Cox and Higham shows that the Bjoerck's
00769 *        row pivoting combined with standard column pivoting
00770 *        has similar effect as Powell-Reid complete pivoting.
00771 *        The ell-infinity norms of A are made nonincreasing.
00772          DO 1952 p = 1, M - 1
00773             q = ISAMAX( M-p+1, WORK(M+N+p), 1 ) + p - 1
00774             IWORK(2*N+p) = q
00775             IF ( p .NE. q ) THEN
00776                TEMP1       = WORK(M+N+p)
00777                WORK(M+N+p) = WORK(M+N+q)
00778                WORK(M+N+q) = TEMP1
00779             END IF
00780  1952    CONTINUE
00781          CALL SLASWP( N, A, LDA, 1, M-1, IWORK(2*N+1), 1 )
00782       END IF
00783 *
00784 *     End of the preparation phase (scaling, optional sorting and
00785 *     transposing, optional flushing of small columns).
00786 *
00787 *     Preconditioning
00788 *
00789 *     If the full SVD is needed, the right singular vectors are computed
00790 *     from a matrix equation, and for that we need theoretical analysis
00791 *     of the Businger-Golub pivoting. So we use SGEQP3 as the first RR QRF.
00792 *     In all other cases the first RR QRF can be chosen by other criteria
00793 *     (eg speed by replacing global with restricted window pivoting, such
00794 *     as in SGEQPX from TOMS # 782). Good results will be obtained using
00795 *     SGEQPX with properly (!) chosen numerical parameters.
00796 *     Any improvement of SGEQP3 improves overal performance of SGEJSV.
00797 *
00798 *     A * P1 = Q1 * [ R1^t 0]^t:
00799       DO 1963 p = 1, N
00800 *        .. all columns are free columns
00801          IWORK(p) = 0
00802  1963 CONTINUE
00803       CALL SGEQP3( M,N,A,LDA, IWORK,WORK, WORK(N+1),LWORK-N, IERR )
00804 *
00805 *     The upper triangular matrix R1 from the first QRF is inspected for
00806 *     rank deficiency and possibilities for deflation, or possible
00807 *     ill-conditioning. Depending on the user specified flag L2RANK,
00808 *     the procedure explores possibilities to reduce the numerical
00809 *     rank by inspecting the computed upper triangular factor. If
00810 *     L2RANK or L2ABER are up, then SGEJSV will compute the SVD of
00811 *     A + dA, where ||dA|| <= f(M,N)*EPSLN.
00812 *
00813       NR = 1
00814       IF ( L2ABER ) THEN
00815 *        Standard absolute error bound suffices. All sigma_i with
00816 *        sigma_i < N*EPSLN*||A|| are flushed to zero. This is an
00817 *        agressive enforcement of lower numerical rank by introducing a
00818 *        backward error of the order of N*EPSLN*||A||.
00819          TEMP1 = SQRT(FLOAT(N))*EPSLN
00820          DO 3001 p = 2, N
00821             IF ( ABS(A(p,p)) .GE. (TEMP1*ABS(A(1,1))) ) THEN
00822                NR = NR + 1
00823             ELSE
00824                GO TO 3002
00825             END IF
00826  3001    CONTINUE
00827  3002    CONTINUE
00828       ELSE IF ( L2RANK ) THEN
00829 *        .. similarly as above, only slightly more gentle (less agressive).
00830 *        Sudden drop on the diagonal of R1 is used as the criterion for
00831 *        close-to-rank-defficient.
00832          TEMP1 = SQRT(SFMIN)
00833          DO 3401 p = 2, N
00834             IF ( ( ABS(A(p,p)) .LT. (EPSLN*ABS(A(p-1,p-1))) ) .OR.
00835      &           ( ABS(A(p,p)) .LT. SMALL ) .OR.
00836      &           ( L2KILL .AND. (ABS(A(p,p)) .LT. TEMP1) ) ) GO TO 3402
00837             NR = NR + 1
00838  3401    CONTINUE
00839  3402    CONTINUE
00840 *
00841       ELSE
00842 *        The goal is high relative accuracy. However, if the matrix
00843 *        has high scaled condition number the relative accuracy is in
00844 *        general not feasible. Later on, a condition number estimator
00845 *        will be deployed to estimate the scaled condition number.
00846 *        Here we just remove the underflowed part of the triangular
00847 *        factor. This prevents the situation in which the code is
00848 *        working hard to get the accuracy not warranted by the data.
00849          TEMP1  = SQRT(SFMIN)
00850          DO 3301 p = 2, N
00851             IF ( ( ABS(A(p,p)) .LT. SMALL ) .OR.
00852      &           ( L2KILL .AND. (ABS(A(p,p)) .LT. TEMP1) ) ) GO TO 3302
00853             NR = NR + 1
00854  3301    CONTINUE
00855  3302    CONTINUE
00856 *
00857       END IF
00858 *
00859       ALMORT = .FALSE.
00860       IF ( NR .EQ. N ) THEN
00861          MAXPRJ = ONE
00862          DO 3051 p = 2, N
00863             TEMP1  = ABS(A(p,p)) / SVA(IWORK(p))
00864             MAXPRJ = AMIN1( MAXPRJ, TEMP1 )
00865  3051    CONTINUE
00866          IF ( MAXPRJ**2 .GE. ONE - FLOAT(N)*EPSLN ) ALMORT = .TRUE.
00867       END IF
00868 *
00869 *
00870       SCONDA = - ONE
00871       CONDR1 = - ONE
00872       CONDR2 = - ONE
00873 *
00874       IF ( ERREST ) THEN
00875          IF ( N .EQ. NR ) THEN
00876             IF ( RSVEC ) THEN
00877 *              .. V is available as workspace
00878                CALL SLACPY( 'U', N, N, A, LDA, V, LDV )
00879                DO 3053 p = 1, N
00880                   TEMP1 = SVA(IWORK(p))
00881                   CALL SSCAL( p, ONE/TEMP1, V(1,p), 1 )
00882  3053          CONTINUE
00883                CALL SPOCON( 'U', N, V, LDV, ONE, TEMP1,
00884      &              WORK(N+1), IWORK(2*N+M+1), IERR )
00885             ELSE IF ( LSVEC ) THEN
00886 *              .. U is available as workspace
00887                CALL SLACPY( 'U', N, N, A, LDA, U, LDU )
00888                DO 3054 p = 1, N
00889                   TEMP1 = SVA(IWORK(p))
00890                   CALL SSCAL( p, ONE/TEMP1, U(1,p), 1 )
00891  3054          CONTINUE
00892                CALL SPOCON( 'U', N, U, LDU, ONE, TEMP1,
00893      &              WORK(N+1), IWORK(2*N+M+1), IERR )
00894             ELSE
00895                CALL SLACPY( 'U', N, N, A, LDA, WORK(N+1), N )
00896                DO 3052 p = 1, N
00897                   TEMP1 = SVA(IWORK(p))
00898                   CALL SSCAL( p, ONE/TEMP1, WORK(N+(p-1)*N+1), 1 )
00899  3052          CONTINUE
00900 *           .. the columns of R are scaled to have unit Euclidean lengths.
00901                CALL SPOCON( 'U', N, WORK(N+1), N, ONE, TEMP1,
00902      &              WORK(N+N*N+1), IWORK(2*N+M+1), IERR )
00903             END IF
00904             SCONDA = ONE / SQRT(TEMP1)
00905 *           SCONDA is an estimate of SQRT(||(R^t * R)^(-1)||_1).
00906 *           N^(-1/4) * SCONDA <= ||R^(-1)||_2 <= N^(1/4) * SCONDA
00907          ELSE
00908             SCONDA = - ONE
00909          END IF
00910       END IF
00911 *
00912       L2PERT = L2PERT .AND. ( ABS( A(1,1)/A(NR,NR) ) .GT. SQRT(BIG1) )
00913 *     If there is no violent scaling, artificial perturbation is not needed.
00914 *
00915 *     Phase 3:
00916 *
00917       IF ( .NOT. ( RSVEC .OR. LSVEC ) ) THEN
00918 *
00919 *         Singular Values only
00920 *
00921 *         .. transpose A(1:NR,1:N)
00922          DO 1946 p = 1, MIN0( N-1, NR )
00923             CALL SCOPY( N-p, A(p,p+1), LDA, A(p+1,p), 1 )
00924  1946    CONTINUE
00925 *
00926 *        The following two DO-loops introduce small relative perturbation
00927 *        into the strict upper triangle of the lower triangular matrix.
00928 *        Small entries below the main diagonal are also changed.
00929 *        This modification is useful if the computing environment does not
00930 *        provide/allow FLUSH TO ZERO underflow, for it prevents many
00931 *        annoying denormalized numbers in case of strongly scaled matrices.
00932 *        The perturbation is structured so that it does not introduce any
00933 *        new perturbation of the singular values, and it does not destroy
00934 *        the job done by the preconditioner.
00935 *        The licence for this perturbation is in the variable L2PERT, which
00936 *        should be .FALSE. if FLUSH TO ZERO underflow is active.
00937 *
00938          IF ( .NOT. ALMORT ) THEN
00939 *
00940             IF ( L2PERT ) THEN
00941 *              XSC = SQRT(SMALL)
00942                XSC = EPSLN / FLOAT(N)
00943                DO 4947 q = 1, NR
00944                   TEMP1 = XSC*ABS(A(q,q))
00945                   DO 4949 p = 1, N
00946                      IF ( ( (p.GT.q) .AND. (ABS(A(p,q)).LE.TEMP1) )
00947      &                    .OR. ( p .LT. q ) )
00948      &                     A(p,q) = SIGN( TEMP1, A(p,q) )
00949  4949             CONTINUE
00950  4947          CONTINUE
00951             ELSE
00952                CALL SLASET( 'U', NR-1,NR-1, ZERO,ZERO, A(1,2),LDA )
00953             END IF
00954 *
00955 *            .. second preconditioning using the QR factorization
00956 *
00957             CALL SGEQRF( N,NR, A,LDA, WORK, WORK(N+1),LWORK-N, IERR )
00958 *
00959 *           .. and transpose upper to lower triangular
00960             DO 1948 p = 1, NR - 1
00961                CALL SCOPY( NR-p, A(p,p+1), LDA, A(p+1,p), 1 )
00962  1948       CONTINUE
00963 *
00964          END IF
00965 *
00966 *           Row-cyclic Jacobi SVD algorithm with column pivoting
00967 *
00968 *           .. again some perturbation (a "background noise") is added
00969 *           to drown denormals
00970             IF ( L2PERT ) THEN
00971 *              XSC = SQRT(SMALL)
00972                XSC = EPSLN / FLOAT(N)
00973                DO 1947 q = 1, NR
00974                   TEMP1 = XSC*ABS(A(q,q))
00975                   DO 1949 p = 1, NR
00976                      IF ( ( (p.GT.q) .AND. (ABS(A(p,q)).LE.TEMP1) )
00977      &                       .OR. ( p .LT. q ) )
00978      &                   A(p,q) = SIGN( TEMP1, A(p,q) )
00979  1949             CONTINUE
00980  1947          CONTINUE
00981             ELSE
00982                CALL SLASET( 'U', NR-1, NR-1, ZERO, ZERO, A(1,2), LDA )
00983             END IF
00984 *
00985 *           .. and one-sided Jacobi rotations are started on a lower
00986 *           triangular matrix (plus perturbation which is ignored in
00987 *           the part which destroys triangular form (confusing?!))
00988 *
00989             CALL SGESVJ( 'L', 'NoU', 'NoV', NR, NR, A, LDA, SVA,
00990      &                      N, V, LDV, WORK, LWORK, INFO )
00991 *
00992             SCALEM  = WORK(1)
00993             NUMRANK = NINT(WORK(2))
00994 *
00995 *
00996       ELSE IF ( RSVEC .AND. ( .NOT. LSVEC ) ) THEN
00997 *
00998 *        -> Singular Values and Right Singular Vectors <-
00999 *
01000          IF ( ALMORT ) THEN
01001 *
01002 *           .. in this case NR equals N
01003             DO 1998 p = 1, NR
01004                CALL SCOPY( N-p+1, A(p,p), LDA, V(p,p), 1 )
01005  1998       CONTINUE
01006             CALL SLASET( 'Upper', NR-1, NR-1, ZERO, ZERO, V(1,2), LDV )
01007 *
01008             CALL SGESVJ( 'L','U','N', N, NR, V,LDV, SVA, NR, A,LDA,
01009      &                  WORK, LWORK, INFO )
01010             SCALEM  = WORK(1)
01011             NUMRANK = NINT(WORK(2))
01012 
01013          ELSE
01014 *
01015 *        .. two more QR factorizations ( one QRF is not enough, two require
01016 *        accumulated product of Jacobi rotations, three are perfect )
01017 *
01018             CALL SLASET( 'Lower', NR-1, NR-1, ZERO, ZERO, A(2,1), LDA )
01019             CALL SGELQF( NR, N, A, LDA, WORK, WORK(N+1), LWORK-N, IERR)
01020             CALL SLACPY( 'Lower', NR, NR, A, LDA, V, LDV )
01021             CALL SLASET( 'Upper', NR-1, NR-1, ZERO, ZERO, V(1,2), LDV )
01022             CALL SGEQRF( NR, NR, V, LDV, WORK(N+1), WORK(2*N+1),
01023      &                   LWORK-2*N, IERR )
01024             DO 8998 p = 1, NR
01025                CALL SCOPY( NR-p+1, V(p,p), LDV, V(p,p), 1 )
01026  8998       CONTINUE
01027             CALL SLASET( 'Upper', NR-1, NR-1, ZERO, ZERO, V(1,2), LDV )
01028 *
01029             CALL SGESVJ( 'Lower', 'U','N', NR, NR, V,LDV, SVA, NR, U,
01030      &                  LDU, WORK(N+1), LWORK, INFO )
01031             SCALEM  = WORK(N+1)
01032             NUMRANK = NINT(WORK(N+2))
01033             IF ( NR .LT. N ) THEN
01034                CALL SLASET( 'A',N-NR, NR, ZERO,ZERO, V(NR+1,1),   LDV )
01035                CALL SLASET( 'A',NR, N-NR, ZERO,ZERO, V(1,NR+1),   LDV )
01036                CALL SLASET( 'A',N-NR,N-NR,ZERO,ONE, V(NR+1,NR+1), LDV )
01037             END IF
01038 *
01039          CALL SORMLQ( 'Left', 'Transpose', N, N, NR, A, LDA, WORK,
01040      &               V, LDV, WORK(N+1), LWORK-N, IERR )
01041 *
01042          END IF
01043 *
01044          DO 8991 p = 1, N
01045             CALL SCOPY( N, V(p,1), LDV, A(IWORK(p),1), LDA )
01046  8991    CONTINUE
01047          CALL SLACPY( 'All', N, N, A, LDA, V, LDV )
01048 *
01049          IF ( TRANSP ) THEN
01050             CALL SLACPY( 'All', N, N, V, LDV, U, LDU )
01051          END IF
01052 *
01053       ELSE IF ( LSVEC .AND. ( .NOT. RSVEC ) ) THEN
01054 *
01055 *        .. Singular Values and Left Singular Vectors                 ..
01056 *
01057 *        .. second preconditioning step to avoid need to accumulate
01058 *        Jacobi rotations in the Jacobi iterations.
01059          DO 1965 p = 1, NR
01060             CALL SCOPY( N-p+1, A(p,p), LDA, U(p,p), 1 )
01061  1965    CONTINUE
01062          CALL SLASET( 'Upper', NR-1, NR-1, ZERO, ZERO, U(1,2), LDU )
01063 *
01064          CALL SGEQRF( N, NR, U, LDU, WORK(N+1), WORK(2*N+1),
01065      &              LWORK-2*N, IERR )
01066 *
01067          DO 1967 p = 1, NR - 1
01068             CALL SCOPY( NR-p, U(p,p+1), LDU, U(p+1,p), 1 )
01069  1967    CONTINUE
01070          CALL SLASET( 'Upper', NR-1, NR-1, ZERO, ZERO, U(1,2), LDU )
01071 *
01072          CALL SGESVJ( 'Lower', 'U', 'N', NR,NR, U, LDU, SVA, NR, A,
01073      &        LDA, WORK(N+1), LWORK-N, INFO )
01074          SCALEM  = WORK(N+1)
01075          NUMRANK = NINT(WORK(N+2))
01076 *
01077          IF ( NR .LT. M ) THEN
01078             CALL SLASET( 'A',  M-NR, NR,ZERO, ZERO, U(NR+1,1), LDU )
01079             IF ( NR .LT. N1 ) THEN
01080                CALL SLASET( 'A',NR, N1-NR, ZERO, ZERO, U(1,NR+1), LDU )
01081                CALL SLASET( 'A',M-NR,N1-NR,ZERO,ONE,U(NR+1,NR+1), LDU )
01082             END IF
01083          END IF
01084 *
01085          CALL SORMQR( 'Left', 'No Tr', M, N1, N, A, LDA, WORK, U,
01086      &               LDU, WORK(N+1), LWORK-N, IERR )
01087 *
01088          IF ( ROWPIV )
01089      &       CALL SLASWP( N1, U, LDU, 1, M-1, IWORK(2*N+1), -1 )
01090 *
01091          DO 1974 p = 1, N1
01092             XSC = ONE / SNRM2( M, U(1,p), 1 )
01093             CALL SSCAL( M, XSC, U(1,p), 1 )
01094  1974    CONTINUE
01095 *
01096          IF ( TRANSP ) THEN
01097             CALL SLACPY( 'All', N, N, U, LDU, V, LDV )
01098          END IF
01099 *
01100       ELSE
01101 *
01102 *        .. Full SVD ..
01103 *
01104          IF ( .NOT. JRACC ) THEN
01105 *
01106          IF ( .NOT. ALMORT ) THEN
01107 *
01108 *           Second Preconditioning Step (QRF [with pivoting])
01109 *           Note that the composition of TRANSPOSE, QRF and TRANSPOSE is
01110 *           equivalent to an LQF CALL. Since in many libraries the QRF
01111 *           seems to be better optimized than the LQF, we do explicit
01112 *           transpose and use the QRF. This is subject to changes in an
01113 *           optimized implementation of SGEJSV.
01114 *
01115             DO 1968 p = 1, NR
01116                CALL SCOPY( N-p+1, A(p,p), LDA, V(p,p), 1 )
01117  1968       CONTINUE
01118 *
01119 *           .. the following two loops perturb small entries to avoid
01120 *           denormals in the second QR factorization, where they are
01121 *           as good as zeros. This is done to avoid painfully slow
01122 *           computation with denormals. The relative size of the perturbation
01123 *           is a parameter that can be changed by the implementer.
01124 *           This perturbation device will be obsolete on machines with
01125 *           properly implemented arithmetic.
01126 *           To switch it off, set L2PERT=.FALSE. To remove it from  the
01127 *           code, remove the action under L2PERT=.TRUE., leave the ELSE part.
01128 *           The following two loops should be blocked and fused with the
01129 *           transposed copy above.
01130 *
01131             IF ( L2PERT ) THEN
01132                XSC = SQRT(SMALL)
01133                DO 2969 q = 1, NR
01134                   TEMP1 = XSC*ABS( V(q,q) )
01135                   DO 2968 p = 1, N
01136                      IF ( ( p .GT. q ) .AND. ( ABS(V(p,q)) .LE. TEMP1 )
01137      &                   .OR. ( p .LT. q ) )
01138      &                   V(p,q) = SIGN( TEMP1, V(p,q) )
01139                      IF ( p. LT. q ) V(p,q) = - V(p,q)
01140  2968             CONTINUE
01141  2969          CONTINUE
01142             ELSE
01143                CALL SLASET( 'U', NR-1, NR-1, ZERO, ZERO, V(1,2), LDV )
01144             END IF
01145 *
01146 *           Estimate the row scaled condition number of R1
01147 *           (If R1 is rectangular, N > NR, then the condition number
01148 *           of the leading NR x NR submatrix is estimated.)
01149 *
01150             CALL SLACPY( 'L', NR, NR, V, LDV, WORK(2*N+1), NR )
01151             DO 3950 p = 1, NR
01152                TEMP1 = SNRM2(NR-p+1,WORK(2*N+(p-1)*NR+p),1)
01153                CALL SSCAL(NR-p+1,ONE/TEMP1,WORK(2*N+(p-1)*NR+p),1)
01154  3950       CONTINUE
01155             CALL SPOCON('Lower',NR,WORK(2*N+1),NR,ONE,TEMP1,
01156      &                   WORK(2*N+NR*NR+1),IWORK(M+2*N+1),IERR)
01157             CONDR1 = ONE / SQRT(TEMP1)
01158 *           .. here need a second oppinion on the condition number
01159 *           .. then assume worst case scenario
01160 *           R1 is OK for inverse <=> CONDR1 .LT. FLOAT(N)
01161 *           more conservative    <=> CONDR1 .LT. SQRT(FLOAT(N))
01162 *
01163             COND_OK = SQRT(FLOAT(NR))
01164 *[TP]       COND_OK is a tuning parameter.
01165 
01166             IF ( CONDR1 .LT. COND_OK ) THEN
01167 *              .. the second QRF without pivoting. Note: in an optimized
01168 *              implementation, this QRF should be implemented as the QRF
01169 *              of a lower triangular matrix.
01170 *              R1^t = Q2 * R2
01171                CALL SGEQRF( N, NR, V, LDV, WORK(N+1), WORK(2*N+1),
01172      &              LWORK-2*N, IERR )
01173 *
01174                IF ( L2PERT ) THEN
01175                   XSC = SQRT(SMALL)/EPSLN
01176                   DO 3959 p = 2, NR
01177                      DO 3958 q = 1, p - 1
01178                         TEMP1 = XSC * AMIN1(ABS(V(p,p)),ABS(V(q,q)))
01179                         IF ( ABS(V(q,p)) .LE. TEMP1 )
01180      &                     V(q,p) = SIGN( TEMP1, V(q,p) )
01181  3958                CONTINUE
01182  3959             CONTINUE
01183                END IF
01184 *
01185                IF ( NR .NE. N )
01186 *              .. save ...
01187      &         CALL SLACPY( 'A', N, NR, V, LDV, WORK(2*N+1), N )
01188 *
01189 *           .. this transposed copy should be better than naive
01190                DO 1969 p = 1, NR - 1
01191                   CALL SCOPY( NR-p, V(p,p+1), LDV, V(p+1,p), 1 )
01192  1969          CONTINUE
01193 *
01194                CONDR2 = CONDR1
01195 *
01196             ELSE
01197 *
01198 *              .. ill-conditioned case: second QRF with pivoting
01199 *              Note that windowed pivoting would be equaly good
01200 *              numerically, and more run-time efficient. So, in
01201 *              an optimal implementation, the next call to SGEQP3
01202 *              should be replaced with eg. CALL SGEQPX (ACM TOMS #782)
01203 *              with properly (carefully) chosen parameters.
01204 *
01205 *              R1^t * P2 = Q2 * R2
01206                DO 3003 p = 1, NR
01207                   IWORK(N+p) = 0
01208  3003          CONTINUE
01209                CALL SGEQP3( N, NR, V, LDV, IWORK(N+1), WORK(N+1),
01210      &                  WORK(2*N+1), LWORK-2*N, IERR )
01211 **               CALL SGEQRF( N, NR, V, LDV, WORK(N+1), WORK(2*N+1),
01212 **     &              LWORK-2*N, IERR )
01213                IF ( L2PERT ) THEN
01214                   XSC = SQRT(SMALL)
01215                   DO 3969 p = 2, NR
01216                      DO 3968 q = 1, p - 1
01217                         TEMP1 = XSC * AMIN1(ABS(V(p,p)),ABS(V(q,q)))
01218                         IF ( ABS(V(q,p)) .LE. TEMP1 )
01219      &                     V(q,p) = SIGN( TEMP1, V(q,p) )
01220  3968                CONTINUE
01221  3969             CONTINUE
01222                END IF
01223 *
01224                CALL SLACPY( 'A', N, NR, V, LDV, WORK(2*N+1), N )
01225 *
01226                IF ( L2PERT ) THEN
01227                   XSC = SQRT(SMALL)
01228                   DO 8970 p = 2, NR
01229                      DO 8971 q = 1, p - 1
01230                         TEMP1 = XSC * AMIN1(ABS(V(p,p)),ABS(V(q,q)))
01231                         V(p,q) = - SIGN( TEMP1, V(q,p) )
01232  8971                CONTINUE
01233  8970             CONTINUE
01234                ELSE
01235                   CALL SLASET( 'L',NR-1,NR-1,ZERO,ZERO,V(2,1),LDV )
01236                END IF
01237 *              Now, compute R2 = L3 * Q3, the LQ factorization.
01238                CALL SGELQF( NR, NR, V, LDV, WORK(2*N+N*NR+1),
01239      &               WORK(2*N+N*NR+NR+1), LWORK-2*N-N*NR-NR, IERR )
01240 *              .. and estimate the condition number
01241                CALL SLACPY( 'L',NR,NR,V,LDV,WORK(2*N+N*NR+NR+1),NR )
01242                DO 4950 p = 1, NR
01243                   TEMP1 = SNRM2( p, WORK(2*N+N*NR+NR+p), NR )
01244                   CALL SSCAL( p, ONE/TEMP1, WORK(2*N+N*NR+NR+p), NR )
01245  4950          CONTINUE
01246                CALL SPOCON( 'L',NR,WORK(2*N+N*NR+NR+1),NR,ONE,TEMP1,
01247      &              WORK(2*N+N*NR+NR+NR*NR+1),IWORK(M+2*N+1),IERR )
01248                CONDR2 = ONE / SQRT(TEMP1)
01249 *
01250                IF ( CONDR2 .GE. COND_OK ) THEN
01251 *                 .. save the Householder vectors used for Q3
01252 *                 (this overwrittes the copy of R2, as it will not be
01253 *                 needed in this branch, but it does not overwritte the
01254 *                 Huseholder vectors of Q2.).
01255                   CALL SLACPY( 'U', NR, NR, V, LDV, WORK(2*N+1), N )
01256 *                 .. and the rest of the information on Q3 is in
01257 *                 WORK(2*N+N*NR+1:2*N+N*NR+N)
01258                END IF
01259 *
01260             END IF
01261 *
01262             IF ( L2PERT ) THEN
01263                XSC = SQRT(SMALL)
01264                DO 4968 q = 2, NR
01265                   TEMP1 = XSC * V(q,q)
01266                   DO 4969 p = 1, q - 1
01267 *                    V(p,q) = - SIGN( TEMP1, V(q,p) )
01268                      V(p,q) = - SIGN( TEMP1, V(p,q) )
01269  4969             CONTINUE
01270  4968          CONTINUE
01271             ELSE
01272                CALL SLASET( 'U', NR-1,NR-1, ZERO,ZERO, V(1,2), LDV )
01273             END IF
01274 *
01275 *        Second preconditioning finished; continue with Jacobi SVD
01276 *        The input matrix is lower trinagular.
01277 *
01278 *        Recover the right singular vectors as solution of a well
01279 *        conditioned triangular matrix equation.
01280 *
01281             IF ( CONDR1 .LT. COND_OK ) THEN
01282 *
01283                CALL SGESVJ( 'L','U','N',NR,NR,V,LDV,SVA,NR,U,
01284      &              LDU,WORK(2*N+N*NR+NR+1),LWORK-2*N-N*NR-NR,INFO )
01285                SCALEM  = WORK(2*N+N*NR+NR+1)
01286                NUMRANK = NINT(WORK(2*N+N*NR+NR+2))
01287                DO 3970 p = 1, NR
01288                   CALL SCOPY( NR, V(1,p), 1, U(1,p), 1 )
01289                   CALL SSCAL( NR, SVA(p),    V(1,p), 1 )
01290  3970          CONTINUE
01291 
01292 *        .. pick the right matrix equation and solve it
01293 *
01294                IF ( NR. EQ. N ) THEN
01295 * :))             .. best case, R1 is inverted. The solution of this matrix
01296 *                 equation is Q2*V2 = the product of the Jacobi rotations
01297 *                 used in SGESVJ, premultiplied with the orthogonal matrix
01298 *                 from the second QR factorization.
01299                   CALL STRSM( 'L','U','N','N', NR,NR,ONE, A,LDA, V,LDV )
01300                ELSE
01301 *                 .. R1 is well conditioned, but non-square. Transpose(R2)
01302 *                 is inverted to get the product of the Jacobi rotations
01303 *                 used in SGESVJ. The Q-factor from the second QR
01304 *                 factorization is then built in explicitly.
01305                   CALL STRSM('L','U','T','N',NR,NR,ONE,WORK(2*N+1),
01306      &                 N,V,LDV)
01307                   IF ( NR .LT. N ) THEN
01308                     CALL SLASET('A',N-NR,NR,ZERO,ZERO,V(NR+1,1),LDV)
01309                     CALL SLASET('A',NR,N-NR,ZERO,ZERO,V(1,NR+1),LDV)
01310                     CALL SLASET('A',N-NR,N-NR,ZERO,ONE,V(NR+1,NR+1),LDV)
01311                   END IF
01312                   CALL SORMQR('L','N',N,N,NR,WORK(2*N+1),N,WORK(N+1),
01313      &                 V,LDV,WORK(2*N+N*NR+NR+1),LWORK-2*N-N*NR-NR,IERR)
01314                END IF
01315 *
01316             ELSE IF ( CONDR2 .LT. COND_OK ) THEN
01317 *
01318 * :)           .. the input matrix A is very likely a relative of
01319 *              the Kahan matrix :)
01320 *              The matrix R2 is inverted. The solution of the matrix equation
01321 *              is Q3^T*V3 = the product of the Jacobi rotations (appplied to
01322 *              the lower triangular L3 from the LQ factorization of
01323 *              R2=L3*Q3), pre-multiplied with the transposed Q3.
01324                CALL SGESVJ( 'L', 'U', 'N', NR, NR, V, LDV, SVA, NR, U,
01325      &              LDU, WORK(2*N+N*NR+NR+1), LWORK-2*N-N*NR-NR, INFO )
01326                SCALEM  = WORK(2*N+N*NR+NR+1)
01327                NUMRANK = NINT(WORK(2*N+N*NR+NR+2))
01328                DO 3870 p = 1, NR
01329                   CALL SCOPY( NR, V(1,p), 1, U(1,p), 1 )
01330                   CALL SSCAL( NR, SVA(p),    U(1,p), 1 )
01331  3870          CONTINUE
01332                CALL STRSM('L','U','N','N',NR,NR,ONE,WORK(2*N+1),N,U,LDU)
01333 *              .. apply the permutation from the second QR factorization
01334                DO 873 q = 1, NR
01335                   DO 872 p = 1, NR
01336                      WORK(2*N+N*NR+NR+IWORK(N+p)) = U(p,q)
01337  872              CONTINUE
01338                   DO 874 p = 1, NR
01339                      U(p,q) = WORK(2*N+N*NR+NR+p)
01340  874              CONTINUE
01341  873           CONTINUE
01342                IF ( NR .LT. N ) THEN
01343                   CALL SLASET( 'A',N-NR,NR,ZERO,ZERO,V(NR+1,1),LDV )
01344                   CALL SLASET( 'A',NR,N-NR,ZERO,ZERO,V(1,NR+1),LDV )
01345                   CALL SLASET( 'A',N-NR,N-NR,ZERO,ONE,V(NR+1,NR+1),LDV )
01346                END IF
01347                CALL SORMQR( 'L','N',N,N,NR,WORK(2*N+1),N,WORK(N+1),
01348      &              V,LDV,WORK(2*N+N*NR+NR+1),LWORK-2*N-N*NR-NR,IERR )
01349             ELSE
01350 *              Last line of defense.
01351 * #:(          This is a rather pathological case: no scaled condition
01352 *              improvement after two pivoted QR factorizations. Other
01353 *              possibility is that the rank revealing QR factorization
01354 *              or the condition estimator has failed, or the COND_OK
01355 *              is set very close to ONE (which is unnecessary). Normally,
01356 *              this branch should never be executed, but in rare cases of
01357 *              failure of the RRQR or condition estimator, the last line of
01358 *              defense ensures that SGEJSV completes the task.
01359 *              Compute the full SVD of L3 using SGESVJ with explicit
01360 *              accumulation of Jacobi rotations.
01361                CALL SGESVJ( 'L', 'U', 'V', NR, NR, V, LDV, SVA, NR, U,
01362      &              LDU, WORK(2*N+N*NR+NR+1), LWORK-2*N-N*NR-NR, INFO )
01363                SCALEM  = WORK(2*N+N*NR+NR+1)
01364                NUMRANK = NINT(WORK(2*N+N*NR+NR+2))
01365                IF ( NR .LT. N ) THEN
01366                   CALL SLASET( 'A',N-NR,NR,ZERO,ZERO,V(NR+1,1),LDV )
01367                   CALL SLASET( 'A',NR,N-NR,ZERO,ZERO,V(1,NR+1),LDV )
01368                   CALL SLASET( 'A',N-NR,N-NR,ZERO,ONE,V(NR+1,NR+1),LDV )
01369                END IF
01370                CALL SORMQR( 'L','N',N,N,NR,WORK(2*N+1),N,WORK(N+1),
01371      &              V,LDV,WORK(2*N+N*NR+NR+1),LWORK-2*N-N*NR-NR,IERR )
01372 *
01373                CALL SORMLQ( 'L', 'T', NR, NR, NR, WORK(2*N+1), N,
01374      &              WORK(2*N+N*NR+1), U, LDU, WORK(2*N+N*NR+NR+1),
01375      &              LWORK-2*N-N*NR-NR, IERR )
01376                DO 773 q = 1, NR
01377                   DO 772 p = 1, NR
01378                      WORK(2*N+N*NR+NR+IWORK(N+p)) = U(p,q)
01379  772              CONTINUE
01380                   DO 774 p = 1, NR
01381                      U(p,q) = WORK(2*N+N*NR+NR+p)
01382  774              CONTINUE
01383  773           CONTINUE
01384 *
01385             END IF
01386 *
01387 *           Permute the rows of V using the (column) permutation from the
01388 *           first QRF. Also, scale the columns to make them unit in
01389 *           Euclidean norm. This applies to all cases.
01390 *
01391             TEMP1 = SQRT(FLOAT(N)) * EPSLN
01392             DO 1972 q = 1, N
01393                DO 972 p = 1, N
01394                   WORK(2*N+N*NR+NR+IWORK(p)) = V(p,q)
01395   972          CONTINUE
01396                DO 973 p = 1, N
01397                   V(p,q) = WORK(2*N+N*NR+NR+p)
01398   973          CONTINUE
01399                XSC = ONE / SNRM2( N, V(1,q), 1 )
01400                IF ( (XSC .LT. (ONE-TEMP1)) .OR. (XSC .GT. (ONE+TEMP1)) )
01401      &           CALL SSCAL( N, XSC, V(1,q), 1 )
01402  1972       CONTINUE
01403 *           At this moment, V contains the right singular vectors of A.
01404 *           Next, assemble the left singular vector matrix U (M x N).
01405             IF ( NR .LT. M ) THEN
01406                CALL SLASET( 'A', M-NR, NR, ZERO, ZERO, U(NR+1,1), LDU )
01407                IF ( NR .LT. N1 ) THEN
01408                   CALL SLASET('A',NR,N1-NR,ZERO,ZERO,U(1,NR+1),LDU)
01409                   CALL SLASET('A',M-NR,N1-NR,ZERO,ONE,U(NR+1,NR+1),LDU)
01410                END IF
01411             END IF
01412 *
01413 *           The Q matrix from the first QRF is built into the left singular
01414 *           matrix U. This applies to all cases.
01415 *
01416             CALL SORMQR( 'Left', 'No_Tr', M, N1, N, A, LDA, WORK, U,
01417      &           LDU, WORK(N+1), LWORK-N, IERR )
01418 
01419 *           The columns of U are normalized. The cost is O(M*N) flops.
01420             TEMP1 = SQRT(FLOAT(M)) * EPSLN
01421             DO 1973 p = 1, NR
01422                XSC = ONE / SNRM2( M, U(1,p), 1 )
01423                IF ( (XSC .LT. (ONE-TEMP1)) .OR. (XSC .GT. (ONE+TEMP1)) )
01424      &          CALL SSCAL( M, XSC, U(1,p), 1 )
01425  1973       CONTINUE
01426 *
01427 *           If the initial QRF is computed with row pivoting, the left
01428 *           singular vectors must be adjusted.
01429 *
01430             IF ( ROWPIV )
01431      &          CALL SLASWP( N1, U, LDU, 1, M-1, IWORK(2*N+1), -1 )
01432 *
01433          ELSE
01434 *
01435 *        .. the initial matrix A has almost orthogonal columns and
01436 *        the second QRF is not needed
01437 *
01438             CALL SLACPY( 'Upper', N, N, A, LDA, WORK(N+1), N )
01439             IF ( L2PERT ) THEN
01440                XSC = SQRT(SMALL)
01441                DO 5970 p = 2, N
01442                   TEMP1 = XSC * WORK( N + (p-1)*N + p )
01443                   DO 5971 q = 1, p - 1
01444                      WORK(N+(q-1)*N+p)=-SIGN(TEMP1,WORK(N+(p-1)*N+q))
01445  5971             CONTINUE
01446  5970          CONTINUE
01447             ELSE
01448                CALL SLASET( 'Lower',N-1,N-1,ZERO,ZERO,WORK(N+2),N )
01449             END IF
01450 *
01451             CALL SGESVJ( 'Upper', 'U', 'N', N, N, WORK(N+1), N, SVA,
01452      &           N, U, LDU, WORK(N+N*N+1), LWORK-N-N*N, INFO )
01453 *
01454             SCALEM  = WORK(N+N*N+1)
01455             NUMRANK = NINT(WORK(N+N*N+2))
01456             DO 6970 p = 1, N
01457                CALL SCOPY( N, WORK(N+(p-1)*N+1), 1, U(1,p), 1 )
01458                CALL SSCAL( N, SVA(p), WORK(N+(p-1)*N+1), 1 )
01459  6970       CONTINUE
01460 *
01461             CALL STRSM( 'Left', 'Upper', 'NoTrans', 'No UD', N, N,
01462      &           ONE, A, LDA, WORK(N+1), N )
01463             DO 6972 p = 1, N
01464                CALL SCOPY( N, WORK(N+p), N, V(IWORK(p),1), LDV )
01465  6972       CONTINUE
01466             TEMP1 = SQRT(FLOAT(N))*EPSLN
01467             DO 6971 p = 1, N
01468                XSC = ONE / SNRM2( N, V(1,p), 1 )
01469                IF ( (XSC .LT. (ONE-TEMP1)) .OR. (XSC .GT. (ONE+TEMP1)) )
01470      &            CALL SSCAL( N, XSC, V(1,p), 1 )
01471  6971       CONTINUE
01472 *
01473 *           Assemble the left singular vector matrix U (M x N).
01474 *
01475             IF ( N .LT. M ) THEN
01476                CALL SLASET( 'A',  M-N, N, ZERO, ZERO, U(NR+1,1), LDU )
01477                IF ( N .LT. N1 ) THEN
01478                   CALL SLASET( 'A',N,  N1-N, ZERO, ZERO,  U(1,N+1),LDU )
01479                   CALL SLASET( 'A',M-N,N1-N, ZERO, ONE,U(NR+1,N+1),LDU )
01480                END IF
01481             END IF
01482             CALL SORMQR( 'Left', 'No Tr', M, N1, N, A, LDA, WORK, U,
01483      &           LDU, WORK(N+1), LWORK-N, IERR )
01484             TEMP1 = SQRT(FLOAT(M))*EPSLN
01485             DO 6973 p = 1, N1
01486                XSC = ONE / SNRM2( M, U(1,p), 1 )
01487                IF ( (XSC .LT. (ONE-TEMP1)) .OR. (XSC .GT. (ONE+TEMP1)) )
01488      &            CALL SSCAL( M, XSC, U(1,p), 1 )
01489  6973       CONTINUE
01490 *
01491             IF ( ROWPIV )
01492      &         CALL SLASWP( N1, U, LDU, 1, M-1, IWORK(2*N+1), -1 )
01493 *
01494          END IF
01495 *
01496 *        end of the  >> almost orthogonal case <<  in the full SVD
01497 *
01498          ELSE
01499 *
01500 *        This branch deploys a preconditioned Jacobi SVD with explicitly
01501 *        accumulated rotations. It is included as optional, mainly for
01502 *        experimental purposes. It does perfom well, and can also be used.
01503 *        In this implementation, this branch will be automatically activated
01504 *        if the  condition number sigma_max(A) / sigma_min(A) is predicted
01505 *        to be greater than the overflow threshold. This is because the
01506 *        a posteriori computation of the singular vectors assumes robust
01507 *        implementation of BLAS and some LAPACK procedures, capable of working
01508 *        in presence of extreme values. Since that is not always the case, ...
01509 *
01510          DO 7968 p = 1, NR
01511             CALL SCOPY( N-p+1, A(p,p), LDA, V(p,p), 1 )
01512  7968    CONTINUE
01513 *
01514          IF ( L2PERT ) THEN
01515             XSC = SQRT(SMALL/EPSLN)
01516             DO 5969 q = 1, NR
01517                TEMP1 = XSC*ABS( V(q,q) )
01518                DO 5968 p = 1, N
01519                   IF ( ( p .GT. q ) .AND. ( ABS(V(p,q)) .LE. TEMP1 )
01520      &                .OR. ( p .LT. q ) )
01521      &                V(p,q) = SIGN( TEMP1, V(p,q) )
01522                   IF ( p. LT. q ) V(p,q) = - V(p,q)
01523  5968          CONTINUE
01524  5969       CONTINUE
01525          ELSE
01526             CALL SLASET( 'U', NR-1, NR-1, ZERO, ZERO, V(1,2), LDV )
01527          END IF
01528 
01529          CALL SGEQRF( N, NR, V, LDV, WORK(N+1), WORK(2*N+1),
01530      &        LWORK-2*N, IERR )
01531          CALL SLACPY( 'L', N, NR, V, LDV, WORK(2*N+1), N )
01532 *
01533          DO 7969 p = 1, NR
01534             CALL SCOPY( NR-p+1, V(p,p), LDV, U(p,p), 1 )
01535  7969    CONTINUE
01536 
01537          IF ( L2PERT ) THEN
01538             XSC = SQRT(SMALL/EPSLN)
01539             DO 9970 q = 2, NR
01540                DO 9971 p = 1, q - 1
01541                   TEMP1 = XSC * AMIN1(ABS(U(p,p)),ABS(U(q,q)))
01542                   U(p,q) = - SIGN( TEMP1, U(q,p) )
01543  9971          CONTINUE
01544  9970       CONTINUE
01545          ELSE
01546             CALL SLASET('U', NR-1, NR-1, ZERO, ZERO, U(1,2), LDU )
01547          END IF
01548 
01549          CALL SGESVJ( 'L', 'U', 'V', NR, NR, U, LDU, SVA,
01550      &        N, V, LDV, WORK(2*N+N*NR+1), LWORK-2*N-N*NR, INFO )
01551          SCALEM  = WORK(2*N+N*NR+1)
01552          NUMRANK = NINT(WORK(2*N+N*NR+2))
01553 
01554          IF ( NR .LT. N ) THEN
01555             CALL SLASET( 'A',N-NR,NR,ZERO,ZERO,V(NR+1,1),LDV )
01556             CALL SLASET( 'A',NR,N-NR,ZERO,ZERO,V(1,NR+1),LDV )
01557             CALL SLASET( 'A',N-NR,N-NR,ZERO,ONE,V(NR+1,NR+1),LDV )
01558          END IF
01559 
01560          CALL SORMQR( 'L','N',N,N,NR,WORK(2*N+1),N,WORK(N+1),
01561      &        V,LDV,WORK(2*N+N*NR+NR+1),LWORK-2*N-N*NR-NR,IERR )
01562 *
01563 *           Permute the rows of V using the (column) permutation from the
01564 *           first QRF. Also, scale the columns to make them unit in
01565 *           Euclidean norm. This applies to all cases.
01566 *
01567             TEMP1 = SQRT(FLOAT(N)) * EPSLN
01568             DO 7972 q = 1, N
01569                DO 8972 p = 1, N
01570                   WORK(2*N+N*NR+NR+IWORK(p)) = V(p,q)
01571  8972          CONTINUE
01572                DO 8973 p = 1, N
01573                   V(p,q) = WORK(2*N+N*NR+NR+p)
01574  8973          CONTINUE
01575                XSC = ONE / SNRM2( N, V(1,q), 1 )
01576                IF ( (XSC .LT. (ONE-TEMP1)) .OR. (XSC .GT. (ONE+TEMP1)) )
01577      &           CALL SSCAL( N, XSC, V(1,q), 1 )
01578  7972       CONTINUE
01579 *
01580 *           At this moment, V contains the right singular vectors of A.
01581 *           Next, assemble the left singular vector matrix U (M x N).
01582 *
01583          IF ( N .LT. M ) THEN
01584             CALL SLASET( 'A',  M-N, N, ZERO, ZERO, U(NR+1,1), LDU )
01585             IF ( N .LT. N1 ) THEN
01586                CALL SLASET( 'A',N,  N1-N, ZERO, ZERO,  U(1,N+1),LDU )
01587                CALL SLASET( 'A',M-N,N1-N, ZERO, ONE,U(NR+1,N+1),LDU )
01588             END IF
01589          END IF
01590 *
01591          CALL SORMQR( 'Left', 'No Tr', M, N1, N, A, LDA, WORK, U,
01592      &        LDU, WORK(N+1), LWORK-N, IERR )
01593 *
01594             IF ( ROWPIV )
01595      &         CALL SLASWP( N1, U, LDU, 1, M-1, IWORK(2*N+1), -1 )
01596 *
01597 *
01598          END IF
01599          IF ( TRANSP ) THEN
01600 *           .. swap U and V because the procedure worked on A^t
01601             DO 6974 p = 1, N
01602                CALL SSWAP( N, U(1,p), 1, V(1,p), 1 )
01603  6974       CONTINUE
01604          END IF
01605 *
01606       END IF
01607 *     end of the full SVD
01608 *
01609 *     Undo scaling, if necessary (and possible)
01610 *
01611       IF ( USCAL2 .LE. (BIG/SVA(1))*USCAL1 ) THEN
01612          CALL SLASCL( 'G', 0, 0, USCAL1, USCAL2, NR, 1, SVA, N, IERR )
01613          USCAL1 = ONE
01614          USCAL2 = ONE
01615       END IF
01616 *
01617       IF ( NR .LT. N ) THEN
01618          DO 3004 p = NR+1, N
01619             SVA(p) = ZERO
01620  3004    CONTINUE
01621       END IF
01622 *
01623       WORK(1) = USCAL2 * SCALEM
01624       WORK(2) = USCAL1
01625       IF ( ERREST ) WORK(3) = SCONDA
01626       IF ( LSVEC .AND. RSVEC ) THEN
01627          WORK(4) = CONDR1
01628          WORK(5) = CONDR2
01629       END IF
01630       IF ( L2TRAN ) THEN
01631          WORK(6) = ENTRA
01632          WORK(7) = ENTRAT
01633       END IF
01634 *
01635       IWORK(1) = NR
01636       IWORK(2) = NUMRANK
01637       IWORK(3) = WARNING
01638 *
01639       RETURN
01640 *     ..
01641 *     .. END OF SGEJSV
01642 *     ..
01643       END
01644 *