zdrgev3.f

Go to the documentation of this file.

*> \brief \b ZDRGEV3
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE ZDRGEV3( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
*                           NOUNIT, A, LDA, B, S, T, Q, LDQ, Z, QE, LDQE,
*                           ALPHA, BETA, ALPHA1, BETA1, WORK, LWORK, RWORK,
*                           RESULT, INFO )
*
*       .. Scalar Arguments ..
*       INTEGER            INFO, LDA, LDQ, LDQE, LWORK, NOUNIT, NSIZES,
*      $                   NTYPES
*       DOUBLE PRECISION   THRESH
*       ..
*       .. Array Arguments ..
*       LOGICAL            DOTYPE( * )
*       INTEGER            ISEED( 4 ), NN( * )
*       DOUBLE PRECISION   RESULT( * ), RWORK( * )
*       COMPLEX*16         A( LDA, * ), ALPHA( * ), ALPHA1( * ),
*      $                   B( LDA, * ), BETA( * ), BETA1( * ),
*      $                   Q( LDQ, * ), QE( LDQE, * ), S( LDA, * ),
*      $                   T( LDA, * ), WORK( * ), Z( LDQ, * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> ZDRGEV3 checks the nonsymmetric generalized eigenvalue problem driver
*> routine ZGGEV3.
*>
*> ZGGEV3 computes for a pair of n-by-n nonsymmetric matrices (A,B) the
*> generalized eigenvalues and, optionally, the left and right
*> eigenvectors.
*>
*> A generalized eigenvalue for a pair of matrices (A,B) is a scalar w
*> or a ratio  alpha/beta = w, such that A - w*B is singular.  It is
*> usually represented as the pair (alpha,beta), as there is reasonable
*> interpretation for beta=0, and even for both being zero.
*>
*> A right generalized eigenvector corresponding to a generalized
*> eigenvalue  w  for a pair of matrices (A,B) is a vector r  such that
*> (A - wB) * r = 0.  A left generalized eigenvector is a vector l such
*> that l**H * (A - wB) = 0, where l**H is the conjugate-transpose of l.
*>
*> When ZDRGEV3 is called, a number of matrix "sizes" ("n's") and a
*> number of matrix "types" are specified.  For each size ("n")
*> and each type of matrix, a pair of matrices (A, B) will be generated
*> and used for testing.  For each matrix pair, the following tests
*> will be performed and compared with the threshold THRESH.
*>
*> Results from ZGGEV3:
*>
*> (1)  max over all left eigenvalue/-vector pairs (alpha/beta,l) of
*>
*>      | VL**H * (beta A - alpha B) |/( ulp max(|beta A|, |alpha B|) )
*>
*>      where VL**H is the conjugate-transpose of VL.
*>
*> (2)  | |VL(i)| - 1 | / ulp and whether largest component real
*>
*>      VL(i) denotes the i-th column of VL.
*>
*> (3)  max over all left eigenvalue/-vector pairs (alpha/beta,r) of
*>
*>      | (beta A - alpha B) * VR | / ( ulp max(|beta A|, |alpha B|) )
*>
*> (4)  | |VR(i)| - 1 | / ulp and whether largest component real
*>
*>      VR(i) denotes the i-th column of VR.
*>
*> (5)  W(full) = W(partial)
*>      W(full) denotes the eigenvalues computed when both l and r
*>      are also computed, and W(partial) denotes the eigenvalues
*>      computed when only W, only W and r, or only W and l are
*>      computed.
*>
*> (6)  VL(full) = VL(partial)
*>      VL(full) denotes the left eigenvectors computed when both l
*>      and r are computed, and VL(partial) denotes the result
*>      when only l is computed.
*>
*> (7)  VR(full) = VR(partial)
*>      VR(full) denotes the right eigenvectors computed when both l
*>      and r are also computed, and VR(partial) denotes the result
*>      when only l is computed.
*>
*>
*> Test Matrices
*> ---- --------
*>
*> The sizes of the test matrices are specified by an array
*> NN(1:NSIZES); the value of each element NN(j) specifies one size.
*> The "types" are specified by a logical array DOTYPE( 1:NTYPES ); if
*> DOTYPE(j) is .TRUE., then matrix type "j" will be generated.
*> Currently, the list of possible types is:
*>
*> (1)  ( 0, 0 )         (a pair of zero matrices)
*>
*> (2)  ( I, 0 )         (an identity and a zero matrix)
*>
*> (3)  ( 0, I )         (an identity and a zero matrix)
*>
*> (4)  ( I, I )         (a pair of identity matrices)
*>
*>         t   t
*> (5)  ( J , J  )       (a pair of transposed Jordan blocks)
*>
*>                                     t                ( I   0  )
*> (6)  ( X, Y )         where  X = ( J   0  )  and Y = (      t )
*>                                  ( 0   I  )          ( 0   J  )
*>                       and I is a k x k identity and J a (k+1)x(k+1)
*>                       Jordan block; k=(N-1)/2
*>
*> (7)  ( D, I )         where D is diag( 0, 1,..., N-1 ) (a diagonal
*>                       matrix with those diagonal entries.)
*> (8)  ( I, D )
*>
*> (9)  ( big*D, small*I ) where "big" is near overflow and small=1/big
*>
*> (10) ( small*D, big*I )
*>
*> (11) ( big*I, small*D )
*>
*> (12) ( small*I, big*D )
*>
*> (13) ( big*D, big*I )
*>
*> (14) ( small*D, small*I )
*>
*> (15) ( D1, D2 )        where D1 is diag( 0, 0, 1, ..., N-3, 0 ) and
*>                        D2 is diag( 0, N-3, N-4,..., 1, 0, 0 )
*>           t   t
*> (16) Q ( J , J ) Z     where Q and Z are random orthogonal matrices.
*>
*> (17) Q ( T1, T2 ) Z    where T1 and T2 are upper triangular matrices
*>                        with random O(1) entries above the diagonal
*>                        and diagonal entries diag(T1) =
*>                        ( 0, 0, 1, ..., N-3, 0 ) and diag(T2) =
*>                        ( 0, N-3, N-4,..., 1, 0, 0 )
*>
*> (18) Q ( T1, T2 ) Z    diag(T1) = ( 0, 0, 1, 1, s, ..., s, 0 )
*>                        diag(T2) = ( 0, 1, 0, 1,..., 1, 0 )
*>                        s = machine precision.
*>
*> (19) Q ( T1, T2 ) Z    diag(T1)=( 0,0,1,1, 1-d, ..., 1-(N-5)*d=s, 0 )
*>                        diag(T2) = ( 0, 1, 0, 1, ..., 1, 0 )
*>
*>                                                        N-5
*> (20) Q ( T1, T2 ) Z    diag(T1)=( 0, 0, 1, 1, a, ..., a   =s, 0 )
*>                        diag(T2) = ( 0, 1, 0, 1, ..., 1, 0, 0 )
*>
*> (21) Q ( T1, T2 ) Z    diag(T1)=( 0, 0, 1, r1, r2, ..., r(N-4), 0 )
*>                        diag(T2) = ( 0, 1, 0, 1, ..., 1, 0, 0 )
*>                        where r1,..., r(N-4) are random.
*>
*> (22) Q ( big*T1, small*T2 ) Z    diag(T1) = ( 0, 0, 1, ..., N-3, 0 )
*>                                  diag(T2) = ( 0, 1, ..., 1, 0, 0 )
*>
*> (23) Q ( small*T1, big*T2 ) Z    diag(T1) = ( 0, 0, 1, ..., N-3, 0 )
*>                                  diag(T2) = ( 0, 1, ..., 1, 0, 0 )
*>
*> (24) Q ( small*T1, small*T2 ) Z  diag(T1) = ( 0, 0, 1, ..., N-3, 0 )
*>                                  diag(T2) = ( 0, 1, ..., 1, 0, 0 )
*>
*> (25) Q ( big*T1, big*T2 ) Z      diag(T1) = ( 0, 0, 1, ..., N-3, 0 )
*>                                  diag(T2) = ( 0, 1, ..., 1, 0, 0 )
*>
*> (26) Q ( T1, T2 ) Z     where T1 and T2 are random upper-triangular
*>                         matrices.
*>
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NSIZES
*> \verbatim
*>          NSIZES is INTEGER
*>          The number of sizes of matrices to use.  If it is zero,
*>          ZDRGEV3 does nothing.  NSIZES >= 0.
*> \endverbatim
*>
*> \param[in] NN
*> \verbatim
*>          NN is INTEGER array, dimension (NSIZES)
*>          An array containing the sizes to be used for the matrices.
*>          Zero values will be skipped.  NN >= 0.
*> \endverbatim
*>
*> \param[in] NTYPES
*> \verbatim
*>          NTYPES is INTEGER
*>          The number of elements in DOTYPE.   If it is zero, ZDRGEV3
*>          does nothing.  It must be at least zero.  If it is MAXTYP+1
*>          and NSIZES is 1, then an additional type, MAXTYP+1 is
*>          defined, which is to use whatever matrix is in A.  This
*>          is only useful if DOTYPE(1:MAXTYP) is .FALSE. and
*>          DOTYPE(MAXTYP+1) is .TRUE. .
*> \endverbatim
*>
*> \param[in] DOTYPE
*> \verbatim
*>          DOTYPE is LOGICAL array, dimension (NTYPES)
*>          If DOTYPE(j) is .TRUE., then for each size in NN a
*>          matrix of that size and of type j will be generated.
*>          If NTYPES is smaller than the maximum number of types
*>          defined (PARAMETER MAXTYP), then types NTYPES+1 through
*>          MAXTYP will not be generated. If NTYPES is larger
*>          than MAXTYP, DOTYPE(MAXTYP+1) through DOTYPE(NTYPES)
*>          will be ignored.
*> \endverbatim
*>
*> \param[in,out] ISEED
*> \verbatim
*>          ISEED is INTEGER array, dimension (4)
*>          On entry ISEED specifies the seed of the random number
*>          generator. The array elements should be between 0 and 4095;
*>          if not they will be reduced mod 4096. Also, ISEED(4) must
*>          be odd.  The random number generator uses a linear
*>          congruential sequence limited to small integers, and so
*>          should produce machine independent random numbers. The
*>          values of ISEED are changed on exit, and can be used in the
*>          next call to ZDRGES to continue the same random number
*>          sequence.
*> \endverbatim
*>
*> \param[in] THRESH
*> \verbatim
*>          THRESH is DOUBLE PRECISION
*>          A test will count as "failed" if the "error", computed as
*>          described above, exceeds THRESH.  Note that the error is
*>          scaled to be O(1), so THRESH should be a reasonably small
*>          multiple of 1, e.g., 10 or 100.  In particular, it should
*>          not depend on the precision (single vs. double) or the size
*>          of the matrix.  It must be at least zero.
*> \endverbatim
*>
*> \param[in] NOUNIT
*> \verbatim
*>          NOUNIT is INTEGER
*>          The FORTRAN unit number for printing out error messages
*>          (e.g., if a routine returns IERR not equal to 0.)
*> \endverbatim
*>
*> \param[in,out] A
*> \verbatim
*>          A is COMPLEX*16 array, dimension(LDA, max(NN))
*>          Used to hold the original A matrix.  Used as input only
*>          if NTYPES=MAXTYP+1, DOTYPE(1:MAXTYP)=.FALSE., and
*>          DOTYPE(MAXTYP+1)=.TRUE.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of A, B, S, and T.
*>          It must be at least 1 and at least max( NN ).
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is COMPLEX*16 array, dimension(LDA, max(NN))
*>          Used to hold the original B matrix.  Used as input only
*>          if NTYPES=MAXTYP+1, DOTYPE(1:MAXTYP)=.FALSE., and
*>          DOTYPE(MAXTYP+1)=.TRUE.
*> \endverbatim
*>
*> \param[out] S
*> \verbatim
*>          S is COMPLEX*16 array, dimension (LDA, max(NN))
*>          The Schur form matrix computed from A by ZGGEV3.  On exit, S
*>          contains the Schur form matrix corresponding to the matrix
*>          in A.
*> \endverbatim
*>
*> \param[out] T
*> \verbatim
*>          T is COMPLEX*16 array, dimension (LDA, max(NN))
*>          The upper triangular matrix computed from B by ZGGEV3.
*> \endverbatim
*>
*> \param[out] Q
*> \verbatim
*>          Q is COMPLEX*16 array, dimension (LDQ, max(NN))
*>          The (left) eigenvectors matrix computed by ZGGEV3.
*> \endverbatim
*>
*> \param[in] LDQ
*> \verbatim
*>          LDQ is INTEGER
*>          The leading dimension of Q and Z. It must
*>          be at least 1 and at least max( NN ).
*> \endverbatim
*>
*> \param[out] Z
*> \verbatim
*>          Z is COMPLEX*16 array, dimension( LDQ, max(NN) )
*>          The (right) orthogonal matrix computed by ZGGEV3.
*> \endverbatim
*>
*> \param[out] QE
*> \verbatim
*>          QE is COMPLEX*16 array, dimension( LDQ, max(NN) )
*>          QE holds the computed right or left eigenvectors.
*> \endverbatim
*>
*> \param[in] LDQE
*> \verbatim
*>          LDQE is INTEGER
*>          The leading dimension of QE. LDQE >= max(1,max(NN)).
*> \endverbatim
*>
*> \param[out] ALPHA
*> \verbatim
*>          ALPHA is COMPLEX*16 array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] BETA
*> \verbatim
*>          BETA is COMPLEX*16 array, dimension (max(NN))
*>
*>          The generalized eigenvalues of (A,B) computed by ZGGEV3.
*>          ( ALPHAR(k)+ALPHAI(k)*i ) / BETA(k) is the k-th
*>          generalized eigenvalue of A and B.
*> \endverbatim
*>
*> \param[out] ALPHA1
*> \verbatim
*>          ALPHA1 is COMPLEX*16 array, dimension (max(NN))
*> \endverbatim
*>
*> \param[out] BETA1
*> \verbatim
*>          BETA1 is COMPLEX*16 array, dimension (max(NN))
*>
*>          Like ALPHAR, ALPHAI, BETA, these arrays contain the
*>          eigenvalues of A and B, but those computed when ZGGEV3 only
*>          computes a partial eigendecomposition, i.e. not the
*>          eigenvalues and left and right eigenvectors.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is COMPLEX*16 array, dimension (LWORK)
*> \endverbatim
*>
*> \param[in] LWORK
*> \verbatim
*>          LWORK is INTEGER
*>          The number of entries in WORK.  LWORK >= N*(N+1)
*> \endverbatim
*>
*> \param[out] RWORK
*> \verbatim
*>          RWORK is DOUBLE PRECISION array, dimension (8*N)
*>          Real workspace.
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is DOUBLE PRECISION array, dimension (2)
*>          The values computed by the tests described above.
*>          The values are currently limited to 1/ulp, to avoid overflow.
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>          = 0:  successful exit
*>          < 0:  if INFO = -i, the i-th argument had an illegal value.
*>          > 0:  A routine returned an error code.  INFO is the
*>                absolute value of the INFO value returned.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup complex16_eig
*
*  =====================================================================
      SUBROUTINE zdrgev3( NSIZES, NN, NTYPES, DOTYPE, ISEED, THRESH,
     $                    NOUNIT, A, LDA, B, S, T, Q, LDQ, Z, QE, LDQE,
     $                    ALPHA, BETA, ALPHA1, BETA1, WORK, LWORK,
     $                    RWORK, RESULT, INFO )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      INTEGER            INFO, LDA, LDQ, LDQE, LWORK, NOUNIT, NSIZES,
     $                   NTYPES
      DOUBLE PRECISION   THRESH
*     ..
*     .. Array Arguments ..
      LOGICAL            DOTYPE( * )
      INTEGER            ISEED( 4 ), NN( * )
      DOUBLE PRECISION   RESULT( * ), RWORK( * )
      COMPLEX*16         A( LDA, * ), ALPHA( * ), ALPHA1( * ),
     $                   b( lda, * ), beta( * ), beta1( * ),
     $                   q( ldq, * ), qe( ldqe, * ), s( lda, * ),
     $                   t( lda, * ), work( * ), z( ldq, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      PARAMETER          ( ZERO = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         CZERO, CONE
      parameter( czero = ( 0.0d+0, 0.0d+0 ),
     $                   cone = ( 1.0d+0, 0.0d+0 ) )
      INTEGER            MAXTYP
      parameter( maxtyp = 26 )
*     ..
*     .. Local Scalars ..
      LOGICAL            BADNN
      INTEGER            I, IADD, IERR, IN, J, JC, JR, JSIZE, JTYPE,
     $                   MAXWRK, MINWRK, MTYPES, N, N1, NB, NERRS,
     $                   nmats, nmax, ntestt
      DOUBLE PRECISION   SAFMAX, SAFMIN, ULP, ULPINV
      COMPLEX*16         CTEMP
*     ..
*     .. Local Arrays ..
      LOGICAL            LASIGN( MAXTYP ), LBSIGN( MAXTYP )
      INTEGER            IOLDSD( 4 ), KADD( 6 ), KAMAGN( MAXTYP ),
     $                   KATYPE( MAXTYP ), KAZERO( MAXTYP ),
     $                   kbmagn( maxtyp ), kbtype( maxtyp ),
     $                   kbzero( maxtyp ), kclass( maxtyp ),
     $                   ktrian( maxtyp ), kz1( 6 ), kz2( 6 )
      DOUBLE PRECISION   RMAGN( 0: 3 )
*     ..
*     .. External Functions ..
      INTEGER            ILAENV
      DOUBLE PRECISION   DLAMCH
      COMPLEX*16         ZLARND
      EXTERNAL           ilaenv, dlamch, zlarnd
*     ..
*     .. External Subroutines ..
      EXTERNAL           alasvm, dlabad, xerbla, zget52, zggev3, zlacpy,
     $                   zlarfg, zlaset, zlatm4, zunm2r
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, dble, dconjg, max, min, sign
*     ..
*     .. Data statements ..
      DATA               kclass / 15*1, 10*2, 1*3 /
      DATA               kz1 / 0, 1, 2, 1, 3, 3 /
      DATA               kz2 / 0, 0, 1, 2, 1, 1 /
      DATA               kadd / 0, 0, 0, 0, 3, 2 /
      DATA               katype / 0, 1, 0, 1, 2, 3, 4, 1, 4, 4, 1, 1, 4,
     $                   4, 4, 2, 4, 5, 8, 7, 9, 4*4, 0 /
      DATA               kbtype / 0, 0, 1, 1, 2, -3, 1, 4, 1, 1, 4, 4,
     $                   1, 1, -4, 2, -4, 8*8, 0 /
      DATA               kazero / 6*1, 2, 1, 2*2, 2*1, 2*2, 3, 1, 3,
     $                   4*5, 4*3, 1 /
      DATA               kbzero / 6*1, 1, 2, 2*1, 2*2, 2*1, 4, 1, 4,
     $                   4*6, 4*4, 1 /
      DATA               kamagn / 8*1, 2, 3, 2, 3, 2, 3, 7*1, 2, 3, 3,
     $                   2, 1 /
      DATA               kbmagn / 8*1, 3, 2, 3, 2, 2, 3, 7*1, 3, 2, 3,
     $                   2, 1 /
      DATA               ktrian / 16*0, 10*1 /
      DATA               lasign / 6*.false., .true., .false., 2*.true.,
     $                   2*.false., 3*.true., .false., .true.,
     $                   3*.false., 5*.true., .false. /
      DATA               lbsign / 7*.false., .true., 2*.false.,
     $                   2*.true., 2*.false., .true., .false., .true.,
     $                   9*.false. /
*     ..
*     .. Executable Statements ..
*
*     Check for errors
*
      info = 0
*
      badnn = .false.
      nmax = 1
      DO 10 j = 1, nsizes
         nmax = max( nmax, nn( j ) )
         IF( nn( j ).LT.0 )
     $      badnn = .true.
   10 CONTINUE
*
      IF( nsizes.LT.0 ) THEN
         info = -1
      ELSE IF( badnn ) THEN
         info = -2
      ELSE IF( ntypes.LT.0 ) THEN
         info = -3
      ELSE IF( thresh.LT.zero ) THEN
         info = -6
      ELSE IF( lda.LE.1 .OR. lda.LT.nmax ) THEN
         info = -9
      ELSE IF( ldq.LE.1 .OR. ldq.LT.nmax ) THEN
         info = -14
      ELSE IF( ldqe.LE.1 .OR. ldqe.LT.nmax ) THEN
         info = -17
      END IF
*
*     Compute workspace
*      (Note: Comments in the code beginning "Workspace:" describe the
*       minimal amount of workspace needed at that point in the code,
*       as well as the preferred amount for good performance.
*       NB refers to the optimal block size for the immediately
*       following subroutine, as returned by ILAENV.
*
      minwrk = 1
      IF( info.EQ.0 .AND. lwork.GE.1 ) THEN
         minwrk = nmax*( nmax+1 )
         nb = max( 1, ilaenv( 1, 'ZGEQRF', ' ', nmax, nmax, -1, -1 ),
     $        ilaenv( 1, 'ZUNMQR', 'LC', nmax, nmax, nmax, -1 ),
     $        ilaenv( 1, 'ZUNGQR', ' ', nmax, nmax, nmax, -1 ) )
         maxwrk = max( 2*nmax, nmax*( nb+1 ), nmax*( nmax+1 ) )
         work( 1 ) = maxwrk
      END IF
*
      IF( lwork.LT.minwrk )
     $   info = -23
*
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZDRGEV3', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( nsizes.EQ.0 .OR. ntypes.EQ.0 )
     $   RETURN
*
      ulp = dlamch( 'Precision' )
      safmin = dlamch( 'Safe minimum' )
      safmin = safmin / ulp
      safmax = one / safmin
      CALL dlabad( safmin, safmax )
      ulpinv = one / ulp
*
*     The values RMAGN(2:3) depend on N, see below.
*
      rmagn( 0 ) = zero
      rmagn( 1 ) = one
*
*     Loop over sizes, types
*
      ntestt = 0
      nerrs = 0
      nmats = 0
*
      DO 220 jsize = 1, nsizes
         n = nn( jsize )
         n1 = max( 1, n )
         rmagn( 2 ) = safmax*ulp / dble( n1 )
         rmagn( 3 ) = safmin*ulpinv*n1
*
         IF( nsizes.NE.1 ) THEN
            mtypes = min( maxtyp, ntypes )
         ELSE
            mtypes = min( maxtyp+1, ntypes )
         END IF
*
         DO 210 jtype = 1, mtypes
            IF( .NOT.dotype( jtype ) )
     $         GO TO 210
            nmats = nmats + 1
*
*           Save ISEED in case of an error.
*
            DO 20 j = 1, 4
               ioldsd( j ) = iseed( j )
   20       CONTINUE
*
*           Generate test matrices A and B
*
*           Description of control parameters:
*
*           KZLASS: =1 means w/o rotation, =2 means w/ rotation,
*                   =3 means random.
*           KATYPE: the "type" to be passed to ZLATM4 for computing A.
*           KAZERO: the pattern of zeros on the diagonal for A:
*                   =1: ( xxx ), =2: (0, xxx ) =3: ( 0, 0, xxx, 0 ),
*                   =4: ( 0, xxx, 0, 0 ), =5: ( 0, 0, 1, xxx, 0 ),
*                   =6: ( 0, 1, 0, xxx, 0 ).  (xxx means a string of
*                   non-zero entries.)
*           KAMAGN: the magnitude of the matrix: =0: zero, =1: O(1),
*                   =2: large, =3: small.
*           LASIGN: .TRUE. if the diagonal elements of A are to be
*                   multiplied by a random magnitude 1 number.
*           KBTYPE, KBZERO, KBMAGN, LBSIGN: the same, but for B.
*           KTRIAN: =0: don't fill in the upper triangle, =1: do.
*           KZ1, KZ2, KADD: used to implement KAZERO and KBZERO.
*           RMAGN: used to implement KAMAGN and KBMAGN.
*
            IF( mtypes.GT.maxtyp )
     $         GO TO 100
            ierr = 0
            IF( kclass( jtype ).LT.3 ) THEN
*
*              Generate A (w/o rotation)
*
               IF( abs( katype( jtype ) ).EQ.3 ) THEN
                  in = 2*( ( n-1 ) / 2 ) + 1
                  IF( in.NE.n )
     $               CALL zlaset( 'Full', n, n, czero, czero, a, lda )
               ELSE
                  in = n
               END IF
               CALL zlatm4( katype( jtype ), in, kz1( kazero( jtype ) ),
     $                      kz2( kazero( jtype ) ), lasign( jtype ),
     $                      rmagn( kamagn( jtype ) ), ulp,
     $                      rmagn( ktrian( jtype )*kamagn( jtype ) ), 2,
     $                      iseed, a, lda )
               iadd = kadd( kazero( jtype ) )
               IF( iadd.GT.0 .AND. iadd.LE.n )
     $            a( iadd, iadd ) = rmagn( kamagn( jtype ) )
*
*              Generate B (w/o rotation)
*
               IF( abs( kbtype( jtype ) ).EQ.3 ) THEN
                  in = 2*( ( n-1 ) / 2 ) + 1
                  IF( in.NE.n )
     $               CALL zlaset( 'Full', n, n, czero, czero, b, lda )
               ELSE
                  in = n
               END IF
               CALL zlatm4( kbtype( jtype ), in, kz1( kbzero( jtype ) ),
     $                      kz2( kbzero( jtype ) ), lbsign( jtype ),
     $                      rmagn( kbmagn( jtype ) ), one,
     $                      rmagn( ktrian( jtype )*kbmagn( jtype ) ), 2,
     $                      iseed, b, lda )
               iadd = kadd( kbzero( jtype ) )
               IF( iadd.NE.0 .AND. iadd.LE.n )
     $            b( iadd, iadd ) = rmagn( kbmagn( jtype ) )
*
               IF( kclass( jtype ).EQ.2 .AND. n.GT.0 ) THEN
*
*                 Include rotations
*
*                 Generate Q, Z as Householder transformations times
*                 a diagonal matrix.
*
                  DO 40 jc = 1, n - 1
                     DO 30 jr = jc, n
                        q( jr, jc ) = zlarnd( 3, iseed )
                        z( jr, jc ) = zlarnd( 3, iseed )
   30                CONTINUE
                     CALL zlarfg( n+1-jc, q( jc, jc ), q( jc+1, jc ), 1,
     $                            work( jc ) )
                     work( 2*n+jc ) = sign( one, dble( q( jc, jc ) ) )
                     q( jc, jc ) = cone
                     CALL zlarfg( n+1-jc, z( jc, jc ), z( jc+1, jc ), 1,
     $                            work( n+jc ) )
                     work( 3*n+jc ) = sign( one, dble( z( jc, jc ) ) )
                     z( jc, jc ) = cone
   40             CONTINUE
                  ctemp = zlarnd( 3, iseed )
                  q( n, n ) = cone
                  work( n ) = czero
                  work( 3*n ) = ctemp / abs( ctemp )
                  ctemp = zlarnd( 3, iseed )
                  z( n, n ) = cone
                  work( 2*n ) = czero
                  work( 4*n ) = ctemp / abs( ctemp )
*
*                 Apply the diagonal matrices
*
                  DO 60 jc = 1, n
                     DO 50 jr = 1, n
                        a( jr, jc ) = work( 2*n+jr )*
     $                                dconjg( work( 3*n+jc ) )*
     $                                a( jr, jc )
                        b( jr, jc ) = work( 2*n+jr )*
     $                                dconjg( work( 3*n+jc ) )*
     $                                b( jr, jc )
   50                CONTINUE
   60             CONTINUE
                  CALL zunm2r( 'L', 'N', n, n, n-1, q, ldq, work, a,
     $                         lda, work( 2*n+1 ), ierr )
                  IF( ierr.NE.0 )
     $               GO TO 90
                  CALL zunm2r( 'R', 'C', n, n, n-1, z, ldq, work( n+1 ),
     $                         a, lda, work( 2*n+1 ), ierr )
                  IF( ierr.NE.0 )
     $               GO TO 90
                  CALL zunm2r( 'L', 'N', n, n, n-1, q, ldq, work, b,
     $                         lda, work( 2*n+1 ), ierr )
                  IF( ierr.NE.0 )
     $               GO TO 90
                  CALL zunm2r( 'R', 'C', n, n, n-1, z, ldq, work( n+1 ),
     $                         b, lda, work( 2*n+1 ), ierr )
                  IF( ierr.NE.0 )
     $               GO TO 90
               END IF
            ELSE
*
*              Random matrices
*
               DO 80 jc = 1, n
                  DO 70 jr = 1, n
                     a( jr, jc ) = rmagn( kamagn( jtype ) )*
     $                             zlarnd( 4, iseed )
                     b( jr, jc ) = rmagn( kbmagn( jtype ) )*
     $                             zlarnd( 4, iseed )
   70             CONTINUE
   80          CONTINUE
            END IF
*
   90       CONTINUE
*
            IF( ierr.NE.0 ) THEN
               WRITE( nounit, fmt = 9999 )'Generator', ierr, n, jtype,
     $            ioldsd
               info = abs( ierr )
               RETURN
            END IF
*
  100       CONTINUE
*
            DO 110 i = 1, 7
               result( i ) = -one
  110       CONTINUE
*
*           Call XLAENV to set the parameters used in ZLAQZ0
*
            CALL xlaenv( 12, 10 )
            CALL xlaenv( 13, 12 )
            CALL xlaenv( 14, 13 )
            CALL xlaenv( 15, 2 )
            CALL xlaenv( 17, 10 )
*
*           Call ZGGEV3 to compute eigenvalues and eigenvectors.
*
            CALL zlacpy( ' ', n, n, a, lda, s, lda )
            CALL zlacpy( ' ', n, n, b, lda, t, lda )
            CALL zggev3( 'V', 'V', n, s, lda, t, lda, alpha, beta, q,
     $                   ldq, z, ldq, work, lwork, rwork, ierr )
            IF( ierr.NE.0 .AND. ierr.NE.n+1 ) THEN
               result( 1 ) = ulpinv
               WRITE( nounit, fmt = 9999 )'ZGGEV31', ierr, n, jtype,
     $            ioldsd
               info = abs( ierr )
               GO TO 190
            END IF
*
*           Do the tests (1) and (2)
*
            CALL zget52( .true., n, a, lda, b, lda, q, ldq, alpha, beta,
     $                   work, rwork, result( 1 ) )
            IF( result( 2 ).GT.thresh ) THEN
               WRITE( nounit, fmt = 9998 )'Left', 'ZGGEV31',
     $            result( 2 ), n, jtype, ioldsd
            END IF
*
*           Do the tests (3) and (4)
*
            CALL zget52( .false., n, a, lda, b, lda, z, ldq, alpha,
     $                   beta, work, rwork, result( 3 ) )
            IF( result( 4 ).GT.thresh ) THEN
               WRITE( nounit, fmt = 9998 )'Right', 'ZGGEV31',
     $            result( 4 ), n, jtype, ioldsd
            END IF
*
*           Do test (5)
*
            CALL zlacpy( ' ', n, n, a, lda, s, lda )
            CALL zlacpy( ' ', n, n, b, lda, t, lda )
            CALL zggev3( 'N', 'N', n, s, lda, t, lda, alpha1, beta1, q,
     $                   ldq, z, ldq, work, lwork, rwork, ierr )
            IF( ierr.NE.0 .AND. ierr.NE.n+1 ) THEN
               result( 1 ) = ulpinv
               WRITE( nounit, fmt = 9999 )'ZGGEV32', ierr, n, jtype,
     $            ioldsd
               info = abs( ierr )
               GO TO 190
            END IF
*
            DO 120 j = 1, n
               IF( alpha( j ).NE.alpha1( j ) .OR. beta( j ).NE.
     $             beta1( j ) )result( 5 ) = ulpinv
  120       CONTINUE
*
*           Do test (6): Compute eigenvalues and left eigenvectors,
*           and test them
*
            CALL zlacpy( ' ', n, n, a, lda, s, lda )
            CALL zlacpy( ' ', n, n, b, lda, t, lda )
            CALL zggev3( 'V', 'N', n, s, lda, t, lda, alpha1, beta1, qe,
     $                   ldqe, z, ldq, work, lwork, rwork, ierr )
            IF( ierr.NE.0 .AND. ierr.NE.n+1 ) THEN
               result( 1 ) = ulpinv
               WRITE( nounit, fmt = 9999 )'ZGGEV33', ierr, n, jtype,
     $            ioldsd
               info = abs( ierr )
               GO TO 190
            END IF
*
            DO 130 j = 1, n
               IF( alpha( j ).NE.alpha1( j ) .OR. beta( j ).NE.
     $             beta1( j ) )result( 6 ) = ulpinv
  130       CONTINUE
*
            DO 150 j = 1, n
               DO 140 jc = 1, n
                  IF( q( j, jc ).NE.qe( j, jc ) )
     $               result( 6 ) = ulpinv
  140          CONTINUE
  150       CONTINUE
*
*           Do test (7): Compute eigenvalues and right eigenvectors,
*           and test them
*
            CALL zlacpy( ' ', n, n, a, lda, s, lda )
            CALL zlacpy( ' ', n, n, b, lda, t, lda )
            CALL zggev3( 'N', 'V', n, s, lda, t, lda, alpha1, beta1, q,
     $                   ldq, qe, ldqe, work, lwork, rwork, ierr )
            IF( ierr.NE.0 .AND. ierr.NE.n+1 ) THEN
               result( 1 ) = ulpinv
               WRITE( nounit, fmt = 9999 )'ZGGEV34', ierr, n, jtype,
     $            ioldsd
               info = abs( ierr )
               GO TO 190
            END IF
*
            DO 160 j = 1, n
               IF( alpha( j ).NE.alpha1( j ) .OR. beta( j ).NE.
     $             beta1( j ) )result( 7 ) = ulpinv
  160       CONTINUE
*
            DO 180 j = 1, n
               DO 170 jc = 1, n
                  IF( z( j, jc ).NE.qe( j, jc ) )
     $               result( 7 ) = ulpinv
  170          CONTINUE
  180       CONTINUE
*
*           End of Loop -- Check for RESULT(j) > THRESH
*
  190       CONTINUE
*
            ntestt = ntestt + 7
*
*           Print out tests which fail.
*
            DO 200 jr = 1, 7
               IF( result( jr ).GE.thresh ) THEN
*
*                 If this is the first test to fail,
*                 print a header to the data file.
*
                  IF( nerrs.EQ.0 ) THEN
                     WRITE( nounit, fmt = 9997 )'ZGV'
*
*                    Matrix types
*
                     WRITE( nounit, fmt = 9996 )
                     WRITE( nounit, fmt = 9995 )
                     WRITE( nounit, fmt = 9994 )'Orthogonal'
*
*                    Tests performed
*
                     WRITE( nounit, fmt = 9993 )
*
                  END IF
                  nerrs = nerrs + 1
                  IF( result( jr ).LT.10000.0d0 ) THEN
                     WRITE( nounit, fmt = 9992 )n, jtype, ioldsd, jr,
     $                  result( jr )
                  ELSE
                     WRITE( nounit, fmt = 9991 )n, jtype, ioldsd, jr,
     $                  result( jr )
                  END IF
               END IF
  200       CONTINUE
*
  210    CONTINUE
  220 CONTINUE
*
*     Summary
*
      CALL alasvm( 'ZGV3', nounit, nerrs, ntestt, 0 )
*
      work( 1 ) = maxwrk
*
      RETURN
*
 9999 FORMAT( ' ZDRGEV3: ', a, ' returned INFO=', i6, '.', / 3x, 'N=',
     $      i6, ', JTYPE=', i6, ', ISEED=(', 3( i5, ',' ), i5, ')' )
*
 9998 FORMAT( ' ZDRGEV3: ', a, ' Eigenvectors from ', a,
     $      ' incorrectly normalized.', / ' Bits of error=', 0p, g10.3,
     $      ',', 3x, 'N=', i4, ', JTYPE=', i3, ', ISEED=(',
     $       3( i4, ',' ), i5, ')' )
*
 9997 FORMAT( / 1x, a3, ' -- Complex Generalized eigenvalue problem ',
     $      'driver' )
*
 9996 FORMAT( ' Matrix types (see ZDRGEV3 for details): ' )
*
 9995 FORMAT( ' Special Matrices:', 23x,
     $      '(J''=transposed Jordan block)',
     $      / '   1=(0,0)  2=(I,0)  3=(0,I)  4=(I,I)  5=(J'',J'')  ',
     $      '6=(diag(J'',I), diag(I,J''))', / ' Diagonal Matrices:  ( ',
     $      'D=diag(0,1,2,...) )', / '   7=(D,I)   9=(large*D, small*I',
     $      ')  11=(large*I, small*D)  13=(large*D, large*I)', /
     $      '   8=(I,D)  10=(small*D, large*I)  12=(small*I, large*D) ',
     $      ' 14=(small*D, small*I)', / '  15=(D, reversed D)' )
 9994 FORMAT( ' Matrices Rotated by Random ', a, ' Matrices U, V:',
     $      / '  16=Transposed Jordan Blocks             19=geometric ',
     $      'alpha, beta=0,1', / '  17=arithm. alpha&beta             ',
     $      '      20=arithmetic alpha, beta=0,1', / '  18=clustered ',
     $      'alpha, beta=0,1            21=random alpha, beta=0,1',
     $      / ' Large & Small Matrices:', / '  22=(large, small)   ',
     $      '23=(small,large)    24=(small,small)    25=(large,large)',
     $      / '  26=random O(1) matrices.' )
*
 9993 FORMAT( / ' Tests performed:    ',
     $      / ' 1 = max | ( b A - a B )''*l | / const.,',
     $      / ' 2 = | |VR(i)| - 1 | / ulp,',
     $      / ' 3 = max | ( b A - a B )*r | / const.',
     $      / ' 4 = | |VL(i)| - 1 | / ulp,',
     $      / ' 5 = 0 if W same no matter if r or l computed,',
     $      / ' 6 = 0 if l same no matter if l computed,',
     $      / ' 7 = 0 if r same no matter if r computed,', / 1x )
 9992 FORMAT( ' Matrix order=', i5, ', type=', i2, ', seed=',
     $      4( i4, ',' ), ' result ', i2, ' is', 0p, f8.2 )
 9991 FORMAT( ' Matrix order=', i5, ', type=', i2, ', seed=',
     $      4( i4, ',' ), ' result ', i2, ' is', 1p, d10.3 )
*
*     End of ZDRGEV3
*
      END