dqrt11()

double precision function dqrt11	(	integer	M,
		integer	K,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( * )	TAU,
		double precision, dimension( lwork )	WORK,
		integer	LWORK
	)

DQRT11

Purpose:

 DQRT11 computes the test ratio

       || Q'*Q - I || / (eps * m)

 where the orthogonal matrix Q is represented as a product of
 elementary transformations.  Each transformation has the form

    H(k) = I - tau(k) v(k) v(k)'

 where tau(k) is stored in TAU(k) and v(k) is an m-vector of the form
 [ 0 ... 0 1 x(k) ]', where x(k) is a vector of length m-k stored
 in A(k+1:m,k).

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A.
[in]	K	K is INTEGER The number of columns of A whose subdiagonal entries contain information about orthogonal transformations.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,K) The (possibly partial) output of a QR reduction routine.
[in]	LDA	LDA is INTEGER The leading dimension of the array A.
[in]	TAU	TAU is DOUBLE PRECISION array, dimension (K) The scaling factors tau for the elementary transformations as computed by the QR factorization routine.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of the array WORK. LWORK >= M*M + M.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Definition at line 97 of file dqrt11.f.

*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), TAU( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d0, one = 1.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, J
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANGE
      EXTERNAL           dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlaset, dorm2r, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble
*     ..
*     .. Local Arrays ..
      DOUBLE PRECISION   RDUMMY( 1 )
*     ..
*     .. Executable Statements ..
*
      dqrt11 = zero
*
*     Test for sufficient workspace
*
      IF( lwork.LT.m*m+m ) THEN
         CALL xerbla( 'DQRT11', 7 )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( m.LE.0 )
     $   RETURN
*
      CALL dlaset( 'Full', m, m, zero, one, work, m )
*
*     Form Q
*
      CALL dorm2r( 'Left', 'No transpose', m, m, k, a, lda, tau, work,
     $             m, work( m*m+1 ), info )
*
*     Form Q'*Q
*
      CALL dorm2r( 'Left', 'Transpose', m, m, k, a, lda, tau, work, m,
     $             work( m*m+1 ), info )
*
      DO 10 j = 1, m
         work( ( j-1 )*m+j ) = work( ( j-1 )*m+j ) - one
   10 CONTINUE
*
      dqrt11 = dlange( 'One-norm', m, m, work, m, rdummy ) /
     $         ( dble( m )*dlamch( 'Epsilon' ) )
*
      RETURN
*
*     End of DQRT11
*

Here is the call graph for this function: