◆ ssysv_aa_2stage()

subroutine ssysv_aa_2stage	(	character	UPLO,
		integer	N,
		integer	NRHS,
		real, dimension( lda, * )	A,
		integer	LDA,
		real, dimension( * )	TB,
		integer	LTB,
		integer, dimension( * )	IPIV,
		integer, dimension( * )	IPIV2,
		real, dimension( ldb, * )	B,
		integer	LDB,
		real, dimension( * )	WORK,
		integer	LWORK,
		integer	INFO
	)

SSYSV_AA_2STAGE computes the solution to system of linear equations A * X = B for SY matrices

Download SSYSV_AA_2STAGE + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SSYSV_AA_2STAGE computes the solution to a real system of
 linear equations
    A * X = B,
 where A is an N-by-N symmetric matrix and X and B are N-by-NRHS
 matrices.

 Aasen's 2-stage algorithm is used to factor A as
    A = U**T * T * U,  if UPLO = 'U', or
    A = L * T * L**T,  if UPLO = 'L',
 where U (or L) is a product of permutation and unit upper (lower)
 triangular matrices, and T is symmetric and band. The matrix T is
 then LU-factored with partial pivoting. The factored form of A
 is then used to solve the system of equations A * X = B.

 This is the blocked version of the algorithm, calling Level 3 BLAS.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrix B. NRHS >= 0.
[in,out]	A	A is REAL array, dimension (LDA,N) On entry, the symmetric matrix A. If UPLO = 'U', the leading N-by-N upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading N-by-N lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit, L is stored below (or above) the subdiaonal blocks, when UPLO is 'L' (or 'U').
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	TB	TB is REAL array, dimension (LTB) On exit, details of the LU factorization of the band matrix.
[in]	LTB	LTB is INTEGER The size of the array TB. LTB >= 4N, internally used to select NB such that LTB >= (3NB+1)*N. If LTB = -1, then a workspace query is assumed; the routine only calculates the optimal size of LTB, returns this value as the first entry of TB, and no error message related to LTB is issued by XERBLA.
[out]	IPIV	IPIV is INTEGER array, dimension (N) On exit, it contains the details of the interchanges, i.e., the row and column k of A were interchanged with the row and column IPIV(k).
[out]	IPIV2	IPIV2 is INTEGER array, dimension (N) On exit, it contains the details of the interchanges, i.e., the row and column k of T were interchanged with the row and column IPIV(k).
[in,out]	B	B is REAL array, dimension (LDB,NRHS) On entry, the right hand side matrix B. On exit, the solution matrix X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	WORK	WORK is REAL workspace of size LWORK
[in]	LWORK	LWORK is INTEGER The size of WORK. LWORK >= N, internally used to select NB such that LWORK >= N*NB. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value. > 0: if INFO = i, band LU factorization failed on i-th column

Author: Univ. of Tennessee; Univ. of California Berkeley; Univ. of Colorado Denver; NAG Ltd.

Definition at line 184 of file ssysv_aa_2stage.f.

 *
 *  -- LAPACK driver routine --
 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 *
       IMPLICIT NONE
 *
 *     .. Scalar Arguments ..
       CHARACTER          UPLO
       INTEGER            N, NRHS, LDA, LDB, LTB, LWORK, INFO
 *     ..
 *     .. Array Arguments ..
       INTEGER            IPIV( * ), IPIV2( * )
       REAL               A( LDA, * ), B( LDB, * ), TB( * ), WORK( * )
 *     ..
 *
 *  =====================================================================
 *     ..
 *     .. Local Scalars ..
       LOGICAL            UPPER, TQUERY, WQUERY
       INTEGER            LWKOPT
 *     ..
 *     .. External Functions ..
       LOGICAL            LSAME
       EXTERNAL           lsame
 *     ..
 *     .. External Subroutines ..
       EXTERNAL           ssytrf_aa_2stage, ssytrs_aa_2stage,
      $                   xerbla
 *     ..
 *     .. Intrinsic Functions ..
       INTRINSIC          max
 *     ..
 *     .. Executable Statements ..
 *
 *     Test the input parameters.
 *
       info = 0
       upper = lsame( uplo, 'U' )
       wquery = ( lwork.EQ.-1 )
       tquery = ( ltb.EQ.-1 )
       IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
          info = -1
       ELSE IF( n.LT.0 ) THEN
          info = -2
       ELSE IF( nrhs.LT.0 ) THEN
          info = -3
       ELSE IF( lda.LT.max( 1, n ) ) THEN
          info = -5
       ELSE IF( ltb.LT.( 4*n ) .AND. .NOT.tquery ) THEN
          info = -7
       ELSE IF( ldb.LT.max( 1, n ) ) THEN
          info = -11
       ELSE IF( lwork.LT.n .AND. .NOT.wquery ) THEN
          info = -13
       END IF
 *
       IF( info.EQ.0 ) THEN
          CALL ssytrf_aa_2stage( uplo, n, a, lda, tb, -1, ipiv,
      $                          ipiv2, work, -1, info )
          lwkopt = int( work(1) )
       END IF
 *
       IF( info.NE.0 ) THEN
          CALL xerbla( 'SSYSV_AA_2STAGE', -info )
          RETURN
       ELSE IF( wquery .OR. tquery ) THEN
          RETURN
       END IF
 *
 *
 *     Compute the factorization A = U**T*T*U or A = L*T*L**T.
 *
       CALL ssytrf_aa_2stage( uplo, n, a, lda, tb, ltb, ipiv, ipiv2,
      $                       work, lwork, info )
       IF( info.EQ.0 ) THEN
 *
 *        Solve the system A*X = B, overwriting B with X.
 *
          CALL ssytrs_aa_2stage( uplo, n, nrhs, a, lda, tb, ltb, ipiv,
      $                          ipiv2, b, ldb, info )
 *
       END IF
 *
       work( 1 ) = lwkopt
 *
       RETURN
 *
 *     End of SSYSV_AA_2STAGE
 *

Here is the call graph for this function:

Here is the caller graph for this function: