LAPACK: SRC/dgejsv.f Source File

00001       SUBROUTINE DGEJSV( JOBA, JOBU, JOBV, JOBR, JOBT, JOBP,
00002      &                   M, N, A, LDA, SVA, U, LDU, V, LDV,
00003      &                   WORK, LWORK, IWORK, INFO )
00004 *
00005 *  -- LAPACK routine (version 3.2.2)                                    --
00006 *
00007 *  -- Contributed by Zlatko Drmac of the University of Zagreb and     --
00008 *  -- Kresimir Veselic of the Fernuniversitaet Hagen                  --
00009 *  -- June 2010                                                       --
00010 *
00011 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
00012 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
00013 *
00014 * This routine is also part of SIGMA (version 1.23, October 23. 2008.)
00015 * SIGMA is a library of algorithms for highly accurate algorithms for
00016 * computation of SVD, PSVD, QSVD, (H,K)-SVD, and for solution of the
00017 * eigenvalue problems Hx = lambda M x, H M x = lambda x with H, M > 0.
00018 *
00019 *     .. Scalar Arguments ..
00020       IMPLICIT    NONE
00021       INTEGER     INFO, LDA, LDU, LDV, LWORK, M, N
00022 *     ..
00023 *     .. Array Arguments ..
00024       DOUBLE PRECISION A( LDA, * ), SVA( N ), U( LDU, * ), V( LDV, * ),
00025      &            WORK( LWORK )
00026       INTEGER     IWORK( * )
00027       CHARACTER*1 JOBA, JOBP, JOBR, JOBT, JOBU, JOBV
00028 *     ..
00029 *
00030 *  Purpose
00031 *  =======
00032 *
00033 *  DGEJSV computes the singular value decomposition (SVD) of a real M-by-N
00034 *  matrix [A], where M >= N. The SVD of [A] is written as
00035 *
00036 *               [A] = [U] * [SIGMA] * [V]^t,
00037 *
00038 *  where [SIGMA] is an N-by-N (M-by-N) matrix which is zero except for its N
00039 *  diagonal elements, [U] is an M-by-N (or M-by-M) orthonormal matrix, and
00040 *  [V] is an N-by-N orthogonal matrix. The diagonal elements of [SIGMA] are
00041 *  the singular values of [A]. The columns of [U] and [V] are the left and
00042 *  the right singular vectors of [A], respectively. The matrices [U] and [V]
00043 *  are computed and stored in the arrays U and V, respectively. The diagonal
00044 *  of [SIGMA] is computed and stored in the array SVA.
00045 *
00046 *  Arguments
00047 *  =========
00048 *
00049 *  JOBA    (input) CHARACTER*1
00050 *        Specifies the level of accuracy:
00051 *       = 'C': This option works well (high relative accuracy) if A = B * D,
00052 *             with well-conditioned B and arbitrary diagonal matrix D.
00053 *             The accuracy cannot be spoiled by COLUMN scaling. The
00054 *             accuracy of the computed output depends on the condition of
00055 *             B, and the procedure aims at the best theoretical accuracy.
00056 *             The relative error max_{i=1:N}|d sigma_i| / sigma_i is
00057 *             bounded by f(M,N)*epsilon* cond(B), independent of D.
00058 *             The input matrix is preprocessed with the QRF with column
00059 *             pivoting. This initial preprocessing and preconditioning by
00060 *             a rank revealing QR factorization is common for all values of
00061 *             JOBA. Additional actions are specified as follows:
00062 *       = 'E': Computation as with 'C' with an additional estimate of the
00063 *             condition number of B. It provides a realistic error bound.
00064 *       = 'F': If A = D1 * C * D2 with ill-conditioned diagonal scalings
00065 *             D1, D2, and well-conditioned matrix C, this option gives
00066 *             higher accuracy than the 'C' option. If the structure of the
00067 *             input matrix is not known, and relative accuracy is
00068 *             desirable, then this option is advisable. The input matrix A
00069 *             is preprocessed with QR factorization with FULL (row and
00070 *             column) pivoting.
00071 *       = 'G'  Computation as with 'F' with an additional estimate of the
00072 *             condition number of B, where A=D*B. If A has heavily weighted
00073 *             rows, then using this condition number gives too pessimistic
00074 *             error bound.
00075 *       = 'A': Small singular values are the noise and the matrix is treated
00076 *             as numerically rank defficient. The error in the computed
00077 *             singular values is bounded by f(m,n)*epsilon*||A||.
00078 *             The computed SVD A = U * S * V^t restores A up to
00079 *             f(m,n)*epsilon*||A||.
00080 *             This gives the procedure the licence to discard (set to zero)
00081 *             all singular values below N*epsilon*||A||.
00082 *       = 'R': Similar as in 'A'. Rank revealing property of the initial
00083 *             QR factorization is used do reveal (using triangular factor)
00084 *             a gap sigma_{r+1} < epsilon * sigma_r in which case the
00085 *             numerical RANK is declared to be r. The SVD is computed with
00086 *             absolute error bounds, but more accurately than with 'A'.
00087 *
00088 *  JOBU    (input) CHARACTER*1
00089 *        Specifies whether to compute the columns of U:
00090 *       = 'U': N columns of U are returned in the array U.
00091 *       = 'F': full set of M left sing. vectors is returned in the array U.
00092 *       = 'W': U may be used as workspace of length M*N. See the description
00093 *             of U.
00094 *       = 'N': U is not computed.
00095 *
00096 *  JOBV    (input) CHARACTER*1
00097 *        Specifies whether to compute the matrix V:
00098 *       = 'V': N columns of V are returned in the array V; Jacobi rotations
00099 *             are not explicitly accumulated.
00100 *       = 'J': N columns of V are returned in the array V, but they are
00101 *             computed as the product of Jacobi rotations. This option is
00102 *             allowed only if JOBU .NE. 'N', i.e. in computing the full SVD.
00103 *       = 'W': V may be used as workspace of length N*N. See the description
00104 *             of V.
00105 *       = 'N': V is not computed.
00106 *
00107 *  JOBR    (input) CHARACTER*1
00108 *        Specifies the RANGE for the singular values. Issues the licence to
00109 *        set to zero small positive singular values if they are outside
00110 *        specified range. If A .NE. 0 is scaled so that the largest singular
00111 *        value of c*A is around DSQRT(BIG), BIG=SLAMCH('O'), then JOBR issues
00112 *        the licence to kill columns of A whose norm in c*A is less than
00113 *        DSQRT(SFMIN) (for JOBR.EQ.'R'), or less than SMALL=SFMIN/EPSLN,
00114 *        where SFMIN=SLAMCH('S'), EPSLN=SLAMCH('E').
00115 *       = 'N': Do not kill small columns of c*A. This option assumes that
00116 *             BLAS and QR factorizations and triangular solvers are
00117 *             implemented to work in that range. If the condition of A
00118 *             is greater than BIG, use DGESVJ.
00119 *       = 'R': RESTRICTED range for sigma(c*A) is [DSQRT(SFMIN), DSQRT(BIG)]
00120 *             (roughly, as described above). This option is recommended.
00121 *                                            ~~~~~~~~~~~~~~~~~~~~~~~~~~~
00122 *        For computing the singular values in the FULL range [SFMIN,BIG]
00123 *        use DGESVJ.
00124 *
00125 *  JOBT    (input) CHARACTER*1
00126 *        If the matrix is square then the procedure may determine to use
00127 *        transposed A if A^t seems to be better with respect to convergence.
00128 *        If the matrix is not square, JOBT is ignored. This is subject to
00129 *        changes in the future.
00130 *        The decision is based on two values of entropy over the adjoint
00131 *        orbit of A^t * A. See the descriptions of WORK(6) and WORK(7).
00132 *       = 'T': transpose if entropy test indicates possibly faster
00133 *        convergence of Jacobi process if A^t is taken as input. If A is
00134 *        replaced with A^t, then the row pivoting is included automatically.
00135 *       = 'N': do not speculate.
00136 *        This option can be used to compute only the singular values, or the
00137 *        full SVD (U, SIGMA and V). For only one set of singular vectors
00138 *        (U or V), the caller should provide both U and V, as one of the
00139 *        matrices is used as workspace if the matrix A is transposed.
00140 *        The implementer can easily remove this constraint and make the
00141 *        code more complicated. See the descriptions of U and V.
00142 *
00143 *  JOBP    (input) CHARACTER*1
00144 *        Issues the licence to introduce structured perturbations to drown
00145 *        denormalized numbers. This licence should be active if the
00146 *        denormals are poorly implemented, causing slow computation,
00147 *        especially in cases of fast convergence (!). For details see [1,2].
00148 *        For the sake of simplicity, this perturbations are included only
00149 *        when the full SVD or only the singular values are requested. The
00150 *        implementer/user can easily add the perturbation for the cases of
00151 *        computing one set of singular vectors.
00152 *       = 'P': introduce perturbation
00153 *       = 'N': do not perturb
00154 *
00155 *  M       (input) INTEGER
00156 *         The number of rows of the input matrix A.  M >= 0.
00157 *
00158 *  N       (input) INTEGER
00159 *         The number of columns of the input matrix A. M >= N >= 0.
00160 *
00161 *  A       (input/workspace) DOUBLE PRECISION array, dimension (LDA,N)
00162 *          On entry, the M-by-N matrix A.
00163 *
00164 *  LDA     (input) INTEGER
00165 *          The leading dimension of the array A.  LDA >= max(1,M).
00166 *
00167 *  SVA     (workspace/output) DOUBLE PRECISION array, dimension (N)
00168 *          On exit,
00169 *          - For WORK(1)/WORK(2) = ONE: The singular values of A. During the
00170 *            computation SVA contains Euclidean column norms of the
00171 *            iterated matrices in the array A.
00172 *          - For WORK(1) .NE. WORK(2): The singular values of A are
00173 *            (WORK(1)/WORK(2)) * SVA(1:N). This factored form is used if
00174 *            sigma_max(A) overflows or if small singular values have been
00175 *            saved from underflow by scaling the input matrix A.
00176 *          - If JOBR='R' then some of the singular values may be returned
00177 *            as exact zeros obtained by "set to zero" because they are
00178 *            below the numerical rank threshold or are denormalized numbers.
00179 *
00180 *  U       (workspace/output) DOUBLE PRECISION array, dimension ( LDU, N )
00181 *          If JOBU = 'U', then U contains on exit the M-by-N matrix of
00182 *                         the left singular vectors.
00183 *          If JOBU = 'F', then U contains on exit the M-by-M matrix of
00184 *                         the left singular vectors, including an ONB
00185 *                         of the orthogonal complement of the Range(A).
00186 *          If JOBU = 'W'  .AND. (JOBV.EQ.'V' .AND. JOBT.EQ.'T' .AND. M.EQ.N),
00187 *                         then U is used as workspace if the procedure
00188 *                         replaces A with A^t. In that case, [V] is computed
00189 *                         in U as left singular vectors of A^t and then
00190 *                         copied back to the V array. This 'W' option is just
00191 *                         a reminder to the caller that in this case U is
00192 *                         reserved as workspace of length N*N.
00193 *          If JOBU = 'N'  U is not referenced.
00194 *
00195 * LDU      (input) INTEGER
00196 *          The leading dimension of the array U,  LDU >= 1.
00197 *          IF  JOBU = 'U' or 'F' or 'W',  then LDU >= M.
00198 *
00199 *  V       (workspace/output) DOUBLE PRECISION array, dimension ( LDV, N )
00200 *          If JOBV = 'V', 'J' then V contains on exit the N-by-N matrix of
00201 *                         the right singular vectors;
00202 *          If JOBV = 'W', AND (JOBU.EQ.'U' AND JOBT.EQ.'T' AND M.EQ.N),
00203 *                         then V is used as workspace if the pprocedure
00204 *                         replaces A with A^t. In that case, [U] is computed
00205 *                         in V as right singular vectors of A^t and then
00206 *                         copied back to the U array. This 'W' option is just
00207 *                         a reminder to the caller that in this case V is
00208 *                         reserved as workspace of length N*N.
00209 *          If JOBV = 'N'  V is not referenced.
00210 *
00211 *  LDV     (input) INTEGER
00212 *          The leading dimension of the array V,  LDV >= 1.
00213 *          If JOBV = 'V' or 'J' or 'W', then LDV >= N.
00214 *
00215 *  WORK    (workspace/output) DOUBLE PRECISION array, dimension at least LWORK.
00216 *          On exit,
00217 *          WORK(1) = SCALE = WORK(2) / WORK(1) is the scaling factor such
00218 *                    that SCALE*SVA(1:N) are the computed singular values
00219 *                    of A. (See the description of SVA().)
00220 *          WORK(2) = See the description of WORK(1).
00221 *          WORK(3) = SCONDA is an estimate for the condition number of
00222 *                    column equilibrated A. (If JOBA .EQ. 'E' or 'G')
00223 *                    SCONDA is an estimate of DSQRT(||(R^t * R)^(-1)||_1).
00224 *                    It is computed using DPOCON. It holds
00225 *                    N^(-1/4) * SCONDA <= ||R^(-1)||_2 <= N^(1/4) * SCONDA
00226 *                    where R is the triangular factor from the QRF of A.
00227 *                    However, if R is truncated and the numerical rank is
00228 *                    determined to be strictly smaller than N, SCONDA is
00229 *                    returned as -1, thus indicating that the smallest
00230 *                    singular values might be lost.
00231 *
00232 *          If full SVD is needed, the following two condition numbers are
00233 *          useful for the analysis of the algorithm. They are provied for
00234 *          a developer/implementer who is familiar with the details of
00235 *          the method.
00236 *
00237 *          WORK(4) = an estimate of the scaled condition number of the
00238 *                    triangular factor in the first QR factorization.
00239 *          WORK(5) = an estimate of the scaled condition number of the
00240 *                    triangular factor in the second QR factorization.
00241 *          The following two parameters are computed if JOBT .EQ. 'T'.
00242 *          They are provided for a developer/implementer who is familiar
00243 *          with the details of the method.
00244 *
00245 *          WORK(6) = the entropy of A^t*A :: this is the Shannon entropy
00246 *                    of diag(A^t*A) / Trace(A^t*A) taken as point in the
00247 *                    probability simplex.
00248 *          WORK(7) = the entropy of A*A^t.
00249 *
00250 *  LWORK   (input) INTEGER
00251 *          Length of WORK to confirm proper allocation of work space.
00252 *          LWORK depends on the job:
00253 *
00254 *          If only SIGMA is needed ( JOBU.EQ.'N', JOBV.EQ.'N' ) and
00255 *            -> .. no scaled condition estimate required ( JOBE.EQ.'N'):
00256 *               LWORK >= max(2*M+N,4*N+1,7). This is the minimal requirement.
00257 *               For optimal performance (blocked code) the optimal value
00258 *               is LWORK >= max(2*M+N,3*N+(N+1)*NB,7). Here NB is the optimal
00259 *               block size for xGEQP3/xGEQRF.
00260 *            -> .. an estimate of the scaled condition number of A is
00261 *               required (JOBA='E', 'G'). In this case, LWORK is the maximum
00262 *               of the above and N*N+4*N, i.e. LWORK >= max(2*M+N,N*N+4N,7).
00263 *
00264 *          If SIGMA and the right singular vectors are needed (JOBV.EQ.'V'),
00265 *            -> the minimal requirement is LWORK >= max(2*N+M,7).
00266 *            -> For optimal performance, LWORK >= max(2*N+M,2*N+N*NB,7),
00267 *               where NB is the optimal block size.
00268 *
00269 *          If SIGMA and the left singular vectors are needed
00270 *            -> the minimal requirement is LWORK >= max(2*N+M,7).
00271 *            -> For optimal performance, LWORK >= max(2*N+M,2*N+N*NB,7),
00272 *               where NB is the optimal block size.
00273 *
00274 *          If full SVD is needed ( JOBU.EQ.'U' or 'F', JOBV.EQ.'V' ) and
00275 *            -> .. the singular vectors are computed without explicit
00276 *               accumulation of the Jacobi rotations, LWORK >= 6*N+2*N*N
00277 *            -> .. in the iterative part, the Jacobi rotations are
00278 *               explicitly accumulated (option, see the description of JOBV),
00279 *               then the minimal requirement is LWORK >= max(M+3*N+N*N,7).
00280 *               For better performance, if NB is the optimal block size,
00281 *               LWORK >= max(3*N+N*N+M,3*N+N*N+N*NB,7).
00282 *
00283 *  IWORK   (workspace/output) INTEGER array, dimension M+3*N.
00284 *          On exit,
00285 *          IWORK(1) = the numerical rank determined after the initial
00286 *                     QR factorization with pivoting. See the descriptions
00287 *                     of JOBA and JOBR.
00288 *          IWORK(2) = the number of the computed nonzero singular values
00289 *          IWORK(3) = if nonzero, a warning message:
00290 *                     If IWORK(3).EQ.1 then some of the column norms of A
00291 *                     were denormalized floats. The requested high accuracy
00292 *                     is not warranted by the data.
00293 *
00294 *  INFO    (output) INTEGER
00295 *           < 0  : if INFO = -i, then the i-th argument had an illegal value.
00296 *           = 0 :  successfull exit;
00297 *           > 0 :  DGEJSV  did not converge in the maximal allowed number
00298 *                  of sweeps. The computed values may be inaccurate.
00299 *
00300 *  Further Details
00301 *  ===============
00302 *
00303 *  DGEJSV implements a preconditioned Jacobi SVD algorithm. It uses SGEQP3,
00304 *  SGEQRF, and SGELQF as preprocessors and preconditioners. Optionally, an
00305 *  additional row pivoting can be used as a preprocessor, which in some
00306 *  cases results in much higher accuracy. An example is matrix A with the
00307 *  structure A = D1 * C * D2, where D1, D2 are arbitrarily ill-conditioned
00308 *  diagonal matrices and C is well-conditioned matrix. In that case, complete
00309 *  pivoting in the first QR factorizations provides accuracy dependent on the
00310 *  condition number of C, and independent of D1, D2. Such higher accuracy is
00311 *  not completely understood theoretically, but it works well in practice.
00312 *  Further, if A can be written as A = B*D, with well-conditioned B and some
00313 *  diagonal D, then the high accuracy is guaranteed, both theoretically and
00314 *  in software, independent of D. For more details see [1], [2].
00315 *     The computational range for the singular values can be the full range
00316 *  ( UNDERFLOW,OVERFLOW ), provided that the machine arithmetic and the BLAS
00317 *  & LAPACK routines called by DGEJSV are implemented to work in that range.
00318 *  If that is not the case, then the restriction for safe computation with
00319 *  the singular values in the range of normalized IEEE numbers is that the
00320 *  spectral condition number kappa(A)=sigma_max(A)/sigma_min(A) does not
00321 *  overflow. This code (DGEJSV) is best used in this restricted range,
00322 *  meaning that singular values of magnitude below ||A||_2 / SLAMCH('O') are
00323 *  returned as zeros. See JOBR for details on this.
00324 *     Further, this implementation is somewhat slower than the one described
00325 *  in [1,2] due to replacement of some non-LAPACK components, and because
00326 *  the choice of some tuning parameters in the iterative part (DGESVJ) is
00327 *  left to the implementer on a particular machine.
00328 *     The rank revealing QR factorization (in this code: SGEQP3) should be
00329 *  implemented as in [3]. We have a new version of SGEQP3 under development
00330 *  that is more robust than the current one in LAPACK, with a cleaner cut in
00331 *  rank defficient cases. It will be available in the SIGMA library [4].
00332 *  If M is much larger than N, it is obvious that the inital QRF with
00333 *  column pivoting can be preprocessed by the QRF without pivoting. That
00334 *  well known trick is not used in DGEJSV because in some cases heavy row
00335 *  weighting can be treated with complete pivoting. The overhead in cases
00336 *  M much larger than N is then only due to pivoting, but the benefits in
00337 *  terms of accuracy have prevailed. The implementer/user can incorporate
00338 *  this extra QRF step easily. The implementer can also improve data movement
00339 *  (matrix transpose, matrix copy, matrix transposed copy) - this
00340 *  implementation of DGEJSV uses only the simplest, naive data movement.
00341 *
00342 *  Contributors
00343 *
00344 *  Zlatko Drmac (Zagreb, Croatia) and Kresimir Veselic (Hagen, Germany)
00345 *
00346 *  References
00347 *
00348 * [1] Z. Drmac and K. Veselic: New fast and accurate Jacobi SVD algorithm I.
00349 *     SIAM J. Matrix Anal. Appl. Vol. 35, No. 2 (2008), pp. 1322-1342.
00350 *     LAPACK Working note 169.
00351 * [2] Z. Drmac and K. Veselic: New fast and accurate Jacobi SVD algorithm II.
00352 *     SIAM J. Matrix Anal. Appl. Vol. 35, No. 2 (2008), pp. 1343-1362.
00353 *     LAPACK Working note 170.
00354 * [3] Z. Drmac and Z. Bujanovic: On the failure of rank-revealing QR
00355 *     factorization software - a case study.
00356 *     ACM Trans. Math. Softw. Vol. 35, No 2 (2008), pp. 1-28.
00357 *     LAPACK Working note 176.
00358 * [4] Z. Drmac: SIGMA - mathematical software library for accurate SVD, PSV,
00359 *     QSVD, (H,K)-SVD computations.
00360 *     Department of Mathematics, University of Zagreb, 2008.
00361 *
00362 *  Bugs, examples and comments
00363 * 
00364 *  Please report all bugs and send interesting examples and/or comments to
00365 *  drmac@math.hr. Thank you.
00366 *
00367 * ==========================================================================
00368 *
00369 *     .. Local Parameters ..
00370       DOUBLE PRECISION   ZERO,  ONE
00371       PARAMETER ( ZERO = 0.0D0, ONE = 1.0D0 )
00372 *     ..
00373 *     .. Local Scalars ..
00374       DOUBLE PRECISION AAPP, AAQQ, AATMAX, AATMIN, BIG, BIG1, COND_OK,
00375      &        CONDR1, CONDR2, ENTRA,  ENTRAT, EPSLN,  MAXPRJ, SCALEM,
00376      &        SCONDA, SFMIN,  SMALL,  TEMP1,  USCAL1, USCAL2, XSC
00377       INTEGER IERR,   N1,     NR,     NUMRANK,        p, q,   WARNING
00378       LOGICAL ALMORT, DEFR,   ERREST, GOSCAL, JRACC,  KILL,   LSVEC,
00379      &        L2ABER, L2KILL, L2PERT, L2RANK, L2TRAN,
00380      &        NOSCAL, ROWPIV, RSVEC,  TRANSP
00381 *     ..
00382 *     .. Intrinsic Functions ..
00383       INTRINSIC DABS,  DLOG, DMAX1, DMIN1, DBLE,
00384      &          MAX0, MIN0, IDNINT,  DSIGN,  DSQRT
00385 *     ..
00386 *     .. External Functions ..
00387       DOUBLE PRECISION  DLAMCH, DNRM2
00388       INTEGER   IDAMAX
00389       LOGICAL   LSAME
00390       EXTERNAL  IDAMAX, LSAME, DLAMCH, DNRM2
00391 *     ..
00392 *     .. External Subroutines ..
00393       EXTERNAL  DCOPY,  DGELQF, DGEQP3, DGEQRF, DLACPY, DLASCL,
00394      &          DLASET, DLASSQ, DLASWP, DORGQR, DORMLQ,
00395      &          DORMQR, DPOCON, DSCAL,  DSWAP,  DTRSM,  XERBLA
00396 *
00397       EXTERNAL  DGESVJ
00398 *     ..
00399 *
00400 *     Test the input arguments
00401 *
00402       LSVEC  = LSAME( JOBU, 'U' ) .OR. LSAME( JOBU, 'F' )
00403       JRACC  = LSAME( JOBV, 'J' )
00404       RSVEC  = LSAME( JOBV, 'V' ) .OR. JRACC
00405       ROWPIV = LSAME( JOBA, 'F' ) .OR. LSAME( JOBA, 'G' )
00406       L2RANK = LSAME( JOBA, 'R' )
00407       L2ABER = LSAME( JOBA, 'A' )
00408       ERREST = LSAME( JOBA, 'E' ) .OR. LSAME( JOBA, 'G' )
00409       L2TRAN = LSAME( JOBT, 'T' )
00410       L2KILL = LSAME( JOBR, 'R' )
00411       DEFR   = LSAME( JOBR, 'N' )
00412       L2PERT = LSAME( JOBP, 'P' )
00413 *
00414       IF ( .NOT.(ROWPIV .OR. L2RANK .OR. L2ABER .OR.
00415      &     ERREST .OR. LSAME( JOBA, 'C' ) )) THEN
00416          INFO = - 1
00417       ELSE IF ( .NOT.( LSVEC  .OR. LSAME( JOBU, 'N' ) .OR.
00418      &                             LSAME( JOBU, 'W' )) ) THEN
00419          INFO = - 2
00420       ELSE IF ( .NOT.( RSVEC .OR. LSAME( JOBV, 'N' ) .OR.
00421      &   LSAME( JOBV, 'W' )) .OR. ( JRACC .AND. (.NOT.LSVEC) ) ) THEN
00422          INFO = - 3
00423       ELSE IF ( .NOT. ( L2KILL .OR. DEFR ) )    THEN
00424          INFO = - 4
00425       ELSE IF ( .NOT. ( L2TRAN .OR. LSAME( JOBT, 'N' ) ) ) THEN
00426          INFO = - 5
00427       ELSE IF ( .NOT. ( L2PERT .OR. LSAME( JOBP, 'N' ) ) ) THEN
00428          INFO = - 6
00429       ELSE IF ( M .LT. 0 ) THEN
00430          INFO = - 7
00431       ELSE IF ( ( N .LT. 0 ) .OR. ( N .GT. M ) ) THEN
00432          INFO = - 8
00433       ELSE IF ( LDA .LT. M ) THEN
00434          INFO = - 10
00435       ELSE IF ( LSVEC .AND. ( LDU .LT. M ) ) THEN
00436          INFO = - 13
00437       ELSE IF ( RSVEC .AND. ( LDV .LT. N ) ) THEN
00438          INFO = - 14
00439       ELSE IF ( (.NOT.(LSVEC .OR. RSVEC .OR. ERREST).AND.
00440      &                           (LWORK .LT. MAX0(7,4*N+1,2*M+N))) .OR.
00441      & (.NOT.(LSVEC .OR. LSVEC) .AND. ERREST .AND.
00442      &                         (LWORK .LT. MAX0(7,4*N+N*N,2*M+N))) .OR.
00443      & (LSVEC .AND. (.NOT.RSVEC) .AND. (LWORK .LT. MAX0(7,2*N+M))) .OR.
00444      & (RSVEC .AND. (.NOT.LSVEC) .AND. (LWORK .LT. MAX0(7,2*N+M))) .OR.
00445      & (LSVEC .AND. RSVEC .AND. .NOT.JRACC .AND. (LWORK.LT.6*N+2*N*N))
00446      & .OR. (LSVEC.AND.RSVEC.AND.JRACC.AND.LWORK.LT.MAX0(7,M+3*N+N*N)))
00447      &   THEN
00448          INFO = - 17
00449       ELSE
00450 *        #:)
00451          INFO = 0
00452       END IF
00453 *
00454       IF ( INFO .NE. 0 ) THEN
00455 *       #:(
00456          CALL XERBLA( 'DGEJSV', - INFO )
00457       END IF
00458 *
00459 *     Quick return for void matrix (Y3K safe)
00460 * #:)
00461       IF ( ( M .EQ. 0 ) .OR. ( N .EQ. 0 ) ) RETURN
00462 *
00463 *     Determine whether the matrix U should be M x N or M x M
00464 *
00465       IF ( LSVEC ) THEN
00466          N1 = N
00467          IF ( LSAME( JOBU, 'F' ) ) N1 = M
00468       END IF
00469 *
00470 *     Set numerical parameters
00471 *
00472 *!    NOTE: Make sure DLAMCH() does not fail on the target architecture.
00473 *
00474 
00475       EPSLN = DLAMCH('Epsilon')
00476       SFMIN = DLAMCH('SafeMinimum')
00477       SMALL = SFMIN / EPSLN
00478       BIG   = DLAMCH('O')
00479 *     BIG   = ONE / SFMIN
00480 *
00481 *     Initialize SVA(1:N) = diag( ||A e_i||_2 )_1^N
00482 *
00483 *(!)  If necessary, scale SVA() to protect the largest norm from
00484 *     overflow. It is possible that this scaling pushes the smallest
00485 *     column norm left from the underflow threshold (extreme case).
00486 *
00487       SCALEM  = ONE / DSQRT(DBLE(M)*DBLE(N))
00488       NOSCAL  = .TRUE.
00489       GOSCAL  = .TRUE.
00490       DO 1874 p = 1, N
00491          AAPP = ZERO
00492          AAQQ = ZERO
00493          CALL DLASSQ( M, A(1,p), 1, AAPP, AAQQ )
00494          IF ( AAPP .GT. BIG ) THEN
00495             INFO = - 9
00496             CALL XERBLA( 'DGEJSV', -INFO )
00497             RETURN
00498          END IF
00499          AAQQ = DSQRT(AAQQ)
00500          IF ( ( AAPP .LT. (BIG / AAQQ) ) .AND. NOSCAL  ) THEN
00501             SVA(p)  = AAPP * AAQQ
00502          ELSE
00503             NOSCAL  = .FALSE.
00504             SVA(p)  = AAPP * ( AAQQ * SCALEM )
00505             IF ( GOSCAL ) THEN
00506                GOSCAL = .FALSE.
00507                CALL DSCAL( p-1, SCALEM, SVA, 1 )
00508             END IF
00509          END IF
00510  1874 CONTINUE
00511 *
00512       IF ( NOSCAL ) SCALEM = ONE
00513 *
00514       AAPP = ZERO
00515       AAQQ = BIG
00516       DO 4781 p = 1, N
00517          AAPP = DMAX1( AAPP, SVA(p) )
00518          IF ( SVA(p) .NE. ZERO ) AAQQ = DMIN1( AAQQ, SVA(p) )
00519  4781 CONTINUE
00520 *
00521 *     Quick return for zero M x N matrix
00522 * #:)
00523       IF ( AAPP .EQ. ZERO ) THEN
00524          IF ( LSVEC ) CALL DLASET( 'G', M, N1, ZERO, ONE, U, LDU )
00525          IF ( RSVEC ) CALL DLASET( 'G', N, N,  ZERO, ONE, V, LDV )
00526          WORK(1) = ONE
00527          WORK(2) = ONE
00528          IF ( ERREST ) WORK(3) = ONE
00529          IF ( LSVEC .AND. RSVEC ) THEN
00530             WORK(4) = ONE
00531             WORK(5) = ONE
00532          END IF
00533          IF ( L2TRAN ) THEN
00534             WORK(6) = ZERO
00535             WORK(7) = ZERO
00536          END IF
00537          IWORK(1) = 0
00538          IWORK(2) = 0
00539          RETURN
00540       END IF
00541 *
00542 *     Issue warning if denormalized column norms detected. Override the
00543 *     high relative accuracy request. Issue licence to kill columns
00544 *     (set them to zero) whose norm is less than sigma_max / BIG (roughly).
00545 * #:(
00546       WARNING = 0
00547       IF ( AAQQ .LE. SFMIN ) THEN
00548          L2RANK = .TRUE.
00549          L2KILL = .TRUE.
00550          WARNING = 1
00551       END IF
00552 *
00553 *     Quick return for one-column matrix
00554 * #:)
00555       IF ( N .EQ. 1 ) THEN
00556 *
00557          IF ( LSVEC ) THEN
00558             CALL DLASCL( 'G',0,0,SVA(1),SCALEM, M,1,A(1,1),LDA,IERR )
00559             CALL DLACPY( 'A', M, 1, A, LDA, U, LDU )
00560 *           computing all M left singular vectors of the M x 1 matrix
00561             IF ( N1 .NE. N  ) THEN
00562                CALL DGEQRF( M, N, U,LDU, WORK, WORK(N+1),LWORK-N,IERR )
00563                CALL DORGQR( M,N1,1, U,LDU,WORK,WORK(N+1),LWORK-N,IERR )
00564                CALL DCOPY( M, A(1,1), 1, U(1,1), 1 )
00565             END IF
00566          END IF
00567          IF ( RSVEC ) THEN
00568              V(1,1) = ONE
00569          END IF
00570          IF ( SVA(1) .LT. (BIG*SCALEM) ) THEN
00571             SVA(1)  = SVA(1) / SCALEM
00572             SCALEM  = ONE
00573          END IF
00574          WORK(1) = ONE / SCALEM
00575          WORK(2) = ONE
00576          IF ( SVA(1) .NE. ZERO ) THEN
00577             IWORK(1) = 1
00578             IF ( ( SVA(1) / SCALEM) .GE. SFMIN ) THEN
00579                IWORK(2) = 1
00580             ELSE
00581                IWORK(2) = 0
00582             END IF
00583          ELSE
00584             IWORK(1) = 0
00585             IWORK(2) = 0
00586          END IF
00587          IF ( ERREST ) WORK(3) = ONE
00588          IF ( LSVEC .AND. RSVEC ) THEN
00589             WORK(4) = ONE
00590             WORK(5) = ONE
00591          END IF
00592          IF ( L2TRAN ) THEN
00593             WORK(6) = ZERO
00594             WORK(7) = ZERO
00595          END IF
00596          RETURN
00597 *
00598       END IF
00599 *
00600       TRANSP = .FALSE.
00601       L2TRAN = L2TRAN .AND. ( M .EQ. N )
00602 *
00603       AATMAX = -ONE
00604       AATMIN =  BIG
00605       IF ( ROWPIV .OR. L2TRAN ) THEN
00606 *
00607 *     Compute the row norms, needed to determine row pivoting sequence
00608 *     (in the case of heavily row weighted A, row pivoting is strongly
00609 *     advised) and to collect information needed to compare the
00610 *     structures of A * A^t and A^t * A (in the case L2TRAN.EQ..TRUE.).
00611 *
00612          IF ( L2TRAN ) THEN
00613             DO 1950 p = 1, M
00614                XSC   = ZERO
00615                TEMP1 = ZERO
00616                CALL DLASSQ( N, A(p,1), LDA, XSC, TEMP1 )
00617 *              DLASSQ gets both the ell_2 and the ell_infinity norm
00618 *              in one pass through the vector
00619                WORK(M+N+p)  = XSC * SCALEM
00620                WORK(N+p)    = XSC * (SCALEM*DSQRT(TEMP1))
00621                AATMAX = DMAX1( AATMAX, WORK(N+p) )
00622                IF (WORK(N+p) .NE. ZERO) AATMIN = DMIN1(AATMIN,WORK(N+p))
00623  1950       CONTINUE
00624          ELSE
00625             DO 1904 p = 1, M
00626                WORK(M+N+p) = SCALEM*DABS( A(p,IDAMAX(N,A(p,1),LDA)) )
00627                AATMAX = DMAX1( AATMAX, WORK(M+N+p) )
00628                AATMIN = DMIN1( AATMIN, WORK(M+N+p) )
00629  1904       CONTINUE
00630          END IF
00631 *
00632       END IF
00633 *
00634 *     For square matrix A try to determine whether A^t  would be  better
00635 *     input for the preconditioned Jacobi SVD, with faster convergence.
00636 *     The decision is based on an O(N) function of the vector of column
00637 *     and row norms of A, based on the Shannon entropy. This should give
00638 *     the right choice in most cases when the difference actually matters.
00639 *     It may fail and pick the slower converging side.
00640 *
00641       ENTRA  = ZERO
00642       ENTRAT = ZERO
00643       IF ( L2TRAN ) THEN
00644 *
00645          XSC   = ZERO
00646          TEMP1 = ZERO
00647          CALL DLASSQ( N, SVA, 1, XSC, TEMP1 )
00648          TEMP1 = ONE / TEMP1
00649 *
00650          ENTRA = ZERO
00651          DO 1113 p = 1, N
00652             BIG1  = ( ( SVA(p) / XSC )**2 ) * TEMP1
00653             IF ( BIG1 .NE. ZERO ) ENTRA = ENTRA + BIG1 * DLOG(BIG1)
00654  1113    CONTINUE
00655          ENTRA = - ENTRA / DLOG(DBLE(N))
00656 *
00657 *        Now, SVA().^2/Trace(A^t * A) is a point in the probability simplex.
00658 *        It is derived from the diagonal of  A^t * A.  Do the same with the
00659 *        diagonal of A * A^t, compute the entropy of the corresponding
00660 *        probability distribution. Note that A * A^t and A^t * A have the
00661 *        same trace.
00662 *
00663          ENTRAT = ZERO
00664          DO 1114 p = N+1, N+M
00665             BIG1 = ( ( WORK(p) / XSC )**2 ) * TEMP1
00666             IF ( BIG1 .NE. ZERO ) ENTRAT = ENTRAT + BIG1 * DLOG(BIG1)
00667  1114    CONTINUE
00668          ENTRAT = - ENTRAT / DLOG(DBLE(M))
00669 *
00670 *        Analyze the entropies and decide A or A^t. Smaller entropy
00671 *        usually means better input for the algorithm.
00672 *
00673          TRANSP = ( ENTRAT .LT. ENTRA )
00674 *
00675 *        If A^t is better than A, transpose A.
00676 *
00677          IF ( TRANSP ) THEN
00678 *           In an optimal implementation, this trivial transpose
00679 *           should be replaced with faster transpose.
00680             DO 1115 p = 1, N - 1
00681                DO 1116 q = p + 1, N
00682                    TEMP1 = A(q,p)
00683                   A(q,p) = A(p,q)
00684                   A(p,q) = TEMP1
00685  1116          CONTINUE
00686  1115       CONTINUE
00687             DO 1117 p = 1, N
00688                WORK(M+N+p) = SVA(p)
00689                SVA(p)      = WORK(N+p)
00690  1117       CONTINUE
00691             TEMP1  = AAPP
00692             AAPP   = AATMAX
00693             AATMAX = TEMP1
00694             TEMP1  = AAQQ
00695             AAQQ   = AATMIN
00696             AATMIN = TEMP1
00697             KILL   = LSVEC
00698             LSVEC  = RSVEC
00699             RSVEC  = KILL
00700 *
00701             ROWPIV = .TRUE.
00702          END IF
00703 *
00704       END IF
00705 *     END IF L2TRAN
00706 *
00707 *     Scale the matrix so that its maximal singular value remains less
00708 *     than DSQRT(BIG) -- the matrix is scaled so that its maximal column
00709 *     has Euclidean norm equal to DSQRT(BIG/N). The only reason to keep
00710 *     DSQRT(BIG) instead of BIG is the fact that DGEJSV uses LAPACK and
00711 *     BLAS routines that, in some implementations, are not capable of
00712 *     working in the full interval [SFMIN,BIG] and that they may provoke
00713 *     overflows in the intermediate results. If the singular values spread
00714 *     from SFMIN to BIG, then DGESVJ will compute them. So, in that case,
00715 *     one should use DGESVJ instead of DGEJSV.
00716 *
00717       BIG1   = DSQRT( BIG )
00718       TEMP1  = DSQRT( BIG / DBLE(N) )
00719 *
00720       CALL DLASCL( 'G', 0, 0, AAPP, TEMP1, N, 1, SVA, N, IERR )
00721       IF ( AAQQ .GT. (AAPP * SFMIN) ) THEN
00722           AAQQ = ( AAQQ / AAPP ) * TEMP1
00723       ELSE
00724           AAQQ = ( AAQQ * TEMP1 ) / AAPP
00725       END IF
00726       TEMP1 = TEMP1 * SCALEM
00727       CALL DLASCL( 'G', 0, 0, AAPP, TEMP1, M, N, A, LDA, IERR )
00728 *
00729 *     To undo scaling at the end of this procedure, multiply the
00730 *     computed singular values with USCAL2 / USCAL1.
00731 *
00732       USCAL1 = TEMP1
00733       USCAL2 = AAPP
00734 *
00735       IF ( L2KILL ) THEN
00736 *        L2KILL enforces computation of nonzero singular values in
00737 *        the restricted range of condition number of the initial A,
00738 *        sigma_max(A) / sigma_min(A) approx. DSQRT(BIG)/DSQRT(SFMIN).
00739          XSC = DSQRT( SFMIN )
00740       ELSE
00741          XSC = SMALL
00742 *
00743 *        Now, if the condition number of A is too big,
00744 *        sigma_max(A) / sigma_min(A) .GT. DSQRT(BIG/N) * EPSLN / SFMIN,
00745 *        as a precaution measure, the full SVD is computed using DGESVJ
00746 *        with accumulated Jacobi rotations. This provides numerically
00747 *        more robust computation, at the cost of slightly increased run
00748 *        time. Depending on the concrete implementation of BLAS and LAPACK
00749 *        (i.e. how they behave in presence of extreme ill-conditioning) the
00750 *        implementor may decide to remove this switch.
00751          IF ( ( AAQQ.LT.DSQRT(SFMIN) ) .AND. LSVEC .AND. RSVEC ) THEN
00752             JRACC = .TRUE.
00753          END IF
00754 *
00755       END IF
00756       IF ( AAQQ .LT. XSC ) THEN
00757          DO 700 p = 1, N
00758             IF ( SVA(p) .LT. XSC ) THEN
00759                CALL DLASET( 'A', M, 1, ZERO, ZERO, A(1,p), LDA )
00760                SVA(p) = ZERO
00761             END IF
00762  700     CONTINUE
00763       END IF
00764 *
00765 *     Preconditioning using QR factorization with pivoting
00766 *
00767       IF ( ROWPIV ) THEN
00768 *        Optional row permutation (Bjoerck row pivoting):
00769 *        A result by Cox and Higham shows that the Bjoerck's
00770 *        row pivoting combined with standard column pivoting
00771 *        has similar effect as Powell-Reid complete pivoting.
00772 *        The ell-infinity norms of A are made nonincreasing.
00773          DO 1952 p = 1, M - 1
00774             q = IDAMAX( M-p+1, WORK(M+N+p), 1 ) + p - 1
00775             IWORK(2*N+p) = q
00776             IF ( p .NE. q ) THEN
00777                TEMP1       = WORK(M+N+p)
00778                WORK(M+N+p) = WORK(M+N+q)
00779                WORK(M+N+q) = TEMP1
00780             END IF
00781  1952    CONTINUE
00782          CALL DLASWP( N, A, LDA, 1, M-1, IWORK(2*N+1), 1 )
00783       END IF
00784 *
00785 *     End of the preparation phase (scaling, optional sorting and
00786 *     transposing, optional flushing of small columns).
00787 *
00788 *     Preconditioning
00789 *
00790 *     If the full SVD is needed, the right singular vectors are computed
00791 *     from a matrix equation, and for that we need theoretical analysis
00792 *     of the Businger-Golub pivoting. So we use DGEQP3 as the first RR QRF.
00793 *     In all other cases the first RR QRF can be chosen by other criteria
00794 *     (eg speed by replacing global with restricted window pivoting, such
00795 *     as in SGEQPX from TOMS # 782). Good results will be obtained using
00796 *     SGEQPX with properly (!) chosen numerical parameters.
00797 *     Any improvement of DGEQP3 improves overal performance of DGEJSV.
00798 *
00799 *     A * P1 = Q1 * [ R1^t 0]^t:
00800       DO 1963 p = 1, N
00801 *        .. all columns are free columns
00802          IWORK(p) = 0
00803  1963 CONTINUE
00804       CALL DGEQP3( M,N,A,LDA, IWORK,WORK, WORK(N+1),LWORK-N, IERR )
00805 *
00806 *     The upper triangular matrix R1 from the first QRF is inspected for
00807 *     rank deficiency and possibilities for deflation, or possible
00808 *     ill-conditioning. Depending on the user specified flag L2RANK,
00809 *     the procedure explores possibilities to reduce the numerical
00810 *     rank by inspecting the computed upper triangular factor. If
00811 *     L2RANK or L2ABER are up, then DGEJSV will compute the SVD of
00812 *     A + dA, where ||dA|| <= f(M,N)*EPSLN.
00813 *
00814       NR = 1
00815       IF ( L2ABER ) THEN
00816 *        Standard absolute error bound suffices. All sigma_i with
00817 *        sigma_i < N*EPSLN*||A|| are flushed to zero. This is an
00818 *        agressive enforcement of lower numerical rank by introducing a
00819 *        backward error of the order of N*EPSLN*||A||.
00820          TEMP1 = DSQRT(DBLE(N))*EPSLN
00821          DO 3001 p = 2, N
00822             IF ( DABS(A(p,p)) .GE. (TEMP1*DABS(A(1,1))) ) THEN
00823                NR = NR + 1
00824             ELSE
00825                GO TO 3002
00826             END IF
00827  3001    CONTINUE
00828  3002    CONTINUE
00829       ELSE IF ( L2RANK ) THEN
00830 *        .. similarly as above, only slightly more gentle (less agressive).
00831 *        Sudden drop on the diagonal of R1 is used as the criterion for
00832 *        close-to-rank-defficient.
00833          TEMP1 = DSQRT(SFMIN)
00834          DO 3401 p = 2, N
00835             IF ( ( DABS(A(p,p)) .LT. (EPSLN*DABS(A(p-1,p-1))) ) .OR.
00836      &           ( DABS(A(p,p)) .LT. SMALL ) .OR.
00837      &           ( L2KILL .AND. (DABS(A(p,p)) .LT. TEMP1) ) ) GO TO 3402
00838             NR = NR + 1
00839  3401    CONTINUE
00840  3402    CONTINUE
00841 *
00842       ELSE
00843 *        The goal is high relative accuracy. However, if the matrix
00844 *        has high scaled condition number the relative accuracy is in
00845 *        general not feasible. Later on, a condition number estimator
00846 *        will be deployed to estimate the scaled condition number.
00847 *        Here we just remove the underflowed part of the triangular
00848 *        factor. This prevents the situation in which the code is
00849 *        working hard to get the accuracy not warranted by the data.
00850          TEMP1  = DSQRT(SFMIN)
00851          DO 3301 p = 2, N
00852             IF ( ( DABS(A(p,p)) .LT. SMALL ) .OR.
00853      &          ( L2KILL .AND. (DABS(A(p,p)) .LT. TEMP1) ) ) GO TO 3302
00854             NR = NR + 1
00855  3301    CONTINUE
00856  3302    CONTINUE
00857 *
00858       END IF
00859 *
00860       ALMORT = .FALSE.
00861       IF ( NR .EQ. N ) THEN
00862          MAXPRJ = ONE
00863          DO 3051 p = 2, N
00864             TEMP1  = DABS(A(p,p)) / SVA(IWORK(p))
00865             MAXPRJ = DMIN1( MAXPRJ, TEMP1 )
00866  3051    CONTINUE
00867          IF ( MAXPRJ**2 .GE. ONE - DBLE(N)*EPSLN ) ALMORT = .TRUE.
00868       END IF
00869 *
00870 *
00871       SCONDA = - ONE
00872       CONDR1 = - ONE
00873       CONDR2 = - ONE
00874 *
00875       IF ( ERREST ) THEN
00876          IF ( N .EQ. NR ) THEN
00877             IF ( RSVEC ) THEN
00878 *              .. V is available as workspace
00879                CALL DLACPY( 'U', N, N, A, LDA, V, LDV )
00880                DO 3053 p = 1, N
00881                   TEMP1 = SVA(IWORK(p))
00882                   CALL DSCAL( p, ONE/TEMP1, V(1,p), 1 )
00883  3053          CONTINUE
00884                CALL DPOCON( 'U', N, V, LDV, ONE, TEMP1,
00885      &              WORK(N+1), IWORK(2*N+M+1), IERR )
00886             ELSE IF ( LSVEC ) THEN
00887 *              .. U is available as workspace
00888                CALL DLACPY( 'U', N, N, A, LDA, U, LDU )
00889                DO 3054 p = 1, N
00890                   TEMP1 = SVA(IWORK(p))
00891                   CALL DSCAL( p, ONE/TEMP1, U(1,p), 1 )
00892  3054          CONTINUE
00893                CALL DPOCON( 'U', N, U, LDU, ONE, TEMP1,
00894      &              WORK(N+1), IWORK(2*N+M+1), IERR )
00895             ELSE
00896                CALL DLACPY( 'U', N, N, A, LDA, WORK(N+1), N )
00897                DO 3052 p = 1, N
00898                   TEMP1 = SVA(IWORK(p))
00899                   CALL DSCAL( p, ONE/TEMP1, WORK(N+(p-1)*N+1), 1 )
00900  3052          CONTINUE
00901 *           .. the columns of R are scaled to have unit Euclidean lengths.
00902                CALL DPOCON( 'U', N, WORK(N+1), N, ONE, TEMP1,
00903      &              WORK(N+N*N+1), IWORK(2*N+M+1), IERR )
00904             END IF
00905             SCONDA = ONE / DSQRT(TEMP1)
00906 *           SCONDA is an estimate of DSQRT(||(R^t * R)^(-1)||_1).
00907 *           N^(-1/4) * SCONDA <= ||R^(-1)||_2 <= N^(1/4) * SCONDA
00908          ELSE
00909             SCONDA = - ONE
00910          END IF
00911       END IF
00912 *
00913       L2PERT = L2PERT .AND. ( DABS( A(1,1)/A(NR,NR) ) .GT. DSQRT(BIG1) )
00914 *     If there is no violent scaling, artificial perturbation is not needed.
00915 *
00916 *     Phase 3:
00917 *
00918 
00919       IF ( .NOT. ( RSVEC .OR. LSVEC ) ) THEN
00920 *
00921 *         Singular Values only
00922 *
00923 *         .. transpose A(1:NR,1:N)
00924          DO 1946 p = 1, MIN0( N-1, NR )
00925             CALL DCOPY( N-p, A(p,p+1), LDA, A(p+1,p), 1 )
00926  1946    CONTINUE
00927 *
00928 *        The following two DO-loops introduce small relative perturbation
00929 *        into the strict upper triangle of the lower triangular matrix.
00930 *        Small entries below the main diagonal are also changed.
00931 *        This modification is useful if the computing environment does not
00932 *        provide/allow FLUSH TO ZERO underflow, for it prevents many
00933 *        annoying denormalized numbers in case of strongly scaled matrices.
00934 *        The perturbation is structured so that it does not introduce any
00935 *        new perturbation of the singular values, and it does not destroy
00936 *        the job done by the preconditioner.
00937 *        The licence for this perturbation is in the variable L2PERT, which
00938 *        should be .FALSE. if FLUSH TO ZERO underflow is active.
00939 *
00940          IF ( .NOT. ALMORT ) THEN
00941 *
00942             IF ( L2PERT ) THEN
00943 *              XSC = DSQRT(SMALL)
00944                XSC = EPSLN / DBLE(N)
00945                DO 4947 q = 1, NR
00946                   TEMP1 = XSC*DABS(A(q,q))
00947                   DO 4949 p = 1, N
00948                      IF ( ( (p.GT.q) .AND. (DABS(A(p,q)).LE.TEMP1) )
00949      &                    .OR. ( p .LT. q ) )
00950      &                     A(p,q) = DSIGN( TEMP1, A(p,q) )
00951  4949             CONTINUE
00952  4947          CONTINUE
00953             ELSE
00954                CALL DLASET( 'U', NR-1,NR-1, ZERO,ZERO, A(1,2),LDA )
00955             END IF
00956 *
00957 *            .. second preconditioning using the QR factorization
00958 *
00959             CALL DGEQRF( N,NR, A,LDA, WORK, WORK(N+1),LWORK-N, IERR )
00960 *
00961 *           .. and transpose upper to lower triangular
00962             DO 1948 p = 1, NR - 1
00963                CALL DCOPY( NR-p, A(p,p+1), LDA, A(p+1,p), 1 )
00964  1948       CONTINUE
00965 *
00966          END IF
00967 *
00968 *           Row-cyclic Jacobi SVD algorithm with column pivoting
00969 *
00970 *           .. again some perturbation (a "background noise") is added
00971 *           to drown denormals
00972             IF ( L2PERT ) THEN
00973 *              XSC = DSQRT(SMALL)
00974                XSC = EPSLN / DBLE(N)
00975                DO 1947 q = 1, NR
00976                   TEMP1 = XSC*DABS(A(q,q))
00977                   DO 1949 p = 1, NR
00978                      IF ( ( (p.GT.q) .AND. (DABS(A(p,q)).LE.TEMP1) )
00979      &                       .OR. ( p .LT. q ) )
00980      &                   A(p,q) = DSIGN( TEMP1, A(p,q) )
00981  1949             CONTINUE
00982  1947          CONTINUE
00983             ELSE
00984                CALL DLASET( 'U', NR-1, NR-1, ZERO, ZERO, A(1,2), LDA )
00985             END IF
00986 *
00987 *           .. and one-sided Jacobi rotations are started on a lower
00988 *           triangular matrix (plus perturbation which is ignored in
00989 *           the part which destroys triangular form (confusing?!))
00990 *
00991             CALL DGESVJ( 'L', 'NoU', 'NoV', NR, NR, A, LDA, SVA,
00992      &                      N, V, LDV, WORK, LWORK, INFO )
00993 *
00994             SCALEM  = WORK(1)
00995             NUMRANK = IDNINT(WORK(2))
00996 *
00997 *
00998       ELSE IF ( RSVEC .AND. ( .NOT. LSVEC ) ) THEN
00999 *
01000 *        -> Singular Values and Right Singular Vectors <-
01001 *
01002          IF ( ALMORT ) THEN
01003 *
01004 *           .. in this case NR equals N
01005             DO 1998 p = 1, NR
01006                CALL DCOPY( N-p+1, A(p,p), LDA, V(p,p), 1 )
01007  1998       CONTINUE
01008             CALL DLASET( 'Upper', NR-1, NR-1, ZERO, ZERO, V(1,2), LDV )
01009 *
01010             CALL DGESVJ( 'L','U','N', N, NR, V,LDV, SVA, NR, A,LDA,
01011      &                  WORK, LWORK, INFO )
01012             SCALEM  = WORK(1)
01013             NUMRANK = IDNINT(WORK(2))
01014 
01015          ELSE
01016 *
01017 *        .. two more QR factorizations ( one QRF is not enough, two require
01018 *        accumulated product of Jacobi rotations, three are perfect )
01019 *
01020             CALL DLASET( 'Lower', NR-1, NR-1, ZERO, ZERO, A(2,1), LDA )
01021             CALL DGELQF( NR, N, A, LDA, WORK, WORK(N+1), LWORK-N, IERR)
01022             CALL DLACPY( 'Lower', NR, NR, A, LDA, V, LDV )
01023             CALL DLASET( 'Upper', NR-1, NR-1, ZERO, ZERO, V(1,2), LDV )
01024             CALL DGEQRF( NR, NR, V, LDV, WORK(N+1), WORK(2*N+1),
01025      &                   LWORK-2*N, IERR )
01026             DO 8998 p = 1, NR
01027                CALL DCOPY( NR-p+1, V(p,p), LDV, V(p,p), 1 )
01028  8998       CONTINUE
01029             CALL DLASET( 'Upper', NR-1, NR-1, ZERO, ZERO, V(1,2), LDV )
01030 *
01031             CALL DGESVJ( 'Lower', 'U','N', NR, NR, V,LDV, SVA, NR, U,
01032      &                  LDU, WORK(N+1), LWORK, INFO )
01033             SCALEM  = WORK(N+1)
01034             NUMRANK = IDNINT(WORK(N+2))
01035             IF ( NR .LT. N ) THEN
01036                CALL DLASET( 'A',N-NR, NR, ZERO,ZERO, V(NR+1,1),   LDV )
01037                CALL DLASET( 'A',NR, N-NR, ZERO,ZERO, V(1,NR+1),   LDV )
01038                CALL DLASET( 'A',N-NR,N-NR,ZERO,ONE, V(NR+1,NR+1), LDV )
01039             END IF
01040 *
01041          CALL DORMLQ( 'Left', 'Transpose', N, N, NR, A, LDA, WORK,
01042      &               V, LDV, WORK(N+1), LWORK-N, IERR )
01043 *
01044          END IF
01045 *
01046          DO 8991 p = 1, N
01047             CALL DCOPY( N, V(p,1), LDV, A(IWORK(p),1), LDA )
01048  8991    CONTINUE
01049          CALL DLACPY( 'All', N, N, A, LDA, V, LDV )
01050 *
01051          IF ( TRANSP ) THEN
01052             CALL DLACPY( 'All', N, N, V, LDV, U, LDU )
01053          END IF
01054 *
01055       ELSE IF ( LSVEC .AND. ( .NOT. RSVEC ) ) THEN
01056 *
01057 *        .. Singular Values and Left Singular Vectors                 ..
01058 *
01059 *        .. second preconditioning step to avoid need to accumulate
01060 *        Jacobi rotations in the Jacobi iterations.
01061          DO 1965 p = 1, NR
01062             CALL DCOPY( N-p+1, A(p,p), LDA, U(p,p), 1 )
01063  1965    CONTINUE
01064          CALL DLASET( 'Upper', NR-1, NR-1, ZERO, ZERO, U(1,2), LDU )
01065 *
01066          CALL DGEQRF( N, NR, U, LDU, WORK(N+1), WORK(2*N+1),
01067      &              LWORK-2*N, IERR )
01068 *
01069          DO 1967 p = 1, NR - 1
01070             CALL DCOPY( NR-p, U(p,p+1), LDU, U(p+1,p), 1 )
01071  1967    CONTINUE
01072          CALL DLASET( 'Upper', NR-1, NR-1, ZERO, ZERO, U(1,2), LDU )
01073 *
01074          CALL DGESVJ( 'Lower', 'U', 'N', NR,NR, U, LDU, SVA, NR, A,
01075      &        LDA, WORK(N+1), LWORK-N, INFO )
01076          SCALEM  = WORK(N+1)
01077          NUMRANK = IDNINT(WORK(N+2))
01078 *
01079          IF ( NR .LT. M ) THEN
01080             CALL DLASET( 'A',  M-NR, NR,ZERO, ZERO, U(NR+1,1), LDU )
01081             IF ( NR .LT. N1 ) THEN
01082                CALL DLASET( 'A',NR, N1-NR, ZERO, ZERO, U(1,NR+1), LDU )
01083                CALL DLASET( 'A',M-NR,N1-NR,ZERO,ONE,U(NR+1,NR+1), LDU )
01084             END IF
01085          END IF
01086 *
01087          CALL DORMQR( 'Left', 'No Tr', M, N1, N, A, LDA, WORK, U,
01088      &               LDU, WORK(N+1), LWORK-N, IERR )
01089 *
01090          IF ( ROWPIV )
01091      &       CALL DLASWP( N1, U, LDU, 1, M-1, IWORK(2*N+1), -1 )
01092 *
01093          DO 1974 p = 1, N1
01094             XSC = ONE / DNRM2( M, U(1,p), 1 )
01095             CALL DSCAL( M, XSC, U(1,p), 1 )
01096  1974    CONTINUE
01097 *
01098          IF ( TRANSP ) THEN
01099             CALL DLACPY( 'All', N, N, U, LDU, V, LDV )
01100          END IF
01101 *
01102       ELSE
01103 *
01104 *        .. Full SVD ..
01105 *
01106          IF ( .NOT. JRACC ) THEN
01107 *
01108          IF ( .NOT. ALMORT ) THEN
01109 *
01110 *           Second Preconditioning Step (QRF [with pivoting])
01111 *           Note that the composition of TRANSPOSE, QRF and TRANSPOSE is
01112 *           equivalent to an LQF CALL. Since in many libraries the QRF
01113 *           seems to be better optimized than the LQF, we do explicit
01114 *           transpose and use the QRF. This is subject to changes in an
01115 *           optimized implementation of DGEJSV.
01116 *
01117             DO 1968 p = 1, NR
01118                CALL DCOPY( N-p+1, A(p,p), LDA, V(p,p), 1 )
01119  1968       CONTINUE
01120 *
01121 *           .. the following two loops perturb small entries to avoid
01122 *           denormals in the second QR factorization, where they are
01123 *           as good as zeros. This is done to avoid painfully slow
01124 *           computation with denormals. The relative size of the perturbation
01125 *           is a parameter that can be changed by the implementer.
01126 *           This perturbation device will be obsolete on machines with
01127 *           properly implemented arithmetic.
01128 *           To switch it off, set L2PERT=.FALSE. To remove it from  the
01129 *           code, remove the action under L2PERT=.TRUE., leave the ELSE part.
01130 *           The following two loops should be blocked and fused with the
01131 *           transposed copy above.
01132 *
01133             IF ( L2PERT ) THEN
01134                XSC = DSQRT(SMALL)
01135                DO 2969 q = 1, NR
01136                   TEMP1 = XSC*DABS( V(q,q) )
01137                   DO 2968 p = 1, N
01138                      IF ( ( p .GT. q ) .AND. ( DABS(V(p,q)) .LE. TEMP1 )
01139      &                   .OR. ( p .LT. q ) )
01140      &                   V(p,q) = DSIGN( TEMP1, V(p,q) )
01141                      IF ( p. LT. q ) V(p,q) = - V(p,q)
01142  2968             CONTINUE
01143  2969          CONTINUE
01144             ELSE
01145                CALL DLASET( 'U', NR-1, NR-1, ZERO, ZERO, V(1,2), LDV )
01146             END IF
01147 *
01148 *           Estimate the row scaled condition number of R1
01149 *           (If R1 is rectangular, N > NR, then the condition number
01150 *           of the leading NR x NR submatrix is estimated.)
01151 *
01152             CALL DLACPY( 'L', NR, NR, V, LDV, WORK(2*N+1), NR )
01153             DO 3950 p = 1, NR
01154                TEMP1 = DNRM2(NR-p+1,WORK(2*N+(p-1)*NR+p),1)
01155                CALL DSCAL(NR-p+1,ONE/TEMP1,WORK(2*N+(p-1)*NR+p),1)
01156  3950       CONTINUE
01157             CALL DPOCON('Lower',NR,WORK(2*N+1),NR,ONE,TEMP1,
01158      &                   WORK(2*N+NR*NR+1),IWORK(M+2*N+1),IERR)
01159             CONDR1 = ONE / DSQRT(TEMP1)
01160 *           .. here need a second oppinion on the condition number
01161 *           .. then assume worst case scenario
01162 *           R1 is OK for inverse <=> CONDR1 .LT. DBLE(N)
01163 *           more conservative    <=> CONDR1 .LT. DSQRT(DBLE(N))
01164 *
01165             COND_OK = DSQRT(DBLE(NR))
01166 *[TP]       COND_OK is a tuning parameter.
01167 
01168             IF ( CONDR1 .LT. COND_OK ) THEN
01169 *              .. the second QRF without pivoting. Note: in an optimized
01170 *              implementation, this QRF should be implemented as the QRF
01171 *              of a lower triangular matrix.
01172 *              R1^t = Q2 * R2
01173                CALL DGEQRF( N, NR, V, LDV, WORK(N+1), WORK(2*N+1),
01174      &              LWORK-2*N, IERR )
01175 *
01176                IF ( L2PERT ) THEN
01177                   XSC = DSQRT(SMALL)/EPSLN
01178                   DO 3959 p = 2, NR
01179                      DO 3958 q = 1, p - 1
01180                         TEMP1 = XSC * DMIN1(DABS(V(p,p)),DABS(V(q,q)))
01181                         IF ( DABS(V(q,p)) .LE. TEMP1 )
01182      &                     V(q,p) = DSIGN( TEMP1, V(q,p) )
01183  3958                CONTINUE
01184  3959             CONTINUE
01185                END IF
01186 *
01187                IF ( NR .NE. N )
01188 *              .. save ...
01189      &         CALL DLACPY( 'A', N, NR, V, LDV, WORK(2*N+1), N )
01190 *
01191 *           .. this transposed copy should be better than naive
01192                DO 1969 p = 1, NR - 1
01193                   CALL DCOPY( NR-p, V(p,p+1), LDV, V(p+1,p), 1 )
01194  1969          CONTINUE
01195 *
01196                CONDR2 = CONDR1
01197 *
01198             ELSE
01199 *
01200 *              .. ill-conditioned case: second QRF with pivoting
01201 *              Note that windowed pivoting would be equaly good
01202 *              numerically, and more run-time efficient. So, in
01203 *              an optimal implementation, the next call to DGEQP3
01204 *              should be replaced with eg. CALL SGEQPX (ACM TOMS #782)
01205 *              with properly (carefully) chosen parameters.
01206 *
01207 *              R1^t * P2 = Q2 * R2
01208                DO 3003 p = 1, NR
01209                   IWORK(N+p) = 0
01210  3003          CONTINUE
01211                CALL DGEQP3( N, NR, V, LDV, IWORK(N+1), WORK(N+1),
01212      &                  WORK(2*N+1), LWORK-2*N, IERR )
01213 **               CALL DGEQRF( N, NR, V, LDV, WORK(N+1), WORK(2*N+1),
01214 **     &              LWORK-2*N, IERR )
01215                IF ( L2PERT ) THEN
01216                   XSC = DSQRT(SMALL)
01217                   DO 3969 p = 2, NR
01218                      DO 3968 q = 1, p - 1
01219                         TEMP1 = XSC * DMIN1(DABS(V(p,p)),DABS(V(q,q)))
01220                         IF ( DABS(V(q,p)) .LE. TEMP1 )
01221      &                     V(q,p) = DSIGN( TEMP1, V(q,p) )
01222  3968                CONTINUE
01223  3969             CONTINUE
01224                END IF
01225 *
01226                CALL DLACPY( 'A', N, NR, V, LDV, WORK(2*N+1), N )
01227 *
01228                IF ( L2PERT ) THEN
01229                   XSC = DSQRT(SMALL)
01230                   DO 8970 p = 2, NR
01231                      DO 8971 q = 1, p - 1
01232                         TEMP1 = XSC * DMIN1(DABS(V(p,p)),DABS(V(q,q)))
01233                         V(p,q) = - DSIGN( TEMP1, V(q,p) )
01234  8971                CONTINUE
01235  8970             CONTINUE
01236                ELSE
01237                   CALL DLASET( 'L',NR-1,NR-1,ZERO,ZERO,V(2,1),LDV )
01238                END IF
01239 *              Now, compute R2 = L3 * Q3, the LQ factorization.
01240                CALL DGELQF( NR, NR, V, LDV, WORK(2*N+N*NR+1),
01241      &               WORK(2*N+N*NR+NR+1), LWORK-2*N-N*NR-NR, IERR )
01242 *              .. and estimate the condition number
01243                CALL DLACPY( 'L',NR,NR,V,LDV,WORK(2*N+N*NR+NR+1),NR )
01244                DO 4950 p = 1, NR
01245                   TEMP1 = DNRM2( p, WORK(2*N+N*NR+NR+p), NR )
01246                   CALL DSCAL( p, ONE/TEMP1, WORK(2*N+N*NR+NR+p), NR )
01247  4950          CONTINUE
01248                CALL DPOCON( 'L',NR,WORK(2*N+N*NR+NR+1),NR,ONE,TEMP1,
01249      &              WORK(2*N+N*NR+NR+NR*NR+1),IWORK(M+2*N+1),IERR )
01250                CONDR2 = ONE / DSQRT(TEMP1)
01251 *
01252                IF ( CONDR2 .GE. COND_OK ) THEN
01253 *                 .. save the Householder vectors used for Q3
01254 *                 (this overwrittes the copy of R2, as it will not be
01255 *                 needed in this branch, but it does not overwritte the
01256 *                 Huseholder vectors of Q2.).
01257                   CALL DLACPY( 'U', NR, NR, V, LDV, WORK(2*N+1), N )
01258 *                 .. and the rest of the information on Q3 is in
01259 *                 WORK(2*N+N*NR+1:2*N+N*NR+N)
01260                END IF
01261 *
01262             END IF
01263 *
01264             IF ( L2PERT ) THEN
01265                XSC = DSQRT(SMALL)
01266                DO 4968 q = 2, NR
01267                   TEMP1 = XSC * V(q,q)
01268                   DO 4969 p = 1, q - 1
01269 *                    V(p,q) = - DSIGN( TEMP1, V(q,p) )
01270                      V(p,q) = - DSIGN( TEMP1, V(p,q) )
01271  4969             CONTINUE
01272  4968          CONTINUE
01273             ELSE
01274                CALL DLASET( 'U', NR-1,NR-1, ZERO,ZERO, V(1,2), LDV )
01275             END IF
01276 *
01277 *        Second preconditioning finished; continue with Jacobi SVD
01278 *        The input matrix is lower trinagular.
01279 *
01280 *        Recover the right singular vectors as solution of a well
01281 *        conditioned triangular matrix equation.
01282 *
01283             IF ( CONDR1 .LT. COND_OK ) THEN
01284 *
01285                CALL DGESVJ( 'L','U','N',NR,NR,V,LDV,SVA,NR,U,
01286      &              LDU,WORK(2*N+N*NR+NR+1),LWORK-2*N-N*NR-NR,INFO )
01287                SCALEM  = WORK(2*N+N*NR+NR+1)
01288                NUMRANK = IDNINT(WORK(2*N+N*NR+NR+2))
01289                DO 3970 p = 1, NR
01290                   CALL DCOPY( NR, V(1,p), 1, U(1,p), 1 )
01291                   CALL DSCAL( NR, SVA(p),    V(1,p), 1 )
01292  3970          CONTINUE
01293 
01294 *        .. pick the right matrix equation and solve it
01295 *
01296                IF ( NR. EQ. N ) THEN
01297 * :))             .. best case, R1 is inverted. The solution of this matrix
01298 *                 equation is Q2*V2 = the product of the Jacobi rotations
01299 *                 used in DGESVJ, premultiplied with the orthogonal matrix
01300 *                 from the second QR factorization.
01301                   CALL DTRSM( 'L','U','N','N', NR,NR,ONE, A,LDA, V,LDV )
01302                ELSE
01303 *                 .. R1 is well conditioned, but non-square. Transpose(R2)
01304 *                 is inverted to get the product of the Jacobi rotations
01305 *                 used in DGESVJ. The Q-factor from the second QR
01306 *                 factorization is then built in explicitly.
01307                   CALL DTRSM('L','U','T','N',NR,NR,ONE,WORK(2*N+1),
01308      &                 N,V,LDV)
01309                   IF ( NR .LT. N ) THEN
01310                     CALL DLASET('A',N-NR,NR,ZERO,ZERO,V(NR+1,1),LDV)
01311                     CALL DLASET('A',NR,N-NR,ZERO,ZERO,V(1,NR+1),LDV)
01312                     CALL DLASET('A',N-NR,N-NR,ZERO,ONE,V(NR+1,NR+1),LDV)
01313                   END IF
01314                   CALL DORMQR('L','N',N,N,NR,WORK(2*N+1),N,WORK(N+1),
01315      &                 V,LDV,WORK(2*N+N*NR+NR+1),LWORK-2*N-N*NR-NR,IERR)
01316                END IF
01317 *
01318             ELSE IF ( CONDR2 .LT. COND_OK ) THEN
01319 *
01320 * :)           .. the input matrix A is very likely a relative of
01321 *              the Kahan matrix :)
01322 *              The matrix R2 is inverted. The solution of the matrix equation
01323 *              is Q3^T*V3 = the product of the Jacobi rotations (appplied to
01324 *              the lower triangular L3 from the LQ factorization of
01325 *              R2=L3*Q3), pre-multiplied with the transposed Q3.
01326                CALL DGESVJ( 'L', 'U', 'N', NR, NR, V, LDV, SVA, NR, U,
01327      &              LDU, WORK(2*N+N*NR+NR+1), LWORK-2*N-N*NR-NR, INFO )
01328                SCALEM  = WORK(2*N+N*NR+NR+1)
01329                NUMRANK = IDNINT(WORK(2*N+N*NR+NR+2))
01330                DO 3870 p = 1, NR
01331                   CALL DCOPY( NR, V(1,p), 1, U(1,p), 1 )
01332                   CALL DSCAL( NR, SVA(p),    U(1,p), 1 )
01333  3870          CONTINUE
01334                CALL DTRSM('L','U','N','N',NR,NR,ONE,WORK(2*N+1),N,U,LDU)
01335 *              .. apply the permutation from the second QR factorization
01336                DO 873 q = 1, NR
01337                   DO 872 p = 1, NR
01338                      WORK(2*N+N*NR+NR+IWORK(N+p)) = U(p,q)
01339  872              CONTINUE
01340                   DO 874 p = 1, NR
01341                      U(p,q) = WORK(2*N+N*NR+NR+p)
01342  874              CONTINUE
01343  873           CONTINUE
01344                IF ( NR .LT. N ) THEN
01345                   CALL DLASET( 'A',N-NR,NR,ZERO,ZERO,V(NR+1,1),LDV )
01346                   CALL DLASET( 'A',NR,N-NR,ZERO,ZERO,V(1,NR+1),LDV )
01347                   CALL DLASET( 'A',N-NR,N-NR,ZERO,ONE,V(NR+1,NR+1),LDV )
01348                END IF
01349                CALL DORMQR( 'L','N',N,N,NR,WORK(2*N+1),N,WORK(N+1),
01350      &              V,LDV,WORK(2*N+N*NR+NR+1),LWORK-2*N-N*NR-NR,IERR )
01351             ELSE
01352 *              Last line of defense.
01353 * #:(          This is a rather pathological case: no scaled condition
01354 *              improvement after two pivoted QR factorizations. Other
01355 *              possibility is that the rank revealing QR factorization
01356 *              or the condition estimator has failed, or the COND_OK
01357 *              is set very close to ONE (which is unnecessary). Normally,
01358 *              this branch should never be executed, but in rare cases of
01359 *              failure of the RRQR or condition estimator, the last line of
01360 *              defense ensures that DGEJSV completes the task.
01361 *              Compute the full SVD of L3 using DGESVJ with explicit
01362 *              accumulation of Jacobi rotations.
01363                CALL DGESVJ( 'L', 'U', 'V', NR, NR, V, LDV, SVA, NR, U,
01364      &              LDU, WORK(2*N+N*NR+NR+1), LWORK-2*N-N*NR-NR, INFO )
01365                SCALEM  = WORK(2*N+N*NR+NR+1)
01366                NUMRANK = IDNINT(WORK(2*N+N*NR+NR+2))
01367                IF ( NR .LT. N ) THEN
01368                   CALL DLASET( 'A',N-NR,NR,ZERO,ZERO,V(NR+1,1),LDV )
01369                   CALL DLASET( 'A',NR,N-NR,ZERO,ZERO,V(1,NR+1),LDV )
01370                   CALL DLASET( 'A',N-NR,N-NR,ZERO,ONE,V(NR+1,NR+1),LDV )
01371                END IF
01372                CALL DORMQR( 'L','N',N,N,NR,WORK(2*N+1),N,WORK(N+1),
01373      &              V,LDV,WORK(2*N+N*NR+NR+1),LWORK-2*N-N*NR-NR,IERR )
01374 *
01375                CALL DORMLQ( 'L', 'T', NR, NR, NR, WORK(2*N+1), N,
01376      &              WORK(2*N+N*NR+1), U, LDU, WORK(2*N+N*NR+NR+1),
01377      &              LWORK-2*N-N*NR-NR, IERR )
01378                DO 773 q = 1, NR
01379                   DO 772 p = 1, NR
01380                      WORK(2*N+N*NR+NR+IWORK(N+p)) = U(p,q)
01381  772              CONTINUE
01382                   DO 774 p = 1, NR
01383                      U(p,q) = WORK(2*N+N*NR+NR+p)
01384  774              CONTINUE
01385  773           CONTINUE
01386 *
01387             END IF
01388 *
01389 *           Permute the rows of V using the (column) permutation from the
01390 *           first QRF. Also, scale the columns to make them unit in
01391 *           Euclidean norm. This applies to all cases.
01392 *
01393             TEMP1 = DSQRT(DBLE(N)) * EPSLN
01394             DO 1972 q = 1, N
01395                DO 972 p = 1, N
01396                   WORK(2*N+N*NR+NR+IWORK(p)) = V(p,q)
01397   972          CONTINUE
01398                DO 973 p = 1, N
01399                   V(p,q) = WORK(2*N+N*NR+NR+p)
01400   973          CONTINUE
01401                XSC = ONE / DNRM2( N, V(1,q), 1 )
01402                IF ( (XSC .LT. (ONE-TEMP1)) .OR. (XSC .GT. (ONE+TEMP1)) )
01403      &           CALL DSCAL( N, XSC, V(1,q), 1 )
01404  1972       CONTINUE
01405 *           At this moment, V contains the right singular vectors of A.
01406 *           Next, assemble the left singular vector matrix U (M x N).
01407             IF ( NR .LT. M ) THEN
01408                CALL DLASET( 'A', M-NR, NR, ZERO, ZERO, U(NR+1,1), LDU )
01409                IF ( NR .LT. N1 ) THEN
01410                   CALL DLASET('A',NR,N1-NR,ZERO,ZERO,U(1,NR+1),LDU)
01411                   CALL DLASET('A',M-NR,N1-NR,ZERO,ONE,U(NR+1,NR+1),LDU)
01412                END IF
01413             END IF
01414 *
01415 *           The Q matrix from the first QRF is built into the left singular
01416 *           matrix U. This applies to all cases.
01417 *
01418             CALL DORMQR( 'Left', 'No_Tr', M, N1, N, A, LDA, WORK, U,
01419      &           LDU, WORK(N+1), LWORK-N, IERR )
01420 
01421 *           The columns of U are normalized. The cost is O(M*N) flops.
01422             TEMP1 = DSQRT(DBLE(M)) * EPSLN
01423             DO 1973 p = 1, NR
01424                XSC = ONE / DNRM2( M, U(1,p), 1 )
01425                IF ( (XSC .LT. (ONE-TEMP1)) .OR. (XSC .GT. (ONE+TEMP1)) )
01426      &          CALL DSCAL( M, XSC, U(1,p), 1 )
01427  1973       CONTINUE
01428 *
01429 *           If the initial QRF is computed with row pivoting, the left
01430 *           singular vectors must be adjusted.
01431 *
01432             IF ( ROWPIV )
01433      &          CALL DLASWP( N1, U, LDU, 1, M-1, IWORK(2*N+1), -1 )
01434 *
01435          ELSE
01436 *
01437 *        .. the initial matrix A has almost orthogonal columns and
01438 *        the second QRF is not needed
01439 *
01440             CALL DLACPY( 'Upper', N, N, A, LDA, WORK(N+1), N )
01441             IF ( L2PERT ) THEN
01442                XSC = DSQRT(SMALL)
01443                DO 5970 p = 2, N
01444                   TEMP1 = XSC * WORK( N + (p-1)*N + p )
01445                   DO 5971 q = 1, p - 1
01446                      WORK(N+(q-1)*N+p)=-DSIGN(TEMP1,WORK(N+(p-1)*N+q))
01447  5971             CONTINUE
01448  5970          CONTINUE
01449             ELSE
01450                CALL DLASET( 'Lower',N-1,N-1,ZERO,ZERO,WORK(N+2),N )
01451             END IF
01452 *
01453             CALL DGESVJ( 'Upper', 'U', 'N', N, N, WORK(N+1), N, SVA,
01454      &           N, U, LDU, WORK(N+N*N+1), LWORK-N-N*N, INFO )
01455 *
01456             SCALEM  = WORK(N+N*N+1)
01457             NUMRANK = IDNINT(WORK(N+N*N+2))
01458             DO 6970 p = 1, N
01459                CALL DCOPY( N, WORK(N+(p-1)*N+1), 1, U(1,p), 1 )
01460                CALL DSCAL( N, SVA(p), WORK(N+(p-1)*N+1), 1 )
01461  6970       CONTINUE
01462 *
01463             CALL DTRSM( 'Left', 'Upper', 'NoTrans', 'No UD', N, N,
01464      &           ONE, A, LDA, WORK(N+1), N )
01465             DO 6972 p = 1, N
01466                CALL DCOPY( N, WORK(N+p), N, V(IWORK(p),1), LDV )
01467  6972       CONTINUE
01468             TEMP1 = DSQRT(DBLE(N))*EPSLN
01469             DO 6971 p = 1, N
01470                XSC = ONE / DNRM2( N, V(1,p), 1 )
01471                IF ( (XSC .LT. (ONE-TEMP1)) .OR. (XSC .GT. (ONE+TEMP1)) )
01472      &            CALL DSCAL( N, XSC, V(1,p), 1 )
01473  6971       CONTINUE
01474 *
01475 *           Assemble the left singular vector matrix U (M x N).
01476 *
01477             IF ( N .LT. M ) THEN
01478                CALL DLASET( 'A',  M-N, N, ZERO, ZERO, U(NR+1,1), LDU )
01479                IF ( N .LT. N1 ) THEN
01480                   CALL DLASET( 'A',N,  N1-N, ZERO, ZERO,  U(1,N+1),LDU )
01481                   CALL DLASET( 'A',M-N,N1-N, ZERO, ONE,U(NR+1,N+1),LDU )
01482                END IF
01483             END IF
01484             CALL DORMQR( 'Left', 'No Tr', M, N1, N, A, LDA, WORK, U,
01485      &           LDU, WORK(N+1), LWORK-N, IERR )
01486             TEMP1 = DSQRT(DBLE(M))*EPSLN
01487             DO 6973 p = 1, N1
01488                XSC = ONE / DNRM2( M, U(1,p), 1 )
01489                IF ( (XSC .LT. (ONE-TEMP1)) .OR. (XSC .GT. (ONE+TEMP1)) )
01490      &            CALL DSCAL( M, XSC, U(1,p), 1 )
01491  6973       CONTINUE
01492 *
01493             IF ( ROWPIV )
01494      &         CALL DLASWP( N1, U, LDU, 1, M-1, IWORK(2*N+1), -1 )
01495 *
01496          END IF
01497 *
01498 *        end of the  >> almost orthogonal case <<  in the full SVD
01499 *
01500          ELSE
01501 *
01502 *        This branch deploys a preconditioned Jacobi SVD with explicitly
01503 *        accumulated rotations. It is included as optional, mainly for
01504 *        experimental purposes. It does perfom well, and can also be used.
01505 *        In this implementation, this branch will be automatically activated
01506 *        if the  condition number sigma_max(A) / sigma_min(A) is predicted
01507 *        to be greater than the overflow threshold. This is because the
01508 *        a posteriori computation of the singular vectors assumes robust
01509 *        implementation of BLAS and some LAPACK procedures, capable of working
01510 *        in presence of extreme values. Since that is not always the case, ...
01511 *
01512          DO 7968 p = 1, NR
01513             CALL DCOPY( N-p+1, A(p,p), LDA, V(p,p), 1 )
01514  7968    CONTINUE
01515 *
01516          IF ( L2PERT ) THEN
01517             XSC = DSQRT(SMALL/EPSLN)
01518             DO 5969 q = 1, NR
01519                TEMP1 = XSC*DABS( V(q,q) )
01520                DO 5968 p = 1, N
01521                   IF ( ( p .GT. q ) .AND. ( DABS(V(p,q)) .LE. TEMP1 )
01522      &                .OR. ( p .LT. q ) )
01523      &                V(p,q) = DSIGN( TEMP1, V(p,q) )
01524                   IF ( p. LT. q ) V(p,q) = - V(p,q)
01525  5968          CONTINUE
01526  5969       CONTINUE
01527          ELSE
01528             CALL DLASET( 'U', NR-1, NR-1, ZERO, ZERO, V(1,2), LDV )
01529          END IF
01530 
01531          CALL DGEQRF( N, NR, V, LDV, WORK(N+1), WORK(2*N+1),
01532      &        LWORK-2*N, IERR )
01533          CALL DLACPY( 'L', N, NR, V, LDV, WORK(2*N+1), N )
01534 *
01535          DO 7969 p = 1, NR
01536             CALL DCOPY( NR-p+1, V(p,p), LDV, U(p,p), 1 )
01537  7969    CONTINUE
01538 
01539          IF ( L2PERT ) THEN
01540             XSC = DSQRT(SMALL/EPSLN)
01541             DO 9970 q = 2, NR
01542                DO 9971 p = 1, q - 1
01543                   TEMP1 = XSC * DMIN1(DABS(U(p,p)),DABS(U(q,q)))
01544                   U(p,q) = - DSIGN( TEMP1, U(q,p) )
01545  9971          CONTINUE
01546  9970       CONTINUE
01547          ELSE
01548             CALL DLASET('U', NR-1, NR-1, ZERO, ZERO, U(1,2), LDU )
01549          END IF
01550 
01551          CALL DGESVJ( 'G', 'U', 'V', NR, NR, U, LDU, SVA,
01552      &        N, V, LDV, WORK(2*N+N*NR+1), LWORK-2*N-N*NR, INFO )
01553          SCALEM  = WORK(2*N+N*NR+1)
01554          NUMRANK = IDNINT(WORK(2*N+N*NR+2))
01555 
01556          IF ( NR .LT. N ) THEN
01557             CALL DLASET( 'A',N-NR,NR,ZERO,ZERO,V(NR+1,1),LDV )
01558             CALL DLASET( 'A',NR,N-NR,ZERO,ZERO,V(1,NR+1),LDV )
01559             CALL DLASET( 'A',N-NR,N-NR,ZERO,ONE,V(NR+1,NR+1),LDV )
01560          END IF
01561 
01562          CALL DORMQR( 'L','N',N,N,NR,WORK(2*N+1),N,WORK(N+1),
01563      &        V,LDV,WORK(2*N+N*NR+NR+1),LWORK-2*N-N*NR-NR,IERR )
01564 *
01565 *           Permute the rows of V using the (column) permutation from the
01566 *           first QRF. Also, scale the columns to make them unit in
01567 *           Euclidean norm. This applies to all cases.
01568 *
01569             TEMP1 = DSQRT(DBLE(N)) * EPSLN
01570             DO 7972 q = 1, N
01571                DO 8972 p = 1, N
01572                   WORK(2*N+N*NR+NR+IWORK(p)) = V(p,q)
01573  8972          CONTINUE
01574                DO 8973 p = 1, N
01575                   V(p,q) = WORK(2*N+N*NR+NR+p)
01576  8973          CONTINUE
01577                XSC = ONE / DNRM2( N, V(1,q), 1 )
01578                IF ( (XSC .LT. (ONE-TEMP1)) .OR. (XSC .GT. (ONE+TEMP1)) )
01579      &           CALL DSCAL( N, XSC, V(1,q), 1 )
01580  7972       CONTINUE
01581 *
01582 *           At this moment, V contains the right singular vectors of A.
01583 *           Next, assemble the left singular vector matrix U (M x N).
01584 *
01585          IF ( N .LT. M ) THEN
01586             CALL DLASET( 'A',  M-N, N, ZERO, ZERO, U(NR+1,1), LDU )
01587             IF ( N .LT. N1 ) THEN
01588                CALL DLASET( 'A',N,  N1-N, ZERO, ZERO,  U(1,N+1),LDU )
01589                CALL DLASET( 'A',M-N,N1-N, ZERO, ONE,U(NR+1,N+1),LDU )
01590             END IF
01591          END IF
01592 *
01593          CALL DORMQR( 'Left', 'No Tr', M, N1, N, A, LDA, WORK, U,
01594      &        LDU, WORK(N+1), LWORK-N, IERR )
01595 *
01596             IF ( ROWPIV )
01597      &         CALL DLASWP( N1, U, LDU, 1, M-1, IWORK(2*N+1), -1 )
01598 *
01599 *
01600          END IF
01601          IF ( TRANSP ) THEN
01602 *           .. swap U and V because the procedure worked on A^t
01603             DO 6974 p = 1, N
01604                CALL DSWAP( N, U(1,p), 1, V(1,p), 1 )
01605  6974       CONTINUE
01606          END IF
01607 *
01608       END IF
01609 *     end of the full SVD
01610 *
01611 *     Undo scaling, if necessary (and possible)
01612 *
01613       IF ( USCAL2 .LE. (BIG/SVA(1))*USCAL1 ) THEN
01614          CALL DLASCL( 'G', 0, 0, USCAL1, USCAL2, NR, 1, SVA, N, IERR )
01615          USCAL1 = ONE
01616          USCAL2 = ONE
01617       END IF
01618 *
01619       IF ( NR .LT. N ) THEN
01620          DO 3004 p = NR+1, N
01621             SVA(p) = ZERO
01622  3004    CONTINUE
01623       END IF
01624 *
01625       WORK(1) = USCAL2 * SCALEM
01626       WORK(2) = USCAL1
01627       IF ( ERREST ) WORK(3) = SCONDA
01628       IF ( LSVEC .AND. RSVEC ) THEN
01629          WORK(4) = CONDR1
01630          WORK(5) = CONDR2
01631       END IF
01632       IF ( L2TRAN ) THEN
01633          WORK(6) = ENTRA
01634          WORK(7) = ENTRAT
01635       END IF
01636 *
01637       IWORK(1) = NR
01638       IWORK(2) = NUMRANK
01639       IWORK(3) = WARNING
01640 *
01641       RETURN
01642 *     ..
01643 *     .. END OF DGEJSV
01644 *     ..
01645       END
01646 *