slangt.f

Go to the documentation of this file.

*> \brief \b SLANGT returns the value of the 1-norm, Frobenius norm, infinity-norm, or the largest absolute value of any element of a general tridiagonal matrix.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download SLANGT + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slangt.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slangt.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slangt.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       REAL             FUNCTION SLANGT( NORM, N, DL, D, DU )
*
*       .. Scalar Arguments ..
*       CHARACTER          NORM
*       INTEGER            N
*       ..
*       .. Array Arguments ..
*       REAL               D( * ), DL( * ), DU( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SLANGT  returns the value of the one norm,  or the Frobenius norm, or
*> the  infinity norm,  or the  element of  largest absolute value  of a
*> real tridiagonal matrix A.
*> \endverbatim
*>
*> \return SLANGT
*> \verbatim
*>
*>    SLANGT = ( max(abs(A(i,j))), NORM = 'M' or 'm'
*>             (
*>             ( norm1(A),         NORM = '1', 'O' or 'o'
*>             (
*>             ( normI(A),         NORM = 'I' or 'i'
*>             (
*>             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
*>
*> where  norm1  denotes the  one norm of a matrix (maximum column sum),
*> normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
*> normF  denotes the  Frobenius norm of a matrix (square root of sum of
*> squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NORM
*> \verbatim
*>          NORM is CHARACTER*1
*>          Specifies the value to be returned in SLANGT as described
*>          above.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.  When N = 0, SLANGT is
*>          set to zero.
*> \endverbatim
*>
*> \param[in] DL
*> \verbatim
*>          DL is REAL array, dimension (N-1)
*>          The (n-1) sub-diagonal elements of A.
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*>          D is REAL array, dimension (N)
*>          The diagonal elements of A.
*> \endverbatim
*>
*> \param[in] DU
*> \verbatim
*>          DU is REAL array, dimension (N-1)
*>          The (n-1) super-diagonal elements of A.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup realOTHERauxiliary
*
*  =====================================================================
      REAL             function slangt( norm, n, dl, d, du )
*
*  -- LAPACK auxiliary routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          norm
      INTEGER            n
*     ..
*     .. Array Arguments ..
      REAL               d( * ), dl( * ), du( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               one, zero
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i
      REAL               anorm, scale, sum, temp
*     ..
*     .. External Functions ..
      LOGICAL            lsame, sisnan
      EXTERNAL           lsame, sisnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           slassq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( n.LE.0 ) THEN
         anorm = zero
      ELSE IF( lsame( norm, 'M' ) ) THEN
*
*        Find max(abs(A(i,j))).
*
         anorm = abs( d( n ) )
         DO 10 i = 1, n - 1
            IF( anorm.LT.abs( dl( i ) ) .OR. sisnan( abs( dl( i ) ) ) )
     $           anorm = abs(dl(i))
            IF( anorm.LT.abs( d( i ) ) .OR. sisnan( abs( d( i ) ) ) )
     $           anorm = abs(d(i))
            IF( anorm.LT.abs( du( i ) ) .OR. sisnan(abs( du( i ) ) ) )
     $           anorm = abs(du(i))
   10    CONTINUE
      ELSE IF( lsame( norm, 'O' ) .OR. norm.EQ.'1' ) THEN
*
*        Find norm1(A).
*
         IF( n.EQ.1 ) THEN
            anorm = abs( d( 1 ) )
         ELSE
            anorm = abs( d( 1 ) )+abs( dl( 1 ) )
            temp = abs( d( n ) )+abs( du( n-1 ) )
            IF( anorm .LT. temp .OR. sisnan( temp ) ) anorm = temp
            DO 20 i = 2, n - 1
               temp = abs( d( i ) )+abs( dl( i ) )+abs( du( i-1 ) )
               IF( anorm .LT. temp .OR. sisnan( temp ) ) anorm = temp
   20       CONTINUE
         END IF
      ELSE IF( lsame( norm, 'I' ) ) THEN
*
*        Find normI(A).
*
         IF( n.EQ.1 ) THEN
            anorm = abs( d( 1 ) )
         ELSE
            anorm = abs( d( 1 ) )+abs( du( 1 ) )
            temp = abs( d( n ) )+abs( dl( n-1 ) )
            IF( anorm .LT. temp .OR. sisnan( temp ) ) anorm = temp
            DO 30 i = 2, n - 1
               temp = abs( d( i ) )+abs( du( i ) )+abs( dl( i-1 ) )
               IF( anorm .LT. temp .OR. sisnan( temp ) ) anorm = temp
   30       CONTINUE
         END IF
      ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
*
*        Find normF(A).
*
         scale = zero
         sum = one
         CALL slassq( n, d, 1, scale, sum )
         IF( n.GT.1 ) THEN
            CALL slassq( n-1, dl, 1, scale, sum )
            CALL slassq( n-1, du, 1, scale, sum )
         END IF
         anorm = scale*sqrt( sum )
      END IF
*
      slangt = anorm
      RETURN
*
*     End of SLANGT
*
      END