LAPACK  3.10.1
LAPACK: Linear Algebra PACKage
zlamswlq.f
Go to the documentation of this file.
1 *> \brief \b ZLAMSWLQ
2 *
3 * Definition:
4 * ===========
5 *
6 * SUBROUTINE ZLAMSWLQ( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T,
7 * $ LDT, C, LDC, WORK, LWORK, INFO )
8 *
9 *
10 * .. Scalar Arguments ..
11 * CHARACTER SIDE, TRANS
12 * INTEGER INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
13 * ..
14 * .. Array Arguments ..
15 * COMPLEX*16 A( LDA, * ), WORK( * ), C(LDC, * ),
16 * $ T( LDT, * )
17 *> \par Purpose:
18 * =============
19 *>
20 *> \verbatim
21 *>
22 *> ZLAMSWLQ overwrites the general complex M-by-N matrix C with
23 *>
24 *>
25 *> SIDE = 'L' SIDE = 'R'
26 *> TRANS = 'N': Q * C C * Q
27 *> TRANS = 'C': Q**H * C C * Q**H
28 *> where Q is a complex unitary matrix defined as the product of blocked
29 *> elementary reflectors computed by short wide LQ
30 *> factorization (ZLASWLQ)
31 *> \endverbatim
32 *
33 * Arguments:
34 * ==========
35 *
36 *> \param[in] SIDE
37 *> \verbatim
38 *> SIDE is CHARACTER*1
39 *> = 'L': apply Q or Q**H from the Left;
40 *> = 'R': apply Q or Q**H from the Right.
41 *> \endverbatim
42 *>
43 *> \param[in] TRANS
44 *> \verbatim
45 *> TRANS is CHARACTER*1
46 *> = 'N': No transpose, apply Q;
47 *> = 'C': Conjugate Transpose, apply Q**H.
48 *> \endverbatim
49 *>
50 *> \param[in] M
51 *> \verbatim
52 *> M is INTEGER
53 *> The number of rows of the matrix C. M >=0.
54 *> \endverbatim
55 *>
56 *> \param[in] N
57 *> \verbatim
58 *> N is INTEGER
59 *> The number of columns of the matrix C. N >= 0.
60 *> \endverbatim
61 *>
62 *> \param[in] K
63 *> \verbatim
64 *> K is INTEGER
65 *> The number of elementary reflectors whose product defines
66 *> the matrix Q.
67 *> M >= K >= 0;
68 *>
69 *> \endverbatim
70 *> \param[in] MB
71 *> \verbatim
72 *> MB is INTEGER
73 *> The row block size to be used in the blocked LQ.
74 *> M >= MB >= 1
75 *> \endverbatim
76 *>
77 *> \param[in] NB
78 *> \verbatim
79 *> NB is INTEGER
80 *> The column block size to be used in the blocked LQ.
81 *> NB > M.
82 *> \endverbatim
83 *>
84 *> \param[in] A
85 *> \verbatim
86 *> A is COMPLEX*16 array, dimension
87 *> (LDA,M) if SIDE = 'L',
88 *> (LDA,N) if SIDE = 'R'
89 *> The i-th row must contain the vector which defines the blocked
90 *> elementary reflector H(i), for i = 1,2,...,k, as returned by
91 *> ZLASWLQ in the first k rows of its array argument A.
92 *> \endverbatim
93 *>
94 *> \param[in] LDA
95 *> \verbatim
96 *> LDA is INTEGER
97 *> The leading dimension of the array A. LDA >= MAX(1,K).
98 *> \endverbatim
99 *>
100 *> \param[in] T
101 *> \verbatim
102 *> T is COMPLEX*16 array, dimension
103 *> ( M * Number of blocks(CEIL(N-K/NB-K)),
104 *> The blocked upper triangular block reflectors stored in compact form
105 *> as a sequence of upper triangular blocks. See below
106 *> for further details.
107 *> \endverbatim
108 *>
109 *> \param[in] LDT
110 *> \verbatim
111 *> LDT is INTEGER
112 *> The leading dimension of the array T. LDT >= MB.
113 *> \endverbatim
114 *>
115 *> \param[in,out] C
116 *> \verbatim
117 *> C is COMPLEX*16 array, dimension (LDC,N)
118 *> On entry, the M-by-N matrix C.
119 *> On exit, C is overwritten by Q*C or Q**H*C or C*Q**H or C*Q.
120 *> \endverbatim
121 *>
122 *> \param[in] LDC
123 *> \verbatim
124 *> LDC is INTEGER
125 *> The leading dimension of the array C. LDC >= max(1,M).
126 *> \endverbatim
127 *>
128 *> \param[out] WORK
129 *> \verbatim
130 *> (workspace) COMPLEX*16 array, dimension (MAX(1,LWORK))
131 *> \endverbatim
132 *>
133 *> \param[in] LWORK
134 *> \verbatim
135 *> LWORK is INTEGER
136 *> The dimension of the array WORK.
137 *> If SIDE = 'L', LWORK >= max(1,NB) * MB;
138 *> if SIDE = 'R', LWORK >= max(1,M) * MB.
139 *> If LWORK = -1, then a workspace query is assumed; the routine
140 *> only calculates the optimal size of the WORK array, returns
141 *> this value as the first entry of the WORK array, and no error
142 *> message related to LWORK is issued by XERBLA.
143 *> \endverbatim
144 *>
145 *> \param[out] INFO
146 *> \verbatim
147 *> INFO is INTEGER
148 *> = 0: successful exit
149 *> < 0: if INFO = -i, the i-th argument had an illegal value
150 *> \endverbatim
151 *
152 * Authors:
153 * ========
154 *
155 *> \author Univ. of Tennessee
156 *> \author Univ. of California Berkeley
157 *> \author Univ. of Colorado Denver
158 *> \author NAG Ltd.
159 *
160 *> \par Further Details:
161 * =====================
162 *>
163 *> \verbatim
164 *> Short-Wide LQ (SWLQ) performs LQ by a sequence of unitary transformations,
165 *> representing Q as a product of other unitary matrices
166 *> Q = Q(1) * Q(2) * . . . * Q(k)
167 *> where each Q(i) zeros out upper diagonal entries of a block of NB rows of A:
168 *> Q(1) zeros out the upper diagonal entries of rows 1:NB of A
169 *> Q(2) zeros out the bottom MB-N rows of rows [1:M,NB+1:2*NB-M] of A
170 *> Q(3) zeros out the bottom MB-N rows of rows [1:M,2*NB-M+1:3*NB-2*M] of A
171 *> . . .
172 *>
173 *> Q(1) is computed by GELQT, which represents Q(1) by Householder vectors
174 *> stored under the diagonal of rows 1:MB of A, and by upper triangular
175 *> block reflectors, stored in array T(1:LDT,1:N).
176 *> For more information see Further Details in GELQT.
177 *>
178 *> Q(i) for i>1 is computed by TPLQT, which represents Q(i) by Householder vectors
179 *> stored in columns [(i-1)*(NB-M)+M+1:i*(NB-M)+M] of A, and by upper triangular
180 *> block reflectors, stored in array T(1:LDT,(i-1)*M+1:i*M).
181 *> The last Q(k) may use fewer rows.
182 *> For more information see Further Details in TPLQT.
183 *>
184 *> For more details of the overall algorithm, see the description of
185 *> Sequential TSQR in Section 2.2 of [1].
186 *>
187 *> [1] “Communication-Optimal Parallel and Sequential QR and LU Factorizations,”
188 *> J. Demmel, L. Grigori, M. Hoemmen, J. Langou,
189 *> SIAM J. Sci. Comput, vol. 34, no. 1, 2012
190 *> \endverbatim
191 *>
192 * =====================================================================
193  SUBROUTINE zlamswlq( SIDE, TRANS, M, N, K, MB, NB, A, LDA, T,
194  $ LDT, C, LDC, WORK, LWORK, INFO )
195 *
196 * -- LAPACK computational routine --
197 * -- LAPACK is a software package provided by Univ. of Tennessee, --
198 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
199 *
200 * .. Scalar Arguments ..
201  CHARACTER SIDE, TRANS
202  INTEGER INFO, LDA, M, N, K, MB, NB, LDT, LWORK, LDC
203 * ..
204 * .. Array Arguments ..
205  COMPLEX*16 A( LDA, * ), WORK( * ), C(LDC, * ),
206  $ t( ldt, * )
207 * ..
208 *
209 * =====================================================================
210 *
211 * ..
212 * .. Local Scalars ..
213  LOGICAL LEFT, RIGHT, TRAN, NOTRAN, LQUERY
214  INTEGER I, II, KK, LW, CTR
215 * ..
216 * .. External Functions ..
217  LOGICAL LSAME
218  EXTERNAL lsame
219 * .. External Subroutines ..
220  EXTERNAL ztpmlqt, zgemlqt, xerbla
221 * ..
222 * .. Executable Statements ..
223 *
224 * Test the input arguments
225 *
226  lquery = lwork.LT.0
227  notran = lsame( trans, 'N' )
228  tran = lsame( trans, 'C' )
229  left = lsame( side, 'L' )
230  right = lsame( side, 'R' )
231  IF (left) THEN
232  lw = n * mb
233  ELSE
234  lw = m * mb
235  END IF
236 *
237  info = 0
238  IF( .NOT.left .AND. .NOT.right ) THEN
239  info = -1
240  ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
241  info = -2
242  ELSE IF( k.LT.0 ) THEN
243  info = -5
244  ELSE IF( m.LT.k ) THEN
245  info = -3
246  ELSE IF( n.LT.0 ) THEN
247  info = -4
248  ELSE IF( k.LT.mb .OR. mb.LT.1) THEN
249  info = -6
250  ELSE IF( lda.LT.max( 1, k ) ) THEN
251  info = -9
252  ELSE IF( ldt.LT.max( 1, mb) ) THEN
253  info = -11
254  ELSE IF( ldc.LT.max( 1, m ) ) THEN
255  info = -13
256  ELSE IF(( lwork.LT.max(1,lw)).AND.(.NOT.lquery)) THEN
257  info = -15
258  END IF
259 *
260  IF( info.NE.0 ) THEN
261  CALL xerbla( 'ZLAMSWLQ', -info )
262  work(1) = lw
263  RETURN
264  ELSE IF (lquery) THEN
265  work(1) = lw
266  RETURN
267  END IF
268 *
269 * Quick return if possible
270 *
271  IF( min(m,n,k).EQ.0 ) THEN
272  RETURN
273  END IF
274 *
275  IF((nb.LE.k).OR.(nb.GE.max(m,n,k))) THEN
276  CALL zgemlqt( side, trans, m, n, k, mb, a, lda,
277  $ t, ldt, c, ldc, work, info)
278  RETURN
279  END IF
280 *
281  IF(left.AND.tran) THEN
282 *
283 * Multiply Q to the last block of C
284 *
285  kk = mod((m-k),(nb-k))
286  ctr = (m-k)/(nb-k)
287 *
288  IF (kk.GT.0) THEN
289  ii=m-kk+1
290  CALL ztpmlqt('L','C',kk , n, k, 0, mb, a(1,ii), lda,
291  $ t(1,ctr*k+1), ldt, c(1,1), ldc,
292  $ c(ii,1), ldc, work, info )
293  ELSE
294  ii=m+1
295  END IF
296 *
297  DO i=ii-(nb-k),nb+1,-(nb-k)
298 *
299 * Multiply Q to the current block of C (1:M,I:I+NB)
300 *
301  ctr = ctr - 1
302  CALL ztpmlqt('L','C',nb-k , n, k, 0,mb, a(1,i), lda,
303  $ t(1,ctr*k+1),ldt, c(1,1), ldc,
304  $ c(i,1), ldc, work, info )
305 
306  END DO
307 *
308 * Multiply Q to the first block of C (1:M,1:NB)
309 *
310  CALL zgemlqt('L','C',nb , n, k, mb, a(1,1), lda, t
311  $ ,ldt ,c(1,1), ldc, work, info )
312 *
313  ELSE IF (left.AND.notran) THEN
314 *
315 * Multiply Q to the first block of C
316 *
317  kk = mod((m-k),(nb-k))
318  ii=m-kk+1
319  ctr = 1
320  CALL zgemlqt('L','N',nb , n, k, mb, a(1,1), lda, t
321  $ ,ldt ,c(1,1), ldc, work, info )
322 *
323  DO i=nb+1,ii-nb+k,(nb-k)
324 *
325 * Multiply Q to the current block of C (I:I+NB,1:N)
326 *
327  CALL ztpmlqt('L','N',nb-k , n, k, 0,mb, a(1,i), lda,
328  $ t(1, ctr * k + 1), ldt, c(1,1), ldc,
329  $ c(i,1), ldc, work, info )
330  ctr = ctr + 1
331 *
332  END DO
333  IF(ii.LE.m) THEN
334 *
335 * Multiply Q to the last block of C
336 *
337  CALL ztpmlqt('L','N',kk , n, k, 0, mb, a(1,ii), lda,
338  $ t(1, ctr * k + 1), ldt, c(1,1), ldc,
339  $ c(ii,1), ldc, work, info )
340 *
341  END IF
342 *
343  ELSE IF(right.AND.notran) THEN
344 *
345 * Multiply Q to the last block of C
346 *
347  kk = mod((n-k),(nb-k))
348  ctr = (n-k)/(nb-k)
349  IF (kk.GT.0) THEN
350  ii=n-kk+1
351  CALL ztpmlqt('R','N',m , kk, k, 0, mb, a(1, ii), lda,
352  $ t(1, ctr * k + 1), ldt, c(1,1), ldc,
353  $ c(1,ii), ldc, work, info )
354  ELSE
355  ii=n+1
356  END IF
357 *
358  DO i=ii-(nb-k),nb+1,-(nb-k)
359 *
360 * Multiply Q to the current block of C (1:M,I:I+MB)
361 *
362  ctr = ctr - 1
363  CALL ztpmlqt('R','N', m, nb-k, k, 0, mb, a(1, i), lda,
364  $ t(1, ctr * k + 1), ldt, c(1,1), ldc,
365  $ c(1,i), ldc, work, info )
366 
367  END DO
368 *
369 * Multiply Q to the first block of C (1:M,1:MB)
370 *
371  CALL zgemlqt('R','N',m , nb, k, mb, a(1,1), lda, t
372  $ ,ldt ,c(1,1), ldc, work, info )
373 *
374  ELSE IF (right.AND.tran) THEN
375 *
376 * Multiply Q to the first block of C
377 *
378  kk = mod((n-k),(nb-k))
379  ii=n-kk+1
380  CALL zgemlqt('R','C',m , nb, k, mb, a(1,1), lda, t
381  $ ,ldt ,c(1,1), ldc, work, info )
382  ctr = 1
383 *
384  DO i=nb+1,ii-nb+k,(nb-k)
385 *
386 * Multiply Q to the current block of C (1:M,I:I+MB)
387 *
388  CALL ztpmlqt('R','C',m , nb-k, k, 0,mb, a(1,i), lda,
389  $ t(1,ctr *k+1), ldt, c(1,1), ldc,
390  $ c(1,i), ldc, work, info )
391  ctr = ctr + 1
392 *
393  END DO
394  IF(ii.LE.n) THEN
395 *
396 * Multiply Q to the last block of C
397 *
398  CALL ztpmlqt('R','C',m , kk, k, 0,mb, a(1,ii), lda,
399  $ t(1, ctr * k + 1),ldt, c(1,1), ldc,
400  $ c(1,ii), ldc, work, info )
401 *
402  END IF
403 *
404  END IF
405 *
406  work(1) = lw
407  RETURN
408 *
409 * End of ZLAMSWLQ
410 *
411  END
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:60
zgemlqt
subroutine zgemlqt(SIDE, TRANS, M, N, K, MB, V, LDV, T, LDT, C, LDC, WORK, INFO)
ZGEMLQT
Definition: zgemlqt.f:168
ztpmlqt
subroutine ztpmlqt(SIDE, TRANS, M, N, K, L, MB, V, LDV, T, LDT, A, LDA, B, LDB, WORK, INFO)
ZTPMLQT
Definition: ztpmlqt.f:214
zlamswlq
subroutine zlamswlq(SIDE, TRANS, M, N, K, MB, NB, A, LDA, T, LDT, C, LDC, WORK, LWORK, INFO)
ZLAMSWLQ
Definition: zlamswlq.f:195