cgels.f

Go to the documentation of this file.

*> \brief <b> CGELS solves overdetermined or underdetermined systems for GE matrices</b>
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download CGELS + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/cgels.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/cgels.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/cgels.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE CGELS( TRANS, M, N, NRHS, A, LDA, B, LDB, WORK, LWORK,
*                         INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          TRANS
*       INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS
*       ..
*       .. Array Arguments ..
*       COMPLEX            A( LDA, * ), B( LDB, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CGELS solves overdetermined or underdetermined complex linear systems
*> involving an M-by-N matrix A, or its conjugate-transpose, using a QR
*> or LQ factorization of A.  It is assumed that A has full rank.
*>
*> The following options are provided:
*>
*> 1. If TRANS = 'N' and m >= n:  find the least squares solution of
*>    an overdetermined system, i.e., solve the least squares problem
*>                 minimize || B - A*X ||.
*>
*> 2. If TRANS = 'N' and m < n:  find the minimum norm solution of
*>    an underdetermined system A * X = B.
*>
*> 3. If TRANS = 'C' and m >= n:  find the minimum norm solution of
*>    an underdetermined system A**H * X = B.
*>
*> 4. If TRANS = 'C' and m < n:  find the least squares solution of
*>    an overdetermined system, i.e., solve the least squares problem
*>                 minimize || B - A**H * X ||.
*>
*> Several right hand side vectors b and solution vectors x can be
*> handled in a single call; they are stored as the columns of the
*> M-by-NRHS right hand side matrix B and the N-by-NRHS solution
*> matrix X.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>          = 'N': the linear system involves A;
*>          = 'C': the linear system involves A**H.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of
*>          columns of the matrices B and X. NRHS >= 0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX array, dimension (LDA,N)
*>          On entry, the M-by-N matrix A.
*>            if M >= N, A is overwritten by details of its QR
*>                       factorization as returned by CGEQRF;
*>            if M <  N, A is overwritten by details of its LQ
*>                       factorization as returned by CGELQF.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,M).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is COMPLEX array, dimension (LDB,NRHS)
*>          On entry, the matrix B of right hand side vectors, stored
*>          columnwise; B is M-by-NRHS if TRANS = 'N', or N-by-NRHS
*>          if TRANS = 'C'.
*>          On exit, if INFO = 0, B is overwritten by the solution
*>          vectors, stored columnwise:
*>          if TRANS = 'N' and m >= n, rows 1 to n of B contain the least
*>          squares solution vectors; the residual sum of squares for the
*>          solution in each column is given by the sum of squares of the
*>          modulus of elements N+1 to M in that column;
*>          if TRANS = 'N' and m < n, rows 1 to N of B contain the
*>          minimum norm solution vectors;
*>          if TRANS = 'C' and m >= n, rows 1 to M of B contain the
*>          minimum norm solution vectors;
*>          if TRANS = 'C' and m < n, rows 1 to M of B contain the
*>          least squares solution vectors; the residual sum of squares
*>          for the solution in each column is given by the sum of
*>          squares of the modulus of elements M+1 to N in that column.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B. LDB >= MAX(1,M,N).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX array, dimension (MAX(1,LWORK))
*>          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK.
*>          LWORK >= max( 1, MN + max( MN, NRHS ) ).
*>          For optimal performance,
*>          LWORK >= max( 1, MN + max( MN, NRHS )*NB ).
*>          where MN = min(M,N) and NB is the optimum block size.
*>
*>          If LWORK = -1, then a workspace query is assumed; the routine
*>          only calculates the optimal size of the WORK array, returns
*>          this value as the first entry of the WORK array, and no error
*>          message related to LWORK is issued by XERBLA.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*>          > 0:  if INFO =  i, the i-th diagonal element of the
*>                triangular factor of A is zero, so that A does not have
*>                full rank; the least squares solution could not be
*>                computed.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complexGEsolve
*
*  =====================================================================
      SUBROUTINE cgels( TRANS, M, N, NRHS, A, LDA, B, LDB, WORK, LWORK,
     $                  INFO )
*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * ), B( LDB, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CZERO
      parameter( czero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, TPSD
      INTEGER            BROW, I, IASCL, IBSCL, J, MN, NB, SCLLEN, WSIZE
      REAL               ANRM, BIGNUM, BNRM, SMLNUM
*     ..
*     .. Local Arrays ..
      REAL               RWORK( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ILAENV
      REAL               CLANGE, SLAMCH
      EXTERNAL           lsame, ilaenv, clange, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgelqf, cgeqrf, clascl, claset, ctrtrs, cunmlq,
     $                   cunmqr, slabad, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments.
*
      info = 0
      mn = min( m, n )
      lquery = ( lwork.EQ.-1 )
      IF( .NOT.( lsame( trans, 'N' ) .OR. lsame( trans, 'C' ) ) ) THEN
         info = -1
      ELSE IF( m.LT.0 ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( nrhs.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -6
      ELSE IF( ldb.LT.max( 1, m, n ) ) THEN
         info = -8
      ELSE IF( lwork.LT.max( 1, mn+max( mn, nrhs ) ) .AND.
     $   .NOT.lquery ) THEN
         info = -10
      END IF
*
*     Figure out optimal block size
*
      IF( info.EQ.0 .OR. info.EQ.-10 ) THEN
*
         tpsd = .true.
         IF( lsame( trans, 'N' ) )
     $      tpsd = .false.
*
         IF( m.GE.n ) THEN
            nb = ilaenv( 1, 'CGEQRF', ' ', m, n, -1, -1 )
            IF( tpsd ) THEN
               nb = max( nb, ilaenv( 1, 'CUNMQR', 'LN', m, nrhs, n,
     $              -1 ) )
            ELSE
               nb = max( nb, ilaenv( 1, 'CUNMQR', 'LC', m, nrhs, n,
     $              -1 ) )
            END IF
         ELSE
            nb = ilaenv( 1, 'CGELQF', ' ', m, n, -1, -1 )
            IF( tpsd ) THEN
               nb = max( nb, ilaenv( 1, 'CUNMLQ', 'LC', n, nrhs, m,
     $              -1 ) )
            ELSE
               nb = max( nb, ilaenv( 1, 'CUNMLQ', 'LN', n, nrhs, m,
     $              -1 ) )
            END IF
         END IF
*
         wsize = max( 1, mn + max( mn, nrhs )*nb )
         work( 1 ) = real( wsize )
*
      END IF
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGELS ', -info )
         RETURN
      ELSE IF( lquery ) THEN
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( min( m, n, nrhs ).EQ.0 ) THEN
         CALL claset( 'Full', max( m, n ), nrhs, czero, czero, b, ldb )
         RETURN
      END IF
*
*     Get machine parameters
*
      smlnum = slamch( 'S' ) / slamch( 'P' )
      bignum = one / smlnum
      CALL slabad( smlnum, bignum )
*
*     Scale A, B if max element outside range [SMLNUM,BIGNUM]
*
      anrm = clange( 'M', m, n, a, lda, rwork )
      iascl = 0
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL clascl( 'G', 0, 0, anrm, smlnum, m, n, a, lda, info )
         iascl = 1
      ELSE IF( anrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL clascl( 'G', 0, 0, anrm, bignum, m, n, a, lda, info )
         iascl = 2
      ELSE IF( anrm.EQ.zero ) THEN
*
*        Matrix all zero. Return zero solution.
*
         CALL claset( 'F', max( m, n ), nrhs, czero, czero, b, ldb )
         GO TO 50
      END IF
*
      brow = m
      IF( tpsd )
     $   brow = n
      bnrm = clange( 'M', brow, nrhs, b, ldb, rwork )
      ibscl = 0
      IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL clascl( 'G', 0, 0, bnrm, smlnum, brow, nrhs, b, ldb,
     $                info )
         ibscl = 1
      ELSE IF( bnrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL clascl( 'G', 0, 0, bnrm, bignum, brow, nrhs, b, ldb,
     $                info )
         ibscl = 2
      END IF
*
      IF( m.GE.n ) THEN
*
*        compute QR factorization of A
*
         CALL cgeqrf( m, n, a, lda, work( 1 ), work( mn+1 ), lwork-mn,
     $                info )
*
*        workspace at least N, optimally N*NB
*
         IF( .NOT.tpsd ) THEN
*
*           Least-Squares Problem min || A * X - B ||
*
*           B(1:M,1:NRHS) := Q**H * B(1:M,1:NRHS)
*
            CALL cunmqr( 'Left', 'Conjugate transpose', m, nrhs, n, a,
     $                   lda, work( 1 ), b, ldb, work( mn+1 ), lwork-mn,
     $                   info )
*
*           workspace at least NRHS, optimally NRHS*NB
*
*           B(1:N,1:NRHS) := inv(R) * B(1:N,1:NRHS)
*
            CALL ctrtrs( 'Upper', 'No transpose', 'Non-unit', n, nrhs,
     $                   a, lda, b, ldb, info )
*
            IF( info.GT.0 ) THEN
               RETURN
            END IF
*
            scllen = n
*
         ELSE
*
*           Underdetermined system of equations A**T * X = B
*
*           B(1:N,1:NRHS) := inv(R**H) * B(1:N,1:NRHS)
*
            CALL ctrtrs( 'Upper', 'Conjugate transpose','Non-unit',
     $                   n, nrhs, a, lda, b, ldb, info )
*
            IF( info.GT.0 ) THEN
               RETURN
            END IF
*
*           B(N+1:M,1:NRHS) = ZERO
*
            DO 20 j = 1, nrhs
               DO 10 i = n + 1, m
                  b( i, j ) = czero
   10          CONTINUE
   20       CONTINUE
*
*           B(1:M,1:NRHS) := Q(1:N,:) * B(1:N,1:NRHS)
*
            CALL cunmqr( 'Left', 'No transpose', m, nrhs, n, a, lda,
     $                   work( 1 ), b, ldb, work( mn+1 ), lwork-mn,
     $                   info )
*
*           workspace at least NRHS, optimally NRHS*NB
*
            scllen = m
*
         END IF
*
      ELSE
*
*        Compute LQ factorization of A
*
         CALL cgelqf( m, n, a, lda, work( 1 ), work( mn+1 ), lwork-mn,
     $                info )
*
*        workspace at least M, optimally M*NB.
*
         IF( .NOT.tpsd ) THEN
*
*           underdetermined system of equations A * X = B
*
*           B(1:M,1:NRHS) := inv(L) * B(1:M,1:NRHS)
*
            CALL ctrtrs( 'Lower', 'No transpose', 'Non-unit', m, nrhs,
     $                   a, lda, b, ldb, info )
*
            IF( info.GT.0 ) THEN
               RETURN
            END IF
*
*           B(M+1:N,1:NRHS) = 0
*
            DO 40 j = 1, nrhs
               DO 30 i = m + 1, n
                  b( i, j ) = czero
   30          CONTINUE
   40       CONTINUE
*
*           B(1:N,1:NRHS) := Q(1:N,:)**H * B(1:M,1:NRHS)
*
            CALL cunmlq( 'Left', 'Conjugate transpose', n, nrhs, m, a,
     $                   lda, work( 1 ), b, ldb, work( mn+1 ), lwork-mn,
     $                   info )
*
*           workspace at least NRHS, optimally NRHS*NB
*
            scllen = n
*
         ELSE
*
*           overdetermined system min || A**H * X - B ||
*
*           B(1:N,1:NRHS) := Q * B(1:N,1:NRHS)
*
            CALL cunmlq( 'Left', 'No transpose', n, nrhs, m, a, lda,
     $                   work( 1 ), b, ldb, work( mn+1 ), lwork-mn,
     $                   info )
*
*           workspace at least NRHS, optimally NRHS*NB
*
*           B(1:M,1:NRHS) := inv(L**H) * B(1:M,1:NRHS)
*
            CALL ctrtrs( 'Lower', 'Conjugate transpose', 'Non-unit',
     $                   m, nrhs, a, lda, b, ldb, info )
*
            IF( info.GT.0 ) THEN
               RETURN
            END IF
*
            scllen = m
*
         END IF
*
      END IF
*
*     Undo scaling
*
      IF( iascl.EQ.1 ) THEN
         CALL clascl( 'G', 0, 0, anrm, smlnum, scllen, nrhs, b, ldb,
     $                info )
      ELSE IF( iascl.EQ.2 ) THEN
         CALL clascl( 'G', 0, 0, anrm, bignum, scllen, nrhs, b, ldb,
     $                info )
      END IF
      IF( ibscl.EQ.1 ) THEN
         CALL clascl( 'G', 0, 0, smlnum, bnrm, scllen, nrhs, b, ldb,
     $                info )
      ELSE IF( ibscl.EQ.2 ) THEN
         CALL clascl( 'G', 0, 0, bignum, bnrm, scllen, nrhs, b, ldb,
     $                info )
      END IF
*
   50 CONTINUE
      work( 1 ) = real( wsize )
*
      RETURN
*
*     End of CGELS
*
      END