sgetsls.f

Go to the documentation of this file.

*> \brief \b SGETSLS
*
*  Definition:
*  ===========
*
*       SUBROUTINE SGETSLS( TRANS, M, N, NRHS, A, LDA, B, LDB,
*     $                     WORK, LWORK, INFO )
*
*       .. Scalar Arguments ..
*       CHARACTER          TRANS
*       INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS
*       ..
*       .. Array Arguments ..
*       REAL               A( LDA, * ), B( LDB, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SGETSLS solves overdetermined or underdetermined real linear systems
*> involving an M-by-N matrix A, using a tall skinny QR or short wide LQ
*> factorization of A.  It is assumed that A has full rank.
*>
*>
*>
*> The following options are provided:
*>
*> 1. If TRANS = 'N' and m >= n:  find the least squares solution of
*>    an overdetermined system, i.e., solve the least squares problem
*>                 minimize || B - A*X ||.
*>
*> 2. If TRANS = 'N' and m < n:  find the minimum norm solution of
*>    an underdetermined system A * X = B.
*>
*> 3. If TRANS = 'T' and m >= n:  find the minimum norm solution of
*>    an undetermined system A**T * X = B.
*>
*> 4. If TRANS = 'T' and m < n:  find the least squares solution of
*>    an overdetermined system, i.e., solve the least squares problem
*>                 minimize || B - A**T * X ||.
*>
*> Several right hand side vectors b and solution vectors x can be
*> handled in a single call; they are stored as the columns of the
*> M-by-NRHS right hand side matrix B and the N-by-NRHS solution
*> matrix X.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] TRANS
*> \verbatim
*>          TRANS is CHARACTER*1
*>          = 'N': the linear system involves A;
*>          = 'T': the linear system involves A**T.
*> \endverbatim
*>
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          The number of rows of the matrix A.  M >= 0.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The number of columns of the matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] NRHS
*> \verbatim
*>          NRHS is INTEGER
*>          The number of right hand sides, i.e., the number of
*>          columns of the matrices B and X. NRHS >=0.
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is REAL array, dimension (LDA,N)
*>          On entry, the M-by-N matrix A.
*>          On exit,
*>          A is overwritten by details of its QR or LQ
*>          factorization as returned by SGEQR or SGELQ.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of the array A.  LDA >= max(1,M).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is REAL array, dimension (LDB,NRHS)
*>          On entry, the matrix B of right hand side vectors, stored
*>          columnwise; B is M-by-NRHS if TRANS = 'N', or N-by-NRHS
*>          if TRANS = 'T'.
*>          On exit, if INFO = 0, B is overwritten by the solution
*>          vectors, stored columnwise:
*>          if TRANS = 'N' and m >= n, rows 1 to n of B contain the least
*>          squares solution vectors.
*>          if TRANS = 'N' and m < n, rows 1 to N of B contain the
*>          minimum norm solution vectors;
*>          if TRANS = 'T' and m >= n, rows 1 to M of B contain the
*>          minimum norm solution vectors;
*>          if TRANS = 'T' and m < n, rows 1 to M of B contain the
*>          least squares solution vectors.
*> \endverbatim
*>
*> \param[in] LDB
*> \verbatim
*>          LDB is INTEGER
*>          The leading dimension of the array B. LDB >= MAX(1,M,N).
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          (workspace) REAL array, dimension (MAX(1,LWORK))
*>          On exit, if INFO = 0, WORK(1) contains optimal (or either minimal
*>          or optimal, if query was assumed) LWORK.
*>          See LWORK for details.
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The dimension of the array WORK.
*>          If LWORK = -1 or -2, then a workspace query is assumed.
*>          If LWORK = -1, the routine calculates optimal size of WORK for the
*>          optimal performance and returns this value in WORK(1).
*>          If LWORK = -2, the routine calculates minimal size of WORK and 
*>          returns this value in WORK(1).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value
*>          > 0:  if INFO =  i, the i-th diagonal element of the
*>                triangular factor of A is zero, so that A does not have
*>                full rank; the least squares solution could not be
*>                computed.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup realGEsolve
*
*  =====================================================================
      SUBROUTINE sgetsls( TRANS, M, N, NRHS, A, LDA, B, LDB,
     $                    WORK, LWORK, INFO )
*
*  -- LAPACK driver routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          TRANS
      INTEGER            INFO, LDA, LDB, LWORK, M, N, NRHS
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), B( LDB, * ), WORK( * )
*
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e0, one = 1.0e0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LQUERY, TRAN
      INTEGER            I, IASCL, IBSCL, J, MAXMN, BROW,
     $                   scllen, tszo, tszm, lwo, lwm, lw1, lw2,
     $                   wsizeo, wsizem, info2
      REAL               ANRM, BIGNUM, BNRM, SMLNUM, TQ( 5 ), WORKQ( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH, SLANGE
      EXTERNAL           lsame, slabad, slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgeqr, sgemqr, slascl, slaset,
     $                   strtrs, xerbla, sgelq, sgemlq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real, max, min, int
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments.
*
      info = 0
      maxmn = max( m, n )
      tran  = lsame( trans, 'T' )
*
      lquery = ( lwork.EQ.-1 .OR. lwork.EQ.-2 )
      IF( .NOT.( lsame( trans, 'N' ) .OR.
     $    lsame( trans, 'T' ) ) ) THEN
         info = -1
      ELSE IF( m.LT.0 ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( nrhs.LT.0 ) THEN
         info = -4
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -6
      ELSE IF( ldb.LT.max( 1, m, n ) ) THEN
         info = -8
      END IF
*
      IF( info.EQ.0 ) THEN
*
*     Determine the optimum and minimum LWORK
*
       IF( m.GE.n ) THEN
         CALL sgeqr( m, n, a, lda, tq, -1, workq, -1, info2 )
         tszo = int( tq( 1 ) )
         lwo  = int( workq( 1 ) )
         CALL sgemqr( 'L', trans, m, nrhs, n, a, lda, tq,
     $                tszo, b, ldb, workq, -1, info2 )
         lwo  = max( lwo, int( workq( 1 ) ) )
         CALL sgeqr( m, n, a, lda, tq, -2, workq, -2, info2 )
         tszm = int( tq( 1 ) )
         lwm  = int( workq( 1 ) )
         CALL sgemqr( 'L', trans, m, nrhs, n, a, lda, tq,
     $                tszm, b, ldb, workq, -1, info2 )
         lwm = max( lwm, int( workq( 1 ) ) )
         wsizeo = tszo + lwo
         wsizem = tszm + lwm
       ELSE
         CALL sgelq( m, n, a, lda, tq, -1, workq, -1, info2 )
         tszo = int( tq( 1 ) )
         lwo  = int( workq( 1 ) )
         CALL sgemlq( 'L', trans, n, nrhs, m, a, lda, tq,
     $                tszo, b, ldb, workq, -1, info2 )
         lwo  = max( lwo, int( workq( 1 ) ) )
         CALL sgelq( m, n, a, lda, tq, -2, workq, -2, info2 )
         tszm = int( tq( 1 ) )
         lwm  = int( workq( 1 ) )
         CALL sgemlq( 'L', trans, n, nrhs, m, a, lda, tq,
     $                tszm, b, ldb, workq, -1, info2 )
         lwm  = max( lwm, int( workq( 1 ) ) )
         wsizeo = tszo + lwo
         wsizem = tszm + lwm
       END IF
*
       IF( ( lwork.LT.wsizem ).AND.( .NOT.lquery ) ) THEN
          info = -10
       END IF
*
       work( 1 ) = real( wsizeo )
*
      END IF
*
      IF( info.NE.0 ) THEN
        CALL xerbla( 'SGETSLS', -info )
        RETURN
      END IF
      IF( lquery ) THEN
        IF( lwork.EQ.-2 ) work( 1 ) = real( wsizem )
        RETURN
      END IF
      IF( lwork.LT.wsizeo ) THEN
        lw1 = tszm
        lw2 = lwm
      ELSE
        lw1 = tszo
        lw2 = lwo
      END IF
*
*     Quick return if possible
*
      IF( min( m, n, nrhs ).EQ.0 ) THEN
           CALL slaset( 'FULL', max( m, n ), nrhs, zero, zero,
     $                  b, ldb )
           RETURN
      END IF
*
*     Get machine parameters
*
       smlnum = slamch( 'S' ) / slamch( 'P' )
       bignum = one / smlnum
       CALL slabad( smlnum, bignum )
*
*     Scale A, B if max element outside range [SMLNUM,BIGNUM]
*
      anrm = slange( 'M', m, n, a, lda, work )
      iascl = 0
      IF( anrm.GT.zero .AND. anrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL slascl( 'G', 0, 0, anrm, smlnum, m, n, a, lda, info )
         iascl = 1
      ELSE IF( anrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL slascl( 'G', 0, 0, anrm, bignum, m, n, a, lda, info )
         iascl = 2
      ELSE IF( anrm.EQ.zero ) THEN
*
*        Matrix all zero. Return zero solution.
*
         CALL slaset( 'F', maxmn, nrhs, zero, zero, b, ldb )
         GO TO 50
      END IF
*
      brow = m
      IF ( tran ) THEN
        brow = n
      END IF
      bnrm = slange( 'M', brow, nrhs, b, ldb, work )
      ibscl = 0
      IF( bnrm.GT.zero .AND. bnrm.LT.smlnum ) THEN
*
*        Scale matrix norm up to SMLNUM
*
         CALL slascl( 'G', 0, 0, bnrm, smlnum, brow, nrhs, b, ldb,
     $                info )
         ibscl = 1
      ELSE IF( bnrm.GT.bignum ) THEN
*
*        Scale matrix norm down to BIGNUM
*
         CALL slascl( 'G', 0, 0, bnrm, bignum, brow, nrhs, b, ldb,
     $                info )
         ibscl = 2
      END IF
*
      IF ( m.GE.n ) THEN
*
*        compute QR factorization of A
*
        CALL sgeqr( m, n, a, lda, work( lw2+1 ), lw1,
     $              work( 1 ), lw2, info )
        IF ( .NOT.tran ) THEN
*
*           Least-Squares Problem min || A * X - B ||
*
*           B(1:M,1:NRHS) := Q**T * B(1:M,1:NRHS)
*
          CALL sgemqr( 'L' , 'T', m, nrhs, n, a, lda,
     $                 work( lw2+1 ), lw1, b, ldb, work( 1 ), lw2,
     $                 info )
*
*           B(1:N,1:NRHS) := inv(R) * B(1:N,1:NRHS)
*
          CALL strtrs( 'U', 'N', 'N', n, nrhs,
     $                  a, lda, b, ldb, info )
          IF( info.GT.0 ) THEN
            RETURN
          END IF
          scllen = n
        ELSE
*
*           Overdetermined system of equations A**T * X = B
*
*           B(1:N,1:NRHS) := inv(R**T) * B(1:N,1:NRHS)
*
            CALL strtrs( 'U', 'T', 'N', n, nrhs,
     $                   a, lda, b, ldb, info )
*
            IF( info.GT.0 ) THEN
               RETURN
            END IF
*
*           B(N+1:M,1:NRHS) = ZERO
*
            DO 20 j = 1, nrhs
               DO 10 i = n + 1, m
                  b( i, j ) = zero
   10          CONTINUE
   20       CONTINUE
*
*           B(1:M,1:NRHS) := Q(1:N,:) * B(1:N,1:NRHS)
*
            CALL sgemqr( 'L', 'N', m, nrhs, n, a, lda,
     $                   work( lw2+1 ), lw1, b, ldb, work( 1 ), lw2,
     $                   info )
*
            scllen = m
*
         END IF
*
      ELSE
*
*        Compute LQ factorization of A
*
         CALL sgelq( m, n, a, lda, work( lw2+1 ), lw1,
     $               work( 1 ), lw2, info )
*
*        workspace at least M, optimally M*NB.
*
         IF( .NOT.tran ) THEN
*
*           underdetermined system of equations A * X = B
*
*           B(1:M,1:NRHS) := inv(L) * B(1:M,1:NRHS)
*
            CALL strtrs( 'L', 'N', 'N', m, nrhs,
     $                   a, lda, b, ldb, info )
*
            IF( info.GT.0 ) THEN
               RETURN
            END IF
*
*           B(M+1:N,1:NRHS) = 0
*
            DO 40 j = 1, nrhs
               DO 30 i = m + 1, n
                  b( i, j ) = zero
   30          CONTINUE
   40       CONTINUE
*
*           B(1:N,1:NRHS) := Q(1:N,:)**T * B(1:M,1:NRHS)
*
            CALL sgemlq( 'L', 'T', n, nrhs, m, a, lda,
     $                   work( lw2+1 ), lw1, b, ldb, work( 1 ), lw2,
     $                   info )
*
*           workspace at least NRHS, optimally NRHS*NB
*
            scllen = n
*
         ELSE
*
*           overdetermined system min || A**T * X - B ||
*
*           B(1:N,1:NRHS) := Q * B(1:N,1:NRHS)
*
            CALL sgemlq( 'L', 'N', n, nrhs, m, a, lda,
     $                   work( lw2+1 ), lw1, b, ldb, work( 1 ), lw2,
     $                   info )
*
*           workspace at least NRHS, optimally NRHS*NB
*
*           B(1:M,1:NRHS) := inv(L**T) * B(1:M,1:NRHS)
*
            CALL strtrs( 'Lower', 'Transpose', 'Non-unit', m, nrhs,
     $                   a, lda, b, ldb, info )
*
            IF( info.GT.0 ) THEN
               RETURN
            END IF
*
            scllen = m
*
         END IF
*
      END IF
*
*     Undo scaling
*
      IF( iascl.EQ.1 ) THEN
        CALL slascl( 'G', 0, 0, anrm, smlnum, scllen, nrhs, b, ldb,
     $               info )
      ELSE IF( iascl.EQ.2 ) THEN
        CALL slascl( 'G', 0, 0, anrm, bignum, scllen, nrhs, b, ldb,
     $               info )
      END IF
      IF( ibscl.EQ.1 ) THEN
        CALL slascl( 'G', 0, 0, smlnum, bnrm, scllen, nrhs, b, ldb,
     $               info )
      ELSE IF( ibscl.EQ.2 ) THEN
        CALL slascl( 'G', 0, 0, bignum, bnrm, scllen, nrhs, b, ldb,
     $               info )
      END IF
*
   50 CONTINUE
      work( 1 ) = real( tszo + lwo )
      RETURN
*
*     End of SGETSLS
*
      END