sbdt04.f

Go to the documentation of this file.

*> \brief \b SBDT04
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SBDT04( UPLO, N, D, E, S, NS, U, LDU, VT, LDVT,
*                          WORK, RESID )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            LDU, LDVT, N, NS
*       REAL               RESID
*       ..
*       .. Array Arguments ..
*       REAL               D( * ), E( * ), S( * ), U( LDU, * ),
*      $                   VT( LDVT, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SBDT04 reconstructs a bidiagonal matrix B from its (partial) SVD:
*>    S = U' * B * V
*> where U and V are orthogonal matrices and S is diagonal.
*>
*> The test ratio to test the singular value decomposition is
*>    RESID = norm( S - U' * B * V ) / ( n * norm(B) * EPS )
*> where VT = V' and EPS is the machine precision.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the matrix B is upper or lower bidiagonal.
*>          = 'U':  Upper bidiagonal
*>          = 'L':  Lower bidiagonal
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix B.
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*>          D is REAL array, dimension (N)
*>          The n diagonal elements of the bidiagonal matrix B.
*> \endverbatim
*>
*> \param[in] E
*> \verbatim
*>          E is REAL array, dimension (N-1)
*>          The (n-1) superdiagonal elements of the bidiagonal matrix B
*>          if UPLO = 'U', or the (n-1) subdiagonal elements of B if
*>          UPLO = 'L'.
*> \endverbatim
*>
*> \param[in] S
*> \verbatim
*>          S is REAL array, dimension (NS)
*>          The singular values from the (partial) SVD of B, sorted in
*>          decreasing order.
*> \endverbatim
*>
*> \param[in] NS
*> \verbatim
*>          NS is INTEGER
*>          The number of singular values/vectors from the (partial)
*>          SVD of B.
*> \endverbatim
*>
*> \param[in] U
*> \verbatim
*>          U is REAL array, dimension (LDU,NS)
*>          The n by ns orthogonal matrix U in S = U' * B * V.
*> \endverbatim
*>
*> \param[in] LDU
*> \verbatim
*>          LDU is INTEGER
*>          The leading dimension of the array U.  LDU >= max(1,N)
*> \endverbatim
*>
*> \param[in] VT
*> \verbatim
*>          VT is REAL array, dimension (LDVT,N)
*>          The n by ns orthogonal matrix V in S = U' * B * V.
*> \endverbatim
*>
*> \param[in] LDVT
*> \verbatim
*>          LDVT is INTEGER
*>          The leading dimension of the array VT.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (2*N)
*> \endverbatim
*>
*> \param[out] RESID
*> \verbatim
*>          RESID is REAL
*>          The test ratio:  norm(S - U' * B * V) / ( n * norm(B) * EPS )
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \ingroup double_eig
*
*  =====================================================================
      SUBROUTINE sbdt04( UPLO, N, D, E, S, NS, U, LDU, VT, LDVT, WORK,
     $                   RESID )
*
*  -- LAPACK test routine --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            LDU, LDVT, N, NS
      REAL               RESID
*     ..
*     .. Array Arguments ..
      REAL               D( * ), E( * ), S( * ), U( LDU, * ),
     $                   vt( ldvt, * ), work( * )
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, K
      REAL               BNORM, EPS
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ISAMAX
      REAL               SASUM, SLAMCH
      EXTERNAL           lsame, isamax, sasum, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, real, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible.
*
      resid = zero
      IF( n.LE.0 .OR. ns.LE.0 )
     $   RETURN
*
      eps = slamch( 'Precision' )
*
*     Compute S - U' * B * V.
*
      bnorm = zero
*
      IF( lsame( uplo, 'U' ) ) THEN
*
*        B is upper bidiagonal.
*
         k = 0
         DO 20 i = 1, ns
            DO 10 j = 1, n-1
               k = k + 1
               work( k ) = d( j )*vt( i, j ) + e( j )*vt( i, j+1 )
   10       CONTINUE
            k = k + 1
            work( k ) = d( n )*vt( i, n )
   20    CONTINUE
         bnorm = abs( d( 1 ) )
         DO 30 i = 2, n
            bnorm = max( bnorm, abs( d( i ) )+abs( e( i-1 ) ) )
   30    CONTINUE
      ELSE
*
*        B is lower bidiagonal.
*
         k = 0
         DO 50 i = 1, ns
            k = k + 1
            work( k ) = d( 1 )*vt( i, 1 )
            DO 40 j = 1, n-1
               k = k + 1
               work( k ) = e( j )*vt( i, j ) + d( j+1 )*vt( i, j+1 )
   40       CONTINUE
   50    CONTINUE
         bnorm = abs( d( n ) )
         DO 60 i = 1, n-1
            bnorm = max( bnorm, abs( d( i ) )+abs( e( i ) ) )
   60    CONTINUE
      END IF
*
      CALL sgemm( 'T', 'N', ns, ns, n, -one, u, ldu, work( 1 ),
     $            n, zero, work( 1+n*ns ), ns )
*
*     norm(S - U' * B * V)
*
      k = n*ns
      DO 70 i = 1, ns
         work( k+i ) =  work( k+i ) + s( i )
         resid = max( resid, sasum( ns, work( k+1 ), 1 ) )
         k = k + ns
   70 CONTINUE
*
      IF( bnorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         IF( bnorm.GE.resid ) THEN
            resid = ( resid / bnorm ) / ( real( n )*eps )
         ELSE
            IF( bnorm.LT.one ) THEN
               resid = ( min( resid, real( n )*bnorm ) / bnorm ) /
     $                 ( real( n )*eps )
            ELSE
               resid = min( resid / bnorm, real( n ) ) /
     $                 ( real( n )*eps )
            END IF
         END IF
      END IF
*
      RETURN
*
*     End of SBDT04
*
      END